Télécharger soudage18.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : soudage18.dgibi
  2. *
  3. graph = faux ;
  4. complet = faux ;
  5.  
  6. * donnees geometriques qu il faudrait sauver
  7. opti dime 3 elem cub8 trac x;
  8. p_ori = 0. 0. 0. ; d0 = 1.d-2 ;
  9.  
  10. e_x = 1. 0. 0. ; e_y = 0. 1. 0. ; e_z = 0. 0. 1. ;
  11. l0_x = 5.d-3 ;l_x = 1.d-2 ; l_y = 10*l_x ; l_zh = 3*l_x ; l_zb = 2*l_x ;
  12. l_cz = 0.5*l_x ; l_cy = 1.05*l_x ;
  13. dens d0 ; n_x = 1 ;
  14.  
  15. *******************
  16. debproc prosym vut1*maillage ;
  17. * surface symetrie
  18. chu1 = coor 2 (manu chml (enve vut1) scal 1.) ;
  19. ssu1 = elem chu1 inferieur (d0*1.e-2) ;
  20. chu2 = coor 2 (manu chml ssu1 scal 1.) ;
  21. ssu2 = elem chu2 superieur (d0*1.e-1) ;
  22. ssu3 = diff ssu1 ssu2 ;
  23. finproc ssu3 ;
  24. *******************
  25.  
  26. **
  27. *si d_ther ;
  28. *opti sauv 'soudage18_lin_a.sauv' ;
  29. **
  30.  
  31. * plaque
  32. pc1m = p_ori moins (l0_x*e_x) ;
  33. pp1m = pc1m moins (l_zb*e_z) ;
  34. pc2m = pc1m plus (l_cy*e_y) plus (l_cz*e_z) ;
  35. pp2m = pp1m plus (l_cy*e_y) ;
  36. pp3m = pp1m plus (l_y*e_y);
  37. pp4m = pp3m plus ((l_zh + l_zb)*e_z) ;
  38. pc3m = pc2m plus (l_cz*e_z) ;
  39. pp5m = pp3m plus ((l_zb + l_cz)*e_z) ;
  40. pp6m = pp5m plus (l_cz*e_z) ;
  41. pp7m = pp2m plus ((l_zh + l_zb)*e_z) ;
  42.  
  43.  
  44. l1c = d pc1m pp1m ; nncz1 = nbel l1c ;
  45. l2c = d pp1m pp2m ; nnc2 = nbel l2c ;
  46. l3c = d nncz1 pp2m pc2m ;
  47. l4c = d nnc2 pc2m pc1m ;
  48. s1c = dall l1c l2c l3c l4c ;
  49.  
  50. l11 = d pp2m pp3m ;
  51. l12 = d nncz1 pp3m pp5m ; l13 = d pp5m pc2m ;
  52. s11 = dall l11 l12 l13 (inve l3c) ;
  53. l21 = d pc3m pc2m ; nncz2 = nbel l21 ;
  54. l23 = d nncz2 pp5m pp6m ; l24 = d pp6m pc3m ;
  55. s22 = dall l21 (inve l13) l23 l24 ;
  56. l31 = d pp7m pc3m ; nncz3 = nbel l31 ;
  57. l33 = d nncz3 pp6m pp4m ; l34 = d pp4m pp7m ;
  58. s33 = dall l31 (inve l24) l33 l34 ;
  59.  
  60. *trac (s1c et s11 et s22 et s33) ;
  61. sp0 = s1c et s11 et s22 et s33 ;
  62. vp0 = sp0 volu n_x trans (l_x*e_x) ;
  63. vpp1 = (face 2 vp0) volu n_x trans (l_x*e_x) ;
  64. vpm1 = sp0 volu n_x trans (-1*l_x*e_x) ;
  65. vv1 = vpm1 et vp0 et vpp1 ;
  66. *trac vv1 cach ;
  67.  
  68. * capteurs thermiques
  69. ppthm1 = pp1m plus (3*l_x*e_y) ;
  70. ppthm2 = ppthm1 plus ((l_zh + l_zb)*e_z) ;
  71.  
  72. *apport
  73. pa1m pa2m pa3m la4c la21 = pc1m pc2m pc3m l4c l21 plus p_ori ;
  74. pa4m = pa1m plus (l_x*e_z) ;
  75. la22 = d pa3m pa4m ; la23 = d pa4m pa1m ;
  76. sa0 = surf plan ((inve la21) et la22 et la23 et (inve la4c)) ;
  77. va0 = sa0 volu n_x trans (l_x*e_x) ; va0 = va0 coul rouge ;
  78.  
  79. *trac (vv1 et va0) cach ;
  80.  
  81. ********************
  82. T_INIT = 20. ;
  83. T_CONV = T_INIT ;
  84. T_FUSION = 1400. ;
  85. t_dep = 1600. ;
  86. ********************
  87.  
  88. mothep = mode vv1 thermique conduction ;
  89. motha0 = mode va0 thermique conduction ;
  90.  
  91. * materiau
  92. TTMP = TABL ;
  93. TTMP. 1 = PROG 20 200 400 600 800 1000 1200 1400 1500 3000 ;
  94. TTMP. 2 = PROG 8.0e3 7.93e3 7.84e3 7.75e3 7.65e3 7.55e3
  95. 7.45e3 7.35e3 7.30e3 7.30e3 ;
  96. EVRHO = EVOL MANU 'T' (TTMP. 1) 'RHO' (TTMP. 2) ;
  97.  
  98. * Parametres thermiques
  99. TTMP = TABL ;
  100. TTMP. 1 = PROG 20 100 200 300 400 500 600 700 800 900 1000
  101. 1200 1400 3000 ;
  102. TTMP. 2 = PROG 0.0147e3 0.0158e3 0.0172e3 0.0186e3 0.02e3
  103. 0.0211e3 0.0222e3 0.0232e3 0.0241e3 0.0248e3 0.0255e3
  104. 0.0269e3 0.0283e3 0.0283e3 ;
  105. EVK = EVOL MANU 'T' (TTMP. 1) 'K' (TTMP. 2);
  106.  
  107. TTMP = TABL ;
  108. TTMP. 1 = PROG 20 100 200 300 400 600 800 1000 1200 1500 3000 ;
  109. TTMP. 2 = PROG 450 490 525 545 560 580 625 660 670 690 690 ;
  110. EVCP = EVOL MANU 'T' (TTMP. 1) 'C' (TTMP. 2);
  111.  
  112. SI GRAPH ;
  113. DESS EVRHO TITR 'Masse Volumique';
  114. DESS EVK TITR 'Conductivite Thermique';
  115. DESS EVCP TITR 'Chaleur Specifique';
  116. FINS;
  117.  
  118. * coefficient de convection avec l'exterieur
  119. he1 = 20. ;
  120.  
  121.  
  122. * MATERIAUX MECANIQUE ET THERMIQUE
  123.  
  124. CATHEP = MATE MOTHEP 'K' EVK 'RHO' EVRHO 'C' EVCP ;
  125.  
  126. cathea0 = mate motha0 'K' EVK 'RHO' EVRHO 'C' EVCP ;
  127.  
  128. **********************************
  129. * procede
  130.  
  131. vpu1 = vv1 ;
  132. mothu1 = mothep ;
  133. cathu1 = cathep ;
  134.  
  135. symvpu1 = prosym vpu1 ;
  136. symva0 = prosym va0 ;
  137. * trac (symvpu1 et symva0) ;
  138.  
  139. * surface convection
  140.  
  141. elim (d0*1.d-3) vpu1 va0 ;
  142. sconvu1 = enve vpu1 ;
  143. sdep1 = inte sconvu1 (enve va0) ;
  144. sconvu1 = diff sconvu1 sdep1 ;
  145. sconvu1 = diff sconvu1 symvpu1 ;
  146. *trac sconvv1 ;
  147.  
  148. * convection
  149. ctconvv1 = manu chpo sconvu1 T 20. ;
  150. ev_conv = evol manu 't (s)' (prog 0. 1.e5) 'Te (oC)' (prog 1. 1.) ;
  151. cha_conv = char teco ev_conv ctconvv1 ;
  152.  
  153. moconvu1 = mode sconvu1 thermique convection ;
  154. caconvu1 = mate moconvu1 'H' he1 ;
  155.  
  156. * temperatures initiale
  157. mpp1_u = diff (changer poi1 vpu1) (changer poi1 sdep1) ;
  158. cptempi = manu chpo 1 mpp1_u T t_init nature diffuse ;
  159.  
  160. ca0tempi = manu chpo 1 (changer poi1 va0) T t_dep nature diffuse ;
  161.  
  162. si graph ;
  163. trac (cptempi et ca0tempi) (vpu1 et va0)
  164. titre 'temperatures initiales' nclk;
  165. finsi ;
  166. * deplacements initiaux
  167. ma0p1_u = diff (changer poi1 va0) (changer poi1 sdep1) ;
  168. ca0depi = manu chpo 3 ma0p1_u ux 0. uy 0. uz 0. nature diffuse ;
  169.  
  170.  
  171.  
  172. tdep = table 'PASAPAS' ; tdep.'PROCESSEURS' = MOT 'AUTOMATIQUE';
  173. tdep . modele = mothu1 et motha0 et moconvu1 ;
  174. tdep . caracteristiques = cathu1 et cathea0 et caconvu1 ;
  175. tdep . chargement = cha_conv ;
  176. tdep . procedure_thermique = DUPONT ;
  177.  
  178. tdep . temperatures = table ;
  179. tdep . temperatures . 0 = cptempi et ca0tempi ;
  180.  
  181. si complet ;
  182. tdep . temps_calcules = prog 0. pas 1. 10. pas 10. 100. pas 1.e2 1.e3;
  183. tdep . temps_sauves = prog 0. 1. 5. 10. 20. 50. 100. 200. 500. 1.e3 ;
  184. sinon ;
  185. tdep . temps_sauves = prog 0. 1. ;
  186. finsi ;
  187. tdep.'GRANDS_DEPLACEMENTS'=vrai;
  188. pasapas tdep ;
  189.  
  190. ****************************************
  191. mailtra1 = enve (extr (mothu1 et motha0) mail) ;
  192. ppthm1 = point mailtra1 proc ppthm1 ; op1 = prog ;
  193. ppthm2 = point mailtra1 proc ppthm2 ; op2 = prog ;
  194. abt = prog ;
  195. * temperature
  196. l_temp = prog 100. 200. 300. 400. 500. 600. 700. 800. 900. 1000.
  197. 1100. 1200. 1300. 1400. ;
  198. si graph ;
  199. repeter bdes (dime tdep . temps) ;
  200. ind1 = &bdes - 1 ;
  201. abt = abt et (prog tdep . temps . ind1) ;
  202. op1 = op1 et (prog (extr tdep . temperatures . ind1 t ppthm1)) ;
  203. op2 = op2 et (prog (extr tdep . temperatures . ind1 t ppthm2)) ;
  204.  
  205. titre 's18_lin_a / temperature / date = ' tdep . temps . ind1 ;
  206. *trac tdep . temperatures . ind1 mailtra1 (arete mailtra1) l_temp ;
  207. trac tdep . temperatures . ind1 mailtra1 l_temp nclk ;
  208. fin bdes ;
  209.  
  210. titre 's18_lin_a / thermocouples ' ;
  211. evcapt = (evol manu abt 't(s)' op1 'T(°C)' coul jaune)
  212. et (evol manu abt 't(s)' op2 'T(°C)' coul rouge) ;
  213. dess evcapt ;
  214. finsi ;
  215. **
  216. *d_ther = faux ;
  217. *sauv tdep;
  218. *finsi ;
  219. **
  220.  
  221. ********************
  222. TAREF = -273.15 ;
  223. ********************
  224. *******************
  225. debpro prpmec tu1*table ;
  226. *calcul mecanique
  227.  
  228. tu1 . blocages_mecaniques = (bloq ux pp3mm1) et
  229. (bloq uz (pp3mm1 et pp3mp2)) et (bloq (symvpu1 et symva0) uy);
  230. tu1 . chargement = ch_temp ;
  231. tu1 . temps_calcules = tdep . temps_sauves ;
  232.  
  233. tu1.'GRANDS_DEPLACEMENTS'=vrai;
  234. pasapas tu1 ;
  235.  
  236. opsy1 = prog ; abst = prog ;
  237.  
  238. repeter beliso (dime tu1 . temps) ;
  239. ind2 = &beliso - 1 ;
  240. si graph ;
  241. titre 's18_lin_a / T /' tu1 . temps . ind2 ' s';
  242. trac tdep . temperatures . ind2 mailtra1 nclk;
  243. titre (et tu1 . etiquette ' / vmises /') tu1 . temps . ind2 ' s';
  244. trac tu1 . modele tu1 . contraintes . ind2 ;
  245. finsi ;
  246. chpu5 = changer chpo tu1 . modele (exco tu1 . contraintes . ind2 smyy);
  247. opsy1 = opsy1 et (prog ((extr chpu5 smyy ppmem1)/1.e6)) ;
  248. abst = abst et (prog tu1 . temps . ind2) ;
  249. fin beliso ;
  250.  
  251. tu1 . ecsmy1 = evol manu abst 't(s)' opsy1 ' smyy (MPa)' ;
  252. si graph ;
  253. titre 's18_lin_a / synthese SMYY' ;
  254. dess tu1 . ecsmy1 nclk;
  255. finsi ;
  256. finproc ;
  257. *******************
  258.  
  259. *******************
  260. *Procédure pour calculer YOUN à partir d'une évolution
  261. 'DEBP' CALYO EV1*EVOLUTION;
  262. X1 = EXTR EV1 'ABSC' ;
  263. Y1 = EXTR EV1 'ORDO' ;
  264. YOU1 = '/' (EXTR Y1 2) (EXTR X1 2) ;
  265. 'FINP' YOU1 ;
  266. *******************
  267.  
  268. **
  269. *si (non d_ther) ;
  270. *opti rest 'soudage18_lin_a.sauv' ;
  271. *rest ;
  272. **
  273.  
  274. *************
  275. * donnees materiau
  276. TTMP = TABL ;
  277. TTMP. 1 = PROG 20. 200. 300. 400. 500. 600.
  278. 700. 800. 900. 1000. 1500. 3000. ;
  279. TTMP. 2 = PROG 197e9 184e9 176e9 168e9
  280. 160e9 151e9 142e9 130e9 108e9 81e9 1e9 1e9 ;
  281. EVYOUN = EVOL MANU 'T' (TTMP. 1) 'YOUN' (TTMP. 2) ;
  282. MAXIT = MAXI (TTMP. 1) ;
  283.  
  284.  
  285. TTMP = TABL ;
  286. TTMP. 1 = PROG 25 100 200 400 500 600 700 800
  287. 900 1000 1100 1200 1300 1390 1420 1450 3000 ;
  288. TTMP. 2 = PROG 0.296 0.298 0.304 0.315 0.32
  289. 0.323 0.326 0.33 0.336 0.339 0.346 0.349 0.353 0.353 0.353 0.353 0.353 ;
  290. DIMNU = DIME TTMP. 1 ;
  291. VALNU = TTMP. 2 ;
  292. EVNU = EVOL MANU 'T' (TTMP. 1) 'NU' (TTMP. 2) ;
  293.  
  294.  
  295. TTMP = TABL ;
  296. TTMP. 1 = PROG 20 200 300 400 500 600 700 800 900 1000 1500 3000 ;
  297. TTMP. 2 = PROG 287e6 198e6 172e6 157e6 152e6 145e6 136e6
  298. 127e6 115e6 79e6 5e6 1e6 ;
  299. EVSIGY = EVOL MANU 'T' (TTMP. 1) 'R0' (TTMP. 2) ;
  300.  
  301. TTMP = TABL ;
  302. TTMP. 1 = PROG 0 100 200 300 400 500 600 700 800 900 1000 1100
  303. 1200 1420 1460 3000 ;
  304. TTMP. 2 = PROG -3.17e-4 0.0013 0.003 0.0048 0.0066 0.0086 0.0106
  305. 0.0126 0.0147 0.0168 0.019 0.0212 0.0235 0.029 0.0298 0.0298 ;
  306. EVDEFT = EVOL MANU 'T' (TTMP. 1) 'EPTH' (TTMP. 2) ;
  307. LALPHA = TTMP. 2 / (TTMP. 1 - TAREF) ;
  308. EVALPHA = EVOL MANU 'T' (TTMP. 1) 'ALPH' LALPHA ;
  309.  
  310. TTMP1 = TABL ;
  311. TTMP1. 1 = PROG 20 200 300 400 500 600 700 800 900 1000 1500 3000 ;
  312. TTMP2 = TABL ;
  313. TTMP2. 1 = PROG 0. 0.01 0.05 0.2 1. 2. ;
  314. TTMP2. 2 = PROG 0 28e6 132e6 274e6 913e6 1369e6 ;
  315. TTMP2. 3 = PROG 0 33e6 136e6 272e6 802e6 1203e6 ;
  316. TTMP2. 4 = PROG 0 29e6 135e6 279e6 728e6 1092e6 ;
  317. TTMP2. 5 = PROG 0 29e6 137e6 278e6 442e6 663e6 ;
  318. TTMP2. 6 = PROG 0 27e6 130e6 267e6 398e6 597e6 ;
  319. TTMP2. 7 = PROG 0 25e6 117e6 242e6 355e6 532e6 ;
  320. TTMP2. 8 = PROG 0 25e6 76e6 204e6 264e6 396e6 ;
  321. TTMP2. 9 = PROG 0 25e6 72e6 167e6 223e6 334e6 ;
  322. TTMP2. 10 = PROG 0 22e6 46e6 54e6 65e6 97e6 ;
  323. TTMP2. 11 = PROG 0 3e6 18e6 21e6 26e6 39e6 ;
  324. TTMP2. 12 = PROG 0 2e6 3e6 4e6 5e6 6e6 ;
  325. TTMP2. 13 = PROG 0 1e6 2e6 3e6 4e6 5e6 ;
  326.  
  327. EVTOT1 = VIDE 'EVOLUTION';
  328. EVTOT2 = VIDE 'EVOLUTION';
  329. LTEMPER = VIDE 'LISTREEL' ;
  330. LSIGY = vide listreel ;
  331. REPE ITEMPER (DIME TTMP1. 1);
  332. J=&ITEMPER;
  333. TEMPER = EXTR (TTMP1 . 1) J;
  334. LTEMPER= LTEMPER ET TEMPER ;
  335.  
  336. * Interpolation du module de YOUNG et SIGY a la temperature TEMPER
  337. YOUNIPOL = IPOL TEMPER EVYOUN;
  338. SIGYIPOL = IPOL TEMPER EVSIGY;
  339.  
  340. * Calcul de EPSIY a partir de YOUNIPOL et SIGYIPOL
  341. EPSIY = SIGYIPOL / YOUNIPOL;
  342.  
  343. * Construction de la courbe de ecrouissage Complete pour Cast3M
  344. LESPI = (PROG 0.) ET ((TTMP2. 1) + EPSIY );
  345. LSIGM = (PROG 0.) ET ((TTMP2. (J+1)) + SIGYIPOL);
  346. EVTRAC= EVOL MANU 'EPS' LESPI 'CONT' LSIGM ;
  347. EVTOT1 = EVTOT1 ET EVTRAC;
  348. LSIGY = LSIGY et (prog SIGYIPOL) ;
  349.  
  350. LSIGM = LSIGM enle 1 ;
  351. LESPI = (LESPI enle 1) - (LSIGM / YOUNIPOL) born mini 0. ;
  352. EVECRO= EVOL VERT MANU 'EPS' LESPI 'ECRO' LSIGM ;
  353. EVTOT2 = EVTOT2 ET EVECRO;
  354.  
  355. * Construction du NUAGE qui associe une EVOLUTION a une TEMPERATURE
  356. SI (J EGA 1);
  357. NUATRAC = NUAGE 'COMP' 'T ' TEMPER
  358. 'COMP' 'ECRO' EVECRO ;
  359. SINO;
  360. NUATRAC = NUATRAC ET (NUAGE 'COMP' 'T ' TEMPER
  361. 'COMP' 'ECRO' EVECRO ) ;
  362. FINS;
  363. FIN ITEMPER;
  364.  
  365. evlimp = EVOL MANU 'T' LTEMPER 'LIMP' ((ipol ltemper evyoun) * 2.e-3) ;
  366.  
  367. SI GRAPH ;
  368. DESS EVYOUN TITR 'Module de YOUNG';
  369. DESS EVNU TITR 'Coefficient de POISSON';
  370. DESS EVSIGY TITR 'Limite Elastique';
  371. DESS EVALPHA TITR 'Coefficient de dilatation Thermique';
  372. DESS (EVTOT1 et EVTOT2) TITR
  373. 'Courbes de traction et d ecrouissage (vert) a differentes temperatures';
  374. dess evlimp TITR 'Limite 1er invariant ' ;
  375. FINS;
  376. *************
  377.  
  378. * point d appui
  379. l1cm1 pp3mm1 = l1c pp3m moins (l_x*e_x) ;
  380. l1cp2 pp3mp2 = l1c pp3m plus (2*l_x*e_x) ;
  381. * symetrie
  382. symvpu1 = prosym vpu1 ;
  383. symva0 = prosym va0 ;
  384. * trac (symvpu1 et symva0) ;
  385. * chargement
  386. ch_temp = char t (tdep . temps) (tdep . temperatures) ;
  387.  
  388. **
  389. momecp = mode vpu1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  390. 'PLASTIQUE' 'ISOTROPE' ;
  391. momca0 = mode va0 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  392. 'PLASTIQUE' 'ISOTROPE' ;
  393. *
  394. momecb = mode (vpu1 et va0) 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  395. 'PLASTIQUE' 'ISOTROPE' 'BBAR' ;
  396. *
  397. momecl = mode (vpu1 et va0) 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  398. 'PLASTIQUE' 'ISOTROPE' 'CRIP' ;
  399. *
  400. momect =mode (vpu1 et va0) 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  401. 'PLASTIQUE' 'ISOTROPE' 'CRIP' 'BBAR' ;
  402.  
  403. **
  404. chT_iniCP ='CHAN' 'CHAM' tdep.temperatures. 0 MOMECP 'RIGIDITE' 'CARACTERISTIQUES';
  405. chT_iniA0 ='CHAN' 'CHAM' tdep.temperatures. 0 MOMCA0 'RIGIDITE' 'CARACTERISTIQUES';
  406. chT_iniCB ='CHAN' 'CHAM' tdep.temperatures. 0 MOMECB 'RIGIDITE' 'CARACTERISTIQUES';
  407. chT_iniCL ='CHAN' 'CHAM' tdep.temperatures. 0 MOMECL 'RIGIDITE' 'CARACTERISTIQUES';
  408. chT_iniCT ='CHAN' 'CHAM' tdep.temperatures. 0 MOMECT 'RIGIDITE' 'CARACTERISTIQUES';
  409.  
  410.  
  411. camecp = MATE MOMECP 'YOUN' EVYOUN 'NU' EVNU 'RHO' EVRHO 'ALPH' EVALPHA 'TREF' chT_iniCP 'TALP' TAREF
  412. 'ECRO' NUATRAC ;
  413. *
  414. camca0 = MATE MOMCA0 'YOUN' EVYOUN 'NU' EVNU 'RHO' EVRHO 'ALPH' EVALPHA 'TREF' chT_iniA0 'TALP' TAREF
  415. 'ECRO' NUATRAC ;
  416. *
  417. camecb = MATE MOMECB 'YOUN' EVYOUN 'NU' EVNU 'RHO' EVRHO 'ALPH' EVALPHA 'TREF' chT_iniCB 'TALP' TAREF
  418. 'ECRO' NUATRAC ;
  419. *
  420. camecl = MATE MOMECL 'YOUN' EVYOUN 'NU' EVNU 'RHO' EVRHO 'ALPH' EVALPHA 'TREF' chT_iniCL 'TALP' TAREF
  421. 'ECRO' NUATRAC 'LIMP' evlimp ;
  422. *
  423. camect = MATE MOMECT 'YOUN' EVYOUN 'NU' EVNU 'RHO' EVRHO 'ALPH' EVALPHA 'TREF' chT_iniCT 'TALP' TAREF
  424. 'ECRO' NUATRAC 'LIMP' evlimp ;
  425. **
  426. mailtra1 = vpu1 et va0 ;
  427. *trac mailtra1 ;
  428. mm125 = elem 125 mailtra1 ;
  429. myu1 = elem mailtra1 appuye largement va0 ;
  430. myu1 = diff myu1 va0 ;
  431.  
  432.  
  433. pp3mm1 = point mailtra1 proc pp3mm1 ;
  434. pp3mp2 = point mailtra1 proc pp3mp2 ;
  435. ppmem1 = point mailtra1 proc ppthm1 ;
  436.  
  437. tmec0 = table 'PASAPAS' ;
  438. tmec0 . modele = momecp et momca0 ;
  439. tmec0 . caracteristiques = camecp et camca0 ;
  440. tmec0 . etiquette = 's18_lin_a / standard' ;
  441. *tu1 = tmec0 ;
  442. prpmec tmec0 ;
  443.  
  444. tmecb = table 'PASAPAS' ;
  445. tmecb . modele = momecb ;
  446. tmecb . caracteristiques = camecb ;
  447. tmecb . etiquette = 's18_lin_a / bbar' ;
  448. prpmec tmecb ;
  449.  
  450. tmecl = table 'PASAPAS' ;
  451. tmecl . modele = momecl ;
  452. tmecl . caracteristiques = camecl ;
  453. tmecl . etiquette = 's18_lin_a / critp' ;
  454. prpmec tmecl ;
  455.  
  456. tmect = table 'PASAPAS' ;
  457. tmect . modele = momect ;
  458. tmect . caracteristiques = camect ;
  459. tmect . etiquette = 's18_lin_a / critp et bbar' ;
  460. prpmec tmect ;
  461.  
  462. tsymb = table ; tsymb . titre = table ;
  463. tsymb . 1 = 'MARQ PLUS' ; tsymb . titre . 1 = 'stand' ;
  464. tsymb . 2 = 'MARQ CARR' ; tsymb . titre . 2 = 'bbar' ;
  465. tsymb . 3 = 'MARQ ETOI' ; tsymb . titre . 3 = 'critp' ;
  466. tsymb . 4 = 'MARQ LOSA' ; tsymb . titre . 4 = 'bbar et critp' ;
  467.  
  468. si graph ;
  469. titre ' s18_lin_a / capteurs contraites ';
  470. dess (tmec0 . ecsmy1 et tmecb . ecsmy1 et tmecl . ecsmy1
  471. et tmect . ecsmy1) tsymb 'LEGE' ;
  472. finsi ;
  473.  
  474. **
  475. *finsi ;
  476. **
  477.  
  478. *test octobre 2018
  479. or0 = extr (extr tmec0 . ecsmy1 ordo) 2 ;
  480. e0 = abs ((or0 - 7.20114E+01) / 7.20114E+01) ;
  481. orb = extr (extr tmecb . ecsmy1 ordo) 2 ;
  482. eb = abs ((orb - 1.80269E+01) / 1.80269E+01) ;
  483. orl = extr (extr tmecl . ecsmy1 ordo) 2 ;
  484. el = abs ((orl - 1.02034E+01) / 1.02034E+01) ;
  485. ort = extr (extr tmect . ecsmy1 ordo) 2 ;
  486. et = abs ((ort - 1.53886E+01) / 1.53886E+01) ;
  487.  
  488. mess ' e0, eb, el, et =', e0 eb el et ;
  489. si ((e0 > 2.e-3) ou (eb > 2.e-3) ou (el > 2.e-3) ou (et > 2.e-3)) ;
  490. erre 21 ;
  491. sinon ;
  492. erre 0 ;
  493. finsi ;
  494.  
  495. fin ;
  496.  
  497.  
  498.  
  499.  
  500.  
  501.  
  502.  
  503.  
  504.  
  505.  
  506.  
  507.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales