Télécharger soret_10.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : soret_10.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * CAS TEST soret_10.dgibi *
  7. ************************************************************************
  8. * Test effet Soret
  9. * - 2D AXIS
  10. * - ELEMENTS FINIS TESTES : 'QUA8'
  11. * - Regime permanent
  12. * - C(R0) = C0
  13. * - C(R1) = C1
  14. * - GRAD(T) choisi en 1/R (T=A*ln(|R|) ==> GRAD(T)= A/R)
  15. * - CONDUCTION et SORET sont en concurrence
  16. ************************************************************************
  17.  
  18.  
  19. ************************************************************************
  20. * OPTIONS & REGLAGES
  21. ************************************************************************
  22. GRAPH = 'N' ;
  23. 'OPTI' 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'AXIS';
  24.  
  25. 'SI' ('NEG' GRAPH 'N');
  26. 'OPTI' 'TRAC' 'X';
  27. 'SINO';
  28. 'OPTI' 'TRAC' 'PSC';
  29. 'FINS';
  30.  
  31. NBE1 = 15 ;
  32. NBE2 = 15 ;
  33.  
  34. K = -7.D0;
  35. A = 1.D0;
  36.  
  37. R0 = 0.5 ;
  38. R1 = 1.5 ;
  39.  
  40. C0 = 1. ;
  41. C1 = 2. ;
  42.  
  43. ************************************************************************
  44. * MAILLAGE
  45. ************************************************************************
  46. P1 = R0 0. ;
  47. P2 = R0 1. ;
  48. P3 = R1 1. ;
  49. P4 = R1 0. ;
  50.  
  51. L1 ='DROI' NBE1 P1 P2;
  52. L2 ='DROI' NBE1 P4 P3;
  53.  
  54. S1 ='REGL' NBE2 L1 L2;
  55. L3 ='COTE' 2 S1;
  56.  
  57. 'TRAC' 'QUAL' S1;
  58.  
  59. ************************************************************************
  60. * MODELE & MATERIAU
  61. ************************************************************************
  62. MOD1 ='MODE' S1 'DIFFUSION' 'FICK' 'INCO' 'HI ' 'QHI ';
  63. MAT1 ='MATE' MOD1 'KD ' 1.D0 ;
  64. MAT2 ='MANU' 'CHML' MOD1 'SCAL' K 'RIGIDITE' ;
  65.  
  66. ************************************************************************
  67. * Champ de temperature pour que le GRAD(T) soit constant
  68. ************************************************************************
  69. COO1 ='COOR' 1 S1 ;
  70. EVO1 ='EVOL' 'BLEU' 'CHPO' COO1 'SCAL' L3 ;
  71. LRR ='EXTR' EVO1 'ORDO' 1 ;
  72. TEMP1 ='CHAN' 'COMP' (A * ('LOG' ('ABS' COO1) )) 'T' ;
  73. 'TITR' 'Evolution de la TEMPERATURE avec (abscisse curviligne)';
  74. EVOT ='EVOL' 'BLEU' 'CHPO' TEMP1 'T' L3 ;
  75. 'DESS' EVOT ;
  76.  
  77. ************************************************************************
  78. * RIGIDITE
  79. ************************************************************************
  80. RIG1 ='COND' MOD1 MAT1;
  81. RIG2 ='SORE' MOD1 MAT1 MAT2 TEMP1;
  82.  
  83. ************************************************************************
  84. * CONDITIONS AUX LIMITES
  85. ************************************************************************
  86. CLIM1 ='BLOQ' 'HI' L1 ;
  87. CLIM2 ='BLOQ' 'HI' L2 ;
  88.  
  89.  
  90. CIMP1 ='DEPI' CLIM1 C0 ;
  91. CIMP2 ='DEPI' CLIM2 C1 ;
  92.  
  93. ************************************************************************
  94. * RESOLUTION
  95. ************************************************************************
  96. SOL1 ='RESO' (RIG1 ET RIG2 ET CLIM1 ET CLIM2) (CIMP1 ET CIMP2);
  97. 'TITR' 'Isovaleurs de concentration en HI';
  98. 'TRAC' SOL1 S1;
  99.  
  100. ************************************************************************
  101. * POST-TRAITEMENT
  102. ************************************************************************
  103. * Solution NUMERIQUE
  104. EVONUM ='EVOL' 'ROUG' 'CHPO' SOL1 'HI ' L3 ;
  105. LCNUM ='EXTR' EVONUM 'ORDO' 1 ;
  106. EVONUM ='EVOL' 'ROUG' 'MANU' 'X' LRR 'HI' LCNUM;
  107.  
  108. * Solution ANALYTIQUE
  109. EVO2 ='EVOL' 'CHPO' TEMP1 'T' L3 ;
  110. FLO1 = -1.*K*A ;
  111.  
  112. LCANA=(((R0**FLO1)*C1) - ((R1**FLO1)*C0) + ((LRR**FLO1)*(C0 - C1))) /
  113. ( (R0**FLO1) - (R1**FLO1));
  114.  
  115. EVOANA ='EVOL' 'BLEU' 'MANU' 'X' LRR 'HICA' LCANA;
  116. 'DESS' (EVONUM ET EVOANA);
  117.  
  118. * Comparaison
  119. LCDIFF = LCNUM - LCANA ;
  120. 'TITR' 'Difference entre la Solutions NUMERIQUE et ANALYTIQUE';
  121. EVODIF ='EVOL' 'VERT' 'MANU' 'X' LRR 'HICA' LCDIFF;
  122. 'DESS' EVODIF;
  123.  
  124.  
  125. * Critere d'erreur
  126. 'OPTI' 'ECHO' 0;
  127. ERRABS ='MAXI' 'ABS' LCDIFF;
  128. ERRREL = ERRABS / (('MAXI' LCANA) - ('MINI' LCANA)) ;
  129. 'MESS' '*********************************************' ;
  130. 'MESS' '* Erreur MAXIMALE absolue :' ERRABS '*';
  131. 'MESS' '* Erreur MAXIMALE relative :' ERRREL '*';
  132. 'MESS' '*********************************************' ;
  133. 'SI' (ERRREL >EG 1.25D-5);
  134. 'ERRE' 5;
  135. 'FINS';
  136.  
  137. 'FIN';
  138.  
  139.  
  140.  
  141.  
  142.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales