Télécharger super4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : super4.dgibi
  2. * section : thermique conduction convection
  3. *----------------------------------------------------------------------*
  4. * S U P E R 4 . D G I B I *
  5. *----------------------------------------------------------------------*
  6. * Objet :
  7. * -------
  8. *
  9. * Exemple d'utilisation du SUPERELEMENT, option MASSE, en thermique
  10. * transitoire sur un probleme avec conduction & convection.
  11. *
  12. * En transitoire, la solution obtenue avec le superelement utilise
  13. * une capacite equivalente qui ne peut qu'approcher la solutione exacte.
  14. * L'erreur comise dans ce cas est d'autant plus grande que le temps
  15. * caracteristique du transitoire est faible.
  16. *
  17. * La resolution du probleme de thermique transitoire est faite sur
  18. * un maillage contenant 2 elements finis. La condensation statique du
  19. * probleme porte sur l'element 2. Une description du probleme traite
  20. * est proposee ci-dessous. Les solutions obtenues avec et sans super-
  21. * -element sont comparees.
  22. *
  23. * Description :
  24. * -------------
  25. *
  26. * Type de calcul : Thermique trasitoire conduction + convection
  27. * Mode de calcul : 2D
  28. * Type d'element : QUA8
  29. * Chargement : Temperature et flux imposes,
  30. * Echange par convection avec milieu a Text
  31. * Reference : Comparaison des solutions avec et sans superelement
  32. * Objectif : Ecart relatif < 5 %
  33. *
  34. * Ilustration :
  35. * -------------
  36. *
  37. * Temperature initiale : Tini = 20
  38. * ----------------------
  39. *
  40. * Flux impose
  41. * -----------
  42. * q = 10.e3
  43. * ^ ^ ^ ^
  44. * | | | |
  45. * _______
  46. * | | |>
  47. * | | |
  48. * | s2 | |> Echange par convection
  49. * | | | ----------------------
  50. * |-------| |> h = 20, Te = 20
  51. * | | |
  52. * | s1 | |>
  53. * | | |
  54. * |_______| |>
  55. * x x x x
  56. * T = 20
  57. * -------------------
  58. * Temperature imposee
  59. *
  60. *----------------------------------------------------------------------*
  61. *
  62. * Pour affichage, mettre IG1 a vrai :
  63. ig1 = faux ;
  64.  
  65. *------------------------------ Maillage ------------------------------*
  66.  
  67. opti dime 2 elem qua8 ;
  68.  
  69. * 1er domaine :
  70. a = 0.1 ;
  71. l1 = (0 0) droi 1 (a 0) ;
  72. s1 = l1 tran 1 (0 a) ;
  73. l2 = s1 cote 2 ;
  74. l3 = s1 cote 3 ;
  75.  
  76. * 2e domaine :
  77. s2 = l3 tran 1 (0 a) ;
  78. l5 = s2 cote 4 ;
  79. l6 = s2 cote 3 ;
  80.  
  81. * Affichage :
  82. si ig1 ;
  83. trac (s1 et s2) qual ;
  84. fins ;
  85.  
  86. * Domaine complete :
  87. s0 = s1 et s2 ;
  88.  
  89. *------------------------------- Modele -------------------------------*
  90.  
  91. * Modele - Caracteristiques :
  92. mo1 = mode s1 thermique ;
  93. mo2 = mode s2 thermique ;
  94. ma1 = mate mo1 'K' 25. 'RHO' 7.5e3 'C' 400. tini 20. ;
  95. ma2 = mate mo2 'K' 25. 'RHO' 7.5e3 'C' 400. tini 20. ;
  96.  
  97. moc1 = mode l2 thermique convection ;
  98. moc2 = mode l5 thermique convection ;
  99. mac1 = mate moc1 h 20. te 20. ;
  100. mac2 = mate moc2 h 20. te 20. ;
  101.  
  102. * Chargement (flux) :
  103. q1 = flux mo1 l1 10.e3 ;
  104. ev1 = evol manu temp (prog 0. 1.e6) (prog 1. 1.) ;
  105. cg1 = char 'Q' q1 ev1 ;
  106.  
  107. *------------------------ Resolution sans SUPE ------------------------*
  108.  
  109. * Liste temps calcules :
  110. ltca1 = prog 0. pas 200. 7200. ;
  111.  
  112. * Table PASAPAS :
  113. ta1 = tabl ;
  114. ta1.modele = mo1 et mo2 et moc1 et moc2 ;
  115. ta1.caracteristiques = ma1 et ma2 et mac1 et mac2 ;
  116. ta1.chargement = cg1 ;
  117. ta1.temps_calcules = ltca1 ;
  118.  
  119. pasapas ta1 ;
  120.  
  121. * Affichage solution sans SUPE :
  122. if1 = dime ta1.temperatures - 1 ;
  123. cht1 = ta1.temperatures.if1 ;
  124. si ig1 ;
  125. trac cht1 s0 titr 'Temperature solution sans SUPE' ;
  126. fins ;
  127.  
  128. *------------------------ Resolution avec SUPE ------------------------*
  129. *
  130. * Construction superelement, conductivites et capacites equivalentes :
  131. k2 = cond mo2 ma2 ;
  132. kc2 = cond moc2 mac2 ;
  133. cp2 = capa mo2 ma2 ;
  134. qc2 = conv moc2 mac2 'T' 20. ;
  135.  
  136. su1 = supe rigidite (k2 et kc2) l3 ;
  137. ksu1 = extr su1 rigi ;
  138. csu1 = supe masse su1 cp2 ;
  139. qsu1 = supe charge su1 qc2 ;
  140. cgsu1 = char 'Q' qsu1 ev1 ;
  141.  
  142. * Table PASAPAS :
  143. ta2 = tabl ;
  144. ta2.modele = mo1 et moc1 ;
  145. ta2.caracteristiques = ma1 et mac1 ;
  146. ta2.chargement = cg1 et cgsu1 ;
  147. ta2.conductivite_constante = ksu1 ;
  148. ta2.capacite_constante = csu1 ;
  149. ta2.temps_calcules = ltca1 ;
  150.  
  151. pasapas ta2 ;
  152.  
  153. * Affichage solution avec SUPE :
  154. if1 = dime ta2.temperatures - 1 ;
  155. chtsu1 = ta2.temperatures.if1 ;
  156. si ig1 ;
  157. trac (chtsu1 - (redu cht1 s1)) s1 titr 'Difference solutions avec-sans SUPE sur partie non condensee' ;
  158. fins ;
  159.  
  160. chtsu1 = supe depla su1 chtsu1 (q1 et qc2) ;
  161. si ig1 ;
  162. trac (chtsu1 - cht1) s0 titr 'Difference solutions avec-sans SUPE' ;
  163. trac chtsu1 s0 titr 'Temperature solution avec SUPE' ;
  164. fins ;
  165.  
  166. *------------------------- Test de validation -------------------------*
  167.  
  168. err1 = maxi abs (cht1 - chtsu1) / (maxi abs cht1) ;
  169.  
  170. list err1 ;
  171. si (err1 > 0.05) ;
  172. erre 5 ;
  173. fins ;
  174.  
  175. fin ;
  176.  
  177.  
  178.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales