Télécharger soret_11.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : soret_11.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * CAS TEST soret_11.dgibi *
  7. ************************************************************************
  8. * Test effet Soret
  9. * - 3D TRID
  10. * - ELEMENTS FINIS TESTES : 'TET4'
  11. * - Regime permanent
  12. * - C(Z0) = C0
  13. * - C(Z1) = C1
  14. * - GRAD(T) choisi lineaire (T=A*(Z**2) / 2.D0 ==> GRAD(T)= A*Z)
  15. * - CONDUCTION et SORET sont en concurrence
  16. ************************************************************************
  17.  
  18.  
  19. ************************************************************************
  20. * OPTIONS & REGLAGES
  21. ************************************************************************
  22. GRAPH = 'N' ;
  23. 'OPTI' 'DIME' 3 ;
  24. 'OPTI' 'ELEM' 'TRI3' ;
  25.  
  26. 'SI' ('NEG' GRAPH 'N');
  27. 'OPTI' 'TRAC' 'X';
  28. 'SINO';
  29. 'OPTI' 'TRAC' 'PSC';
  30. 'FINS';
  31.  
  32. NBE1 = 5 ;
  33. NBE2 = 5 ;
  34. NBE3 = 15 ;
  35.  
  36. K = -7.D0;
  37. A = 1.D0;
  38.  
  39. Z0 = -0.5 ;
  40. Z1 = 1. ;
  41.  
  42. C0 = 1. ;
  43. C1 = 2. ;
  44.  
  45. ************************************************************************
  46. * MAILLAGE
  47. ************************************************************************
  48. P1 = 0. 0. Z0;
  49. P2 = 0. 1. Z0;
  50. P3 = 1. 1. Z0;
  51. P4 = 1. 0. Z0;
  52.  
  53. L1 ='DROI' NBE1 P1 P2;
  54. L2 ='DROI' NBE1 P4 P3;
  55.  
  56. S1 ='REGL' NBE2 L1 L2;
  57. S2 = S1 'PLUS' (0. 0. (Z1 - Z0));
  58. L4 ='COTE' 4 S2;
  59. P5 ='POIN' L4 'FINAL';
  60.  
  61. 'OPTI' 'ELEM' 'PRI6';
  62. V1 ='VOLU' NBE3 S1 S2 ;
  63. V1 ='CHAN' 'TET4' V1 ;
  64. ENV1='ENVE' V1;
  65. ARE1='ARET' ENV1;
  66. PAR1='CHAN' 'POI1' ARE1 ;
  67. M1 ='POIN' PAR1 'DROIT' P1 P5 1.D-5;
  68.  
  69. L6 = 'ELEM' ARE1 'APPU' 'STRI' M1;
  70. 'TRAC' 'QUAL' ENV1;
  71. 'TRAC' 'QUAL' ARE1;
  72.  
  73. ************************************************************************
  74. * MODELE & MATERIAU
  75. ************************************************************************
  76. MOD1 ='MODE' V1 'DIFFUSION' 'FICK' 'INCO' 'HI ' 'QHI ';
  77. MAT1 ='MATE' MOD1 'KD ' 1.D0 ;
  78. MAT2 ='MANU' 'CHML' MOD1 'SCAL' K 'RIGIDITE' ;
  79.  
  80. ************************************************************************
  81. * Champ de temperature pour que le GRAD(T) soit constant
  82. ************************************************************************
  83. COO3 ='COOR' 3 V1 ;
  84. EVO1 ='EVOL' 'BLEU' 'CHPO' COO3 'SCAL' L6 ;
  85. LRZ ='EXTR' EVO1 'ORDO' 1 ;
  86. TEMP1 ='CHAN' 'COMP' (A / 2.D0 * (COO3 ** 2)) 'T' ;
  87. 'TITR' 'Evolution de la TEMPERATURE avec (abscisse curviligne)';
  88. EVOT ='EVOL' 'BLEU' 'CHPO' TEMP1 'T' L6 ;
  89. 'DESS' EVOT ;
  90.  
  91. ************************************************************************
  92. * RIGIDITE
  93. ************************************************************************
  94. RIG1 ='COND' MOD1 MAT1;
  95. RIG2 ='SORE' MOD1 MAT1 MAT2 TEMP1;
  96.  
  97. ************************************************************************
  98. * CONDITIONS AUX LIMITES
  99. ************************************************************************
  100. CLIM1 ='BLOQ' 'HI' S1 ;
  101. CLIM2 ='BLOQ' 'HI' S2 ;
  102.  
  103.  
  104. CIMP1 ='DEPI' CLIM1 C0 ;
  105. CIMP2 ='DEPI' CLIM2 C1 ;
  106.  
  107. ************************************************************************
  108. * RESOLUTION
  109. ************************************************************************
  110. SOL1 ='RESO' (RIG1 ET RIG2 ET CLIM1 ET CLIM2) (CIMP1 ET CIMP2);
  111. 'TITR' 'Isovaleurs de concentration en HI';
  112. 'TRAC' SOL1 V1;
  113.  
  114. ************************************************************************
  115. * POST-TRAITEMENT
  116. ************************************************************************
  117. * Solution NUMERIQUE
  118. EVONUM ='EVOL' 'ROUG' 'CHPO' SOL1 'HI ' L6 ;
  119. LCNUM ='EXTR' EVONUM 'ORDO' 1 ;
  120. EVONUM ='EVOL' 'ROUG' 'MANU' 'X' LRZ 'HI' LCNUM;
  121.  
  122. * Solution ANALYTIQUE
  123. EVO2 ='EVOL' 'CHPO' TEMP1 'HI' L6 ;
  124. FLO1 = ((-2*K*A)**0.5)/2. ;
  125. XDENO= ( 'EXP'(K/2.*A*(LRZ**2)) ) *
  126. (('ERF'(FLO1*Z1)) - ('ERF'(FLO1*Z0)));
  127. LNUME= (('ERF'(FLO1*LRZ))*C1*('EXP'(K/2.*A*(Z1**2))))-
  128. (('ERF'(FLO1*LRZ))*C0*('EXP'(K/2.*A*(Z0**2))))+
  129. (('ERF'(FLO1*Z1 ))*C0*('EXP'(K/2.*A*(Z0**2))))-
  130. (('ERF'(FLO1*Z0 ))*C1*('EXP'(K/2.*A*(Z1**2))));
  131.  
  132. LCANA = LNUME / XDENO;
  133.  
  134. EVOANA ='EVOL' 'BLEU' 'MANU' 'X' LRZ 'HICA' LCANA;
  135. 'DESS' (EVONUM ET EVOANA);
  136.  
  137. * Comparaison
  138. LCDIFF = LCNUM - LCANA ;
  139. 'TITR' 'Difference entre la Solutions NUMERIQUE et ANALYTIQUE';
  140. EVODIF ='EVOL' 'VERT' 'MANU' 'X' LRZ 'HICA' LCDIFF;
  141. 'DESS' EVODIF;
  142.  
  143.  
  144. * Critere d'erreur
  145. 'OPTI' 'ECHO' 0;
  146. ERRABS ='MAXI' 'ABS' LCDIFF;
  147. ERRREL = ERRABS / (('MAXI' LCANA) - ('MINI' LCANA)) ;
  148. 'MESS' '*********************************************' ;
  149. 'MESS' '* Erreur MAXIMALE absolue :' ERRABS '*';
  150. 'MESS' '* Erreur MAXIMALE relative :' ERRREL '*';
  151. 'MESS' '*********************************************' ;
  152. 'SI' (ERRREL >EG 2.18D-2);
  153. 'ERRE' 5;
  154. 'FINS';
  155.  
  156. 'FIN';
  157.  
  158.  
  159.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales