Télécharger test_vari_props.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : test_vari_props.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *-----------------------------------------------------------------------
  6. *FRA Exemple simple de definition d'une proriete thermique variable
  7. * fonction de 1 parametre (EVOL) ou plusieurs parametres (NUAGE)
  8. * Simulation axisymetrique d'une trempe sur un cylindre avec echange
  9. * convectif avec l'air ambient. Il s'agit de la conductivite du tube
  10. * est variable : evolution de T ou nuage de T et ETAT.
  11. *-----------------------------------------------------------------------
  12. *ENG Easy example of a variable thermal property, function of 1
  13. * parameter (EVOL) or of several parameters (NUAGE)
  14. * Axisymetric modelisation of a tube quenching with convective heat
  15. * exchange with ambient atmosphere. The tube heat conductivity is a
  16. * function of the temperature T or a function of T and ETAT.
  17. *-----------------------------------------------------------------------
  18. 'OPTION' 'ECHO' 1 ;
  19. OPTI DEBU 1;
  20.  
  21. * ***** ********************* *******************
  22. * * 1 * (FRA) Definitions generales - (ENG) General definitions
  23. * ***** ********************* *******************
  24.  
  25. 'OPTION' 'DIME' 2 'ELEM' QUA4 'MODE' AXIS ;
  26.  
  27. * (FRA) Definition du maillage - (ENG) Mesh definition
  28. * ---------------------- ---------------
  29. PD = 0. 0. ;
  30. PC = 0.1 0. ;
  31. PB = 0.1 0.02 ;
  32. PA = 0. 0.02 ;
  33. D1 = 'DROITE' 20 PD PC ;
  34. Tube = 'TRANSLATION' 1 D1 (0. 0.02) ;
  35.  
  36. D2 = 'COTE' 2 Tube ;
  37. D3 = 'COTE' 3 Tube ;
  38. D4 = 'COTE' 4 Tube ;
  39.  
  40. pt_TC2 = Tube 'POINT' 'PROC' (0.095 0.) ;
  41. pt_TC1 = Tube 'POINT' 'PROC' (0.05 0.) ;
  42. ** 'TRACER' Tube ;
  43.  
  44. * (FRA) Definition des modeles thermiques (conduction et convection)
  45. * (ENG) Thermic models definition (conduction and convective exchange)
  46. * --------------------------------------------------------------
  47. Mod_Tube = 'MODELISER' Tube 'THERMIQUE' 'ISOTROPE' ;
  48. Mod_Teco = 'MODELISER' D2 'THERMIQUE' 'CONVECTION' ;
  49. ModTot = Mod_Tube 'ET' Mod_Teco ;
  50.  
  51. * (FRA) Defintion du modele de convection
  52. * (ENG) Convective model definition
  53. * ---------------------------------
  54. Mat_Teco = 'MATERIAU' Mod_TECO 'H ' 1515. ;
  55.  
  56. * (FRA) Chargement convectif - Temperature constante de l'air ambient
  57. * (ENG) Convective loading - The temperature room is constant
  58. * -------------------------------------------------------------
  59. T_air = 25. ;
  60. EvTECO = 'EVOL' 'MANU' 'TEMPS' ('PROG' 0. 1.E+9)
  61. 'T' ('PROG' 1. 1.) ;
  62. ChpTECO = 'MANU' 'CHPO' D2 1 'T' T_air ;
  63. CharTECO = 'CHARGEMENT' 'TECO' ChpTECO EvTECO ;
  64.  
  65. * (FRA) Temperature initiale du tube uniforme
  66. * (ENG) The initial temperature of the tube is uniform
  67. * ----------------------------------------------
  68. T_ini = 800. ;
  69. ChpT0 = 'MANU' 'CHPO' Tube 1 'T ' T_ini ;
  70.  
  71. * (FRA) Instants calcules et sauves - (ENG) Calculated and saved times
  72. * --------------------------------------------------------------
  73. l_tcalc = 'PROG' 0. 'PAS' 10. 400. ;
  74. l_tsauv = 'PROG' 0. 10. 20. 30. 40. 50. 'PAS' 50. 400. ;
  75.  
  76. * ***** ******************************************
  77. * * 2 * (FRA) Calcul PASAPAS - Conductivite fonction de T
  78. * * * (ENG) PASAPAS call - Conductivity function of temperature
  79. * ***** ******************************************
  80.  
  81. * (FRA) Defintion de la conductivite du tube (fonction de T)
  82. * (ENG) Conductivity tube definition (temperature function)
  83. * ----------------------------------------------------
  84. EvK = 'EVOL' 'MANU' 'T ' ('PROG' 0. 2000.) 'K ' ('PROG' 10. 30.) ;
  85. Mat_Tube = 'MATERIAU' Mod_Tube 'K ' EvK 'C ' 400. 'RHO ' 7800. ;
  86. MatTot = Mat_Tube 'ET' Mat_Teco ;
  87.  
  88. * (FRA) Appel a PASAPAS-TRANSNON - (ENG) PASAPAS-TRANSNON call
  89. * ------------------------ ---------------------
  90. ETAB1 = 'TABLE' ;
  91. ETAB1.'MODELE' = ModTot ;
  92. ETAB1.'CARACTERISTIQUES' = MatTot ;
  93. ETAB1.'CHARGEMENT' = CharTECO ;
  94. ETAB1.'TEMPERATURES' = 'TABLE' ;
  95. ETAB1.'TEMPERATURES'. 0 = ChpT0 ;
  96. ETAB1.'TEMPS_SAUVES' = l_tsauv ;
  97. ETAB1.'TEMPS_CALCULES' = l_tcalc ;
  98.  
  99. PASAPAS ETAB1 ;
  100.  
  101. * (FRA) Depouillement des resultats - (ENG) Results extraction
  102. * --------------------------- ------------------
  103. TEMP1_1 = 'PROG' ; TEMP2_1 = 'PROG' ;
  104. I = 0 ;
  105. 'REPETER' Boucle ('DIMENSION' ETAB1.'TEMPS') ;
  106. Tps = ETAB1.'TEMPS'.I ;
  107. T1 = 'EXTRAIRE' (ETAB1.'TEMPERATURES'.I) 'T ' pt_TC1 ;
  108. T2 = 'EXTRAIRE' (ETAB1.'TEMPERATURES'.I) 'T ' pt_TC2 ;
  109. TEMP1_1 = TEMP1_1 'ET' ('PROG' T1) ;
  110. TEMP2_1 = TEMP2_1 'ET' ('PROG' T2) ;
  111. I = I + 1 ;
  112. 'FIN' Boucle ;
  113.  
  114. * ***** *******************************
  115. * * 3 * (FRA) Calcul PASAPAS - Conductivite fonction de T et de ETAT
  116. * * * (ENG) PASAPAS call - Conductivity function of temperature and ETAT parameter
  117. * ***** *******************************
  118.  
  119. * (FRA) Defintion de la conductivite du tube : K est une fonction de T et ETAT
  120. * (ENG) Conductivity tube definition : K is function of T and ETAT
  121. * -----------------------------------------------------
  122. EvK = 'EVOL' 'MANU' 'T ' ('PROG' 0. 2000.) 'K ' ('PROG' 10. 30.) ;
  123. NuagK = 'NUAGE' 'ETAT'*'FLOTTANT' 'K '*'EVOLUTION' 0. EvK 10. EvK ;
  124. * (FRA) Ici ETAT n'a aucune influence sur K (ENG) Here ETAT plays no role on K
  125. Mat_Tube = 'MATERIAU' Mod_Tube 'K ' NuagK 'C ' 400. 'RHO ' 7800. ;
  126. MatTot = Mat_Tube 'ET' Mat_Teco ;
  127.  
  128. * (FRA) Evolution du parametre externe 'ETAT'
  129. * (ENG) Evolution of the external parameter 'ETAT'
  130. * --------------------------------------------------------------
  131. EvEtat = 'EVOL' 'MANU' 'TEMPS' ('PROG' 0. 1.E+9)
  132. 'ETAT' ('PROG' 2. 2.) ;
  133. Chp_E1 = 'MANU' 'CHPO' Tube 1 'ETAT' 1. ;
  134. CharEtat = 'CHARGEMENT' 'ETAT' Chp_E1 EvEtat ;
  135.  
  136. * (FRA) Appel a PASAPAS-TRANSNON - (ENG) PASAPAS-TRANSNON call
  137. * ------------------------ ---------------------
  138. ETAB2 = 'TABLE' ;
  139. ETAB2.'MODELE' = ModTot ;
  140. ETAB2.'CARACTERISTIQUES' = MatTot ;
  141. ETAB2.'CHARGEMENT' = CharTECO 'ET' CharEtat ;
  142. ETAB2.'TEMPERATURES' = 'TABLE' ;
  143. ETAB2.'TEMPERATURES'. 0 = ChpT0 ;
  144. ETAB2.'TEMPS_SAUVES' = l_tsauv ;
  145. ETAB2.'TEMPS_CALCULES' = l_tcalc ;
  146.  
  147. PASAPAS ETAB2 ;
  148.  
  149. * (FRA) Depouillement des resultats - (ENG) Results extraction
  150. * --------------------------- ------------------
  151. TEMP1_2 = 'PROG' ; TEMP2_2 = 'PROG' ;
  152. I = 0 ;
  153. 'REPETER' Boucle ('DIMENSION' ETAB2.'TEMPS') ;
  154. Tps = ETAB2.'TEMPS'.I ;
  155. T1 = 'EXTRAIRE' (ETAB2.'TEMPERATURES'.I) 'T ' pt_TC1 ;
  156. T2 = 'EXTRAIRE' (ETAB2.'TEMPERATURES'.I) 'T ' pt_TC2 ;
  157. TEMP1_2 = TEMP1_2 'ET' ('PROG' T1) ;
  158. TEMP2_2 = TEMP2_2 'ET' ('PROG' T2) ;
  159. I = I + 1 ;
  160. 'FIN' Boucle ;
  161.  
  162.  
  163. * ***** ******************************************
  164. * * 4 * (FRA) Comparaison des resultats - Tests d'erreur
  165. * * * (ENG) Results comparison - Error tests
  166. * ***** ******************************************
  167.  
  168. EcT_1 = 100. * ('MAXIMUM' ('ABS' (TEMP1_2 - TEMP1_1))) ;
  169. EcT_2 = 100. * ('MAXIMUM' ('ABS' (TEMP2_2 - TEMP2_1))) ;
  170.  
  171. 'MESS' ;
  172. 'MESS' 'Ecart Point 1 : ' EcT_1 ' %' ;
  173. 'MESS' 'Ecart Point 2 : ' EcT_2 ' %' ;
  174. 'MESS' ;
  175. *
  176. 'SI' (('>' EcT_1 1.E-3) 'OU' ('>' EcT_2 1.E-3)) ;
  177. 'ERREUR' 5 ;
  178. 'FINSI' ;
  179.  
  180. 'FIN' ;
  181.  
  182.  
  183.  
  184.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales