Télécharger stru1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : stru1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  5. SAUT PAGE;
  6.  
  7. *********************************************************************
  8. * *
  9. * TEST STRU1 *
  10. * *
  11. * PLAQUE RAIDIE SUR APPUIS SIMPLES, SOUS CHARGE UNIFORMEMENT *
  12. * REPARTIE *
  13. * *
  14. * La plaque rectangulaire de 2 metre de long, de 1 metre de *
  15. * large et 0.06 metre d'epaisseur est raidie a l'aide de 6 *
  16. * raidisseurs de 0.01 metre d'epaisseur. *
  17. * *
  18. * La plaque superieure (uniquement) repose simplement sur les *
  19. * quatre cotes et est uniformement chargee. *
  20. * *
  21. * Pour des raisons de symetrie on ne maille que le quart de la *
  22. * structure. *
  23. * *
  24. * On se propose de chercher : *
  25. * - d'une part le deplacement vertical du milieu de la plaque,*
  26. * - d'autre part le deplacement vertical maximal. *
  27. * *
  28. * Ref. : JL. BATOZ,J.CHATELAIN,JP. JAMEUX *
  29. * ETUDE D UNE PLAQUE RAIDIE *
  30. * BULLETIN DU CLUB S.A.P - VOLUME VIII, N1 *
  31. * *
  32. *********************************************************************
  33.  
  34. GRAPH = 'N';
  35.  
  36. SAUT PAGE;
  37. SI (NEG GRAPH 'N') ;
  38. OPTI ECHO 1 ;
  39. OPTI TRAC PSC ;
  40. SINO ;
  41. OPTI ECHO 0 ;
  42. FINSI ;
  43.  
  44. SAUT PAGE;
  45. *
  46. OPTION ELEM QUA4;
  47.  
  48. *
  49. * QUELQUES DONNEES
  50. *
  51. OEIL = 10000 -10000 10000;
  52. *
  53. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  54. * GEOMETRIE *
  55. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  56. *
  57. * PLAQUE SUPERIEURE
  58. *
  59. PA = 0 .5 0; PB =1. .5 0; PD = 1. 0 0; PC = 0 0 0;
  60. PF = .6667 0 0; PE = .3333 0 0;
  61. *
  62. DAB = PA DROIT 18 PB; DBD = PB DROIT 10 PD;
  63. DDC = PD DROIT 18 PC; DCA = PC DROIT 10 PA;
  64. SU1 = DALLER DAB DBD DDC DCA PLAN;
  65. *
  66. * RAIDISSEUR CENTRAL
  67. *
  68. PA2 = 0 .5 -.1; PC2 = 0 0 -.1;
  69. D1 = PA DROIT 10 PC;
  70. D3 = PC2 DROIT 10 PA2;
  71. D2 = PC DROIT 2 PC2;
  72. D4 = PA2 DROIT 2 PA;
  73. RA1 = DALL D1 D2 D3 D4 PLAN;
  74. *
  75. * SEGMENTS DE DROITES POUR CONDITIONS DE SYMETRIE
  76. D5 = D2 PLUS (.33333 0. 0.);
  77. D6 = D2 PLUS (.66667 0. 0.);
  78. *
  79. * RAIDISSEURS 2 ET 3
  80. *
  81. RA2 = RA1 PLUS (.33333 0 0) ;
  82. RA3 = RA1 PLUS (.66667 0 0) ;
  83. *
  84. SURF = SU1 ET RA1 ET RA2 ET RA3;
  85. *
  86. ELIM SURF .0001;
  87. ELIM (SURF ET D1 ET D2 ET D3 ET D4 ET D5 ET D6) .001;
  88. *
  89. SI (NEG GRAPH 'N');
  90. TITR ' TEST STRU1 : MAILLAGE';
  91. TRAC CACH OEIL QUAL SURF;
  92. FINSI;
  93. *
  94. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  95. * MODELE *
  96. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  97. *
  98. MODL1 = MODE RA1 MECANIQUE ELASTIQUE ISOTROPE COQ4;
  99. MODL2 = MODE RA2 MECANIQUE ELASTIQUE ISOTROPE COQ4;
  100. MODL3 = MODE RA3 MECANIQUE ELASTIQUE ISOTROPE COQ4;
  101. MODL4 = MODE SU1 MECANIQUE ELASTIQUE ISOTROPE COQ4;
  102. MODL5 = MODL1 ET MODL2 ET MODL3 ET MODL4;
  103. *
  104. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  105. * MATERIAUX - CARACTERISTIQUES *
  106. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  107. *
  108. MATR1 = MATE MODL1 YOUN 2.E11 NU 0.3 EPAI 0.005 EXCEN 0.0025;
  109. MATR2 = MATE MODL2 YOUN 2.E11 NU 0.3 EPAI 0.01 EXCEN 0.0;
  110. MATR3 = MATE MODL3 YOUN 2.E11 NU 0.3 EPAI 0.01 EXCEN 0.0;
  111. MATR4 = MATE MODL4 YOUN 2.E11 NU 0.3 EPAI 0.006 EXCEN 0.0;
  112. MATR5 = MATR1 ET MATR2 ET MATR3 ET MATR4;
  113. *
  114. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  115. * CONDITIONS AUX LIMITES *
  116. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  117. *
  118. CL1 = BLOQUE DAB UZ;
  119. CL2 = BLOQUE DAB RY;
  120. CL3 = BLOQUE DBD UZ;
  121. CL4 = BLOQUE DBD RX;
  122. CL5 = SYMT DEPL ROTA (0 0 0) (0 1 0) (0 0 1) SURF 0.0001;
  123. CL6 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 0 1) SURF 0.0001;
  124. CL = CL1 ET CL2 ET CL3 ET CL4 ET CL5 ET CL6;
  125. *
  126. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  127. * CHARGEMENT
  128. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  129. *
  130. MOP = 'MODE' SU1 'CHARGEMENT' 'PRESSION' 'COQ4' ;
  131. MAP = 'MATE' MOP 'PRES' 5E4 'EPAI' 0.006 ;
  132. CHARG = 'PRES' MOP MAP ;
  133. *
  134. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  135. * RESOLUTION - CALCUL ELASTIQUE
  136. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  137. *
  138. RIG = RIGI MODL5 MATR5;
  139. RIG = RIG ET CL;
  140. *
  141. DEP = RESO RIG CHARG;
  142. *
  143. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  144. * RESULTATS
  145. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  146. *
  147. NOSURF = NBNO SURF ;
  148. ELSURF = NBEL SURF ;
  149. *
  150. SI (NEG GRAPH 'N');
  151. AMPL1 = 1.E-5;
  152. REA1 = REAC DEP RIG;
  153. VE = VECT REA1 AMPL1 FX FY FZ BLEU ;
  154. VF = VECT CHARG (AMPL1 * 20) FX FY FZ ROUGE;
  155. VV = VE ET VF;
  156. DEF0 = DEFO SURF DEP 0.;
  157. DEF1 = DEFO SURF DEP 25. VV VERT;
  158. TITR ' STRU1 : DEFORMEE, CHARGEMENT, REACTIONS' ;
  159. TRACE OEIL (DEF0 ET DEF1);
  160.  
  161. TITR 'STRU1 : Deplacements UZ';
  162. TRAC CACH SURF (EXCO DEP UZ);
  163.  
  164. DEF1 = DEFO SURF DEP 25. ROUGE;
  165. OEIL = 0.25 -1.E6 0.;
  166. TITR ' STRU1 : DEFORMEE';
  167. TRACE OEIL (DEF0 ET DEF1);
  168. FINSI;
  169. *
  170. UZC = EXTR DEP UZ PC ;
  171. UZC1 = -0.475E-3;
  172. ERG1 = ABS ((UZC - UZC1) / UZC1) * 100 ;
  173. *
  174. DZ = EXCO DEP UZ;
  175. ZMIN = MAXI (ABS (DZ)); ZMIN = -1. * ZMIN;
  176. ZMIN1 = -0.126E-2;
  177. ERG2 = ABS ((ZMIN - ZMIN1) / ZMIN1) * 100 ;
  178. *
  179. SAUT PAGE ;
  180. *
  181. MESS ' RESULTATS ';
  182. MESS ' --------- ';
  183. *
  184. MESS ' DEPLACEMENT THEORIQUE AU POINT PC : ' UZC1 'METRES';
  185. MESS ' DEPLACEMENT CALCULE AU POINT PC : ' UZC 'METRES' ;
  186. MESS ' SOIT UN ECART DE : ' ERG1 '%' ;
  187. *
  188. MESS ' DEPLACEMENT THEORIQUE MAXIMUM (ABS) : ' ZMIN1 'METRES';
  189. MESS ' DEPLACEMENT CALCULE MAXIMUM (ABS) : ' ZMIN 'METRES';
  190. MESS ' SOIT UN ECART DE : ' ERG2 '%' ;
  191. *
  192. *SAUT 1 LIGNE;
  193. *MESS ' ABSICE DU POINT OU SE TROUVE LE MAXIMUM : ' ;
  194. *MESS ' - ABSICE THEORIQUE : ' XX1 'METRES';
  195. *MESS ' - ABSICE CALCULEE : ' XX 'METRES';
  196. *MESS ' SOIT UN ECART DE : ' ERG3 '%' ;
  197. *
  198. SAUT 1 LIGNE;
  199. MESS ' Nombre de noeuds : ' NOSURF ;
  200. MESS ' Nombre d elements : ' ELSURF ;
  201. MESS ' Soit ' (NOSURF * 6) 'd.d.l.';
  202. SAUT 1 LIGNE;
  203. *
  204. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  205. * CODE FONCTIONNEMENT *
  206. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  207. *
  208. ERGMAX = MAXI (PROG ERG1 ERG2);
  209. *
  210. * Il y a erreur si un des pourcentages ERG* est suprieur 5%
  211. *
  212. SI (ERGMAX <EG 5.);
  213. ERRE 0 ;
  214. SINO;
  215. ERRE 5 ;
  216. FINSI;
  217. *
  218. TEMPS;
  219.  
  220. FIN;
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  
  227.  
  228.  
  229.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales