Télécharger ther2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : ther2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************
  6. * Test ther2.dgibi: jeux de données *
  7. * --------------------------------- *
  8. *******************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18. OPTI ECHO 1 ;
  19. OPTI TRAC PSC ;
  20. SINO ;
  21. OPTI ECHO 0 ;
  22. FINSI ;
  23.  
  24. SAUT PAGE;
  25. *-----------------------------------------*
  26. * THER2 *
  27. * *
  28. * TEST DES CL DE TEMPERATURE *
  29. * EN MODE AXISYMETRIQUE *
  30. * ----------------------------------------*
  31. * *
  32. * TEMPERATURE IMPOSEE + CONVECTION *
  33. * + FLUX *
  34. * + SOURCE *
  35. * *
  36. * *
  37. * Comme dans le test THER1, cet exemple *
  38. * permet de tester les conditions aux *
  39. * limites de température en calcul *
  40. * axisymétrique. *
  41. * *
  42. * Trois cas sont envisagés ici : *
  43. * - un tube épais soumis à une *
  44. * température imposée et à un *
  45. * flux imposé *
  46. * - un tube épais soumis à une *
  47. * température imposée et à une *
  48. * source volumique de chaleur *
  49. * - un tube épais soumis à une *
  50. * température imposée et à une *
  51. * convection forcée *
  52. *-----------------------------------------*
  53. *
  54. *--- 1er problème
  55. * ------------
  56. *
  57. *--- Description :
  58. *
  59. * établir le champ de température dans
  60. * un tube épais soumis à une condition
  61. * de température imposée et à un flux
  62. * imposé
  63. * -----------
  64. *--- Description de la géométrie :
  65. *
  66. * | axe de symétrie
  67. * .
  68. * | _________________________
  69. * . | |
  70. * . | |
  71. * . | |
  72. * . | |
  73. * . | |
  74. * . | |
  75. * | | K=130. |
  76. * . |_________________________|
  77. * | TI=0.57 F=0.72
  78. * RI=0.0515 RE=0.2015
  79. *
  80. *--- Commentaires :
  81. *
  82. * le problème est à symétrie de révolution
  83. * température imposée sur la paroi interne
  84. * (TI=0.57)
  85. * flux imposé sur la paroi externe
  86. * (F=0.72)
  87. * conductibilité isotrope
  88. * (K=130)
  89. *
  90. *--- Solution analytique :
  91. *
  92. * T(R) = TI + LOG(R/RI) * (F * RE)/K
  93. * Le test est réalisé en T(R=Re)
  94. *
  95. *------------------------------------------
  96.  
  97. TITR 'THER2 - C.L. TEMPERATURE -
  98. CALCUL AXISYMETRIQUE';
  99. OPTI DIME 2 ELEM QUA4 MODE AXIS ;
  100. TEMPS ;
  101.  
  102. *--- CREATION DE LA GEOMETRIE:
  103. P1 = 0.0515 0. ;P20 = 0.0665 0. ;
  104. P19 = 0.0665 0.5 ;P2 = 0.0515 0.5 ;
  105. P18 = 0.0815 0. ;P17 = 0.0815 0.5 ;
  106. P16 = 0.0965 0. ;P15 = 0.0965 0.5 ;
  107. P14 = 0.1115 0. ;P13 = 0.1115 0.5 ;
  108. P12 = 0.1265 0. ;P11 = 0.1265 0.5 ;
  109. P10 = 0.1415 0. ;P9 = 0.1415 0.5 ;
  110. P8 = 0.1565 0. ;P7 = 0.1565 0.5 ;
  111. P6 = 0.1715 0. ;P5 = 0.1715 0.5 ;
  112. P24 = 0.1865 0. ;P23 = 0.1865 0.5 ;
  113. P4 = 0.2015 0.5 ;P3 = 0.2015 0. ;
  114.  
  115. SURF1 = MANUEL QUA4 P1 P20 P19 P2 ;
  116. SURF2 = MANUEL QUA4 P20 P18 P17 P19 ;
  117. SURF3 = MANUEL QUA4 P18 P16 P15 P17 ;
  118. SURF4 = MANUEL QUA4 P16 P14 P13 P15 ;
  119. SURF5 = MANUEL QUA4 P14 P12 P11 P13 ;
  120. SURF6 = MANUEL QUA4 P12 P10 P9 P11 ;
  121. SURF7 = MANUEL QUA4 P10 P8 P7 P9 ;
  122. SURF8 = MANUEL QUA4 P8 P6 P5 P7 ;
  123. SURF9 = MANUEL QUA4 P6 P24 P23 P5 ;
  124. SURF10 = MANUEL QUA4 P24 P3 P4 P23 ;
  125. SURF11 = SURF1 ET SURF2 ET SURF3 ET SURF4
  126. ET SURF5 ET SURF6 ET SURF7
  127. ET SURF8 ET SURF9 ET SURF10;
  128.  
  129. D1 = DROITE 1 P1 P2 ;
  130. D3 = DROITE 1 P3 P4 ;
  131.  
  132. *--- DONNEES DU PROBLEME DE THERMIQUE:
  133.  
  134. *--- MODELISATION:
  135. MOD1 = MODE SURF11 THERMIQUE ISOTROPE ;
  136.  
  137. *--- CARACTERISTIQUES DU MATERIAU:
  138. KC = 130. ;
  139. MAT1 = MATE MOD1 K KC ;
  140.  
  141. *--- MATRICE DE CONDUCTIVITE:
  142. CND1 = CONDUCTIVITE MOD1 MAT1 ;
  143.  
  144. *--- TEMPERATURES IMPOSEES: BLOQUE + DEPI
  145. B1 = BLOQUE T D1 ;
  146. TI = 0.57 ;
  147. E1 = DEPI B1 TI ;
  148.  
  149. *--- FLUX IMPOSE:
  150. F = 0.72;
  151. F1 = FLUX MOD1 F D3 ;
  152.  
  153. *--- ASSEMBLAGE:
  154. RIG1 = CND1 ET B1 ;
  155. FF1 = E1 ET F1 ;
  156.  
  157. *--- RESOLUTION:
  158. CHTER1 = RESO RIG1 FF1 ;
  159. TETA1 = EXTR CHTER1 T P3 ;
  160.  
  161. SI(NEG GRAPH 'N');
  162. TRAC 'QUAL' SURF11 ;
  163. TRAC CHTER1 SURF11 ;
  164. FINSI;
  165.  
  166. *--- TEST DE NON REGRESSION:
  167. R = COOR 1 P3;
  168. RI = COOR 1 P1;
  169. RE = COOR 1 P4;
  170.  
  171. TREF1 = TI +((LOG (R/RI)) * (F * RE) / KC);
  172.  
  173. RESI1=100. * (ABS((TETA1-TREF1)/TREF1));
  174.  
  175. MESS 'Temperature theorique :' TREF1' C';
  176. MESS 'Temperature calculee :' TETA1' C';
  177. MESS ' Soit un ecart de : ' RESI1 '%';
  178. RESITOT = PROG RESI1 ;
  179.  
  180. SAUTER 1 LIGNES ;
  181.  
  182. *------------------------------------------
  183. *--- 2eme problème
  184. *
  185. * établir le champ de température dans un
  186. * tube épais soumis à une condition de
  187. * température imposée ainsi qu'à une source
  188. * volumique
  189.  
  190. *--- Description de la géométrie :
  191. *
  192. * | Y (axe de symétrie)
  193. * .
  194. * | ______________________________
  195. * . | |
  196. * | | Q=20. K=1. |
  197. * . ------------------------------
  198. * | TI=100. F=0.
  199. * RI=6. RE=16.
  200. *
  201. *
  202. *--- Commentaires :
  203. *
  204. * Le problème est à symétrie de révolution.
  205. * Température sur la paroi interne (TI=100)
  206. * Flux imposé sur la paroi externe (F=0)
  207. * ( DT / DN = 0 )
  208. * Source volumique imposée (Q=20)
  209. * Conductibilité isotrope (K=1)
  210. *
  211. *--- Solution analytique :
  212. *
  213. * T(R) = TI - (Q/4K)*(R**2-RI**2) +
  214. * (Q*RE/2)*RE*LOG(R/RI)
  215.  
  216. * Le test est réalisé en T(R=Re)
  217. *
  218. *------------------------------------------
  219. *
  220. *--- CREATION DE LA GEOMETRIE:
  221. *
  222. P1 = 6 0 ;
  223. P2 = 16 0 ;
  224. P3 = 16 4 ;
  225. P4 = 6 4 ;
  226. D1 = DROITE 8 P1 P2 ;
  227. D2 = DROITE 6 P2 P3 ;
  228. D3 = DROITE 9 P3 P4 ;
  229. D4 = DROITE 4 P4 P1 ;
  230. LIG1 = D1 ET D2 ET D3 ET D4 ;
  231. SURF1 = SURFACE LIG1 PLANE ;
  232.  
  233. *--- DONNEES DU PROBLEME DE THERMIQUE:
  234.  
  235. *--- MODELISATION:
  236. MOD1 = MODE SURF1 THERMIQUE ISOTROPE ;
  237.  
  238. *--- CARACTERISTIQUES DU MATERIAU:
  239. KC = 1. ;
  240. MAT1 = MATE MOD1 K KC ;
  241.  
  242. *--- MATRICE DE CONDUCTIVITE:
  243. CND1 = COND MOD1 MAT1 ;
  244.  
  245. *--- TEMPERATURES IMPOSEES: BLOQUE + DEPI
  246. B1 = BLOQUE T D4 ;
  247. TI = 100. ;
  248. E1 = DEPI B1 TI ;
  249.  
  250. *--- FLUX IMPOSE:
  251. E2 = FLUX MOD1 0. D2 ;
  252.  
  253. *--- SOURCE VOLUMIQUE:
  254. Q = 20. ;
  255. E3 = SOURCE MOD1 Q SURF1 ;
  256.  
  257. *--- ASSEMBLAGE PREMIER ET SECOND MEMBRE:
  258. RIG1 = CND1 ET B1 ;
  259. FF1 = E1 ET E2 ET E3 ;
  260.  
  261. *--- RESOLUTION:
  262. CHTER2 = RESO RIG1 FF1 ;
  263. TETA2 = EXTR CHTER2 T P3 ;
  264.  
  265. SI(NEG GRAPH 'N');
  266. TRAC 'QUAL' SURF1 ;
  267. TRAC CHTER2 SURF1 ;
  268. FINSI;
  269.  
  270. *--- TEST DE NON REGRESSION:
  271. R = COOR 1 P3;
  272. RI = COOR 1 P1;
  273. RE = COOR 1 P3;
  274.  
  275. C1 = Q * (RE**2)/(2*KC);
  276. TREF2=TI +
  277. ((Q /(2*KC)) *
  278. ((((RI**2) - (RE**2))/2) +
  279. ((RE**2) * (LOG (RE/RI))) )) ;
  280.  
  281.  
  282. RESI2=100. * (ABS((TETA2-TREF2)/TREF2));
  283.  
  284. MESS 'Temperature theorique :' TREF2' C';
  285. MESS 'Temperature calculee :' TETA2' C';
  286. MESS ' Soit un ecart de : ' RESI2 '%';
  287. RESITOT = RESITOT ET (PROG RESI2) ;
  288.  
  289. SAUTER 1 LIGNES ;
  290.  
  291. *------------------------------------------
  292. *--- 3eme problème
  293. *
  294. *--- Description du problème :
  295. *
  296. * établir le champ de température dans
  297. * un tube épais soumis à une condition
  298. * interne de température ainsi qu'à une
  299. * convection sur sa paroi externe
  300. *
  301. *--- Données du problème :
  302. *
  303. * Conductibilité isotrope du matériau
  304. * (K=8)
  305. * Coefficient d'échange en convection
  306. * (HC=5)
  307. * Température imposée sur la paroi
  308. * interne (TI=100)
  309. * Température du milieu extérieur
  310. * (TE=125)
  311. *
  312. *--- Solution :
  313. * Comparaison à la solution analytique
  314. *------------------------------------------
  315. *--- CREATION DE LA GEOMETRIE:
  316. * - rayon intéreiur RI = 6.
  317. * - rayon extérieur RE = 16.
  318. * - hauteur H = 4.
  319. * - surface interne : D4
  320. * - surface externe : D2
  321.  
  322. P1 = 6 0 ;
  323. P2 = 16 0 ;
  324. P3 = 16 4 ;
  325. P4 = 6 4 ;
  326. D1 = DROITE 8 P1 P2 ;
  327. D2 = DROITE 5 P2 P3 ;
  328. D3 = DROITE 9 P3 P4 ;
  329. D4 = DROITE 6 P4 P1 ;
  330. LIG1 = D1 ET D2 ET D3 ET D4 ;
  331. SURF1 = SURF LIG1 PLANE ;
  332.  
  333. *--- DONNEES DU PROBLEME DE THERMIQUE:
  334.  
  335. *--- MODELISATION:
  336. MOD1 = MODE SURF1 THERMIQUE ISOTROPE ;
  337. MOD2 = MODE D2 THERMIQUE CONVECTION ;
  338.  
  339. * DONNEE DES CARACTERISTIQUES DU MATERIAU:
  340. KC = 8. ;
  341. MAT1 = MATE MOD1 K KC ;
  342. HC = 5. ;
  343. MAT2 = MATE MOD2 H HC ;
  344.  
  345. *--- MATRICES DE CONDUCTIVITE:
  346. CND1 = CONDUCTIVITE MOD1 MAT1 ;
  347. CNF1 = CONDUCTIVITE MOD2 MAT2 ;
  348.  
  349. *--- FLUX EQUIVALENTS A LA CONVECTION:
  350. TEX = 125. ;
  351. FF1 = CONVECTION MOD2 MAT2 T TEX ;
  352.  
  353. *--- TEMPERATURE IMPOSEE: BLOQUE + DEPI
  354. B1 = BLOQUE T D4 ;
  355.  
  356. TI = 100. ;
  357. E1 = DEPI B1 TI ;
  358.  
  359. *--- ASSEMBLAGE:
  360. RIG1 = CND1 ET CNF1 ET B1 ;
  361. Q1 = FF1 ET E1 ;
  362.  
  363. *--- RESOLUTION:
  364. CHTER3 = RESO RIG1 Q1 ;
  365. TETA3 = EXTR CHTER3 T P3 ;
  366.  
  367. SI(NEG GRAPH 'N');
  368. TRAC 'QUAL' SURF1 ;
  369. TRAC CHTER3 SURF1 ;
  370. FINSI;
  371.  
  372. *--- POST-TRAITEMENT
  373. RI = COOR 1 P1;
  374. RE = COOR 1 P3;
  375.  
  376. *Valeur Théorique de la température en RE
  377. TREF3=(TI + (HC*RE*TEX/KC*(LOG(RE/RI)))) /
  378. ( 1 + (HC*RE/KC*(LOG(RE/RI))));
  379.  
  380. RESI3=100. * (ABS((TETA3-TREF3)/TREF3));
  381.  
  382. MESS 'Temperature theorique :' TREF3' C';
  383. MESS 'Temperature calculee :' TETA3' C';
  384. MESS ' Soit un ecart de : ' RESI3 '%';
  385. RESITOT = RESITOT ET (PROG RESI3) ;
  386.  
  387. TEMPS ;
  388. * CODE DE FONCTIONNEMENT
  389. SI((MAXI RESITOT) <EG 0.4);
  390. ERRE 0;
  391. SINO;
  392. ERRE 5;
  393. FINSI;
  394. FIN;
  395.  
  396.  
  397.  
  398.  
  399.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales