Télécharger soret.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : soret.dgibi
  2. *******************CAS TEST soret.dgibi***************************
  3. * test effet Soret sur un disque plan avec trou central
  4. * en modéle axisymetrique
  5. * le potentiel agissant sur la concentration donne un gradient
  6. * radial constant
  7. * Concentration fixées sur les bords interne et externe
  8. *
  9. *******************************************************************
  10. GRAPH = 'N' ;
  11. 'OPTION' 'DIME' 2 'ELEM' 'QUA4' ;
  12. 'OPTION' 'MODE' 'AXIS' ;
  13. nbb = 100 ;l = 100. ;
  14. rint = 100. ;rext = rint + l ;
  15.  
  16. *---- solution analytique calculée a partir d'une integrale-------
  17. *-----donnée par MATLAB pour pour v = .5 ----------------------
  18. *- pour ri = 100. re= 200. diffusivité du materiau 1.2
  19. *--------- concentrations interne 20. externe 100. ---------------
  20. l1 = 'PROG'0. 'PAS' 1. 11. 15. 20. 'PAS' 10. 100. ;
  21. l2 = 'PROG'20. 80.15 119.15 144.21 160.09 169.94 175.83 179.11
  22. 180.68 181.14 180.88 180.15 175.19 168.03 154.89 143.63 133.89
  23. 125.39 117.27 111.27 105.35 100. ;
  24. evana = 'EVOL' 'MANU' 'ABSC' l1 'ORDO' l2 ;
  25. **
  26. *------ on definit un maillage au pas de l1----------------------
  27.  
  28. p1 = rint 0 ; p2 = rext 0. ; p3 = rint 1.;
  29. pp1 = 111. 0. ; pp2 = 115. 0 ; pp3 = 120. 0. ;
  30. nr = 1 ;
  31. su1 = ('DROI' 1 p3 p1 ) 'TRAN' (11 * nr) (pp1 'MOINS' p1 )
  32. 'TRAN' nr (pp2 'MOINS' pp1)
  33. 'TRAN' nr (pp3 'MOINS' pp2)
  34. 'TRAN' (8 * nr) (p2 'MOINS' pp3) ;
  35.  
  36. 'TITRE' ' traitement axi ' ;
  37. 'SI' ('NEG' GRAPH 'N') ;
  38. 'TRAC' su1 ;
  39. 'FINSI' ;
  40. v = .5 ;
  41. lig1 = su1 'COTE' 2 ;
  42. cext = su1 'COTE' 3 ;
  43. cint = su1 'COTE' 1 ;
  44. kdif = 1.2 ;
  45. r = coor 1 su1 ;
  46. * Cacul du potentiel T donnant T,R = v constante
  47. TT = ( r * v ) ;
  48. kv = manu chpo su1 1 SCAL (1./kdif ) ;
  49. *
  50. mod1 = su1 'MODE' 'THERMIQUE' 'ISOTROPE' ;
  51. mat1 = 'MATE' mod1 'K' kdif ;
  52. *------------- matrice de diffusion normale -------------------------
  53. rig1 = 'CONDUC' mod1 mat1 ;
  54. *--------------matrice effet Soret -----------------------------------
  55. kvv = chan cham kv mod1 'RIGIDITE' ;
  56. * rig2 = 'SORE' mod1 mat1 TT ;
  57. rig2 = sore mod1 mat1 kvv TT ;
  58. *
  59. clime= 'BLOQUER' 'T' cext ;
  60. clims= 'BLOQUER' 'T' cint ;
  61. ff = ('DEPIMP' clime 100. ) 'ET' ( 'DEPIMP' clims 20.);
  62. *
  63. sol1 = 'RESO' ( rig1 et rig2 et clime et clims) ff ;
  64. 'TITR' 'Comparaison solution analytique / F.E. ' ;
  65. ev3 = 'EVOL' roug 'CHPO' sol1 'T' lig1 ;
  66. r1 = sol1 clime 'REAC' 'RESU' 'MAXI' ;
  67. r2 = sol1 clims 'REAC' 'RESU' 'MAXI' ;
  68. tabu = table ;
  69. tabu.1= 'MARQ CROI ' ;
  70. tabu.2= 'MARQ TRIA ' ;
  71. tabu.'TITRE' = table ;
  72. tabu.'TITRE'. 1 = MOT 'ANALYTIQUE' ;
  73. tabu.'TITRE'. 2 = MOT 'AXISYMETRIQUE' ;
  74.  
  75. 'SI' ('NEG' GRAPH 'N' ) ;
  76. 'DESS' ( evana et ev3 ) lege tabu xbor 0. 100. ;
  77. finsi ;
  78. *----------------calcul de l'erreur ---------------------------------
  79. l3 = 'EXTR' ev3 'ORDO' ;
  80. si (( dime l2 ) neg (dime (ev3 extr absc ))) ;
  81. l3 = ipol (extr evana absc ) (ev3 extr absc ) ( ev3 extr ordo ) ;
  82. finsi ;
  83. delta = (l3 - l2) ;
  84. eeee = 'ABS' (delta / l2 ) ;
  85. 'TITR' 'Erreur absolue ' ;
  86. ever1 = 'EVOL' 'MANU' 'ABSC' l1 'ORDO' delta ;
  87.  
  88. 'TITR' 'Erreur relative ' ;
  89. ever2 = 'EVOL' 'MANU' 'ABSC' l1 'ORDO' eeee ;
  90. ermax = 'MAXI' eeee ;
  91.  
  92. 'SI' ('NEG' GRAPH 'N' ) ;
  93. 'DESS' ever1 'XBOR' 0. 100. ;
  94. 'DESS' ever2 'XBOR' 0. 100. ;
  95. finsi ;
  96.  
  97.  
  98. 'MESS' ' FLUX en ENTREE ' R2 ;
  99. 'MESS' ' FLUX en SORTIE ' R1 ;
  100.  
  101. 'SI' (ermax > 1.e-2 ) ;
  102. 'ERRE' 5 ;
  103. 'FINS' ;
  104. 'FIN' ;
  105.  
  106.  
  107.  
  108.  
  109.  
  110.  
  111.  
  112.  
  113.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales