Télécharger test_pres_cham.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * Utilisation de l'operateur PRES avec un MCHAML *
  3. * *
  4. * Une comparaison est faite entre les utilisation dans PRES *
  5. * - d'un CHPOINT (CHAR1) *
  6. * - d'un MCHAML (CHAR2) *
  7. * *
  8. * Calcul mecanique avec d'une poutre avec section en T : *
  9. * - encastrement de la face gauche *
  10. * - pression variable repartie sur la face superieure *
  11. ************************************************************************
  12. 'OPTI' 'DIME' 3 'ELEM' 'CUB8' 'TRAC' 'X' 'ECHO' 0 ;
  13.  
  14. * Indicateur pour traces
  15. ITRAC = FAUX ;
  16. *
  17. *-----------------------------------------------------------------------*
  18. * Maillage *
  19. *-----------------------------------------------------------------------*
  20. * Dimensions section
  21. LA = 0.004 ; LB = 0.02 ; H1 = 0.03 ;
  22. * Longueur de la poutre
  23. LONG = 0.2 ;
  24. * Taille de maille cible
  25. OPTI 'DENS' LA ;
  26. *
  27. P0 = 0. 0. 0. ;
  28. P1 = P0 PLUS (0. LA 0.) ;
  29. P2 = P1 PLUS (0. 0. (H1 - (2*LA))) ;
  30. P3 = P2 PLUS (0. (LB - LA) 0.) ;
  31. P4 = P3 PLUS (0. 0. (2*LA)) ;
  32. P5 = P0 PLUS (0. 0. H1) ;
  33. LIG1 = D P0 P1 ;
  34. LIG1 = D LIG1 P2 ;
  35. LIG1 = D LIG1 P3 ;
  36. LIG1 = D LIG1 P4 ;
  37. LIG1 = D LIG1 P5 ;
  38. LIG1 = D LIG1 P0 ;
  39. SUR1 = SURF LIG1 'PLAN' ;
  40. SUR1 = SUR1 ET (SUR1 SYME 'DROI' P0 P5) ;
  41. ELIM SUR1 1.E-9 ;
  42. *
  43. VOL1 = SUR1 VOLU 'TRAN' 50 (LONG 0. 0.) ;
  44. 'SI' ITRAC ;
  45. TRAC 'CACH' VOL1 'TITR' 'Maillage' ;
  46. 'FINSI' ;
  47. *
  48. ENV1 = ENVE VOL1 ;
  49. PHAUT = ENV1 POIN 'PLAN' P4 P5 (P4 PLUS (1. 0. 0.)) ;
  50. SHAUT = ENV1 ELEM 'APPU' 'STRI' PHAUT ;
  51. *
  52. *-----------------------------------------------------------------------*
  53. * Modeles *
  54. *-----------------------------------------------------------------------*
  55. * Modele mecanique
  56. MOMEC = 'MODE' VOL1 'MECANIQUE' 'ELASTIQUE' ;
  57. MAMEC = 'MATE' MOMEC 'YOUN' 200.E9 'NU' 0.3 ;
  58. *
  59. *-----------------------------------------------------------------------*
  60. * Conditions aux limites *
  61. *-----------------------------------------------------------------------*
  62. * Encastrement
  63. BL1 = BLOQ 'DEPL' SUR1 ;
  64. *
  65. *-----------------------------------------------------------------------*
  66. * Chargements *
  67. *-----------------------------------------------------------------------*
  68. * Pression repartie sur la face superieure
  69. PMAX = 2.E6 ;
  70. CHX = 'COOR' SHAUT 1 ;
  71. CHP = PMAX * ((CHX - ('MINI' CHX)) / (('MAXI' CHX) - ('MINI' CHX))) ;
  72. LTPS = 'PROG' 0. 5. 10. ; LCOE = 'PROG' 0. 1. 2. ;
  73. EV1 = EVOL 'MANU' 'TEMP' LTPS 'COEF' LCOE ;
  74. *
  75. * Chargement PRES avec un CHPOINT
  76. F1 = 'PRES' 'MASS' MOMEC CHP ;
  77. CHAR1 = 'CHAR' 'MECA' F1 EV1 ;
  78. *
  79. * Chargement PRES avec un MCHAML
  80. F2 = 'PRES' 'MASS' MOMEC ('CHAN' 'CHAM' CHP SHAUT) ;
  81. CHAR2 = 'CHAR' 'MECA' F2 EV1 ;
  82. *
  83. * Trace
  84. V1 = 'VECT' F1 'FORC' 'ROUG' ;
  85. 'SI' ITRAC ;
  86. TITR_Z = 'CHAI' 'Pression repartie' ;
  87. TRAC 'CACH' V1 (SHAUT ET ('ARETE' ENV1)) 'TITR' TITR_Z ;
  88. 'FINSI' ;
  89. *
  90. *-----------------------------------------------------------------------*
  91. * Resolution *
  92. *-----------------------------------------------------------------------*
  93. * Resolution avec PASAPAS
  94. TAB1 = TABL ;
  95. TAB1.'MODELE' = MOMEC ;
  96. TAB1.'CARACTERISTIQUES' = MAMEC ;
  97. TAB1.'BLOCAGES_MECANIQUES' = BL1 ;
  98. TAB1.'CHARGEMENT' = CHAR1 ;
  99. TAB1.'TEMPS_CALCULES' = LTPS ;
  100. PASAPAS TAB1 ;
  101. *
  102. TAB2 = TABL ;
  103. TAB2.'MODELE' = MOMEC ;
  104. TAB2.'CARACTERISTIQUES' = MAMEC ;
  105. TAB2.'BLOCAGES_MECANIQUES' = BL1 ;
  106. TAB2.'CHARGEMENT' = CHAR2 ;
  107. TAB2.'TEMPS_CALCULES' = LTPS ;
  108. PASAPAS TAB2 ;
  109. *
  110. *-----------------------------------------------------------------------*
  111. * Visualisation *
  112. *-----------------------------------------------------------------------*
  113. * Deformee de la poutre
  114. DEP1 = TAB1.'DEPLACEMENTS' ;DEP2 = TAB2.'DEPLACEMENTS' ;
  115. DEF_T0 = 'DEFO' VOL1 DEP1. 0 1 VERT ;
  116. 'REPE' BDEP ('DIME' DEP1) ;
  117. DEF1_TI = 'DEFO' VOL1 DEP1. (&BDEP - 1) 10. ROUGE ;
  118. DEF2_TI = 'DEFO' VOL1 DEP2. (&BDEP - 1) 10. BLEU ;
  119. 'SI' ITRAC ;
  120. TITR_Z = 'CHAI' 'Instant ' TAB1.'TEMPS'. (&BDEP - 1) ;
  121. TRAC (DEF_T0 'ET' DEF1_TI 'ET' DEF2_TI) 'TITR' TITR_Z 'CACH' ;
  122. 'FINSI' ;
  123. 'FIN' BDEP ;
  124. *
  125. *-----------------------------------------------------------------------*
  126. * Comparaison des resultats *
  127. *-----------------------------------------------------------------------*
  128. PT = VOL1 POIN PROC (P5 PLUS (LONG 0. 0.)) ;
  129. DEP1_PT = 'EXTR' (TAB1.'DEPLACEMENTS'. (('DIME' DEP1) - 1)) 'UZ' PT ;
  130. DEP2_PT = 'EXTR' (TAB2.'DEPLACEMENTS'. (('DIME' DEP2) - 1)) 'UZ' PT ;
  131. ERRMAX = 'ABS' (DEP1_PT - DEP2_PT) ;
  132. 'SI' (ERRMAX '>' 1.E-3) ;
  133. 'ERRE' 5 ;
  134. 'FINSI' ;
  135. *
  136. 'FIN' ;
  137.  
  138.  
  139.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales