Télécharger soudage5.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : soudage5.dgibi
  2. * section : thermique conduction convection changement_phase
  3. *----------------------------------------------------------------------*
  4. * S O U D A G E 5 . D G I B I *
  5. *----------------------------------------------------------------------*
  6. * Objet :
  7. * -------
  8. *
  9. * Exemple d'utilisation d'un modele de SOURCE THERMIQUE GAUSSIENNE
  10. * pour la simulation d'une ligne de fusion en soudage sur une plaque
  11. * en acier 316L (proprietes approchees) avec prise e compte ou non de
  12. * la chaleur latente de changement de phase.
  13. *
  14. * La ligne de fusion est volotairement non conforme au maillage de
  15. * la plaque afin d'illustrer la mise en donnee du deplacement d'une
  16. * source de chaleur suivant une trajectoire independante du maillage
  17. * de calcul.
  18. *
  19. * Les points de la trajectoire sont neanmoins "accroches" au maillage
  20. * de calcul (RELA ACCRO) afin de pouvoir post-traiter l'evolution de la
  21. * temperature le long de cette ligne (en temps ou en espace).
  22. *
  23. * Enfin, on illustre aussi la possibilite de faire des affichages au
  24. * cours du calcul avec la procedure PERSO2 et l'option NCLK de TRAC.
  25. *
  26. * Description :
  27. * -------------
  28. *
  29. * Type de calcul : Thermique Transitoire
  30. * Mode de calcul : 3D
  31. * Type d'element : CUB8
  32. * Chargement : Source de chaleur, Convection
  33. *
  34. *----------------------------------------------------------------------*
  35. *
  36. * Mettre ig1 a VRAI pour visualiser le calcul :
  37. ig1 = faux ;
  38. opti trac psc ;
  39.  
  40. * Mettre icomplet a VRAI pour le calcul complet :
  41. * fcomp1 : fraction du calcul complet
  42. icomplet = faux ;
  43. fcomp1 = 0.05 ;
  44.  
  45. * Racine du nom du fichier (pour nom fichier sauvegarde et animation) :
  46. fic1 = 'soudage5' ;
  47.  
  48. ig1 = ig1 ou (ega (vale trac) 'PSC') ;
  49.  
  50. *---------------------------- Parametres -----------------------------*
  51. *
  52. * Geometrie : longueur, largeur, epaisseur
  53. lo1 = 100.e-3 ;
  54. la1 = 50.e-3 ;
  55. ep1 = 10.e-3 ;
  56.  
  57. * Densite maillage :
  58. de1 = 2.5e-3 ;
  59.  
  60. *---- Parametres physiques :
  61. * rho1 : masse volumique (kg/m3)
  62. * cp1 : capacite calorifique (J/kg/K)
  63. * k1 : conductivite thermique (W/m/K)
  64. * Tfus1 : temperature de fusion (degC)
  65. * Qlat1 : Chaleur latente de fusion (J/m3)
  66. rho1 = 7760. ;
  67. cp1 = 500. ;
  68. k1 = 24. ;
  69. Tfus1 = 1450. ;
  70. Qlat1 = 2.e9 ;
  71.  
  72. *---- Parametres du chargement :
  73. * Soudage :
  74. * vs1 : vitesse de soudage (m/s)
  75. * tis1 : instant debut deplacement de la torche (s)
  76. vs1 = 80.e-3 / 60. ;
  77. tis1 = 0. ;
  78.  
  79. * Source de chaleur Gaussienne :
  80. * q0 : puissance thermique totale (W)
  81. * r0 : rayon source Gaussienne (m)
  82. * z0 : profondeur source Gaussienne (m)
  83. q0 = 1.5e3 ;
  84. r0 = 5.e-3 ;
  85. z0 = 3.e-3 ;
  86. *
  87. * Conditions iniiale & aux limites
  88. * h1 : coefficient d'echange convectif (W/m2/K)
  89. * tini0 : temperature initiale
  90. * te0 : temperature exterieure de convection
  91. h1 = 20. ;
  92. tini0 = 20. ;
  93. te0 = 20. ;
  94.  
  95. *------------------------------ Maillage ------------------------------*
  96. opti dime 3 elem cub8 isov suli ;
  97.  
  98. * Repere :
  99. O1 = 0 0 0 ;
  100. X1 = 1 0 0 ;
  101. Y1 = 0 1 0 ;
  102. Z1 = 0 0 1 ;
  103.  
  104. * Maillage de la plaque :
  105. P1 = la1 * y1 ;
  106. l1 = O1 droi P1 dini de1 dfin de1 ;
  107. s1 = l1 tran (ep1 * z1) dini de1 dfin de1 ;
  108. v1 = s1 volu tran (lo1 * x1) dini de1 dfin de1 ;
  109.  
  110. * Surface de convection :
  111. scv1 = enve v1 ;
  112.  
  113. si ig1 ;
  114. trac cach v1 titre ' Maillage de la plaque ' ;
  115. trac cach scv1 titre ' Surface echange convectif = enveloppe maillage ' ;
  116. fins ;
  117.  
  118. *------------------------ CI - CL / Chargement -----------------------*
  119.  
  120. ***** Definition du chargement thermique de la torche *****
  121. * Ligne de fusion :
  122. ps1 = 3.e-3 0.e-3 ep1 ;
  123. ps2 = (lo1 - 5.e-3) (la1 - 2.e-3) ep1 ;
  124. ls1 = ps1 droi 50 ps2 ;
  125. ls1 = ls1 coul roug ;
  126. chs1 = ls1 coor curv ;
  127. si ig1 ;
  128. trac cach (v1 et ls1) titre 'Maillage de la ligne de fusion' ;
  129. trac chs1 ls1 titre 'Abscisse curiviligne de la ligne de fusion' ;
  130. fins ;
  131.  
  132. * Evolution temporelle de la position de la torche TIG (m/s) :
  133. * tfs1 : instant fin de deplacement de la torche (s)
  134. lls1 = maxi chs1 ;
  135. tfs1 = ((mesu ls1) / vs1) + tis1 ;
  136. lts1 = prog 0. tis1 tfs1 ;
  137. lxs1 = prog 0. 0. lls1 ;
  138. evs1 = evol vert manu temp lts1 lxs1 ;
  139. si ig1 ;
  140. dess evs1 xbor 0. tfs1
  141. titre ' Evolution temporelle du deplacement de la torche (abscisse curviligne)' ;
  142. fins ;
  143.  
  144. * Chargement decrivant le trajet de la source :
  145. cg2 = char traj chs1 evs1 ;
  146.  
  147. * Evolution temporelle de la puissance de la torche :
  148. lq1 = prog 1. 1. 1. ;
  149. evq1 = evol roug manu temp lts1 qtot lq1 ;
  150. evq1 = q0 * evq1 ;
  151. si ig1 ;
  152. dess evq1 xbor 0. tfs1
  153. titre ' Evolution temporelle de la puissance thermique de la torche (W) ' ;
  154. fins ;
  155.  
  156. *--------------------- Modele / Caracteristiques ----------------------*
  157.  
  158. * Conduction :
  159. mo1 = mode v1 thermique ;
  160. ma1 = mate mo1 k k1 rho rho1 'C' cp1 'TINI' tini0 ;
  161.  
  162. mocp1 = mode v1 changement_phase parfait inco 'T' 'Q' ;
  163. macp1 = mate mocp1 prim Tfus1 dual Qlat1 ;
  164.  
  165. * Convection :
  166. mocv1 = mode scv1 thermique convection ;
  167. macv1 = mate mocv1 'H' h1 'TE' te0 ;
  168.  
  169. * Source Gaussienne isotrope_transverse :
  170. moq1 = mode v1 thermique source gaussienne isotrope_transverse ;
  171. maq1 = mate moq1 qtot evq1 orig cg2 rgau r0 dire (0 0 1) zgau z0 ;
  172.  
  173. *------------ Affichages T au cours du calcul avec PERSO2 -------------*
  174.  
  175. debp PERSO2 tu1*table ;
  176. tps1 = tu1.estimation.temps ;
  177. liso1 = prog 0. 200. pas 125. 1700. ;
  178. titre (chai format '(F7.2)' 'Temperature au temps ' tps1 ' (s)') ;
  179. si ig1 ;
  180. trac liso1 nclk tu1.wtable.ther_courant v1 (aret v1) ;
  181. fins ;
  182. finp ;
  183.  
  184. *------------------ Calcul SANS Changement de Phase -------------------*
  185.  
  186. * Instants de calcul :
  187. * pas1 : pas de temps pour avancer d'un 1/2 element
  188. pas1 = 0.2 * de1 / vs1 ;
  189. ltca1 = prog 0. pas (0.2*pas1) (2.*pas1) pas pas1 (fcomp1*tfs1) ;
  190. si icomplet ;
  191. ltca1 = prog 0. pas (0.2*pas1) (2.*pas1) pas pas1 tfs1 ;
  192. fins ;
  193.  
  194. * Table PASAPAS :
  195. ta1 = table ;
  196. ta1 . modele = mo1 et mocv1 et moq1 ;
  197. ta1 . caracteristiques = ma1 et macv1 et maq1 ;
  198. ta1 . blocages_thermiques = rela ls1 accro v1 (mots T) ;
  199. ta1 . temps_calcules = ltca1 ;
  200. ta1 . procedure_perso2 = ig1 ;
  201.  
  202. pasapas ta1 ;
  203.  
  204. *------------------ Calcul AVEC Changement de Phase -------------------*
  205.  
  206. * Table PASAPAS :
  207. ta2 = table ;
  208. ta2 . modele = mo1 et mocv1 et moq1 et mocp1 ;
  209. ta2 . caracteristiques = ma1 et macv1 et maq1 et macp1 ;
  210. ta2 . blocages_thermiques = ta1 . blocages_thermiques ;
  211. ta2 . temps_calcules = ltca1 ;
  212. ta2 . procedure_perso2 = ig1 ;
  213.  
  214. pasapas ta2 ;
  215.  
  216. *-------------------------- Post-Traitement ---------------------------*
  217.  
  218. * Evolution temporelle de la temperature :
  219. * - Au point de depart de la ligne de fusion
  220. * - A 75% du parcours fait sur de la ligne de fusion
  221. si icomplet ;
  222. fac2 = 0.75 ;
  223. sino ;
  224. fac2 = 0.75 * fcomp1 ;
  225. fins ;
  226. Pt1 = Ps1 ;
  227. Pt2 = ls1 poin proc (Pt1 plus ((Ps2 moin Ps1) * fac2)) ;
  228. si ig1 ;
  229. trac cach ((v1 moin (0 0 1.e-6)) et ((Pt1 et Pt2) coul vert)) qual titr ' Pt2, Pt2 : positions thermocouples' ;
  230. fins ;
  231.  
  232. evpt11 = evol bleu temp ta1 temperatures T Pt1 ;
  233. evpt21 = evol oran temp ta1 temperatures T Pt2 ;
  234. evpt12 = evol bleu temp ta2 temperatures T Pt1 ;
  235. evpt22 = evol oran temp ta2 temperatures T Pt2 ;
  236. evt0 = evpt11 et evpt21 et evpt12 et evpt22 ;
  237.  
  238. si ig1 ;
  239. tleg1 = table ;
  240. tleg1 . titre = table ;
  241. tleg1 . titre . 1 = 'T(Pt1) Sans Chgt Phase' ;
  242. tleg1 . titre . 2 = 'T(Pt2) Sans Chgt Phase' ;
  243. tleg1 . titre . 3 = 'T(Pt1) Avec Chgt Phase' ;
  244. tleg1 . titre . 4 = 'T(Pt2) Avec Chgt Phase' ;
  245. tleg1 . 2 = mot 'TIRR' ;
  246. tleg1 . 3 = mot 'MARQ S CROI NOLI' ;
  247. tleg1 . 4 = mot 'MARQ S ROND NOLI' ;
  248. dess evt0 lege tleg1 titr 'Comparaison thermogrammes calculs avec ou sans changement de phase' ;
  249. fins ;
  250.  
  251. * Evolution spatiale de la temperature a 2 instants differents :
  252. * - 5% du temps final
  253. * - 75% du temps final
  254. tf1 = maxi ta1.temps_calcules ;
  255. cht11 = peche ta1 temperatures (0.05*tf1) ipol ;
  256. cht21 = peche ta1 temperatures (0.75*tf1) ipol ;
  257. cht12 = peche ta2 temperatures (0.05*tf1) ipol ;
  258. cht22 = peche ta2 temperatures (0.75*tf1) ipol ;
  259. evls11 = evol bleu chpo cht11 T ls1 ;
  260. evls21 = evol oran chpo cht21 T ls1 ;
  261. evls12 = evol bleu chpo cht12 T ls1 ;
  262. evls22 = evol oran chpo cht22 T ls1 ;
  263. evls0 = evls11 et evls21 et evls12 et evls22 ;
  264.  
  265. si ig1 ;
  266. tleg1 = table ;
  267. tleg1 . titre = table ;
  268. tleg1 . titre . 1 = 'T(t1) Sans Chgt Phase' ;
  269. tleg1 . titre . 2 = 'T(t2) Sans Chgt Phase' ;
  270. tleg1 . titre . 3 = 'T(t1) Avec Chgt Phase' ;
  271. tleg1 . titre . 4 = 'T(t2) Avec Chgt Phase' ;
  272. tleg1 . 2 = mot 'TIRR' ;
  273. tleg1 . 3 = mot 'MARQ S CROI NOLI' ;
  274. tleg1 . 4 = mot 'MARQ S ROND NOLI' ;
  275. si icomplet ;
  276. dess evls0 lege tleg1 titr 'Comparaison evolution spatiale T avec ou sans Chgt Phase' ;
  277. sino ;
  278. dess evls0 lege tleg1 xbor 0. 0.05 titr 'Comparaison evolution spatiale T avec ou sans Chgt Phase' ;
  279. fins ;
  280. fins ;
  281.  
  282. fin ;
  283.  
  284.  
  285.  
  286.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales