Télécharger test_met.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : test_met.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *-----------------------------------------
  5. *Tracé des courbes (T;pA) en fonction de V
  6. *-----------------------------------------
  7.  
  8. * Mettre GRAPH a VRAI si trace en interactif, sinon trace en Postscript
  9. GRAPH = FAUX ;
  10. 'SI' ('NON' GRAPH) ; 'OPTION' 'TRAC' 'PSC' ; 'FINSI' ;
  11.  
  12. *------------------------------------------------------------------PRO1
  13. DEBPROC PRO1 Vc*FLOTTANT;
  14.  
  15. OPTI DIME 3 ELEM cub8 echo 1;
  16. *Definition du maillage
  17. *----------------------
  18. p0 = 0. 0. 0.;
  19. e1 = 1. 0. 0.;
  20. e2 = 0. 1. 0.;
  21. e3 = 0. 0. 1.;
  22. l1 = d 1 P0 (p0 plus e1);
  23. s1 = l1 tran 1 e2;
  24. v1 = s1 volu 1 tran e3;
  25. TRACE v1;
  26.  
  27. *Definition du modèle de mélange
  28. *-------------------------------
  29. mm2 = mode v1 melange TMM_LMT2;
  30.  
  31. *chargement thermique et temporel
  32. *--------------------------------
  33. TI=830.;
  34. TCF=1000.;
  35. *TF=20.;
  36. pas_T=1.;
  37. *VR=10.;
  38. LIST_T=PROG TI pas pas_T TCF;
  39. LIST_TPS=PROG 0. pas (pas_T / VC) ((1/VC) * (TCF - TI));
  40.  
  41. *======================Calcul sur plusieurs pas=========================
  42. *Création de la table
  43. *--------------------
  44. tm = TABLE;
  45. tm.TEMPERATURE=TABLE;
  46. tm.TEMPS=TABLE;
  47. tm.PHASE1=TABLE;
  48. tm.PHASE2=TABLE;
  49. tm.PHASE3=TABLE;
  50. tm.PHASE4=TABLE;
  51. tm.PHASE5=TABLE;
  52. tm.TPSINCUB=TABLE;
  53. tm.Amax=TABLE;
  54.  
  55. *Valeurs initiales de la table:
  56. *------------------------------
  57. tm.PHASE1.0=1.;
  58. tm.PHASE2.0=0.;
  59. tm.PHASE3.0=0.;
  60. tm.PHASE4.0=0.;
  61. tm.PHASE5.0=0.;
  62. tm.TPSINCUB.0=0.;
  63. tm.Amax.0=0.;
  64. tm.TEMPERATURE=LIST_T;
  65. tm.TEMPS=LIST_TPS;
  66.  
  67. *Préparation au dépouillement:
  68. *-----------------------------
  69. R_PHA1=PROG tm.PHASE1.0;
  70. R_PHA2=PROG tm.PHASE2.0;
  71. R_PHA3=PROG tm.PHASE3.0;
  72. R_PHA4=PROG tm.PHASE3.0;
  73. R_PHA5=PROG tm.PHASE3.0;
  74. R_TINC=PROG tm.TPSINCUB.0;
  75. m=0.;
  76.  
  77. *************************BOUCLE*****************************************
  78. REPETE i ((DIME LIST_T) - 1);
  79. *initialisation de la temperature et du temps au cours du pas:
  80. *-------------------------------------------------------------
  81. chtb0=MANU chml v1 'T' (EXTR (tm.TEMPERATURE) &i);
  82. chtb1=MANU chml v1 'T' (EXTR (tm.TEMPERATURE) (&i + 1));
  83. tps0=MANU chml v1 'TEMP' (EXTR (tm.TEMPS) &i);
  84. tps1=MANU chml v1 'TEMP' (EXTR (tm.TEMPS) (&i + 1));
  85. *composantes à l'état initial
  86. *----------------------------
  87. camb0=MATE mm2 'PHA1' tm.PHASE1.(&i - 1) 'PHA2' tm.PHASE2.(&i - 1)
  88. 'PHA3' tm.PHASE3.(&i - 1) 'tinc' tm.TPSINCUB.(&i - 1) 'AC1' 839.
  89. 'Ka' 0.066 'm' 1.3767 'Kea' 6.787626E15 'Eea' 456380.4166 'Ms' 420.
  90. 'Ks' 0.0354244 'Ar' 0.040628 'Br' 897. 'Cr' 43.68
  91. 'Amax' tm.Amax.(&i - 1) 'n' 2.5 'TF1' 1450. 'TF2' 1500.
  92. 'PHA4' tm.PHASE4.(&i - 1) 'PHA5' tm.PHASE5.(&i - 1);
  93. *Calcul avec l'opérateur COMP
  94. *----------------------------
  95. chobm = COMP mm2 (camb0 et chtb0 et tps0) (chtb1 et tps1);
  96. tm.PHASE1.&i=EXTR (EXCO chobm 'PHA1') 'PHA1' 1 1 1;
  97. tm.PHASE2.&i=EXTR (EXCO chobm 'PHA2') 'PHA2' 1 1 1;
  98. tm.PHASE3.&i=EXTR (EXCO chobm 'PHA3') 'PHA3' 1 1 1;
  99. tm.PHASE4.&i=EXTR (EXCO chobm 'PHA4') 'PHA4' 1 1 1;
  100. tm.PHASE5.&i=EXTR (EXCO chobm 'PHA5') 'PHA5' 1 1 1;
  101. tm.TPSINCUB.&i=EXTR (EXCO chobm 'tinc') 'tinc' 1 1 1;
  102. tm.Amax.&i=EXTR (EXCO chobm 'Amax') 'Amax' 1 1 1;
  103. *dépouillement:
  104. *--------------
  105. *proportion de phase1:
  106. R_PHA1=R_PHA1 ET (PROG tm.PHASE1.&i);
  107. *proportion de phase2:
  108. R_PHA2=R_PHA2 ET (PROG tm.PHASE2.&i);
  109. *proportion de phase3:
  110. R_PHA3=R_PHA3 ET (PROG tm.PHASE3.&i);
  111. *proportion de phase4:
  112. R_PHA4=R_PHA4 ET (PROG tm.PHASE4.&i);
  113. *proportion de phase5:
  114. R_PHA5=R_PHA5 ET (PROG tm.PHASE5.&i);
  115. *temps d'incubation:
  116. R_TINC=R_TINC ET (PROG tm.TPSINCUB.&i);
  117. *Température de début de transformation:
  118. *---------------------------------------
  119. SI ((m EGA 0.) ET (tm.PHASE2.&i > 0.));
  120. m=1.;
  121. Tdeb=EXTR (tm.TEMPERATURE) &i;
  122. FINSI;
  123. S_PHA2=R_PHA2;
  124. S_T=LIST_T;
  125. FIN i;
  126. FINPROC S_T S_PHA2;
  127. *----------------------------------------------------------------------
  128.  
  129. ****************************V=0.1
  130. *points expérimentaux
  131. E_PHA2=PROG 1. 10. 20. 30. 40. 50. 60. 70. 80. 90. 99.;
  132. E_PHA2=E_PHA2 * 1.E-2;
  133. E_T=PROG 854.74 857.87 859.89 861.88 863.23 865.18 867.63 870.29 873.34
  134. 879.64 898.72;
  135. *courbe expérimentale:
  136. EVE01=EVOL VERT 'MANU' 'temperature' E_T 'PHA2' E_PHA2;
  137. *courbe simulée:
  138. S_T S_PHA2=PRO1 0.1;
  139. EVS01=EVOL VERT 'MANU' 'temperature' S_T 'PHA2' S_PHA2;
  140.  
  141. ****************************V=1
  142. *points expérimentaux
  143. E_PHA2=PROG 1. 10. 20. 30. 40. 50. 60. 70. 80. 90. 99.;
  144. E_PHA2=E_PHA2 * 1.E-2;
  145. E_T=PROG 867.24 872.08 874.30 876.29 877.94 879.98 882.05 884.63 888.08
  146. 895.32 918.32;
  147. *courbe expérimentale:
  148. EVE1=EVOL ROUG 'MANU' 'temperature' E_T 'PHA2' E_PHA2;
  149. *courbe simulée:
  150. S_T S_PHA2=PRO1 1.;
  151. EVS1=EVOL ROUG 'MANU' 'temperature' S_T 'PHA2' S_PHA2;
  152.  
  153. ****************************V=100
  154. *points expérimentaux
  155. E_PHA2=PROG 1. 10. 20. 30. 40. 50. 60. 70. 80. 90. 99.;
  156. E_PHA2=E_PHA2 * 1.E-2;
  157. E_T=PROG 897.57 912.98 918.93 922.92 925.78 928.49 931.40 933.81 938.40
  158. 944.56 951.78;
  159. *courbe expérimentale:
  160. EVE100=EVOL BLEU 'MANU' 'temperature' E_T 'PHA2' E_PHA2;
  161. *courbe simulée:
  162. S_T S_PHA2=PRO1 100.;
  163. EVS100=EVOL BLEU 'MANU' 'temperature' S_T 'PHA2' S_PHA2;
  164.  
  165.  
  166.  
  167.  
  168. *Tracé des courbes:
  169. tabdess = table;
  170. tabdess . 1 = 'MARQ TRIA NOLI' ;
  171. tabdess . 2 = 'MARQ LOSA NOLI' ;
  172. tabdess . 3 = 'MARQ CARR NOLI' ;
  173. tabdess . 'TITRE' = table ;
  174. tabdess . 'TITRE' . 1 = MOT 'courbe expérimentale V=0.1°C/s' ;
  175. tabdess . 'TITRE' . 2 = MOT 'courbe expérimentale V=1°C/s' ;
  176. tabdess . 'TITRE' . 3 = MOT 'courbe expérimentale V=100°C/s' ;
  177. tabdess . 'TITRE' . 4 = MOT 'courbe simulée V=0.1°C/s' ;
  178. tabdess . 'TITRE' . 5 = MOT 'courbe simulée V=1°C/s' ;
  179. tabdess . 'TITRE' . 6 = MOT 'courbe simulée V=100°C/s' ;
  180. DESS (EVE01 ET EVE1 ET EVE100 ET EVS01 ET EVS1 ET EVS100) LEGE
  181. TITX 'temperature' TITY 'pA' tabdess;
  182. FIN;
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales