Télécharger snap.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : snap.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *************************************************************************
  5. * TEST SNAP
  6. *
  7. * EXEMPLE D UTILISATION DE LA PROCEDURE PASAPAS ( ET INCREME)
  8. *
  9. * PROBLEME DE GRANDS DEPLACEMENTS
  10. *
  11. * PROBLEME DU SNAP une seule barre est maillee et calculee
  12. *
  13. *
  14. *
  15. * ||
  16. * ||
  17. * \/ F
  18. * /\
  19. * / \
  20. * | / \ |
  21. * |/ \|
  22. * | |
  23. *************************************************************************
  24. *
  25. *
  26. TITRE ' SNAP ' ;
  27. *
  28. *TEMPS ;
  29. *
  30. *------------- geometrie ligne ST formee d' 1 SEG2 -------------------
  31. * PAR SYMETRIE, ON N'ETUDIE QUE LA MOITIE
  32. *
  33. OPTI ECHO 0 ;
  34. OPTI DIME 2 ELEM SEG2 MODE PLAN CONT ;DENS 1. ;
  35. P1 = 0. 1. ; P2 = 10. 0. ;
  36. ST = P1 D 1 P2 ;
  37. *
  38. *------------ calcul mecanique . ------------------
  39. *
  40. MO = MODE ST MECANIQUE BARR ;
  41. *
  42. * MATERIAU ET CARACTERISTIQUES
  43. *
  44. *
  45. MA1 = MATE MO YOUN 2.1E11 NU 0.3 ;
  46. CAR1 = CARA MO SECT 0.05 ;
  47. MACA= MA1 ET CAR1;
  48. *
  49. *----------- calcul de la rigidite --------------------------------------
  50. *
  51. RI1 = RIGI MACA MO ;
  52. *
  53. *----------- definition des conditions aux limites ----------------------
  54. *
  55. CL1 = BLOQ UX P1 ;
  56. CL2 = BLOQ UX P2 ;
  57. CL3 = BLOQ UY P2 ;
  58. CL4 = BLOQ UY p1;
  59. CL = CL1 ET CL2 ET CL3 ;
  60. *
  61. *----------- definition du chargement -----------------------------------
  62. *
  63. FP11 = FORCE ( 0 -12.5e5 ) p1;
  64. LIX1 = PROG 0. 40. ;
  65. LIY1 = PROG 0. 40. ;
  66. EV1 = EVOL MANU T LIX1 F(T) LIY1 ;
  67. *
  68. *----------- resolution par la procedure NONLIN -------------------------
  69. * CALCUL EN GRANDS DEPLACEMENTS
  70. *
  71. TAB2 = TABLE ;
  72. CHA1 = CHAR MECA FP11 EV1 ;
  73. TAB2.'GRANDS_DEPLACEMENTS'=VRAI;
  74. TAB2.'AUTOMATIQUE' = VRAI;
  75. *
  76. * ---------- pilotage suivant le deplacement du point P1
  77. *
  78. 'DEBPROC' AUTOPILO DELT*'CHPOINT' DELA*'CHPOINT' ZMOD*'MMODEL'
  79. ZMAT*'MCHAML' TTT*TABLE ;
  80. NORM1 = (extraire delt p1 'UY' ) *-1 ;
  81. * mess ' norm1 ' norm1;
  82. FINPROC NORM1;
  83. *--------------------------------------------------------
  84. *
  85. TAB2.'AUTOPAS' = 200;
  86. TAB2.'AUTOCRIT' = 0.075;
  87. TAB2.'AUTORESU' = 1;
  88. TAB2.'BLOCAGES_MECANIQUES' = CL;
  89. TAB2.'MODELE' = MO;
  90. TAB2.'CARACTERISTIQUES' = MACA;
  91. TAB2.'CHARGEMENT' = CHA1;
  92. LIS11 = PROG 0. 2. ;
  93. TAB2.'TEMPS_CALCULES' = LIS11;
  94. tab2.'REAC_GRANDS'=200.;
  95. PASAPAS TAB2 ;
  96. *
  97. *----------- resultats --------------------------------------------------
  98. * courbe de snap through : montee descente montee
  99. PGX = PROG 0.;
  100. PGY = PROG 0.;
  101. NDIM = (DIME ( TAB2 . DEPLACEMENTS )) - 1 ;
  102.  
  103. REPETER TBOU2 NDIM ;
  104.  
  105. LEDEP = TAB2 . DEPLACEMENTS. (&TBOU2);
  106. REA1 = REAC CL3 LEDEP ;
  107. V = EXTR LEDEP UY P1 ;
  108. PGX = PGX ET ( PROG V ) ;
  109. VV = EXTR REA1 FY P2 ;
  110. PGY = PGY ET ( PROG VV ) ;
  111. FIN TBOU2 ;
  112. *
  113. pgx = pgx * -1.;
  114. strou = mini pgy;
  115. sref = -2.e+6;
  116. smp= sref * 1.05;smb = sref * 0.95;
  117. mess ' borne min ' smp 'valeur trouvée' strou 'borne max' smb;
  118. *
  119. si (( strou > smb ) ou ( strou < smp) ) ;
  120. erreur (5);
  121. finsi;
  122. *
  123. *EV5 = EVOL TURQ MANU 'Deplacement' PGX 'Force de reaction' PGY ;
  124. *DESS EV5 ;
  125. fin;
  126.  
  127.  
  128.  
  129.  
  130.  
  131.  
  132.  
  133.  
  134.  
  135.  
  136.  
  137.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales