Télécharger soudage7.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier soudage7.dgibi
  2. * section : thermique conduction convection rayonnement mecanique plastique
  3. *----------------------------------------------------------------------*
  4. * S O U D A G E 7 . D G I B I *
  5. *----------------------------------------------------------------------*
  6. * Objet :
  7. * -------
  8. *
  9. * Exemple de simulation thermomecanique du soudage d'un raidisseur
  10. * sur une plaque avec apport de matiere (4 passes). Les materiaux sont
  11. * en acier inoxydable (316 L).
  12.  
  13. * On modelise la conduction, la convection et le rayonnement avec le
  14. * milieu ambiant. La source de chaleur suit une distribution gaussienne.
  15. *
  16. * Le materiau a un comportement mecanique elastoplastique a
  17. * ecrouissage isotrope lineaire.
  18.  
  19. * On resout la thermique et la mecanique separemment, par deux appels
  20. * distincts a la procedure PASAPAS.
  21. *
  22. * L'apport de matiere est defini a l'aide d'un chargement de nom MODE
  23. * qui decrit l'evolution du modele au cours du temps. Un chargement de
  24. * nom MATE definit celle de ses caracteristiques.
  25. *
  26. * La procedure SOUDAGE permet de definir la sequence de soudage et
  27. * d'indexer les elements du maillage des cordons de soudure en fonction
  28. * de l'evolution de l'outil le long de la trajectoire de soudage.
  29. *
  30. * Description :
  31. * -------------
  32. *
  33. * Type de calcul : Thermique Transitoire, Mecanique non lineaire materiau
  34. * Mode de calcul : 3D
  35. * Type d'element : CUB8, PRY6
  36. * Chargement : Source de chaleur, Convection, Apport de matiere
  37. *
  38. *----------------------------------------------------------------------*
  39. *
  40. opti dime 3 elem cub8 mode trid ;
  41.  
  42. * Pour affichage traces, mettre IG1 a VRAI :
  43. IG1 = faux ;
  44.  
  45. * Pour calcul complet, mettre icomplet a VRAI :
  46. icomplet = faux ;
  47.  
  48. *opti trac psc eptr 5 ;
  49. ig1 = ig1 ou (ega (vale trac) 'PSC') ;
  50.  
  51. *----------------------------------------------------------------------*
  52. * Donnees du probleme *
  53. *----------------------------------------------------------------------*
  54. *
  55. *----------------------- Parametres geometriques ----------------------*
  56.  
  57. * Geometrie pieces a souder :
  58. * la1 : largeur plaque (m)
  59. * hr1 : hauteur du raidisseur (m)
  60. * lw1 : longueur a souder (m)
  61. * ep1 : epaisseur plaque (m)
  62. * er1 : epaisseur raidisseur (m)
  63. la1 = 60.e-3 ;
  64. hr1 = 40.e-3 ;
  65. lw1 = 30.e-3 ;
  66. ep1 = 30.e-3 ;
  67. er1 = 10.e-3 ;
  68. de1 = 1.5e-3 ;
  69. de2 = 5.e-3 ;
  70. de3 = 15.e-3 ;
  71.  
  72. * Geometrie cordons :
  73. * lc1 : largeur cordons (m)
  74. lc1 = 6.e-3 ;
  75. * Pour la geometrie modelisee, section de cordon identique :
  76. Sc1 = 0.5 * lc1 * lc1 ;
  77. * Positions cordons :
  78. Pc1 = (0.5*er1*(1 0 0)) plus ((lc1 lc1 0.) * 0.5) ;
  79. Pc2 = Pc1 plus (lc1 0. 0.) ;
  80. Pc3 = Pc1 plus ((lc1 lc1 0.) * 0.5) ;
  81. Pc4 = Pc1 plus (0. lc1 0.) ;
  82.  
  83. *--------------------- Donnees probleme thermique ---------------------*
  84.  
  85. * CI / CL :
  86. * Tini1 : temperature initiale :
  87. * Te1 : temperature milieu ambiant :
  88. * h1 : coefficient d'echange convectif (W/m2/K)
  89. * em1 : emissivite
  90. * tps0 : temps de maintien avant debut deplacement torche (s)
  91. Tini1 = 20. ;
  92. Te1 = 20. ;
  93. h1 = 20. ;
  94. em1 = 0.5 ;
  95. tps0 = 1. ;
  96.  
  97. * Parametres soudage :
  98. * Us1 : tension de soudage (V)
  99. * Is1 : Intensite de soudage (A)
  100. * Vs1 : Vitesse de soudage (m/s)
  101. * Vd1 : Vitesse de deplacement (m/s)
  102. * Vf1 : vitesse de debit de fil (m/s)
  103. * Df1 : diametre du fil (m) : pas utilisee dans le calcul
  104. * Xpas1 : pas de discretisation de l'apport de matiere (m)
  105. Us1 = 12. ;
  106. Is1 = 400. ;
  107. Vs1 = 0.3 / 60. ;
  108. Vd1 = 0.1 * Vs1 ;
  109. Df1 = 1.2e-3 ;
  110. Xpas1 = 5.e-3 ;
  111.  
  112. * L'intensite de soudage est deduite du debit volumique de matiere et
  113. * de l'energie thermique qu'il faut fournir pour la fondre (on ne tient
  114. * pas compte du rendement).
  115. * A titre indicatif, calcul effectue pour l'estimer (avec : rho = 7.6e3 kg/m3,
  116. * Cp = 500. J/kg/m3, dT = 1500. degC, Qlat = 1.e9 J/m3)
  117. Is0 = Sc1 * Vs1 * (7.6e3 * 500. * 1500. + 1.e9) / Us1 ;
  118. list Is0 ;
  119.  
  120. * La vitesse de fil est deduite de la section des cordons et de la vitesse
  121. * de soudage. Elle n'intervient pas dans le calcul car geometrie cordon fixee.
  122. * A titre indicatif, son calcul et affichage (m/min.) :
  123. Vf1 = Sc1 * Vs1 / (pi * Df1 * Df1 /4.) ;
  124. List (Vf1 * 60.) ;
  125.  
  126. * Parametres modele source Gaussienne 3D :
  127. * Qtot1 : puissance thermique de la source (J)
  128. * Rg1 : "rayon" de la source Gaussienne (m)
  129. * Zg1 : "profondeur" de la source Gaussienne (m)
  130. Qtot1 = Us1 * Is1 ;
  131. Rg1 = 6.0e-3 ;
  132. Zg1 = 4.5e-3 ;
  133.  
  134. *-------------------------- Donnees materiau --------------------------*
  135. * Ref. :
  136. * Camille Cambon, Issam Bendaoud, Sebastien Rouquette, Fabien Soulie.
  137. * “Influence of the first weld bead on strain and stress states in wire+arc additive manufacturing”.
  138. * The 12th International Seminar ”Numerical Analysis of Weldability”,
  139. * Institute for Materials Science, Joining and Forming (IMAT),Sep 2018, Seggau, Austria.
  140. * hal-01954354 https://hal.archives-ouvertes.fr/hal-01954354
  141. *
  142. * rho1 : masse volumique (kg/m3)
  143. * Tfus1 : temperature de changement de phase solide-liquide (degC)
  144. * Qlat1 : chaleur latente de fusion de l'acier (J/m3)
  145. rho1 = 7760. ;
  146. Tfus1 = 1450. ;
  147. Qlat1 = 2.e9 ;
  148.  
  149. * k1 : conductivite thermique (W/m/K) en fonction de la temperature
  150. lt1 = prog 20. 100. pas 100. 1500. ;
  151. lk1 = prog 14. 15.2 16.6 17.9 19. 20.6 21.8 23.1 24.3 26. 27.3 28.6 29.9 45. 60. 60. ;
  152. k1 = evol vert manu 'T' lt1 'K' lk1 ;
  153. si ig1 ;
  154. dess k1 titr 'Conductivite thermique 316L (W/m/K)' ;
  155. fins ;
  156.  
  157. * Cp1 : capacite thermique massique (J/m3) en fonction de la temperature
  158. * On derive l'enthalpie :
  159. lt1 = prog 0. pas 100. 1500. ;
  160. lh1 = prog 0.983 1.36 1.76 2.19 2.62 3.06 3.51 3.96 4.43 4.92 5.42 5.92 6.44 6.97 9.51 ;
  161. lh2 = prog 1.36 1.76 2.19 2.62 3.06 3.51 3.96 4.43 4.92 5.42 5.92 6.44 6.97 9.51 10.1 ;
  162. dhdt1 = (lh2 - lh1) / 100. ;
  163. lc0 = dhdt1 * 1.e9 / rho1 ;
  164. lt0 = prog 50. pas 100. 1450. ;
  165. cp0 = evol manu 'T' lt0 'C' lc0 ;
  166. idx0 = posi (maxi lc0) dans lc0 ;
  167. lc2 = lc0 enle idx0 ;
  168. lt2 = lt0 enle idx0 ;
  169. cp2 = evol oran manu 'T' lt2 'C' lc2 ;
  170. cp1 = cp2 ;
  171. si ig1 ;
  172. tleg1 = table ;
  173. tleg1 . titre = table ;
  174. tleg1 . 1 = 'Cp derivee publi.' ;
  175. tleg1 . 2 = 'Cp utilisee' ;
  176. dess (cp0 et cp1) titr ' Capacite thermique massique 316L (J/m3)' lege tleg1 ;;
  177. fins ;
  178.  
  179. * Proprietes mecaniques 316L (dependantes de T) :
  180. * nu1 : coefficient de Poisson
  181. nu1 = 0.3 ;
  182.  
  183. * Ym1 : module de Young (Pa)
  184. lt1 = prog 20. 100. pas 100. 1200. ;
  185. lym1 = prog 197000. 191500. 184000. 176500. 168000. 160000. 151500. 142500. 130000. 108000. 81500. 32000. 7400. ;
  186. lym1 = 1.e6 * lym1 ;
  187. ym1 = evol vert manu T lt1 youn lym1 ;
  188.  
  189. * Sy1 : limite d'elasticite (Pa)
  190. lt1 = prog 20. pas 100. 1400. ;
  191. lsy1 = prog 287. 237. 198. 172. 157. 151. 145. 136. 127. 115. 79. 38. 24. 18. 2. ;
  192. lsy1 = 1.e6 * lsy1 ;
  193. sy1 = evol vert manu T lt1 SIGY lsy1 ;
  194.  
  195. * Alph1 : dilatation thermique (/K)
  196. lt1 = prog 20. 100. 300. 400. 600. 700. 800. 1000. 1400. ;
  197. lalph1 = prog 1.55 1.60 1.71 1.75 1.84 1.87 1.90 1.94 1.96 ;
  198. lalph1 = 1.e-5 * lalph1 ;
  199. alph1 = evol vert manu T lt1 ALPH lalph1 ;
  200.  
  201. * Hx : module d'ecrouissage cinematique (Pa)
  202. lt1 = prog 20. 700. pas 100. 1300. ;
  203. lh1 = prog 2400. 2400. 2350. 1500. 800. 725. 150. 10. ;
  204. lh1 = 1.e6 * lh1 ;
  205. Hx1 = evol vert manu T lt1 H lh1 ;
  206.  
  207. * Courbes d'ecrouissage :
  208. nb1 = dime lt1 ;
  209. lep1 = prog 0. 1. ;
  210. nua1 = vide nuage ;
  211. ecro1 = vide evolution ;
  212. tleg1 = table ;
  213. tleg1 . titre = table ;
  214. repe b1 nb1 ;
  215. ti1 = extr lt1 &b1 ;
  216. syi1 = ipol sy1 ti1 ;
  217. hi1 = ipol Hx1 ti1 ;
  218. lmsi1 = prog syi1 (syi1+hi1) ;
  219. ecroi1 = evol oran manu eps lep1 sig lmsi1 ;
  220. ecroi1 = ecroi1 coul &b1 ;
  221. nua1 = nua1 et (nuag comp T ti1 comp ECRO ecroi1) ;
  222. ecro1 = ecro1 et ecroi1 ;
  223. tleg1.titre.&b1 = chai 'T = ' (enti ti1) ;
  224. fin b1 ;
  225.  
  226. si ig1 ;
  227. dess ym1 titr ' Module de Young (Pa)' ;
  228. dess sy1 titr ' Limite elastique (Pa)' ;
  229. dess alph1 titr ' Coef. dilatation thermique (/K)' ;
  230. dess (1.e-6*ecro1) xbor 0. 0.2 ybor 0. 500.
  231. titr 'Courbes d ecrouissage a differentes temperatures (MPa)' lege tleg1 ;
  232. fins ;
  233.  
  234. *----------------------------------------------------------------------*
  235. * Maillage *
  236. *----------------------------------------------------------------------*
  237.  
  238. * Repere :
  239. O1 = 0 0 0 ;
  240. X1 = 1 0 0 ;
  241. Y1 = 0 1 0 ;
  242. Z1 = 0 0 -1 ;
  243. oeil0 = 100 +100 100 ;
  244.  
  245. *-------------------- Maillage Plaque et Raidisseur -------------------*
  246.  
  247. * Plaque : maillage surface dans plan (0,xy)
  248. Pp1 = 0.5*er1*X1 ;
  249. Pp2 = Pp1 plus (3.*lc1*X1) ;
  250. lp1 = ((0 0 0) droi Pp1 dini de1 dfin de1) et (Pp1 droi Pp2 dini de1 dfin de1) ;
  251. sp1 = lp1 tran (-0.4*ep1*Y1) dini de1 dfin de1 ;
  252. sp1 = sp1 coul gris ;
  253. lp2 = sp1 cote 2 ;
  254. lp3 = sp1 cote 3 ;
  255. Pp3 = lp2 poin proc (Pp2 moin Y1) ;
  256. PP4 = Pp3 moin (0.6*ep1*Y1) ;
  257. Pp5 = PP4 moin (0.5*er1*X1) moin (3.*lc1*X1) ;
  258. Pp6 = lp3 poin proc (-1 -1 0) ;
  259. CntSp2 = Pp3 droi Pp4 dini de1 dfin de2 ;
  260. CntSp2 = CntSp2 et (Pp4 droi Pp5 dini de2 dfin de2) ;
  261. CntSp2 = CntSp2 et (Pp5 droi Pp6 dini de2 dfin de1) ;
  262. CntSp2 = CntSp2 et (inve lp3) ;
  263. Sp2 = surf CntSp2 plan ;
  264. Sp2 = sp2 coul gris ;
  265. lp22 = CntSp2 elem comp Pp3 Pp4 ;
  266. Pp7 = la1*X1 ;
  267. Pp8 = Pp7 moin (ep1*Y1) ;
  268. Pp9 = Lp22 poin proc (Pp2 moin (ep1*Y1)) ;
  269. CntSp3 = Pp2 droi Pp7 dini de1 dfin de3 ;
  270. CntSp3 = CntSp3 et (Pp7 droi Pp8 dini de3 dfin de3) ;
  271. CntSp3 = CntSp3 et (Pp8 droi Pp9 dini de3 dfin de2) ;
  272. CntSp3 = CntSp3 et (inve (Lp2 et lp22)) ;
  273. Sp3 = surf CntSp3 plan ;
  274. Sp3 = Sp3 coul gris ;
  275. spz0 = sp1 et Sp2 et Sp3 ;
  276.  
  277. * Raidisseur : maillage surface dans plan (0,xy)
  278. * Pr1 = Pp1 : Noeuds l'arete a l'angle de la plaque et du raidisseur commun aux 2 pieces :
  279. Pr2 = Pp1 plus (2.*lc1*Y1) ;
  280. lr1 = (0 0 0) droi Pp1 dini de1 dfin de1 ;
  281. sr1 = lr1 tran (2.*lc1*Y1) dini de1 dfin de1 ;
  282. Pr2 = sr1 poin proc Pr2 ;
  283. sr1 = sr1 coul vert ;
  284. lr3 = sr1 cote 3 ;
  285. sr2 = lr3 tran ((hr1-lc1-lc1)*Y1) dini de1 dfin de2 ;
  286. sr2 = sr2 coul vert ;
  287. srz0 = sr1 et sr2 ;
  288.  
  289. * Extrusion maillage volumique :
  290. Sz0 = Spz0 et Srz0 ;
  291. Vp0 = spz0 volu tran (lw1*Z1) dini de1 dfin de1 ;
  292. Vr0 = srz0 volu tran (lw1*Z1) dini de1 dfin de1 ;
  293. Vs0 = Vp0 et Vr0 ;
  294.  
  295. *------------------------ Maillage des cordons ------------------------*
  296.  
  297. * Maillage surface cordons dans plan (O,x,y) :
  298. opti elem tet4 ;
  299.  
  300. * Cordon 1 :
  301. Pc12 = lp1 poin proc (Pp1 plus (lc1*X1)) ;
  302. Pc13 = (sr1 cote 2) poin proc (Pp1 plus (lc1*Y1)) ;
  303. CntC1 = lp1 elem comp Pp1 Pc12 ;
  304. CntC1 = CntC1 et (Pc12 droi Pc13 dini de1 dfin de1) ;
  305. CntC1 = CntC1 et ((sr1 cote 2) elem comp Pc13 Pp1) ;
  306. SuC1 = surf CntC1 plan ;
  307. Suc1 = Suc1 coul 1 ;
  308.  
  309. * Cordon 2 :
  310. Pc22 = lp1 poin proc (Pp1 plus (2.*lc1*X1)) ;
  311. Pc23 = Pc22 plus ((-0.5*lc1) (0.5*lc1) 0.) ;
  312. Pc24 = Pc23 moin (lc1*X1) ;
  313. Pc24 = Cntc1 poin proc Pc24 ;
  314. CntC2 = lp1 elem comp Pc12 Pc22 ;
  315. CntC2 = CntC2 et (Pc22 droi Pc23 dini de1 dfin de1) ;
  316. CntC2 = CntC2 et (Pc23 droi Pc24 dini de1 dfin de1) ;
  317. CntC2 = CntC2 et (((CntC1 inve) elem comp Pc24 Pc12) ) ;
  318. Suc2 = Cntc2 surf plan ;
  319. Suc2 = Suc2 coul 2 ;
  320.  
  321. * Cordon 3 :
  322. Pc33 = Pc23 plus ((-0.5*lc1) (0.5*lc1) 0.) ;
  323. CntC3 = (inve CntC2) elem comp Pc24 Pc23 ;
  324. CntC3 = CntC3 et (Pc23 droi Pc33 dini de1 dfin de1) ;
  325. CntC3 = CntC3 et (Pc33 droi Pc13 dini de1 dfin de1) ;
  326. CntC3 = CntC3 et ((inve CntC1) elem comp Pc13 Pc24) ;
  327. SuC3 = surf CntC3 plan ;
  328. SuC3 = SuC3 coul 3 ;
  329.  
  330. * Cordon 4 :
  331. CntC4 = (inve CntC3) elem comp Pc13 Pc33 ;
  332. CntC4 = CntC4 et (Pc33 droi Pr2 dini de1 dfin de1) ;
  333. CntC4 = CntC4 et ((sr1 cote 2) elem comp Pr2 Pc13) ;
  334. SuC4 = CntC4 surf plan ;
  335. SuC4 = SuC4 coul 4 ;
  336.  
  337. * Volume cordons :
  338. Suc0 = Suc1 et Suc2 et Suc3 et Suc4 ;
  339. *trac (0 0 1000) Suc0 ;
  340. Vc0 = Suc0 volu tran (lw1*Z1) dini de1 dfin de1 ;
  341.  
  342. * Maillage volumique de chaque cordon :
  343. Vc1 = Vc0 elem coul 1 ;
  344. Vc2 = Vc0 elem coul 2 ;
  345. Vc3 = Vc0 elem coul 3 ;
  346. Vc4 = Vc0 elem coul 4 ;
  347.  
  348. * Fusion noeuds communs cordons/plaque et cordons/raidisseur mais pas plaque/raidisseur
  349. elim ((enve Vc0) et (enve Vp0)) 1.e-5 ;
  350. elim ((enve Vc0) et (enve Vr0)) 1.e-5 ;
  351.  
  352. * Maillage total :
  353. V0 = Vc0 et Vs0 ;
  354.  
  355. * Affichages :
  356. si IG1 ;
  357. mot1 = chai ' Maillage plaque et raidisseur :' (nbno Vs0) ' noeuds,' (nbel Vs0) ' elem.' ;
  358. trac oeil0 face Vs0 titr mot1 ;
  359. mbox2 = boite (Sp1 et Sr1 et Vc0) ;
  360. mot1 = chai ' Maillage plaque, raidisseur et cordons :' (nbno V0) ' noeuds,' (nbel V0) ' elem.' ;
  361. trac oeil0 face V0 titr mot1 ;
  362. trac (0 1 10) face V0 boit mbox2 titr mot1 ;
  363. fins ;
  364.  
  365. *----------------------------------------------------------------------*
  366. * Sequence de soudage *
  367. *----------------------------------------------------------------------*
  368.  
  369. * Initialisation table de soudage :
  370. tsoud1 = table ;
  371. tsoud1 . vitesse_de_soudage = Vs1 ;
  372. tsoud1 . vitesse_de_deplacement = Vd1 ;
  373. tsoud1 . puissance_de_soudage = Qtot1 ;
  374. tsoud1 . diametre_de_fil = Df1 ;
  375. tsoud1 . vitesse_de_fil = Vf1 ;
  376. tsoud1 . point_de_depart = Pc1 ;
  377.  
  378. * Specification de la sequence :
  379. * Delai de 0,5 s avant de faire la 1ere passe :
  380. soudage tsoud1 point tps0 ;
  381. * 1ere passe :
  382. soudage tsoud1 passe droi (lw1*Z1) ;
  383. * 2e passe :
  384. soudage tsoud1 depla droi Pc2 abso ;
  385. soudage tsoud1 point 600. puis 0. debi 0. ;
  386. soudage tsoud1 passe droi (lw1*Z1) ;
  387. * 3e passe :
  388. soudage tsoud1 depla droi Pc3 abso ;
  389. soudage tsoud1 point 600. puis 0. debi 0. ;
  390. soudage tsoud1 passe droi (lw1*Z1) ;
  391. * 4e passe :
  392. soudage tsoud1 depla droi Pc4 abso ;
  393. soudage tsoud1 point 600. puis 0. debi 0. ;
  394. soudage tsoud1 passe droi (lw1*Z1) ;
  395. * Refroidissement
  396. soudage tsoud1 point 600. puis 0. debi 0. ;
  397.  
  398. * Sequencage maillage des cordons le long de la trajectoire :
  399. tab2 = soudage tsoud1 'MAIL' vc0 'PAS' Xpas1 'TEMP' ;
  400.  
  401. ttps1 = tab2.evolution_maillage.temps ;
  402.  
  403. si ig1 ;
  404. titr ' Trajectoire soudage des 4 passes (vert : depl. outil)' ;
  405. trac (1 2 10) (tsoud1.trajectoire et (aret vc1) et (aret vc2 coul defa) et (aret vc3 coul defa) et (aret vc4 coul defa)) ;
  406. dess tsoud1.evolution_deplacement titr 'Evolution temporelle du deplacement sur la trajectoire' ;
  407. dess tsoud1.evolution_puissance titr 'Evolution tempeorelle de la puissance thermique' ;
  408. *
  409. opti oeil (1. 2. 3.) ;
  410. waam tab2 visu cach ;
  411. *dess (evol manu tab2.temps_calcules (prog 1. pas 1. (dime tab2.temps_calcules))) titr 'Temps calcules' ;
  412. fins ;
  413.  
  414. *----------------------------------------------------------------------*
  415. * Modele Physique *
  416. *----------------------------------------------------------------------*
  417.  
  418. *--------------------------- C.L. thermique ---------------------------*
  419.  
  420. * Accrochage DDL thermique bord raidisseur sur plaque :
  421. clt1 = rela accro (enve Vr0) vp0 (mots T) ;
  422.  
  423. * sinte1 : surface interieure : a retirer de la surface qui convecte
  424. * partie du raidisseur en vis-a-vis de la plaque (surface y = ymin.)
  425. ptry0 = (vr0 coor 2) poin mini ;
  426. sury0 = (vr0 enve) elem appu stri ptry0 ;
  427. sinte1 = sury0 ;
  428. * partie de la plaque en vis-a-vis du raidisseur (maillage non-conforme)
  429. pclt1 = clt1 extr mail nomu ;
  430. supi1 = (enve Vp0) elem appu stri (pclt1 et sury0) ;
  431. sinte1 = sinte1 et supi1 ;
  432. * plan de symetrie en x=0
  433. ptx0 = (V0 coor 1) poin infe 1.e-6 ;
  434. sux0 = (enve V0) elem appu stri ptx0 ;
  435. sinte1 = sinte1 et sux0 ;
  436.  
  437. si ig1 ;
  438. trac (-5 1 3) cach ((enve V0) diff sinte1) boit (boite vc0) titr 'Surface de convection' ;
  439. fins ;
  440.  
  441. *--------------------------- C.L. mecanique ---------------------------*
  442.  
  443. * Condition de symetrie plan (0,y,z) :
  444. ptx0 = (V0 coor 1) poin infe 1.e-5 ;
  445. clu1 = bloq ux ptx0 ;
  446.  
  447. * Blocage mouvements corps rigide (traslation Ux bloquer par C.L. symetrie)
  448. * > translations suivant Uy et Uz
  449. * > rotation autour de (0,x) (blocage PP7 suivant Uz)
  450. clu2 = bloq Pp7 uy uz ;
  451. clu3 = bloq Pp8 uz ;
  452.  
  453. * Condition de non-interpenetration des surface parties non conformes
  454. * maillages plaque/raidisseur :
  455. * clu4 : Uy(Sraid.) - Uy(Splaq.) > 0 ;
  456. clu4 = rela mini 1. uy sury0 - 1. uy supi1 ;
  457.  
  458. si ig1 ;
  459. trac (-1 -1 2) cach (ptx0 coul roug et (aret V0 coul defa)) titr 'C.L. symetrie : Ux(Pts_rouge) = 0' ;
  460. mbox1 = boite (Pp7 et Pp8) ;
  461. mbox1 = mbox1 homo (bary mbox1) 1.5 ;
  462. mot1 = mot 'C.L. : Uy(Pp7)=0, Uz(Pp7)=0, Uz(Pp8)=0' ;
  463. trac (-1 -1 2) qual ((Pp7 et Pp8) coul roug et (aret Vs0 coul defa)) titr mot1 ;
  464. mot1 = mot 'Uy(Sverte) - Uy(Sgrise) > 0' ;
  465. trac (-1 -1 2) (sury0 plus (0 0.001 0) et supi1 et (aret Vs0 coul defa)) titr mot1 boit mbox1 ;
  466. fins ;
  467.  
  468. *---------------------- Modele / Carateristiques ----------------------*
  469.  
  470. * Conduction / Convection :
  471. mod1 = mode V0 thermique ;
  472. mat1 = mate mod1 rho rho1 k k1 'C' cp1 'TINI' Tini1 ;
  473.  
  474. * Source thermique :
  475. evqt1 = tsoud1.evolution_puissance ;
  476. evxs1 = tsoud1.evolution_deplacement ;
  477. chxs1 = tsoud1.trajectoire coor curv ;
  478. cgxs1 = char traj chxs1 evxs1 ;
  479. mod3 = mode V0 thermique source gaussienne isotrope_transverse ;
  480. mat3 = mate mod3 qtot evqt1 orig cgxs1 rgau Rg1 dire (1. 1. 0.) zgau Zg1 ;
  481.  
  482. * Mecanique :
  483. mod5 = mode V0 mecanique elastique plastique isotrope fusion cons 316L ;
  484. mat5 = mate mod5 youn ym1 nu nu1 alph alph1 ecro ecro1 tref tini1 talp tini1 tfus Tfus1 ;
  485.  
  486. * Tables d'evolution des modeles et caracteristiques :
  487. ttps1 = tab2.evolution_maillage.temps ;
  488. tmai1 = tab2.evolution_maillage.maillage ;
  489. nb1 = dime ttps1 ;
  490. tmod1 = table ;
  491. tmod2 = table ;
  492. tmod3 = table ;
  493. tmod4 = table ;
  494. tmod5 = table ;
  495. tmat1 = table ;
  496. tmat2 = table ;
  497. tmat3 = table ;
  498. tmat4 = table ;
  499. tmat5 = table ;
  500. repe b1 nb1 ;
  501. geoi1 = tmai1 . (&b1 - 1) ;
  502. geoi1 = geoi1 et Vp0 et Vr0 ;
  503. tmod1 . (&b1 - 1) = redu mod1 geoi1 ;
  504. tmat1 . (&b1 - 1) = redu mat1 (tmod1 . (&b1 - 1)) ;
  505. sconv1 = (enve geoi1) diff sinte1 ;
  506. *trac nclk cach sconv1 boit (boite vc0) ;
  507. tmod2 . (&b1 - 1) = mode sconv1 thermique convection ;
  508. tmat2 . (&b1 - 1) = mate (tmod2 . (&b1 - 1)) 'H' h1 'TC' Te1 ;
  509. tmod3 . (&b1 - 1) = redu mod3 geoi1 ;
  510. tmat3 . (&b1 - 1) = redu mat3 (tmod3 . (&b1 - 1)) ;
  511. tmod4 . (&b1 - 1) = mode sconv1 thermique rayonnement infini ;
  512. tmat4 . (&b1 - 1) = mate (tmod4 . (&b1 - 1)) 'EMIS' em1 'T_IN' Te1 ;
  513. tmod5 . (&b1 - 1) = redu mod5 geoi1 ;
  514. tmat5 . (&b1 - 1) = redu mat5 (tmod5 . (&b1 - 1)) ;
  515. fin b1 ;
  516.  
  517. * Chargements MODE / MATE :
  518. cgmod1 = char mode ttps1 tmod1 ;
  519. cgmod2 = char mode ttps1 tmod2 ;
  520. cgmod3 = char mode ttps1 tmod3 ;
  521. cgmod4 = char mode ttps1 tmod4 ;
  522. cgmod5 = char mode ttps1 tmod5 ;
  523. cgmod0 = cgmod1 et cgmod2 et cgmod3 et cgmod4 ;
  524.  
  525. cgmat1 = char mate ttps1 tmat1 ;
  526. cgmat2 = char mate ttps1 tmat2 ;
  527. cgmat3 = char mate ttps1 tmat3 ;
  528. cgmat4 = char mate ttps1 tmat4 ;
  529. cgmat5 = char mate ttps1 tmat5 ;
  530. cgmat0 = cgmat1 et cgmat2 et cgmat3 et cgmat4 ;
  531.  
  532. cg0 = cgmod0 et cgmat0 ;
  533.  
  534. *----------------------------------------------------------------------*
  535. * THERMIQUE *
  536. *----------------------------------------------------------------------*
  537.  
  538. * Liste des temps calcules :
  539. ltca0 = tab2.temps_calcules ;
  540. it0 = posi tps0 dans ltca0 ;
  541. ltca0 = (prog 0. pas 0.2 tps0) et (ltca0 extr (lect (it0 + 1) pas 1 (dime ltca0))) ;
  542. si (non icomplet) ;
  543. ltca1 = ltca0 extr (lect 1 pas 1 10) ;
  544. sino ;
  545. ltca1 = ltca0 ;
  546. fins ;
  547. list ltca1 ;
  548.  
  549. * Liste des temps des sauvegardes :
  550. si icomplet ;
  551. ltsg1 = ltca1 extr (lect 50 pas 50 ((dime ltca1) / 50 * 50)) ;
  552. si ((maxi ltsg1) neg (maxi ltca1)) ;
  553. ltsg1 = ltsg1 et (maxi ltca1) ;
  554. fins ;
  555. list ltsg1 ;
  556. fins ;
  557.  
  558. *-------------------- Resolution Thermique PASAPAS --------------------*
  559.  
  560. * Table PASAPAS :
  561. tpas1 = table ;
  562. tpas1.modele = cgmod0 ;
  563. tpas1.caracteristiques = cgmat0 ;
  564. tpas1.blocages_thermiques = clt1 ;
  565. tpas1.temps_calcules = ltca1 ;
  566. tpas1.temps_sauves = ltca1 ;
  567. tpas1.celsius = vrai ;
  568.  
  569. si icomplet ;
  570. tpas1.temps_sauvegardes = ltsg1 ;
  571. opti sauv 'soudage7.sauv' ;
  572. sauv ;
  573. fins ;
  574.  
  575.  
  576. pasapas tpas1 ;
  577.  
  578. * Affichage temps de calcul :
  579. duree1 = temp horl ;
  580. duree1 = (duree1 / 1000) ;
  581. dmin1 = (duree1 / 60) ;
  582. dsec1 = duree1 - (60 * dmin1) ;
  583. mot1 = chai '***** DUREE DU CALCUL (s) :' dmin1 ' min' dsec1 ' s' ;
  584. mess mot1 ;
  585.  
  586. *------------------- Petit post-traitement thermique ------------------*
  587.  
  588. si ig1 ;
  589.  
  590. * Animation du champ de temperature :
  591. if1 = (dime tpas1.temps) - 1 ;
  592. modf1 = tpas1.modeles.if1 ;
  593. mailf1 = (extr modf1 mate conduction) extr mail ;
  594. dep0 = manu chpo mailf1 3 ux 0. uy 0. uz 0. ;
  595. def1 = vide deforme ;
  596. liso1 = prog 50. 100. PAS 150. 1450. ;
  597. vtra1 = vale trac ;
  598. si (ega vtra1 'PSC') ;
  599. opti ftra 'Temperature_soudage7_anim.ps' ;
  600. fins ;
  601. mbox1 = boite Vc0 ;
  602. repe b1 if1 ;
  603. modi1 = tpas1.modeles.(&b1-1) ;
  604. maili1 = (extr modi1 mate conduction) extr mail ;
  605. chti1 = tpas1.temperatures.(&b1-1) ;
  606. defoi1 = defo maili1 dep0 chti1 ;
  607. def1 = def1 et defoi1 ;
  608. si (ega vtra1 'PSC') ;
  609. mot1 = chai format '(F6.1)' 'Temperature (degC) au temps (s) :' (tpas1.temps.(&b1-1)) ;
  610. trac (1 2 3) chti1 maili1 liso1 titr mot1 boit mbox1 ;
  611. fins ;
  612. fin b1 ;
  613. si (neg vtra1 'PSC') ;
  614. trac (1 2 3) anim def1 liso1 boit mbox1 ;
  615. fins ;
  616.  
  617. fins ;
  618.  
  619. *----------------------------------------------------------------------*
  620. * MECANIQUE *
  621. *----------------------------------------------------------------------*
  622.  
  623. *-------------------- Resolution Mecanique PASAPAS --------------------*
  624.  
  625. * Chargement thermique :
  626. cgt1 = char 'T' (tpas1.temps) (tpas1.temperatures) ;
  627.  
  628. * Table PASAPAS :
  629. tpas2 = table ;
  630. tpas2.modele = cgmod5 ;
  631. tpas2.caracteristiques = cgmat5 ;
  632. tpas2.chargement = cgt1 ;
  633. tpas2.blocages_mecaniques = clu1 et clu2 et clu3 et clu4 ;
  634. tpas2.temps_calcules = ltca1 ;
  635. tpas2.processeurs = mot comportement ;
  636.  
  637. si icomplet ;
  638. ntca1 = dime ltca1 ;
  639. tpas2.temps_sauvegardes = ltca1 extr (lect 50 pas 50 (ntca1 / 50 * 50) ntca1) ;
  640. opti sauv 'soudage7.sauv' ;
  641. fins ;
  642.  
  643.  
  644. pasapas tpas2 ;
  645.  
  646. * Affichage temps de calcul :
  647. duree1 = temp horl ;
  648. duree1 = (duree1 / 1000) ;
  649. dmin1 = (duree1 / 60) ;
  650. dsec1 = duree1 - (60 * dmin1) ;
  651. mot1 = chai '***** DUREE DU CALCUL MECANIQUE (s) :' dmin1 ' min' dsec1 ' s' ;
  652. mess mot1 ;
  653.  
  654. *------------------- Petit post-traitement mecanique ------------------*
  655.  
  656. * Animation contrainte de von Mises :
  657. vtra1 = vale trac ;
  658.  
  659. si ig1 ;
  660. if1 = (dime tpas2.temps) - 1 ;
  661. def1 = vide deforme ;
  662. si (ega vtra1 'PSC') ;
  663. opti ftra 'Contrainte_soudage7_anim.ps' ;
  664. fins ;
  665. liso1 = prog 25. pas 25. 350. ;
  666. mbox1 = boite Vc0 ;
  667. repe b1 if1 ;
  668. i1 = &b1-1 ;
  669. modi1 = tpas2.modeles.i1 ;
  670. geoi1 = (extr modi1 form mecanique) extr mail ;
  671. depi1 = tpas2.deplacements.i1 ;
  672. sigi1 = tpas2.contraintes.i1 ;
  673. sigi1 = 1.e-6 * sigi1 ;
  674. sigi1 = vmis modi1 sigi1 ;
  675. defoi1 = defo geoi1 depi1 1. sigi1 modi1 ;
  676. def1 = def1 et defoi1 ;
  677. si (ega vtra1 'PSC') ;
  678. mot1 = chai format '(F6.1)' 'Contrainte de von Mises (MPa) au temps (s) :' (tpas2.temps.i1) ;
  679. trac (1 2 3) defoi1 liso1 titr mot1 boit mbox1 ;
  680. fins ;
  681. fin b1 ;
  682. si (neg vtra1 'PSC') ;
  683. trac (1 2 3) anim def1 liso1 titr 'Contrainte de Von Mises (MPa)' ;
  684. fins ;
  685. fins ;
  686.  
  687. *-------------- F I N S O U D A G E 7 . D G I B I --------------*
  688. fin ;
  689.  
  690.  
  691.  
  692.  
  693.  
  694.  
  695.  
  696.  
  697.  
  698.  
  699.  
  700.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales