Télécharger ther3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : ther3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************
  6. * Test ther3.dgibi: jeux de données *
  7. * --------------------------------- *
  8. *******************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18. OPTI ECHO 1 ;
  19. OPTI TRAC PSC ;
  20. SINO ;
  21. OPTI ECHO 0 ;
  22. FINSI ;
  23.  
  24. SAUT PAGE;
  25. *-----------------------------------------*
  26. * THER3 *
  27. * *
  28. * TEST DES CL DE TEMPERATURE POUR *
  29. * PYR5 CUB8 TET4 PRI6 TRIDIM: *
  30. *-----------------------------------------*
  31. * *
  32. * TEMPERATURE IMPOSEE + CONVECTION *
  33. * + FLUX *
  34. * + SOURCE *
  35. * *
  36. * Comme dans le test THER1, cet exemple *
  37. * permet de tester les conditions aux li- *
  38. * -mites de température pour des éléments *
  39. * massifs linéaires PYR5, CUB8, TET4, PRI6*
  40. * *
  41. * Un parallélépipède rectangle constitué *
  42. * des éléments cités plus haut est soumis *
  43. * à une température imposée à sa face su- *
  44. * -périeure et à une condition de flux im-*
  45. * -posée, une condition de source volu- *
  46. * -mique ou une condition de convection *
  47. * forcée. *
  48. * *
  49. * Les résultats sont présentés sous forme *
  50. * d'isotempérature dans une tranche verti-*
  51. * -cale du parallélépipède. Les courbes *
  52. * doivent etre parallèles aux faces supé- *
  53. * -rieure et inférieure. *
  54. * *
  55. * 21 DECEMBRE 1988. *
  56. *-----------------------------------------*
  57. *
  58. * Disposition des noeuds des éléments :
  59. *
  60. * A4________F4_________D4
  61. * / / /|
  62. * / / / |
  63. * B4_________E4_________C4 D3
  64. * | | | /
  65. * | 6PYR5 | 12TE4 |/
  66. * B3_________E3_________C3
  67. *
  68. * IN: noeud milieu de
  69. * (AN BN EN FN AN+1 BN+1 EN+1 FN+1)
  70. *
  71. * A3________F3_________D3
  72. * / / /|
  73. * / / / |
  74. * B3_________E3_________C3 D2
  75. * | | | /
  76. * | 1CUB8 | 6PYR5 |/
  77. * B2_________E2_________C2
  78. *
  79. * JN: noeud milieu de
  80. * (DN CN EN FN DN+1 CN+1 EN+1 FN+1)
  81. *
  82. * A2________F2_________D2
  83. * / / /|
  84. * / / / |
  85. * B2_________E2_________C2 D1
  86. * | | | /
  87. * | 6PYR5 | 2PRI6 |/
  88. * B1_________E1_________C1
  89. *
  90. *
  91. *-----------------------------------------*
  92.  
  93. *--- OPTIONS GENERALES DE CALCUL:
  94. TITR 'THER3 - C.L. TEMPERATURE - ELEMENTS LINEAIRES 3D' ;
  95. OPTION DIME 3 ELEM SEG2 ;
  96. TEMPS ;
  97.  
  98. *--- CREATION DE LA GEOMETRIE:
  99. * POINTS SUPPORTS DES ELEMENTS
  100. A1=0. 0. 0.; B1=1. 0. 0.;
  101. C1=1. 3. 0.; D1=0. 3. 0.;
  102. A2=0. 0. 2.; B2=1. 0. 2.;
  103. C2=1. 3. 2.; D2=0. 3. 2.;
  104. A3=0. 0. 4.; B3=1. 0. 4.;
  105. C3=1. 3. 4.; D3=0. 3. 4.;
  106. A4=0. 0. 6.; B4=1. 0. 6.;
  107. C4=1. 3. 6.; D4=0. 3. 6.;
  108. E1=1. 1.5 0.; F1=0. 1.5 0.;
  109. E2=1. 1.5 2.; F2=0. 1.5 2.;
  110. E3=1. 1.5 4.; F3=0. 1.5 4.;
  111. E4=1. 1.5 6.; F4=0. 1.5 6.;
  112. I1= .5 .75 1.; I3= .5 .75 5.;
  113. J1= .5 2.25 1.; J2=.5 2.25 3.;
  114. J3= .5 2.25 5.;
  115.  
  116. *--- CREATION DES PYRAMIDES A 5 NOEUDS:
  117. PP01 = MANU PYR5 A1 B1 E1 F1 I1 ;
  118. PP02 = MANU PYR5 E1 F1 F2 E2 I1 ;
  119. PP03 = MANU PYR5 E2 F2 A2 B2 I1 ;
  120. PP04 = MANU PYR5 A2 B2 B1 A1 I1 ;
  121. PP05 = MANU PYR5 B1 E1 E2 B2 I1 ;
  122. PP06 = MANU PYR5 A1 F1 F2 A2 I1 ;
  123.  
  124. PP07 = MANU PYR5 D2 C2 E2 F2 J2 ;
  125. PP08 = MANU PYR5 E2 F2 F3 E3 J2 ;
  126. PP09 = MANU PYR5 E3 F3 D3 C3 J2 ;
  127. PP10 = MANU PYR5 D3 C3 C2 D2 J2 ;
  128. PP11 = MANU PYR5 C2 E2 E3 C3 J2 ;
  129. PP12 = MANU PYR5 D2 F2 F3 D3 J2 ;
  130.  
  131. PP13 = MANU PYR5 A3 B3 E3 F3 I3 ;
  132. PP14 = MANU PYR5 E3 F3 F4 E4 I3 ;
  133. PP15 = MANU PYR5 E4 F4 A4 B4 I3 ;
  134. PP16 = MANU PYR5 A4 B4 B3 A3 I3 ;
  135. PP17 = MANU PYR5 B3 E3 E4 B4 I3 ;
  136. PP18 = MANU PYR5 A3 F3 F4 A4 I3 ;
  137.  
  138. *VOLUME COMPOSE DES 18 PYRAMIDES A 5 NOEUDS
  139. VOL1 = PP01 ET PP02 ET PP03 ET PP04 ET PP05 ET PP06 ET PP07 ET PP08 ET PP09 ET PP10 ET PP11 ET PP12 ET PP13 ET PP14 ET PP15 ET PP16 ET PP17 ET PP18 ;
  140.  
  141. *--- CREATION DES PRISMES A 6 NOEUDS:
  142. PR01 = MANU PRI6 E1 D1 F1 E2 D2 F2 ;
  143. PR02 = MANU PRI6 E1 C1 D1 E2 C2 D2 ;
  144.  
  145. * VOLUME COMPOSE DES 2 PRISMES A 6 NOEUDS
  146. VOL2 = PR01 ET PR02 ;
  147.  
  148. *--- CREATION DES TETRAEDRES A 4 NOEUDS:
  149. TT01 = MANU TET4 E3 D3 F3 J3 ;
  150. TT02 = MANU TET4 E3 D3 C3 J3 ;
  151. TT03 = MANU TET4 C3 D4 D3 J3 ;
  152. TT04 = MANU TET4 C3 D4 C4 J3 ;
  153. TT05 = MANU TET4 C4 F4 E4 J3 ;
  154. TT06 = MANU TET4 C4 F4 D4 J3 ;
  155. TT07 = MANU TET4 E3 F4 E4 J3 ;
  156. TT08 = MANU TET4 E3 F4 F3 J3 ;
  157. TT09 = MANU TET4 E3 C4 C3 J3 ;
  158. TT10 = MANU TET4 E3 C4 E4 J3 ;
  159. TT11 = MANU TET4 F3 D4 D3 J3 ;
  160. TT12 = MANU TET4 F3 D4 F4 J3 ;
  161.  
  162. *VOLUME COMPOSE DES 12 TETRA A 4 NOEUDS
  163. VOL3 = TT01 ET TT02 ET TT03 ET TT04 ET TT05 ET TT06 ET TT07 ET TT08 ET TT09 ET TT10 ET TT11 ET TT12 ;
  164.  
  165. *--- CREATION DU CUBE A 8 NOEUDS:
  166. VOL4 = MANU CUB8 B2 E2 F2 A2 B3 E3 F3 A3 ;
  167.  
  168. *--- REUNION DES VOLUMES ELEMENTAIRES:
  169. VOLTOT = VOL1 ET VOL2 ET VOL3 ET VOL4 ;
  170.  
  171. *--- POST-TRAITEMENT: TRACE DU MAILLAGE
  172. OEIL = 100. 100. 100. ;
  173. TITR 'ELEMENTS PYR5 CUB8 TET4 PRI6 : MAILLAGE' ;
  174. SI(NEG GRAPH 'N');
  175. TRAC 'QUAL' OEIL VOLTOT ;
  176. FINSI;
  177.  
  178. VOLSOUR = PP13 ET PP14 ET PP15 ET PP16 ET PP17 ET PP18 ET TT01 ET TT02 ET TT03 ET TT04 ET TT05 ET TT06 ET TT07 ET TT08 ET TT09 ET TT10 ET TT11 ET TT12 ;
  179.  
  180. *--- L_INF ETANT BASEE SUR LES POINTS:
  181. * A1 B1 E1 C1 D1 F1
  182. DD1 = D 1 A1 B1 ;
  183. DD2 = D 1 B1 E1 ;
  184. DD3 = D 1 E1 C1 ;
  185. DD4 = D 1 C1 D1 ;
  186. DD5 = D 1 D1 F1 ;
  187. DD6 = D 1 F1 A1 ;
  188.  
  189. L_INF = DD1 ET DD2 ET DD3 ET DD4 ET DD5 ET DD6 ;
  190.  
  191. *--- SURFACE INFERIEURE:
  192. S_INF = SURF L_INF PLANE ;
  193.  
  194. *--- L_SUP ETANT BASEE SUR LES POINTS:
  195. * A4 B4 E4 C4 D4 F4
  196.  
  197. LL1 = D 1 A4 B4 ;
  198. LL2 = D 1 B4 E4 ;
  199. LL3 = D 1 E4 C4 ;
  200. LL4 = D 1 C4 D4 ;
  201. LL5 = D 1 D4 F4 ;
  202. LL6 = D 1 F4 A4 ;
  203.  
  204. L_SUP = LL1 ET LL2 ET LL3 ET LL4 ET LL5 ET LL6 ;
  205.  
  206. *--- SURFACE SUPERIEURE:
  207. S_SUP = SURF L_SUP PLANE ;
  208.  
  209. *--- DONNEES DU PROBLEME DE THERMIQUE:
  210. *--- MODELISATION:
  211. MOD1 = MODE VOLTOT THERMIQUE ISOTROPE ;
  212. MOD2 = MODE S_SUP THERMIQUE CONVECTION ;
  213.  
  214. *--DONNEE DES CARACTERISTIQUES DU MATERIAU:
  215. KC = 100. ;
  216. MAT1 = MATE MOD1 'K' KC ;
  217. HC = 15. ;
  218. MAT2 = MATE MOD2 'H' HC ;
  219.  
  220. *--- CREATION DES MATRICES DE CONDUCTIVITE:
  221. CND1 = CONDUCTIVITE MOD1 MAT1 ;
  222. CND2 = CONDUCTIVITE MOD2 MAT2 ;
  223.  
  224. *--- TEMPERATURES IMPOSEES: BLOQUE + DEPI
  225. BB1 = BLOQ S_INF 'T' ;
  226. TI = 10. ;
  227. EE1 = DEPI BB1 TI ;
  228.  
  229. *--- FLUX CONVECTIF A LA SURFACE:
  230. TEX = 200. ;
  231. CNV1 = CONVECTION MOD2 MAT2 'T' TEX ;
  232.  
  233. *--- FLUX IMPOSE:
  234. PHI = 20. ;
  235. FLU1 = FLUX MOD1 PHI S_SUP ;
  236.  
  237. *--- SOURCE VOLUMIQUE:
  238. QVOL = 2. ;
  239. S1 = SOUR MOD1 QVOL VOLSOUR ;
  240.  
  241. *-- ASSEMBLAGE DES TERMES DE CONDUCTIVITE:
  242. CCC1 = CND1 ET CND2 ET BB1 ;
  243. CCC2 = CND1 ET BB1 ;
  244.  
  245. *ASSEMBLAGE DES TERMES DE FLUX EQUIVALENTS:
  246. FFF1 = EE1 ET CNV1 ;
  247. FFF2 = EE1 ET FLU1 ;
  248. FFF3 = EE1 ET S1 ;
  249.  
  250. *--- 1ERE RESOLUTION:
  251. * TEMPERATURE IMPOSEE + CONVECTION
  252. CHTER1 = RESO CCC1 FFF1 ;
  253.  
  254. *--- POST-TRAITEMENT
  255. Z1 = COOR 3 F1;
  256. Z2 = COOR 3 F4;
  257.  
  258. *Valeur Théorique de la température en Z2
  259. TREF1=((KC * TI) + (HC * Z2 * TEX)) / ((KC ) + (HC * Z2 )) ;
  260. TETA1 = EXTR CHTER1 T F4 ;
  261. RESI1=100. * (ABS((TETA1-TREF1)/TREF1));
  262.  
  263. MESS 'Temperature theorique :' TREF1' C';
  264. MESS 'Temperature calculee :' TETA1' C';
  265. MESS ' Soit un ecart de : ' RESI1 '%';
  266. RESITOT = PROG RESI1 ;
  267.  
  268. OEIL = 100. 0. 0. ;
  269. SI(NEG GRAPH 'N');
  270. TITR 'ELEMENTS PYR5 CUB8 TET4 PRI6 : CONVECTION' ;
  271. TRAC OEIL VOLTOT CHTER1 ;
  272. FINSI;
  273.  
  274. *--- 2EME RESOLUTION:
  275. * TEMPERATURE IMPOSEE + FLUX
  276. CHTER2 = RESO CCC2 FFF2 ;
  277.  
  278. TREF2= TI + (PHI * Z2 / KC );
  279. TETA2 = EXTR CHTER2 T F4 ;
  280. RESI2=100. * (ABS((TETA2-TREF2)/TREF2));
  281. MESS 'Temperature theorique :' TREF2' C';
  282. MESS 'Temperature calculee :' TETA2' C';
  283. MESS ' Soit un ecart de : ' RESI2 '%';
  284. RESITOT = RESITOT ET (PROG RESI2) ;
  285.  
  286. SI(NEG GRAPH 'N');
  287. TITR 'ELEMENTS PYR5 CUB8 TET4 PRI6 : FLUX';
  288. TRAC OEIL VOLTOT CHTER2 ;
  289. FINSI;
  290.  
  291. *--- 3EME RESOLUTION:
  292. * TEMPERATURE IMPOSEE + SOURCE
  293. CHTER3 = RESO CCC2 FFF3 ;
  294.  
  295. TREF3= TI - (QVOL * (Z2**2) / (2 * KC)) + (QVOL * (Z2**2) / ( KC));
  296. TETA3 = EXTR CHTER3 T F4 ;
  297. RESI3=100. * (ABS((TETA3-TREF3)/TREF3));
  298. MESS 'Temperature theorique :' TREF3' C';
  299. MESS 'Temperature calculee :' TETA3' C';
  300. MESS ' Soit un ecart de : ' RESI3 '%';
  301. RESITOT = RESITOT ET (PROG RESI3) ;
  302.  
  303. SI(NEG GRAPH 'N');
  304. TITR 'ELEMENTS PYR5 CUB8 TET4 PRI6 : SOURCE';
  305. TRAC OEIL VOLTOT CHTER3 ;
  306. FINSI;
  307.  
  308. * CODE DE FONCTIONNEMENT
  309. LIST RESITOT;
  310. SI((MAXI RESITOT) <EG 1.);
  311. ERRE 0;
  312. SINO;
  313. ERRE 5;
  314. FINSI;
  315. FIN;
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales