Télécharger sissi.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : sissi.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************
  6. * Test sissi.dgibi: jeux de données *
  7. * --------------------------------- *
  8. *******************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18. OPTI ECHO 1 ;
  19. OPTI TRAC PSC ;
  20. SINO ;
  21. OPTI ECHO 0 ;
  22. FINSI ;
  23.  
  24. SAUT PAGE;
  25. *******************************************
  26. * *
  27. * Mots-clés : Vibrations, calcul modal, *
  28. * poutre, seisme *
  29. * *
  30. * SISSI *
  31. * *
  32. * CAS TEST DU 91/06/19 PROVENANCE : PLAF *
  33. * CAS TEST DU 91/06/18 PROVENANCE : PLAF *
  34. * *
  35. * test de la procedure SISSIB *
  36. * *
  37. * 1 poutre encastree, 20 elements finis, *
  38. * IY different de IZ, un spectre *
  39. * d'oscillateurs en ACCE direction du *
  40. * seisme : X *
  41. * *
  42. *******************************************
  43.  
  44. TEMPS ;
  45. OPTI DIME 3 ELEM 'SEG2' ;
  46. OPTI EPSI 'LINEAIRE';
  47. *
  48. C1 = 0. 0. 0. ;
  49. C2 = 0. 0. 5. ;
  50. C3 = 0. 0. 10. ;
  51. L1 = DROITE 10 C1 C2 ;
  52. L2 = DROITE 10 C2 C3 ;
  53. LI = L1 ET L2 ;
  54.  
  55.  
  56. SI (NEG GRAPH 'N');
  57. TRAC 'QUAL' LI;
  58. FINSI;
  59.  
  60. MOD1 = MODE LI MECANIQUE ELASTIQUE POUT ;
  61.  
  62. CH_MAT = MATE MOD1 YOUNG 2.E11 NU 0.3
  63. RHO 7800. ;
  64. CH_CAR = CARA MOD1 SECT 0.25 INRY 0.006
  65. INRZ 0.004 TORS 0.01
  66. VECT ( 0. 1. 0. ) ;
  67. CH_MAT=CH_MAT et CH_CAR;
  68.  
  69. RIG1 = RIGI CH_MAT MOD1 ;
  70. ENC1 = BLOQ C1 DEPL ROTA ;
  71. RIGFI= RIG1 ET ENC1 ;
  72.  
  73. MAS1 = MASS CH_MAT MOD1 ;
  74.  
  75. * Calcul des premiers modes
  76.  
  77. L_FREQ = PROG 3.58 4.38 24.09 25.15 ;
  78. MODE_POU = VIBR PROCHE L_FREQ RIGFI
  79. MAS1 TBAS ;
  80.  
  81. * Calcul des contraintes modales
  82. MODE_POU = SIGSOL MOD1 CH_MAT MODE_POU ;
  83.  
  84. * Calcul des reactions modales
  85. MODE_POU = REAC ENC1 MODE_POU ;
  86.  
  87. ITAB2 = MODE_POU . 'MODES' ;
  88. NB_MODE = ( DIME ITAB2 ) - 2 ;
  89.  
  90. * Definition du spectre acceleration
  91. LIS_TEMP = PROG 0. PAS 1.E-2 0.50 ;
  92. LIS_ACCE = PROG
  93. 0. 0.5 1. 0.5 0. -0.5 -1. -0.5
  94. 0. 0.5 1. 0.5 0. -0.5 -1. -0.5
  95. 0. 0.5 1. 0.5 0. -0.5 -1. -0.5
  96. 0. 0.5 1. 0.5 0. -0.5 -1. -0.5
  97. 0. 0.5 1. 0.5 0. -0.35 -0.7 -0.35
  98. 0. 0.25 0.5 0.25 0. -0.15 -0.3 -0.15
  99. 0. 0.1 0. ;
  100.  
  101. LIS_CHAR = EVOL MANU LIS_TEMP LIS_ACCE ;
  102.  
  103. SI (NEG GRAPH 'N');
  104. TITR 'Chargement en Acceleration';
  105. DESS LIS_CHAR;
  106. FINSI;
  107.  
  108. LIS_FREQ = PROG 1. PAS 2. 400. ;
  109. LIS_AMOR = PROG 2. 5. 10. 15. ;
  110. LIS_AMOR = LIS_AMOR * 1.e-2 ;
  111. SEISME_X = SPO LIS_CHAR 'AMOR'
  112. LIS_AMOR 'FREQ'
  113. LIS_FREQ 'ACCE' ;
  114.  
  115. BAS_AMOR = PROG 4. 6. 7. 9. ;
  116. BAS_AMOR = BAS_AMOR * 1.e-2 ;
  117.  
  118. TAB1 = TABL ;
  119.  
  120. TAB1 . 'STRUCTURE' = MODE_POU ;
  121. TAB1 . 'AMORTISSEMENT' = BAS_AMOR ;
  122.  
  123. TAB3 = 'TABLE' 'EXCITATION' ;
  124. TAB1 . 'EXCITATION' = TAB3 ;
  125.  
  126. TAB3 . 1 = 'TABLE' ;
  127. TAB3 . 1 . 'DIRECTION' = 'X' ;
  128. TAB3 . 1 . 'SPECTRE' = SEISME_X ;
  129. TAB3 . 1 . 'AMORTISSEMENT' = LIS_AMOR ;
  130.  
  131. TAB1 . 'RECOMBINAISON_MODES' = 'SRSS';
  132. TAB1 . 'RECOMBINAISON_DIRECTIONS' =
  133. 'QUADRATIQUE' ;
  134.  
  135. TAB4 = 'TABLE' 'SORTIES' ;
  136. TAB1 . 'SORTIES' = TAB4 ;
  137. TAB4 . 'DOMAINE' = MOD1 ;
  138. TAB4 . 'DEPLACEMENTS' = VRAI ;
  139. TAB4 . 'CONTRAINTES' = VRAI ;
  140. TAB4 . 'ACCELERATIONS' = VRAI ;
  141.  
  142. TAB2 = SISSIB TAB1 ;
  143.  
  144. MESS ' Chpoint de deplacement du point
  145. C3 issu de SISSIB :' ;
  146. MESS ' ' ;
  147. CHP_DEP = TAB2 . 'X' . 'DEPLACEMENTS' ;
  148. LIST ( REDU CHP_DEP C3 ) ;
  149. MESS ' Chpoint d acceleration du point
  150. C3 issu de SISSIB :' ;
  151. MESS ' ' ;
  152. CHP_ACC = TAB2 . 'X' . 'ACCELERATIONS' ;
  153. LIST ( REDU CHP_ACC C3 ) ;
  154.  
  155. CHE_CONT = TAB2 . 'X' . 'CONTRAINTES' ;
  156. MAX_CONT = MAXI CHE_CONT ;
  157. MESS ' Valeur maximale des contraintes
  158. issue de SISSIB =' MAX_CONT ;
  159. MESS ' ' ;
  160.  
  161. *-----------------------------------------*
  162. * *
  163. * Verification de la procedure *
  164. * *
  165. *-----------------------------------------*
  166. * Verification du deplacement
  167. * Verification de l'acceleration
  168. * Verification de la contrainte maximale
  169.  
  170. * ----- calcul de S(N,X,B) -----
  171. TSEIS = TABL ;
  172. NB_AMOR = 'DIME' LIS_AMOR ;
  173. I_MODE = 0 ;
  174. REPETER BOUC1 NB_MODE ;
  175. I_MODE = I_MODE + 1 ;
  176. ITAB3 = ITAB2 . I_MODE ;
  177. F_N = ITAB3 . 'FREQUENCE' ;
  178. LOG_F_N = LOG F_N ;
  179. B_N = EXTRAIRE BAS_AMOR I_MODE ;
  180.  
  181. P_SPEC = 'PROG' ;
  182. I_AMOR = 0 ;
  183. REPETER BOUC10 NB_AMOR ;
  184. I_AMOR = I_AMOR '+' 1 ;
  185. EVOLS1 = 'EXTR' SEISME_X 'COUR'
  186. I_AMOR ;
  187. LISABS1 = 'EXTR' EVOLS1 'ABSC' ;
  188. LISORD1 = 'EXTR' EVOLS1 'ORDO' ;
  189. LOG_ABS1 = 'LOG' LISABS1 ;
  190. LOG_ORD1 = 'LOG' LISORD1 ;
  191. S1 = IPOL LOG_F_N LOG_ABS1 LOG_ORD1 ;
  192. S_1 = 'EXP' S1 ;
  193.  
  194. P_SPEC = P_SPEC ET ( 'PROG' S_1 ) ;
  195. FIN BOUC10 ;
  196.  
  197. S_N = 'IPOL' B_N LIS_AMOR P_SPEC ;
  198.  
  199. TSEIS . I_MODE = S_N ;
  200. FIN BOUC1 ;
  201.  
  202. I_MODE = 0 ;
  203. ZTRON = 'MANU' 'CHPO' LI 1 'UX' 1. ;
  204. *
  205. REPETER BOUC2 NB_MODE ;
  206. I_MODE = I_MODE + 1 ;
  207. S_I = TSEIS . I_MODE ;
  208. ITAB3 = ITAB2 . I_MODE ;
  209. F_I = ITAB3 .'FREQUENCE' ;
  210. D_I = ITAB3 .'DEFORMEE_MODALE' ;
  211. C_I = ITAB3 .'CONTRAINTE_MODALE' ;
  212. ITAB4=ITAB3 .'DEPLACEMENTS_GENERALISES';
  213. Q_I = ITAB4 . 1 ;
  214. M_I = ITAB3 . 'MASSE_GENERALISEE' ;
  215. W_I = 2.0 * PI * F_I ;
  216. QSM = Q_I / M_I ;
  217. COEF_1 = QSM / ( W_I * W_I ) ;
  218. DEPL_I = COEF_1 * S_I * D_I ;
  219. ACCE_I = QSM * S_I * D_I ;
  220. ZTRON = ZTRON - ( QSM * D_I ) ;
  221. CONT_I = COEF_1 * S_I * C_I ;
  222. 'SI' ( I_MODE 'EGA' 1 ) ;
  223. DEPL_T = DEPL_I ** 2 ;
  224. ACCE_T = ACCE_I ** 2 ;
  225. CONT_T = CONT_I ** 2 ;
  226. 'SINON' ;
  227. DEPL_T = DEPL_T + ( DEPL_I ** 2 ) ;
  228. ACCE_T = ACCE_T + ( ACCE_I ** 2 ) ;
  229. CONT_T = CONT_T + ( CONT_I ** 2 ) ;
  230. 'FINSI' ;
  231. FIN BOUC2 ;
  232.  
  233. LISORD1 = 'EXTR' SEISME_X 'ORDO' 1 ;
  234. NVAL_1 = 'DIME' LISORD1 ;
  235. GAMMA0 = 'EXTR' LISORD1 NVAL_1 ;
  236. ACCE_T = ACCE_T + ( ( GAMMA0 * GAMMA0 ) *
  237. ( ZTRON ** 2 ) );
  238.  
  239. DEPL_T = DEPL_T ** 0.5 ;
  240. ACCE_T = ACCE_T ** 0.5 ;
  241. CONT_T = CONT_T ** 0.5 ;
  242.  
  243. D_SOM_X = 'EXTR' DEPL_T C3 'UX' ;
  244. A_SOM_X = 'EXTR' ACCE_T C3 'UX' ;
  245. C_MAX = 'MAXI' CONT_T ;
  246.  
  247.  
  248. DEP = EXTR CHP_DEP C3 'UX' ;
  249. ACC = EXTR CHP_ACC C3 'UX' ;
  250.  
  251.  
  252. MESS ' deplacement du point C3 :' ;
  253. LIST ( 'REDU' DEPL_T C3 ) ;
  254. SAUTER 2 LIGNES ;
  255. MESS ' acceleration du point C3 :' ;
  256. LIST ( 'REDU' ACCE_T C3 ) ;
  257. SAUTER 2 LIGNES ;
  258. MESS ' contrainte maximale =' C_MAX ;
  259. SAUTER 2 LIGNES ;
  260.  
  261. TEMPS ;
  262.  
  263. * Code de bon fonctionnement
  264. REF_DEP = D_SOM_X ;
  265. REF_ACC = A_SOM_X ;
  266. REF_CON = C_MAX ;
  267. RES1 = 100 *
  268. (ABS ( ( DEP - REF_DEP ) / REF_DEP ));
  269. RES2 = 100 *
  270. (ABS ( ( ACC - REF_ACC ) / REF_ACC ));
  271. RES3 = 100 *
  272. (ABS ( ( MAX_CONT - REF_CON ) / REF_CON ));
  273.  
  274. SAUTER 2 LIGNES ;
  275.  
  276. MESS 'deplacement theorique :' D_SOM_X 'm';
  277. MESS 'deplacement calculee :' DEP 'm';
  278. MESS ' Soit un ecart de : ' RES1 '%';
  279. SAUTER 1 LIGNES ;
  280.  
  281. MESS 'acceleration theorique:' A_SOM_X 'm';
  282. MESS 'acceleration calculee :' ACC 'm';
  283. MESS ' Soit un ecart de : ' RES2 '%';
  284. SAUTER 1 LIGNES ;
  285.  
  286.  
  287. SI ( RES1 <EG 1. ) ;
  288. ERRE 0 ;
  289. SINON ;
  290. ERRE 5 ;
  291. FINSI ;
  292. SI ( RES2 <EG 1. ) ;
  293. ERRE 0 ;
  294. SINON ;
  295. ERRE 5 ;
  296. FINSI ;
  297. SI ( RES3 <EG 1. ) ;
  298. ERRE 0 ;
  299. SINON ;
  300. ERRE 5 ;
  301. FINSI ;
  302.  
  303. FIN ;
  304.  
  305.  
  306.  
  307.  
  308.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales