Télécharger stru3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : stru3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. OPTI ECHO 1;
  5. GRAPH = 'N';
  6. *
  7. *********************************************************************
  8. * TEST : SSLS34/91 DE LA COMMISSION "STRUCTURES ASSEMBLEES" *
  9. * ---- *
  10. * *
  11. * DESCRIPTION : PLAQUE ORTHOTROPE RAIDIE SUR APPUIS SIMPLES, *
  12. * SOUS UNE CHARGE UNIFORMEMENT REPARTIE. *
  13. * Elements DKT *
  14. * *
  15. * *
  16. * REF. : JL. BATOZ,J.CHATELAIN,JP. JAMEUX *
  17. * ETUDE D'UNE PLAQUE RAIDIE - BULLETIN DU CLUB S.A.P - *
  18. * VOLUME VIII, N›1. *
  19. * Comparaison avec les codes CA.ST.OR, ASELF, ELFINI, PERMAS *
  20. * Test envoye pour evolution le 17/09/92 *
  21. * *
  22. *********************************************************************
  23. OPTI ECHO 0;
  24. OPTI ELEM tri3;
  25. *
  26. * QUELQUES DONNEES
  27. *
  28. OEIL = 10000 -10000 10000;
  29. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  30. * GEOMETRIE *
  31. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  32. *
  33. * PLAQUE SUPERIEURE
  34. *
  35. PA = 0 .5 0; PB =1. .5 0; PD = 1. 0 0; PC = 0 0 0;
  36. PF = .6667 0 0; PE = .3333 0 0;
  37. *
  38. DAB = PA DROIT 36 PB; DBD = PB DROIT 20 PD;
  39. DDC = PD DROIT 36 PC; DCA = PC DROIT 20 PA;
  40. SU1 = DALLER DAB DBD DDC DCA PLAN;
  41. *
  42. * RAIDISSEUR CENTRAL
  43. *
  44. PA2 = 0 .5 -.1; PC2 = 0 0 -.1;
  45. D1 = PA DROIT 20 PC;
  46. D3 = PC2 DROIT 20 PA2;
  47. D2 = PC DROIT 4 PC2;
  48. D4 = PA2 DROIT 4 PA;
  49. RA1 = DALL D1 D2 D3 D4 PLAN;
  50. *
  51. * SEGMENTS DE DROITES POUR CONDITIONS DE SYMETRIE
  52. *
  53. D5 = D2 PLUS (.33333 0. 0.);
  54. D6 = D2 PLUS (.66667 0. 0.);
  55. *
  56. * RAIDISSEURS 2 ET 3
  57. *
  58. RA2 = RA1 PLUS (.33333 0 0);
  59. RA3 = RA1 PLUS (.66667 0 0);
  60. SURF = SU1 ET RA1 ET RA2 ET RA3;
  61. ELIM (SURF ET D1 ET D2 ET D3 ET D4 ET D5 ET D6) .001;
  62. *
  63. SI (NEG GRAPH 'N');
  64. TRAC OEIL SURF;
  65. FINSI;
  66. *
  67. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  68. * MODELE
  69. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  70. *
  71. MODL1 = MODE RA1 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  72. MODL2 = MODE RA2 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  73. MODL3 = MODE RA3 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  74. MODL4 = MODE SU1 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  75. MODL5 = MODL1 ET MODL2 ET MODL3 ET MODL4;
  76.  
  77. *
  78. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  79. * MATERIAUX - CARACTERISTIQUES *
  80. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  81. *
  82. DIR1 = 0. 1. 0.;
  83. *
  84. MAT1 = MATE MODL1 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11
  85. NU12 .3 G12 .222E11 EPAI 0.005;
  86. *
  87. MAT2 = MATE MODL2 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11
  88. NU12 .3 G12 .222E11 EPAI 0.01 ;
  89. *
  90. MAT3 = MATE MODL3 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11
  91. NU12 .3 G12 .222E11 EPAI 0.01 ;
  92. *
  93. MAT4 = MATE MODL4 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11
  94. NU12 .3 G12 .222E11 EPAI 0.006 ;
  95.  
  96. MAT = MAT1 ET MAT2 ET MAT3 ET MAT4;
  97. *
  98.  
  99. *
  100. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  101. * CONDITIONS AUX LIMITES *
  102. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  103. *
  104. CL1 = BLOQUE DAB UZ;
  105. CL2 = BLOQUE DAB RY;
  106. CL3 = BLOQUE DBD UZ;
  107. CL4 = BLOQUE DBD RX;
  108. CL5 = SYMT DEPL ROTA (0 0 0) (0 1 0) (0 0 1) SURF 0.0001;
  109. CL6 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 0 1) SURF 0.0001;
  110. CL = CL1 ET CL2 ET CL3 ET CL4 ET CL5 ET CL6;
  111. *
  112. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  113. * CHARGEMENT *
  114. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  115. *
  116. MOP = 'MODE' SU1 'CHARGEMENT' 'PRESSION' 'DKT' ;
  117. MAP = 'MATE' MOP 'PRES' 5E4 'EPAI' 0.006 ;
  118. CH = 'PRES' MOP MAP ;
  119. *
  120. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  121. * RESOLUTION - CALCUL ELASTIQUE *
  122. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  123. *
  124. RI = RIGI MODL5 MAT;
  125. RIG = RI ET CL ;
  126. DEP = RESO RIG CH ;
  127. *
  128. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  129. * RESULTATS *
  130. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  131. *
  132. NOSURF = NBNO SURF ;
  133. ELSURF = NBEL SURF ;
  134. *
  135. SI (NEG GRAPH 'N');
  136. TITR ' PLAQUE RAIDIE : DEFORMEE ' ;
  137. DEF0 = DEFO SURF DEP 0. ;
  138. DEF1 = DEFO SURF DEP 25. ROUGE;
  139. TRACE OEIL (DEF0 ET DEF1) ;
  140. OEIL =0.25 -1.E6 0.;
  141. TRACE OEIL (DEF0 ET DEF1) ;
  142. FINSI ;
  143. *
  144. UZC = EXTR DEP UZ PC ;
  145. UZC1 = -.603e-3;
  146. ERG1 = ABS ((UZC - UZC1) / UZC1) * 100 ;
  147. *
  148. DZ = EXCO DEP UZ;
  149. ZMIN = MINI DZ;
  150. ZMIN1 = -.319e-2;
  151. ERG2 = ABS ((ZMIN - ZMIN1) / ZMIN1) * 100 ;
  152.  
  153.  
  154. *
  155. X1 = DZ POIN 'MINI';
  156. XX = MAXI ( COOR 1 X1);
  157. XX1 = 0.833;
  158. ERG3 = ABS ((XX - XX1) / XX1) * 100 ;
  159.  
  160. SAUT PAGE ;
  161. OPTI ECHO 0;
  162. *
  163. MESS ' TEST : SSLS34/90 (FICHIER stru3.DGIBI)';
  164. MESS ' ----';
  165. MESS ' PLAQUE ORTHOTROPE RAIDIE
  166. CHARGEE UNIFORMEMENT SUR APPUIS SIMPLES '
  167. *
  168. SAUT 2 LIGN ;
  169. MESS ' RESULTATS ';
  170. MESS ' --------- ';
  171. *
  172. SAUT 2 LIGN ;
  173. MESS ' DEPLACEMENT THEORIQUE AU POINT PC : ' UZC1 'METRES';
  174. MESS ' DEPLACEMENT CALCULE AU POINT PC : ' UZC 'METRES' ;
  175. MESS ' SOIT UN ECART DE : ' ERG1 '%' ;
  176. *
  177. SAUT 2 LIGN ;
  178. MESS ' DEPLACEMENT THEORIQUE MAXIMUM (ABS) : ' ZMIN1 'METRES';
  179. MESS ' DEPLACEMENT CALCULE MAXIMUM (ABS) : ' ZMIN 'METRES';
  180. MESS ' SOIT UN ECART DE : ' ERG2 '%' ;
  181. *
  182. SAUT 1 LIGNE;
  183. MESS ' ABSICE DU POINT OU SE TROUVE LE MAXIMUM : ' ;
  184. MESS ' - ABSICE THEORIQUE : ' XX1 'METRES';
  185. MESS ' - ABSICE CALCULEE : ' XX 'METRES';
  186. MESS ' SOIT UN ECART DE : ' ERG3 '%' ;
  187. *
  188. SAUT 1 LIGNE;
  189. MESS ' NOMBRE DE NOEUDS : ' NOSURF ;
  190. MESS ' NOMBRE D ELEMENTS : ' ELSURF ;
  191. *
  192. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  193. * CODE FONCTIONNEMENT *
  194. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  195. *
  196. ERGMAX = MAXI (PROG ERG1 ERG2);
  197. *
  198. * Il y a erreur si un des pourcentages ERG* est suprieur 5%
  199. *
  200. *
  201. SI (ERGMAX <EG 5.);
  202. ERRE 0 ;
  203. SINON;
  204. ERRE 5 ;
  205. FINSI;
  206. *
  207. TEMPS;
  208. *
  209. FIN;
  210.  
  211.  
  212.  
  213.  
  214.  
  215.  
  216.  
  217.  
  218.  
  219.  
  220.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales