Télécharger sinebump.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : sine_bumpBM.dgibi
  2. ******************************************************************
  3. * CALCUL DE L'ECOULEMENT SUBSONIQUE STATIONNAIRE DANS UN CANAL *
  4. * AVEC SINE-SHAPED BUMP *
  5. * FORMULATION VF COMPRESSIBLE EXPLICITE/IMPLICIT *
  6. * *
  7. * H. PAILLERE/P. GALON TTMF AOUT 1997 *
  8. * *
  9. * MODIF BECCANTINI MARS 97 *
  10. * *
  11. * BECCANTINI NOVEMBRE 98 *
  12. * MODIF BECCANTINI AUGUST 2021 *
  13. * *
  14. * Compressible AUSM+ scheme is used for computation *
  15. ******************************************************************
  16.  
  17. GRAPH = VRAI ;
  18. COMPLET = VRAI ;
  19.  
  20. GRAPH = FAUX ;
  21. COMPLET = FAUX ;
  22.  
  23. 'SI' complet ;
  24. RAF = 8 ;
  25. NITER = 20 ;
  26. 'SINON' ;
  27. RAF = 5 ;
  28. NITER = 20 ;
  29. 'FINSI' ;
  30.  
  31.  
  32. TYEL = 'QUA4' ;
  33.  
  34. 'OPTION' 'DIME' 2 'ELEM' TYEL 'ISOV' 'SULI'
  35. 'ECHO' 1 'TRAC' 'X';
  36.  
  37. *
  38. *** C.L. et initiales
  39. *
  40.  
  41. RO_INF = 1.4D0 ;
  42. P_INF = 1.0D0 ;
  43. U_INF = 0.50 ;
  44. GAMSCAL = 1.4D0;
  45.  
  46. *
  47. *
  48. ************************************************************************
  49. ************************************************************************
  50. ***************** PARTIE PROCEDURES ************************************
  51. ************************************************************************
  52. ************************************************************************
  53. ************************************************************************
  54. *
  55. *
  56. * Put it in utilproc
  57. * Procedures will finish in FIN PARTIE PROCEDURES
  58. *
  59.  
  60. ***** $$$$ EXEXCH
  61. *
  62. *****************************************************
  63. *****************************************************
  64. ** PROCEDURE EXEX POUR FORMULATION VF COMPRESSIBLE **
  65. *****************************************************
  66. *****************************************************
  67. *
  68. * We check wether the table RV is complete
  69. *
  70. *
  71. 'DEBPROC' EXEXCH ;
  72. 'ARGUMENT' RV*TABLE ;
  73. 'MESSAGE' ;
  74. 'MESSAGE' 'PROCEDURE EXEXCH' ;
  75. *
  76. **** Initialisation d'un CHPOINT 'ET' d'une MATRIK vide
  77. *
  78. CHPVID MATVID = 'KOPS' 'MATRIK' ;
  79. RESPRO CHPVID MATVID ;
  80. *
  81. **** Les inconnues
  82. *
  83. 'SI' ('NON' ('EXISTE' RV 'UN')) ;
  84. 'MESSAGE' ;
  85. 'MESSAGE' 'UN = ???' ;
  86. 'ERREUR' 21 ;
  87. 'FINSI' ;
  88. *
  89. **** We check the compatibility between the variables and their names
  90. *
  91. 'SI' ('NON' ('EXISTE' RV 'LISTCONS')) ;
  92. 'MESSAGE' ;
  93. 'MESSAGE' 'LISTCONS = ???' ;
  94. 'ERREUR' 21 ;
  95. 'FINSI' ;
  96. 'MESSAGE' ;
  97. 'MESSAGE' 'Conservative variables check' ;
  98. UNCELL = 'EXCO' (RV . 'LISTCONS') (RV . 'UN') (RV . 'LISTCONS') ;
  99. ERRO = 'MAXIMUM' (UNCELL '-' (RV . 'UN')) 'ABS' ;
  100. ERRO = ERRO '/' (('MAXIMUM' UNCELL 'ABS') '+' 1.0D-15) ;
  101. 'SI' (ERRO > 1.0D-6) ;
  102. 'MESSAGE' ;
  103. 'MESSAGE' 'UN = ???' ;
  104. 'MESSAGE' 'LISTCONS = ???' ;
  105. 'ERREUR' 21 ;
  106. 'SINON' ;
  107. 'MESSAGE' 'OK' ;
  108. 'FINSI' ;
  109. *
  110. **** On which variables the error has to be computed?
  111. *
  112. 'SI' ('NON' ('EXISTE' RV 'ERROMOTS')) ;
  113. 'MESSAGE' ;
  114. 'MESSAGE' 'ERROMOTS = ???' ;
  115. 'ERREUR' 21 ;
  116. 'FINSI' ;
  117. *
  118. **** Definition of the table containing some results
  119. *
  120. 'SI' ('NON' ('EXISTE' RV 'RESULTATS')) ;
  121. RV . 'RESULTATS' = 'TABLE' ;
  122. 'FINSI' ;
  123. *
  124. **** Existence d'une procédure pour imposer le conditions aux limites
  125. * à chaque iteration (interne ou externe)
  126. *
  127. 'SI' ('NON' ('EXISTE' RV 'CLIM')) ;
  128. 'MESSAGE' ;
  129. 'MESSAGE' 'CLIM = ???' ;
  130. 'ERREUR' 21 ;
  131. 'FINSI' ;
  132. * Par securité, on les impose tout de suite
  133. 'SI' (RV . 'CLIM') ;
  134. 'SI' ('NON' ('EXISTE' RV 'MAIFAN')) ;
  135. 'MESSAGE' ;
  136. 'MESSAGE' 'MAIFAN = ???' ;
  137. 'ERREUR' 21 ;
  138. 'FINSI' ;
  139. RV . 'UN' = PROLIM RV ;
  140. * DUCLIM à imposer dans l'inversion matricielle:
  141. * pas d'increment sur les cellules fantomes
  142. DUCLIM = 0.0 '*' ('REDU' (RV . 'UN') (RV . 'MAIFAN')) ;
  143. 'SINON' ;
  144. DUCLIM = 'COPIER' CHPVID ;
  145. 'FINSI' ;
  146.  
  147. RESPRO DUCLIM ;
  148. *
  149. *
  150. ****** Mise a jour de la matrice à inverser pendant les iterations internes?
  151. *
  152. * RV . 'MATUPDAT'
  153. * RV . 'MUPINT'
  154. *
  155. 'SI' ('NON' ('EXISTE' RV 'MATUPDAT')) ;
  156. 'MESSAGE' ;
  157. 'MESSAGE' 'MATUPDAT = ???' ;
  158. 'ERREUR' 21 ;
  159. 'FINSI' ;
  160. 'SI' (RV . 'MATUPDAT') ;
  161. 'MESSAGE' ;
  162. 'MESSAGE'
  163. 'We always update the matrix to inverse' ;
  164. LOGMAOLD = FAUX ;
  165. 'SINON' ;
  166. 'MESSAGE' ;
  167. 'MESSAGE'
  168. 'We don t always update the matrix to inverse' ;
  169. LOGMAOLD = VRAI ;
  170. 'FINSI' ;
  171. *
  172. RESPRO LOGMAOLD ;
  173. *
  174. **** Iterations externes et/ou temps final
  175. * La table 'PASDETPS'
  176. *
  177. 'SI' ('NON'
  178. (('EXISTE' RV 'NITMAEX') 'OU' ('EXISTE' RV 'TFINAL'))) ;
  179. 'MESSAGE' ;
  180. 'MESSAGE' 'NITMAEX = ???' ;
  181. 'MESSAGE' 'ou' ;
  182. 'MESSAGE' 'TFINAL = ???' ;
  183. 'ERREUR' 21 ;
  184. 'FINSI' ;
  185. *
  186. **** Gas model
  187. *
  188. 'SI' ('NON' ('EXISTE' RV 'PGAZ')) ;
  189. 'MESSAGE' ;
  190. 'MESSAGE' 'PGAZ = ???' ;
  191. 'ERREUR' 21 ;
  192. 'FINSI' ;
  193. *
  194. **** BAS MACH
  195. *
  196. 'SI' ('NON' ('EXISTE' RV 'BASMACH')) ;
  197. 'MESSAGE' ;
  198. 'MESSAGE' 'BASMACH = ???' ;
  199. 'ERREUR' 21 ;
  200. 'SINON' ;
  201. 'SI' (RV . 'BASMACH') ;
  202. 'SI' (('NON' ('EXISTE' RV 'CO1')) 'OU'
  203. ('NON' ('EXISTE' RV 'CO2'))) ;
  204. 'MESSAGE' ;
  205. 'MESSAGE' 'CO1 = ???' ;
  206. 'MESSAGE' 'CO2 = ???' ;
  207. 'ERREUR' 21 ;
  208. 'FINSI' ;
  209. 'FINSI' ;
  210. 'FINSI' ;
  211. *
  212. *** La table PASDETPS
  213. *
  214. 'SI' ('NON' ('EXISTE' RV 'PASDETPS')) ;
  215. 'MESSAGE' ;
  216. 'MESSAGE' 'We create the table PASDETPS' ;
  217. RV . 'PASDETPS' = 'TABLE' ;
  218. 'SINON' ;
  219. 'MESSAGE' ;
  220. 'MESSAGE' 'We use the table PASDETPS that already exists' ;
  221. 'FINSI' ;
  222. KTPS = RV . 'PASDETPS' ;
  223. *
  224. RESPRO KTPS ;
  225. * Initialisation éventuelle de la table
  226. 'SI' (('NON' ('EXISTE' KTPS 'NUPASDT')) 'OU'
  227. ('NON' ('EXISTE' KTPS 'TPS')) 'OU'
  228. ('NON' ('EXISTE' KTPS 'TPSM'))) ;
  229. 'MESSAGE' ;
  230. 'MESSAGE' 'Table PASDETPS' ;
  231. 'MESSAGE' 'NUPASDT = 0' ;
  232. 'MESSAGE' 'TPS = 0.0' ;
  233. 'MESSAGE' ;
  234. KTPS . 'NUPASDT' = 0 ;
  235. KTPS . 'TPSM' = 0.0D0 ;
  236. KTPS . 'TPS' = 0.0D0 ;
  237. 'FINSI' ;
  238. *
  239. * KTPS contient
  240. *
  241. * KTPS . 'NUPASDT' = numero de pas de TPS actuel dans les itérations
  242. * internes
  243. *
  244. * KTPS . 'TPSM' = le TPS aprés (KTPS . 'NUPASDT' '-' 2) itérations
  245. * KTPS . 'TPS' = le TPS aprés (KTPS . 'NUPASDT' '-' 1) itérations
  246. * KTPS . 'TPSP' = le TPS aprés (KTPS . 'NUPASDT') itérations, i.e. à
  247. * la fin de l'itération actuelle
  248. *
  249. *
  250. *
  251. * N.B. 'XINIT' is used in the iterative methods
  252. * We have decided to keep it 0
  253. RV . 'MATINV' . 'XINIT' = 0.0 '*' (RV . 'UN') ;
  254. 'FINPROC' ;
  255.  
  256.  
  257. **** $$$$ EXEXIM
  258. *
  259. *****************************************************
  260. *****************************************************
  261. ** PROCEDURE EXEX POUR FORMULATION VF COMPRESSIBLE **
  262. *****************************************************
  263. *****************************************************
  264. *
  265. * RV . 'UN' = les variables conservatives
  266. *
  267. * RV . 'ANOM' = LOGIQUE (anomalie detectée ?)
  268. *
  269. * RV . 'DTIMP' = pas de tmps imposé (facultatif)
  270. *
  271. * RV . 'LISTCONS'= noms des variables conservatives
  272. *
  273. * RV . 'ERROMOTS'= noms des variables sur lesquelles on calcule Linf
  274. *
  275. * RV . 'CLIM' = logique qui me dit si existe une procédure pour le
  276. * calcul de conditions limites (procédure PROLIM)
  277. *
  278. * RV . 'MAIFAN' = (a définir si RV . 'CLIM')
  279. * les cellules fantômes
  280. *
  281. * RV . 'TFINAL' = le temps final
  282. *
  283. * RV . 'NITMAEX' = le nombre d'itération externes
  284. *
  285. * N.B. Si RV . 'TFINAL' et RV . 'NITMAEX' sont les deux spécifiés, on
  286. * s'arrête quand un des deux critères est satisfait
  287. *
  288. * RV . 'MATUPDAT' = si VRAI, on ne met pas toujours à jour la matrice
  289. * à inverser
  290. *
  291. * RV . 'MUPEXT' = si (RV . 'MATUPDAT'), indice de mise à jours de la
  292. * matrice jacobienne pendant les itérations externes
  293. *
  294. * RV . 'MUPINT' = si (RV . 'MATUPDAT'), indice de mise à jours de la
  295. * matrice jacobienne pendant les itérations internes
  296. *
  297. * RV . 'MUPINI' = si (RV . 'MATUPDAT'), nombre initial de pas de temps
  298. * pendant lesquels on met à jour la matrice à chaque
  299. * itération externe
  300. *
  301. * RV . 'MUPLIN' = si (RV . 'MATUPDAT') et on utilise un solveur
  302. * itératif pour la résolution du système linéaire,
  303. * si le nombre d'itérations linéaires est > que
  304. * RV . 'MUPLIN', alors on met à jour le
  305. * preconditionneur
  306. *
  307. * RV . 'MATACC' = si (RV . 'MATUPDAT'), logique qui nous dit si on
  308. * veut utiliser la méthode de Broyden.
  309. *
  310. * RV . 'LISTOPER' = liste des opérateurs (ou des procédures) qui
  311. * interviennent dans le calcul (chaque opérateur a une
  312. * table associée), qui s'appelle &NOMPER ou
  313. * & = position de l'opérateur dedans cette liste
  314. * NOMPER = noms de l'opérateur ou de la procédure
  315. *
  316. * RV . 'NITMAIN' = (à définir dans le cas d'un calcul implicite)
  317. * le nombre max d'itération internes
  318. * RV . 'NITMIIN' = (à définir dans le cas d'un calcul implicite)
  319. * le nombre min d'itération internes
  320. *
  321. * RV . 'EPSINT' = (à définir dans le cas d'un calcul implicite)
  322. * l'erreur pour le critère de convergence sur les
  323. * itérations internes
  324. *
  325. * RV . 'MATHINV' = (a définir sans la cas d'un calcul implicite)
  326. * table de SOUSTYPE 'TYPINV' pour l'inversion de
  327. * MATRIK (pour l'opérateur 'KRES')
  328. *
  329. * RV . 'RESULTATS' = table qui contient des resultats
  330. * 'NITERLIN' = nombre de iterations lineaires
  331. * dans le solveur iteratif
  332. * 'ERROLIN' = residu de l'erreur du solveur
  333. * iteratif
  334. * 'ITERIN' = iteration interne (0, 1, ...)
  335. *
  336. *************************************************************************
  337. * MODIF
  338. *************************************************************************
  339. * Message en anglais!
  340. *
  341. 'DEBPROC' EXEXIM ;
  342. 'ARGUMENT' RV*TABLE ;
  343. 'MESSAGE' ;
  344. 'MESSAGE' 'PROCEDURE EXEXIM' ;
  345. *
  346. **** Initialisation and controls into exexch
  347. *
  348.  
  349. CHPVID MATVID DUCLIM LOGMAOLD KTPS = EXEXCH RV ;
  350.  
  351. *************************************************************************
  352. *************************************************************************
  353. *************************************************************************
  354. *************************************************************************
  355. ************** ITÉRATIONS EXTERNES ************************************
  356. *************************************************************************
  357. *************************************************************************
  358. *************************************************************************
  359. *************************************************************************
  360. LOGEXP = VRAI ;
  361. * LOGEXP = variable logique qui me dit si on est en explicite ;
  362. LOGQIE = FAUX ;
  363. *
  364. **** Boucle qui s'arrête quand LOGQIE = VRAI ; i.e.
  365. *
  366. * (KTPS . NUPASDT) = (RV . 'NITMAEX')
  367. * ou
  368. * (KTPS . 'TPS') = (RV . 'TFINAL');
  369. *
  370. *
  371. 'SI' ('EXISTE' RV 'DTIMP') ;
  372. ALPDT = RV . 'DTIMP' ;
  373. 'SINON' ;
  374. ALPDT = 0.0 ;
  375. 'FINSI' ;
  376. NITEX = 0 ;
  377. 'REPETER' BLEX -1 ;
  378. NITEX = NITEX '+' 1 ;
  379. *
  380. ****** Iteration interne
  381. *
  382. RV . 'RESULTATS' . 'ITERIN' = 0 ;
  383. *
  384. ****** Mise à jour de la matrice à inverser
  385. *
  386. 'SI' ((NITEX 'EGA' 1) 'OU' (RV . 'ANOM')) ;
  387. * A la premiere iteration externe on doit calculer la matrice
  388. LOGUPEX = VRAI ;
  389. 'SINON' ;
  390. 'SI' LOGMAOLD ;
  391. MUPEXT = RV . 'MUPEXT' ;
  392. * On met a jour la matrice toutes les MUPEXT iterations externes
  393. LOGUPEX = ((NITEX '/' MUPEXT) '*' MUPEXT) 'EGA' NITEX ;
  394. 'FINSI' ;
  395. 'FINSI' ;
  396. *
  397. ****** Trop d'iterations externes?
  398. *
  399. KTPS . 'NUPASDT' = KTPS . 'NUPASDT' '+' 1 ;
  400. 'SI' ('EXISTE' RV 'NITMAEX') ;
  401. 'SI' ( (KTPS . 'NUPASDT') '>EG' (RV . 'NITMAEX')) ;
  402. LOGQIE = VRAI ;
  403. 'FINSI' ;
  404. 'FINSI' ;
  405. *
  406. ****** Impression
  407. *
  408. 'MESSAGE' ;
  409. 'MESSAGE' ('CHAINE' 'PASDETPS = ' (KTPS . 'NUPASDT')
  410. ' TPS = ' (KTPS . 'TPS') ' DTM1 = ' ALPDT) ;
  411. *
  412. *** ALGORITHM A RESOUDRE
  413. *
  414. * F(U^{n+1}) = 0
  415. *
  416. * if (RV . INST) then
  417. *
  418. * F(U^{n+1}) = -1. * (U^{n+1} - U^{n}) '/' (\delta t)
  419. * '+' \sum_k Res_k(U^{n+1}) '+' \sum_kexpl Res_kexpl(U^{n})
  420. *
  421. * else
  422. *
  423. * F(U^{n+1}) = -\sum_k Res_k(U^{n+1})
  424. *
  425. * endif
  426. *
  427. *
  428. * Avec une methode de type Newton-Raphson
  429. *
  430. * a) U^{n+1,0} = U^{n}
  431. *
  432. * b) for l=0,1,2,...
  433. *
  434. * MAT(U^{n+1,l}) \delta U^{n+1,l} = -F(U^{n+1,l})
  435. *
  436. * U^{n+1,l+1} = U^{n+1,l} '+' \delta U^{n+1,l}
  437. *
  438. * if || \delta U^{n+1,l} ||_{\inf} < \epsilon goto c)
  439. *
  440. * c)
  441. *
  442. * U^{n+1} = U^{n+1,l+1}
  443. *
  444. * endif
  445. *
  446. *** LES VARIABLES
  447. *
  448. * RESIMP = \sum_k Res_k(U^{n+1,l})
  449. * RESEXP = \sum_kexpl Res_kexpl(U^{n})
  450. * MATASS = - \sum_k JACR_k(U^{n+1,l})
  451. * UNM = conserved variables at t^{n}
  452. * UNM = conserved variables at t^{n-1}
  453. * LREEDT = LISTREEL de (\delta t)_k t.q.
  454. * \delta t = min (\delta t)_k
  455. *
  456. RESIMP = 'COPIER' CHPVID ;
  457. RESEXP = 'COPIER' CHPVID ;
  458. 'SI' ('EXISTE' RV 'UNM2') ;
  459. RV . 'UNM3' = 'COPIER' (RV . 'UNM2') ;
  460. 'FINSI' ;
  461. 'SI' ('EXISTE' RV 'UNM') ;
  462. RV . 'UNM2' = 'COPIER' (RV . 'UNM') ;
  463. 'FINSI' ;
  464. RV . 'UNM' = 'COPIER' (RV . 'UN') ;
  465. MATASS = 'KOPS' 'MULT' 0.0 MATVID ;
  466. LREEDT = 'PROG' ;
  467. *
  468. ***********************************************
  469. ********* Boucle sur les operateurs ***********
  470. ***********************************************
  471. *** On calcule: LREEDT
  472. * RESIMP
  473. * RESEXP
  474. * (MATASS)
  475. *
  476. 'REPETER' BLOP ('DIME' (RV . 'LISTOPER')) ;
  477. NOMPER = 'EXTRAIRE' &BLOP (RV . 'LISTOPER') ;
  478. NOTABLE = 'MOT' ('TEXTE' ('CHAINE' &BLOP NOMPER) ) ;
  479. 'SI' (RV . NOTABLE . 'IMPL') ;
  480. 'SI' ('EGA' NITEX 1) ;
  481. 'MESSAGE' ;
  482. 'MESSAGE' ('CHAINE' ('MOT' NOMPER) ': implicit') ;
  483. 'FINSI' ;
  484. * JACO = objet de type MATRIK (éventuellement vide)
  485. * RESIDU = " RESIDU "
  486. * ALPHADT = " LISTREEL "
  487. LOGEXP = FAUX ;
  488. JACO RESIDU ALPHADT = ('TEXTE' NOMPER) (RV . NOTABLE) ;
  489. 'SI' (RV . NOTABLE . 'ANOM') ;
  490. RV . 'ANOM' = VRAI ;
  491. RV . NOTABLE . 'ANOM' = FAUX ;
  492. 'QUITTER' BLOP ;
  493. 'SINON' ;
  494. MATASS = MATASS 'ET' ('KOPS' 'MULT' -1.0D0 JACO ) ;
  495. RESIMP = RESIMP 'ET' RESIDU ;
  496. 'FINSI' ;
  497. 'SINON' ;
  498. 'SI' ('EGA' NITEX 1) ;
  499. 'MESSAGE' ;
  500. 'MESSAGE' ('CHAINE' ('MOT' NOMPER) ': explicit') ;
  501. 'FINSI' ;
  502. RESIDU ALPHADT = ('TEXTE' NOMPER) (RV . NOTABLE) ;
  503. 'SI' (RV . NOTABLE . 'ANOM') ;
  504. RV . 'ANOM' = VRAI ;
  505. 'QUITTER' BLOP ;
  506. 'SINON' ;
  507. RESEXP = RESEXP 'ET' RESIDU ;
  508. 'FINSI' ;
  509. 'FINSI' ;
  510. LREEDT = LREEDT 'ET' ALPHADT ;
  511. 'FIN' BLOP ;
  512. ***********************************************
  513. ***** Fin de la boucle sur les operateurs ****
  514. ***********************************************
  515. *
  516. ******* Anomalie detectée (CTRL+S 9999)
  517. * On arrete ici
  518. *
  519. 'SI' ('NON' (RV . 'ANOM')) ;
  520. *
  521. ******* On controlle la compatibilité E/S (si NITEX = 1)
  522. *
  523. 'SI' ('EGA' NITEX 1) ;
  524. *
  525. **** Dans le cas implicite, on verifie l'existence
  526. * des parametres pour les itérations internes
  527. *
  528. 'SI' ('NON' LOGEXP) ;
  529. 'SI' ('NON' (('EXISTE' RV 'NITMAIN') 'ET'
  530. ('EXISTE' RV 'EPSINT') 'ET' ('EXISTE' RV 'NITMIIN')));
  531. 'MESSAGE' ;
  532. 'MESSAGE' 'NITMAIN = ??? ' ;
  533. 'MESSAGE' 'NITMIIN = ??? ' ;
  534. 'MESSAGE' 'EPSINT = ??? ' ;
  535. 'ERREUR' 21 ;
  536. 'FINSI' ;
  537. 'FINSI' ;
  538. 'FINSI' ;
  539. *
  540. ******* Fin contrôle compatibilité E/S
  541. *
  542. *** Mise a jour de la table RV . 'PASDETPS' au debu du calcul
  543. *
  544. 'SI' ('EXISTE' RV 'DTIMP') ;
  545. ALPDT = RV . 'DTIMP' ;
  546. 'SINON' ;
  547. ALPDT = 'MINIMUM' LREEDT ;
  548. 'FINSI' ;
  549. ALPDT1 = (RV . 'TFINAL') '-' (KTPS . 'TPS') ;
  550. 'SI' ((ALPDT 'EGA' ALPDT1 (ALPDT '*' 1.0D-6)) 'OU'
  551. (ALPDT > ALPDT1)) ;
  552. KTPS . 'TPSP' = (RV . 'TFINAL') ;
  553. ALPDT = ALPDT1 ;
  554. LOGQIE = VRAI ;
  555. * Dans ce cas, il faut metre a jour la matrice à inverser
  556. * car elle peut etre tres differnte pas rapport à celle
  557. * calculé precedentment
  558. LOGMAOLD = FAUX ;
  559. 'SINO' ;
  560. KTPS . 'TPSP' = (KTPS . 'TPS') '+' ALPDT ;
  561. 'FINSI' ;
  562. *
  563. 'SI' LOGEXP ;
  564. *************************************************************************
  565. ********** Cas explicite pour les variables conservatives ***************
  566. *************************************************************************
  567. 'SI' ((NITEX 'EGA' 1) 'OU' ((RV . 'ORDTPS') 'EGA' 1)) ;
  568. RV . 'UN' = (RV . 'UNM') '+' (ALPDT '*' RESEXP) ;
  569. 'SINON' ;
  570. RV . 'UN' = ((4. '/' 3.) '*' (RV . 'UNM')) '+'
  571. ((-1. '/' 3.) '*' (RV . 'UNM2')) '+'
  572. (((2. * ALPDT) '/' 3.) '*' RESEXP) ;
  573. 'FINSI' ;
  574. 'SI' (RV . 'CLIM') ;
  575. * 'MESSAGE' 'PROLIM after an explicit iteration' ;
  576. RV . 'UN' = PROLIM RV ;
  577. 'FINSI' ;
  578. 'SINON' ;
  579. *************************************************************************
  580. ********** Cas implicite pour les variables conservatives ***************
  581. *************************************************************************
  582. *
  583. ****** Initialisation of RV . 'RESULTATS' . 'ERRONLIN' ;
  584. *
  585. RV . 'RESULTATS' . 'ERRONLIN' = 'PROG' ;
  586. *
  587. *************************************************************************
  588. ************** Les iterations internes **********************************
  589. *************************************************************************
  590. *
  591. 'REPETER' BLINT (RV . 'NITMAIN') ;
  592. *
  593. RV . 'RESULTATS' . 'ITERIN' = &BLINT ;
  594. *
  595. ****** Implicite
  596. *
  597. 'SI' ((NITEX 'EGA' 1) 'OU' ((RV . 'ORDTPS') 'EGA' 1)) ;
  598. *
  599. *************** Implicit Euler
  600. *
  601. MAT1 = 'KOPS' 'MULT' (1. '/' ALPDT)
  602. (RV . 'MATIDE') ;
  603. SMB = ((RV . 'UNM') '-' (RV . 'UN')) '/' ALPDT ;
  604. 'SINON' ;
  605. *
  606. **************** BDF2
  607. *
  608. MAT1 = 'KOPS' 'MULT' (1.5 '/' ALPDT)
  609. (RV . 'MATIDE') ;
  610. SMB = ((4. '*' (RV . 'UNM'))
  611. '+' (-3. '*' (RV . 'UN'))
  612. '+' (-1. '*' (RV . 'UNM2'))) '/' (2. '*' ALPDT) ;
  613. 'FINSI' ;
  614. *
  615. ********* Bas Mach
  616. *
  617. 'SI' (RV . 'BASMACH') ;
  618. MAT1 = MAT1 'ET' (RV . 'GAMSDTAU') ;
  619. 'FINSI' ;
  620. *
  621. MATTOT = MAT1 'ET' MATASS ;
  622. RESTOT = SMB 'ET' RESIMP 'ET' RESEXP ;
  623. *
  624. ********* LOGOLD = VRAI
  625. * Si methode directe, on utilise la meme parametrisation LU
  626. * Si methode iterative, on utilise le meme preconditionneur
  627. *
  628. LOGOLD = VRAI ;
  629. 'SI' LOGMAOLD ;
  630. 'SI' (LOGUPEX 'ET' (&BLINT 'EGA' 1)) ;
  631. * LOGUPEX = VRAI -> At this external iteration we can
  632. * update the matrix to inverse
  633. 'OUBLIER' MATOLD ;
  634. 'MENAGE' ;
  635. MATOLD = MATTOT ;
  636. LOGOLD = FAUX ;
  637. 'MESSAGE' ;
  638. 'MESSAGE' 'We update the matrix' ;
  639. 'SINON' ;
  640. * We don't care about LOGUPEX if (&BLINT > 1)
  641. * In this case we update the matrix each MUPINT-th
  642. * iteration
  643. 'SI'
  644. (((&BLINT '/' (RV . 'MUPINT')) '*' (RV . 'MUPINT'))
  645. 'EGA' &BLINT) ;
  646. 'OUBLIER' MATOLD ;
  647. 'MENAGE' ;
  648. MATOLD = MATTOT ;
  649. LOGOLD = FAUX ;
  650. 'MESSAGE' ;
  651. 'MESSAGE' 'We update the matrix' ;
  652. 'FINSI' ;
  653. 'FINSI' ;
  654. 'SINON' ;
  655. *
  656. * We always update the matrix to inverse
  657. *
  658. 'OUBLIER' MATOLD ;
  659. 'MENAGE' ;
  660. LOGOLD = FAUX ;
  661. MATOLD = MATTOT ;
  662. 'FINSI' ;
  663. *
  664. 'SI' ('EXISTE' (RV . 'MATINV') 'CONVINV') ;
  665. 'SI' LOGOLD ;
  666. NLIT = ('DIME' (RV . 'MATINV' . 'CONVINV')) ;
  667. 'SI' (NLIT > RV . 'MUPLIN') ;
  668. 'MESSAGE' ;
  669. 'MESSAGE' 'We update the matrix' ;
  670. 'OUBLIER' MATOLD ;
  671. 'MENAGE' ;
  672. MATOLD = MATTOT ;
  673. 'FINSI' ;
  674. 'FINSI' ;
  675. 'FINSI' ;
  676. RV . 'MATINV' . 'MATASS' = MATOLD ;
  677. RV . 'MATINV' . 'MAPREC' = MATOLD ;
  678. *
  679. 'SI' LOGOLD ;
  680. *
  681. * LOGOLD vrai si on utilise la meme
  682. * parametrisation LU ou le meme preconditionneur
  683. * pour calculer la solution du systeme lineaire
  684. *
  685. 'SI' ((RV . 'MATINV' . 'TYPINV') 'EGA' 1) ;
  686. * Meme parametrisation LU que MATOLD
  687. DELTAU = 'KRES' MATOLD
  688. 'TYPI' (RV . 'MATINV')
  689. 'CLIM' DUCLIM
  690. 'SMBR' RESTOT
  691. 'IMPR' 0 ;
  692. 'SINON' ;
  693. * Meme preconditionneur que MATOLD
  694. DELTAU = 'KRES' MATTOT
  695. 'TYPI' (RV . 'MATINV')
  696. 'CLIM' DUCLIM
  697. 'SMBR' RESTOT
  698. 'IMPR' 0 ;
  699. 'FINSI' ;
  700. 'SINON' ;
  701. DELTAU = 'KRES' MATOLD
  702. 'TYPI' (RV . 'MATINV')
  703. 'CLIM' DUCLIM
  704. 'SMBR' RESTOT
  705. 'IMPR' 0 ;
  706. 'FINSI' ;
  707.  
  708. RV . 'UN' = (RV . 'UN') '+' DELTAU ;
  709.  
  710. 'SI' (RV . 'CLIM') ;
  711. UNCELL = RV . 'UN' ;
  712. * 'PROLIM after the matrix inversion' ;
  713. RV . 'UN' = PROLIM RV ;
  714. * We redefine DELTAU to compute the error
  715. DELTAU = ((RV . 'UN') '-' UNCELL) '+' DELTAU ;
  716. 'FINSI' ;
  717. *
  718. ********* Boucle sur les operateurs implicites pour calculer RESIMP
  719. * et MATASS de RV . 'UN'
  720.  
  721. RESIMP = 'COPIER' CHPVID ;
  722. MATASS = 'KOPS' 'MULT' 0.0 MATVID ;
  723. 'REPETER' BLOP ('DIME' (RV . 'LISTOPER')) ;
  724. NOMPER = 'EXTRAIRE' &BLOP (RV . 'LISTOPER') ;
  725. NOTABLE = 'MOT' ('TEXTE' ('CHAINE' &BLOP NOMPER) ) ;
  726. 'SI' (RV . NOTABLE . 'IMPL') ;
  727. JACO RESIDU ALPHADT =
  728. ('TEXTE' NOMPER) (RV . NOTABLE) ;
  729. 'SI' (RV . NOTABLE . 'ANOM') ;
  730. RV . 'ANOM' = VRAI ;
  731. 'QUITTER' BLINT ;
  732. 'SINON' ;
  733. MATASS = MATASS 'ET' ('KOPS' 'MULT'
  734. -1.0D0 JACO ) ;
  735. RESIMP = RESIMP 'ET' RESIDU ;
  736. 'FINSI' ;
  737. 'FINSI' ;
  738. 'FIN' BLOP ;
  739. *
  740. ********* Test de convergence
  741. *
  742. ERRO = 'MAXIMUM' DELTAU 'ABS' 'AVEC' (RV . 'ERROMOTS') ;
  743. 'SI' (&blint 'EGA' 1) ;
  744. ERRO0 = ERRO ;
  745. 'FINSI' ;
  746. RV . 'RESULTATS' . 'ERRONLIN' = (RV . 'RESULTATS'
  747. . 'ERRONLIN') 'ET' ('PROG' ERRO) ;
  748. *
  749. ********* Impression
  750. *
  751. 'MESSAGE' ;
  752. 'MESSAGE' ('CHAINE' 'PASDETPS = ' (KTPS . 'NUPASDT')
  753. ' TPS = ' (KTPS . 'TPS') ' DT = ' ALPDT) ;
  754. 'MESSAGE' ('CHAINE' 'ITERIN = ' &BLINT) ;
  755. 'REPETER' BLERRO ('DIME' (RV . 'LISTCONS')) ;
  756. MOTERR = 'EXTRAIRE' (RV . 'LISTCONS') &BLERRO ;
  757. ERRBLE = 'MAXIMUM' DELTAU 'ABS' 'AVEC'
  758. ('MOTS' MOTERR) ;
  759. 'MESSAGE' (CHAIN 'ERREUR on ' MOTERR ' = ' ERRBLE) ;
  760. 'FIN' BLERRO ;
  761. 'SI' (('EXISTE' (RV . 'MATINV') 'CONVINV')) ;
  762. NLIT = ('DIME' (RV . 'MATINV' . 'CONVINV')) ;
  763. 'MESSAGE' ('CHAINE' 'Linear iterations = ' NLIT );
  764. RV . 'RESULTATS' . 'NITERLIN' = NLIT ;
  765. REIT = 'EXTR' (RV . 'MATINV' . 'CONVINV') NLIT ;
  766. 'MESSAGE' ('CHAINE' 'Linear residuum = ' REIT );
  767. RV . 'RESULTATS' . 'ERROLIN' = REIT ;
  768. 'FINSI' ;
  769. *
  770. ************ Criteres de sortie
  771. *
  772. 'SI' (&BLINT > (RV . 'NITMIIN')) ;
  773. 'SI' ('EXISTE' RV 'EPSREL') ;
  774. 'SI' (ERRO < ((RV . 'EPSREL') '*' ERRO0)) ;
  775. 'QUITTER' BLINT ;
  776. 'FINSI' ;
  777. 'FINSI' ;
  778. 'SI' (ERRO '<' (RV . 'EPSINT')) ;
  779. 'QUITTER' BLINT ;
  780. 'FINSI' ;
  781. 'FINSI' ;
  782. * 'SI' (ERRO > (1.0D3 '*' ERRO0)) ;
  783. * RV . 'ANOM' = VRAI ;
  784. * 'QUITTER' BLINT ;
  785. * 'FINSI' ;
  786. * 'SI' (&BLINT '>EG' (RV . 'NITMAIN')) ;
  787. * RV . 'ANOM' = VRAI ;
  788. * 'QUITTER' BLINT ;
  789. * 'FINSI' ;
  790. 'FIN' BLINT ;
  791. *************************************************************************
  792. **************** Fin boucle iterations internes *************************
  793. *************************************************************************
  794. ***********************************************
  795. ************* Fin cas implicite ***************
  796. ***********************************************
  797. 'FINSI' ;
  798. * ('SI' (RV . 'ANOM') ;)
  799. 'FINSI' ;
  800. *
  801. 'SI' (RV . 'ANOM') ;
  802. LOGQIE = FAUX ;
  803. NITEX = NITEX '-' 1 ;
  804. KTPS . 'NUPASDT' = KTPS . 'NUPASDT' '-' 1 ;
  805. KTPS . 'TPSP' = KTPS . 'TPS' ;
  806. RV . 'UN' = 'COPIER' RV . 'UNM' ;
  807. 'SI' ('EXISTE' RV 'UNM2') ;
  808. RV . 'UNM' = 'COPIER' (RV . 'UNM2') ;
  809. 'FINSI' ;
  810. 'SINON' ;
  811. *
  812. *** Mise a jour de la table RV . 'PASDETPS' à la fin du calcul
  813. *
  814. KTPS . 'TPSM' = KTPS . 'TPS' ;
  815. KTPS . 'TPS' = KTPS . 'TPSP' ;
  816. 'FINSI' ;
  817. *
  818. **** Dernier commande de BLEX
  819. *
  820. 'SI' LOGQIE ;
  821. 'QUITTER' BLEX ;
  822. 'FINSI' ;
  823.  
  824. 'FIN' BLEX ;
  825.  
  826. 'FINPROC' ;
  827.  
  828. *****************************************************
  829. *****************************************************
  830. ** FIN PROCEDURE EXEX **
  831. *****************************************************
  832. *****************************************************
  833.  
  834. *****$$$$ PKON
  835.  
  836. *****************************************************
  837. *****************************************************
  838. ** PROCÉDURE PKON **
  839. *****************************************************
  840. *****************************************************
  841. * Il faut définir:
  842. *
  843. * *KKONV . 'EQEX' = table générale, qui contient toutes les
  844. * informations sur le calcul qu'on va faire.
  845. * Dans ce table, on ne prend que:
  846. * - la table (KKONV . 'EQEX' . 'PASDETPS')
  847. * - les inconnues du problème
  848. * (KKONV . 'EQEX' . 'UN')
  849. * - le maillage fantome
  850. * (KKONV . 'EQEX' . 'MAIFAN')
  851. * - les vitesses de cut-off pour le bas Mach
  852. * (KKONV . 'EQEX' . 'CO1')
  853. * (KKONV . 'EQEX' . 'CO2')
  854. *
  855. * *KKONV . 'GAZ' = le modelé de gaz qu'on considère
  856. * - si KKONV . 'GAZ' = 'PERFMONO', alors
  857. * on considère un gaz parfait mono-espèce
  858. * polytropique
  859. *
  860. * *KKONV . 'MODELE' = objet modele
  861. *
  862. * *KKONV . 'LISTCONS' = les noms des variables conservatives, i.e.
  863. * densité, q.d.m., energie totale par unité de
  864. * volume
  865. *
  866. * *KKONV . 'IMPL' = calcul implicite ou non ?
  867. *
  868. * *KKONV . 'METHODE' = méthode pour le calcul du flux convectif
  869. *
  870. * *KKONV . 'TYPEJACO' = 'VLH'
  871. * 'AUSMPLUS'
  872. * 'AUSMPLM'
  873. * (à donner si (KKONV . 'IMPL'))
  874. *
  875. * *KKONV . 'ORDREESP' = ordre en espace (1 ou 2) ;
  876. *
  877. * *KKONV . 'GRADRN' coeff. pour calculer le gradient de la densité
  878. * *KKONV . 'GRADVN' coeff. pour calculer le gradient de la vitesse
  879. * *KKONV . 'GRADPN' coeff. pour calculer le gradient de la pression
  880. * *KKONV . 'VLIM' vitesses au bord imposées
  881. * (à donner si (KKONV . 'ORDREESP') = 2)
  882. *
  883. * *KKONV . 'LIMITEUR' = limiteur utilisé
  884. * (à donner si (KKONV . 'ORDREESP') = 2)
  885. *
  886. * *KKONV . 'NFROZLIM' = entier
  887. * On gele les limiteurs quand
  888. * RV . 'PASDETPS' . 'NUPASDT' = KKONV . 'NFROZLIM'
  889. * On le met dedans
  890. * *KKONV . 'FROZALR'
  891. * *KKONV . 'FROZALP'
  892. * *KKONV . 'FROZALV'
  893. *
  894. * *KKONV . 'ALPHA' = coefficient de securité pour le quel on
  895. * multiplie le pas de tps determiné par un
  896. * condition de type CFL.
  897. * Il peut etre:
  898. * - un flottant
  899. * - une mot que veut 'INF'
  900. *
  901. * *KKON . 'FACELIM' = maillage de centres de face ou on ne calcule pas
  902. * le flux convectif et le jacobien
  903. *
  904. * *KKON . 'CLIM' = LOGIQUE
  905. * si vrai on doit definir une procedure PKOCLI
  906. *
  907. * *KKON . 'DT' = output. Donne les pas de temps plus petit
  908. * (r_elem/(u+c))
  909. *
  910. 'DEBPROC' PKON ;
  911. 'ARGUMENT' KKONV * TABLE ;
  912. *
  913. CHPVID MATVID = 'KOPS' 'MATRIK' ;
  914. *
  915. METO = KKONV . 'METHODE' ;
  916. *
  917. RV = KKONV . 'EQEX' ;
  918. *
  919. LOGIMP = KKONV . 'IMPL';
  920. LOGEXP = 'NON' LOGIMP ;
  921. *
  922. ORDESP = KKONV . 'ORDREESP' ;
  923. *
  924. 'SI' (('NEG' (KKONV . 'ALPHA') 'INF') 'ET'
  925. ('NEG' ('TYPE' (KKONV . 'ALPHA')) FLOTTANT)) ;
  926. 'MESSAGE' 'PKON . ALPHA = ???' ;
  927. 'ERREUR' 21 ;
  928. 'FINSI' ;
  929. *
  930. UN = 'REDU' (RV . 'UN') ('DOMA' (KKONV . 'MODELE') 'CENTRE') ;
  931. *
  932. 'SI' ('NEG' (KKONV . 'GAZ') 'PERFMONO') ;
  933. *
  934. ******** EULER, monoespece, "calorically perfect" (cv = constant)
  935. *
  936. 'MESSAGE' ;
  937. 'MESSAGE' 'PKON . GAZ = ???' ;
  938. 'ERREUR' 21 ;
  939. 'FINSI' ;
  940. *
  941. **** Type de jacobien (Bas Mach ?)
  942. *
  943. 'SI' LOGIMP ;
  944. ITJACO = 0 ;
  945. 'SI' (('EGA' (KKONV . 'TYPEJACO') 'AUSMPLM') 'OU'
  946. ('EGA' (KKONV . 'TYPEJACO') 'RUSANOLM') 'OU'
  947. ('EGA' (KKONV . 'TYPEJACO') 'ROELM') 'OU'
  948. ('EGA' (KKONV . 'TYPEJACO') 'HLLCLM')) ;
  949. ITJACO = -1 ;
  950. 'FINSI' ;
  951. 'FINSI' ;
  952. *
  953. ITMETO = 0 ;
  954. 'SI' (('EGA' METO 'AUSMPLM') 'OU'
  955. ('EGA' METO 'RUSANOLM') 'OU'
  956. ('EGA' METO 'ROELM') 'OU'
  957. ('EGA' METO 'HLLCLM')) ;
  958. ITMETO = -1 ;
  959. 'FINSI' ;
  960. *
  961. ***** Les variables conservatives
  962. *
  963. MOT1 = 'EXTRAIRE' (KKONV . 'LISTCONS') 1 ;
  964. 'SI' ('EGA' ('VALE' 'DIME') 2) ;
  965. NOMMOM = 'EXTRAIRE' (KKONV . 'LISTCONS')
  966. ('LECT' 2 3 ) ;
  967. NOMVEL = 'MOTS' 'UX' 'UY' ;
  968. MOT2 = 'EXTRAIRE' (KKONV . 'LISTCONS') 4 ;
  969. NOMGP = 'MOTS' 'P1DX' 'P1DY' ;
  970. 'SINON' ;
  971. NOMMOM = 'EXTRAIRE' (KKONV . 'LISTCONS')
  972. ('LECT' 2 3 4) ;
  973. NOMVEL = 'MOTS' 'UX' 'UY' 'UZ' ;
  974. MOT2 = 'EXTRAIRE' (KKONV . 'LISTCONS') 5 ;
  975. NOMGP = 'MOTS' 'P1DX' 'P1DY' 'P1DZ' ;
  976. 'FINSI' ;
  977. RN = 'EXCO' MOT1 UN 'SCAL' ;
  978. GN = 'EXCO' NOMMOM UN NOMVEL ;
  979. RETN = 'EXCO' MOT2 UN 'SCAL' ;
  980. *
  981. ***** On calcule les variables primitive
  982. *
  983. GAMN = (RV . 'PGAZ' . 'GAMN') ;
  984. VN PN = 'PRIM' 'PERFMONO' RN GN RETN GAMN ;
  985. * VN PN = PPRIM RN GN RETN GAMN ;
  986. * 'SI' ((('MINIMUM' PN) < 0) 'OU' (('MINIMUM' RN) < 0)) ;
  987. * 'MESSAGE' 'Negative density or pressure' ;
  988. * KKONV . 'ANOM' = VRAI ;
  989. * RN = ('ABS' RN) '+' (('MAXIMUM' RN 'ABS') '*' 1.001) ;
  990. * PN = ('ABS' PN) '+' (('MAXIMUM' PN 'ABS') '*' 1.001) ;
  991. * 'FINSI' ;
  992. *
  993. **** Conditions aux limits ???
  994. *
  995. 'SI' (KKONV . 'CLIM') ;
  996.  
  997. * TABLIM = 'TABLE' definie dans le programme principal ;
  998.  
  999. KKONV . 'TABLIM' . 'RN' = RN ;
  1000. KKONV . 'TABLIM' . 'VN' = VN ;
  1001. KKONV . 'TABLIM' . 'PN' = PN ;
  1002. KKONV . 'TABLIM' . 'GAMN' = GAMN ;
  1003.  
  1004. CHPLIM RESLIM JACLIM = PKOLIM (KKONV . 'TABLIM') ;
  1005. MAILLIM = ('EXTRAIRE' CHPLIM 'MAILLAGE') 'ET' (KKONV . 'FACELIM') ;
  1006. 'SINON' ;
  1007. MAILLIM = KKONV . 'FACELIM' ;
  1008. RESLIM JACLIM = 'KOPS' 'MATRIK' ;
  1009. CHPLIM = 'COPIER' RESLIM ;
  1010. 'FINSI' ;
  1011. MAILLIM = 'CHANGER' 'POI1' MAILLIM ;
  1012. *
  1013. **** La gravite
  1014. *
  1015. *
  1016. RESGRA = 'FIMP' 'VF' 'GRAVMONO' 'RESI' (KKONV . 'LISTCONS')
  1017. RN GN (KKONV . 'GRAVITE') ;
  1018. *
  1019. JACGRA = 'FIMP' 'VF' 'GRAVMONO' 'JACOCONS' (KKONV . 'LISTCONS')
  1020. RN GN (KKONV . 'GRAVITE') ;
  1021. *
  1022. * Fin contribution gravité
  1023. *
  1024.  
  1025. *
  1026. ***** On calcule les variables aux faces
  1027. *
  1028. ORDTPS = 1 ;
  1029.  
  1030. *
  1031. 'SI' (ORDESP 'EGA' 1) ;
  1032. *
  1033. ********* Ordre 1 en espace
  1034. *
  1035. ROF VITF PF GAMF = 'PRET' 'PERFMONO' 1 ORDTPS
  1036. (KKONV . 'MODELE') RN VN PN GAMN ;
  1037. 'SINON' ;
  1038. *
  1039. ********* Ordre 2 en espace
  1040. *
  1041. 'SI' (KKONV . 'CLIM') ;
  1042. GRADV ALV = 'PENT' (KKONV . 'MODELE') 'CENTRE' 'EULEVECT'
  1043. (KKONV . 'LIMITEUR') NOMVEL VN 'CLIM'
  1044. ((KKONV . 'VLIM') '+' ('EXCO' NOMVEL CHPLIM))
  1045. 'GRADGEO' (KKONV . 'GRADVN') ;
  1046. GRADR ALR = 'PENT' (KKONV . 'MODELE') 'CENTRE' 'EULESCAL'
  1047. (KKONV . 'LIMITEUR') ('MOTS' 'SCAL') RN
  1048. 'CLIM' ('EXCO' 'RN' CHPLIM) 'GRADGEO' (KKONV . 'GRADRN') ;
  1049. *
  1050. GRADP ALP = 'PENT' (KKONV . 'MODELE') 'CENTRE' 'EULESCAL'
  1051. (KKONV . 'LIMITEUR') ('MOTS' 'SCAL') PN
  1052. 'CLIM' ('EXCO' 'PN' CHPLIM) 'GRADGEO' (KKONV . 'GRADPN') ;
  1053. *
  1054. 'SINON' ;
  1055. GRADV ALV = 'PENT' (KKONV . 'MODELE') 'CENTRE' 'EULEVECT'
  1056. (KKONV . 'LIMITEUR') NOMVEL VN 'CLIM'
  1057. (KKONV . 'VLIM')
  1058. 'GRADGEO' (KKONV . 'GRADVN') ;
  1059. GRADR ALR = 'PENT' (KKONV . 'MODELE') 'CENTRE' 'EULESCAL'
  1060. (KKONV . 'LIMITEUR') ('MOTS' 'SCAL') RN
  1061. 'GRADGEO' (KKONV . 'GRADRN') ;
  1062. *
  1063. GRADP ALP = 'PENT' (KKONV . 'MODELE') 'CENTRE' 'EULESCAL'
  1064. (KKONV . 'LIMITEUR') ('MOTS' 'SCAL') PN
  1065. 'GRADGEO' (KKONV . 'GRADPN') ;
  1066. 'FINSI' ;
  1067. *
  1068. ****** Limiters = 0 on ghostcells
  1069. *
  1070. 'SI' (('EXISTE' RV 'MAIFAN')) ;
  1071. ALRLEV = ('REDU' ALR (RV . 'MAIFAN')) ;
  1072. ALPLEV = ('REDU' ALP (RV . 'MAIFAN')) ;
  1073. ALVLEV = ('REDU' ALV (RV . 'MAIFAN')) ;
  1074. CELL = ALR ;
  1075. ALR = ALR '-' ALRLEV ;
  1076. 'DETR' CELL ;
  1077. CELL = ALP ;
  1078. ALP = ALP '-' ALPLEV ;
  1079. 'DETR' CELL ;
  1080. CELL = ALV ;
  1081. ALV = ALV '-' ALVLEV ;
  1082. 'DETR' CELL ;
  1083. 'FINSI' ;
  1084. *
  1085. ****** Frozen Limiters
  1086. *
  1087. * External iterations
  1088. *
  1089. 'SI' ('EXISTE' KKONV 'NFROZLIM') ;
  1090. ITEREX = RV . 'PASDETPS' . 'NUPASDT' ;
  1091. 'SI' (ITEREX 'EGA' (KKONV . 'NFROZLIM')) ;
  1092. 'MESSAGE' ;
  1093. 'MESSAGE' 'External iterations' ;
  1094. 'MESSAGE' 'We froze the limiters' ;
  1095. KKONV . 'FROZALR' = 'COPIER' ALR ;
  1096. KKONV . 'FROZALP' = 'COPIER' ALP ;
  1097. KKONV . 'FROZALV' = 'COPIER' ALV ;
  1098. 'SINON' ;
  1099. 'SI' (ITEREX > (KKONV . 'NFROZLIM')) ;
  1100. *
  1101. * Min
  1102. *
  1103. DAR = (ALR '-' (KKONV . 'FROZALR')) 'ABS' ;
  1104. DAP = (ALP '-' (KKONV . 'FROZALP')) 'ABS' ;
  1105. DAV = (ALV '-' (KKONV . 'FROZALV')) 'ABS' ;
  1106. ALR = (ALR '+' (KKONV . 'FROZALR')) '-' DAR ;
  1107. ALP = (ALP '+' (KKONV . 'FROZALP')) '-' DAP ;
  1108. ALV = (ALV '+' (KKONV . 'FROZALV')) '-' DAV ;
  1109. ALR = ALR '/' 2.0 ;
  1110. ALV = ALV '/' 2.0 ;
  1111. ALP = ALP '/' 2.0 ;
  1112. KKONV . 'FROZALR' = 'COPIER' ALR ;
  1113. KKONV . 'FROZALP' = 'COPIER' ALP ;
  1114. KKONV . 'FROZALV' = 'COPIER' ALV ;
  1115. 'FINSI' ;
  1116. 'FINSI' ;
  1117. 'FINSI' ;
  1118. *
  1119. * Internal iterations
  1120. *
  1121. 'SI' ('EXISTE' KKONV 'NFROZLII') ;
  1122. ITERIN = RV . 'RESULTATS' . 'ITERIN' ;
  1123. 'SI' (ITERIN 'EGA' (KKONV . 'NFROZLII')) ;
  1124. 'MESSAGE' ;
  1125. 'MESSAGE' 'Internal iterations' ;
  1126. 'MESSAGE' 'We froze the limiters' ;
  1127. KKONV . 'FROZALR' = 'COPIER' ALR ;
  1128. KKONV . 'FROZALP' = 'COPIER' ALP ;
  1129. KKONV . 'FROZALV' = 'COPIER' ALV ;
  1130. 'SINON' ;
  1131. 'SI' (ITERIN > (KKONV . 'NFROZLII')) ;
  1132. DAR = (ALR '-' (KKONV . 'FROZALR')) 'ABS' ;
  1133. DAP = (ALP '-' (KKONV . 'FROZALP')) 'ABS' ;
  1134. DAV = (ALV '-' (KKONV . 'FROZALV')) 'ABS' ;
  1135. ALR = (ALR '+' (KKONV . 'FROZALR')) '-' DAR ;
  1136. ALP = (ALP '+' (KKONV . 'FROZALP')) '-' DAP ;
  1137. ALV = (ALV '+' (KKONV . 'FROZALV')) '-' DAV ;
  1138. ALR = ALR '/' 2.0 ;
  1139. ALV = ALV '/' 2.0 ;
  1140. ALP = ALP '/' 2.0 ;
  1141. KKONV . 'FROZALR' = 'COPIER' ALR ;
  1142. KKONV . 'FROZALP' = 'COPIER' ALP ;
  1143. KKONV . 'FROZALV' = 'COPIER' ALV ;
  1144. 'FINSI' ;
  1145. 'FINSI' ;
  1146. 'FINSI' ;
  1147. *
  1148.  
  1149. *
  1150. ********* Ordre 1 en temps
  1151. *
  1152. ROF VITF PF GAMF = 'PRET' 'PERFMONO' ORDESP ORDTPS
  1153. (KKONV . 'MODELE')
  1154. RN GRADR ALR
  1155. VN GRADV ALV
  1156. PN GRADP ALP
  1157. GAMN ;
  1158. 'FINSI' ;
  1159.  
  1160. *
  1161. 'SI' (ITMETO 'EGA' (-1)) ;
  1162. RESIDU DELTAT = 'KONV' 'VF' 'PERFMONO' 'RESI' METO
  1163. (KKONV . 'LISTCONS') (KKONV . 'MODELE')
  1164. ROF VITF PF GAMF
  1165. MAILLIM (RV . 'CO1')
  1166. (RV . 'CO2') ;
  1167. 'SINON' ;
  1168. RESIDU DELTAT = 'KONV' 'VF' 'PERFMONO' 'RESI' METO
  1169. (KKONV . 'LISTCONS') (KKONV . 'MODELE')
  1170. ROF VITF PF GAMF
  1171. MAILLIM ;
  1172. 'FINSI' ;
  1173. *
  1174. 'SI' ('EGA' ('TYPE' (KKONV . 'ALPHA')) FLOTTANT) ;
  1175. ALPDT = 'PROG' ((KKONV . 'ALPHA') '*' DELTAT) ;
  1176. 'SINON' ;
  1177. ALPDT = 'PROG' ;
  1178. 'FINSI' ;
  1179.  
  1180. KKONV . 'DT' = DELTAT ;
  1181.  
  1182. *
  1183. **** Low Mach
  1184. *
  1185. 'SI' (RV . 'BASMACH') ;
  1186. MATBM = 'KONV' 'VF' 'PERFMONO' 'GAMMCONS' (KKONV . 'LISTCONS')
  1187. ('DOMA' (KKONV . 'MODELE') 'CENTRE')
  1188. ('DOMA' (KKONV . 'MODELE') 'DIAMIN')
  1189. RN VN PN GAMN (RV . 'CO1')
  1190. (RV . 'CO2') ;
  1191. RV . 'GAMSDTAU' = 'KOPS' 'MULT'
  1192. (1. '/' (KKONV . 'CFLDTAU')) MATBM ;
  1193. 'FINSI' ;
  1194. *
  1195. 'SI' LOGIMP ;
  1196. 'SI' (ITJACO 'EGA' 0) ;
  1197. JACO = 'KONV' 'VF' 'PERFMONO' 'JACOCONS' (KKONV . 'MODELE')
  1198. (KKONV . 'LISTCONS')
  1199. MAILLIM (KKONV . 'TYPEJACO')
  1200. RN VN PN GAMN ;
  1201. 'SINON' ;
  1202. JACO = 'KONV' 'VF' 'PERFMONO' 'JACOCONS' (KKONV . 'MODELE')
  1203. (KKONV . 'LISTCONS')
  1204. MAILLIM (KKONV . 'TYPEJACO')
  1205. RN VN PN GAMN (RV . 'CO1')
  1206. (RV . 'CO2') ;
  1207. 'FINSI' ;
  1208. 'RESPRO' (JACO 'ET' JACLIM 'ET' JACGRA)
  1209. (RESIDU '+' RESLIM '+' RESGRA)
  1210. ALPDT ;
  1211. 'SINON' ;
  1212. 'RESPRO' (RESIDU '+' RESLIM '+' RESGRA) ALPDT ;
  1213. 'FINSI' ;
  1214. *
  1215. **** On detrui les choses qui ne servent plus
  1216. *
  1217. 'DETR' UN ;
  1218. 'OUBL' UN ;
  1219. 'DETR' RN ;
  1220. 'DETR' GN ;
  1221. 'DETR' RETN ;
  1222. 'DETR' VN ;
  1223. 'DETR' PN ;
  1224. 'OUBL' RN ;
  1225. 'OUBL' GN ;
  1226. 'OUBL' RETN ;
  1227. 'OUBL' VN ;
  1228. 'OUBL' PN ;
  1229. *
  1230. **** Les MCHAML faces
  1231. *
  1232. 'DETR' ROF ;
  1233. 'DETR' VITF ;
  1234. 'DETR' PF ;
  1235. 'DETR' GAMF ;
  1236. 'OUBL' ROF ;
  1237. 'OUBL' VITF ;
  1238. 'OUBL' PF ;
  1239. 'OUBL' GAMF ;
  1240. *
  1241. **** Les pentes et les limiteurs
  1242. *
  1243. 'SI' (ORDESP 'EGA' 2);
  1244. *
  1245. 'DETR' GRADR ;
  1246. 'DETR' GRADP ;
  1247. 'DETR' GRADV ;
  1248. 'DETR' ALR ;
  1249. 'DETR' ALP ;
  1250. 'DETR' ALV;
  1251. *
  1252. 'OUBL' GRADR ;
  1253. 'OUBL' GRADP ;
  1254. 'OUBL' GRADV ;
  1255. 'OUBL' ALR ;
  1256. 'OUBL' ALP ;
  1257. 'OUBL' ALV;
  1258. *
  1259. 'FINSI' ;
  1260.  
  1261. 'FINPROC' ;
  1262. *****************************************************
  1263. *****************************************************
  1264. ** FIN PROCEDURE PKON **
  1265. *****************************************************
  1266. *****************************************************
  1267.  
  1268.  
  1269. *********************************************************************
  1270. **** Procedure PKOLIM ***********************************************
  1271. *********************************************************************
  1272.  
  1273.  
  1274. 'DEBPROC' PKOLIM ;
  1275. 'ARGUMENT' TABLIM*'TABLE' ;
  1276.  
  1277. LISTP = 'MOTS' 'RN' 'UX' 'UY' 'PN' ;
  1278.  
  1279. RCHLIM1 RCHRES1 = 'KONV' 'VF' 'PERFMONO' 'CLIM' 'RESI'
  1280. MDOMINT MLIGG LISTCONS LISTP
  1281. (TABLIM . 'RN') (TABLIM . 'VN') (TABLIM . 'PN')
  1282. (TABLIM . 'GAMN') (TABLIM . 'CHINRI') 'INRI' ;
  1283.  
  1284. RJACO1 = 'KONV' 'VF' 'PERFMONO' 'CLIM' 'JACOCONS'
  1285. MDOMINT MLIGG LISTCONS LISTP
  1286. (TABLIM . 'RN') (TABLIM . 'VN') (TABLIM . 'PN')
  1287. (TABLIM . 'GAMN') (TABLIM . 'CHINRI') 'INRI' ;
  1288.  
  1289. RCHLIM2 RCHRES2 = 'KONV' 'VF' 'PERFMONO' 'CLIM' 'RESI'
  1290. MDOMINT MLIGD LISTCONS LISTP
  1291. (TABLIM . 'RN') (TABLIM . 'VN') (TABLIM . 'PN')
  1292. (TABLIM . 'GAMN') (TABLIM . 'CHOUTR') 'OUTRI' ;
  1293.  
  1294. RJACO2 = 'KONV' 'VF' 'PERFMONO' 'CLIM' 'JACOCONS'
  1295. MDOMINT MLIGD LISTCONS LISTP
  1296. (TABLIM . 'RN') (TABLIM . 'VN') (TABLIM . 'PN')
  1297. (TABLIM . 'GAMN') (TABLIM . 'CHOUTR') 'OUTRI' ;
  1298.  
  1299.  
  1300. CHPLIM = RCHLIM1 '+' RCHLIM2 ;
  1301. RESLIM = RCHRES1 '+' RCHRES2 ;
  1302. JACLIM = RJACO1 'ET' RJACO2 ;
  1303.  
  1304. 'RESPRO' CHPLIM RESLIM JACLIM ;
  1305. 'FINPROC' ;
  1306.  
  1307. *********************************************************************
  1308. **** Procedure CALC *************************************************
  1309. *********************************************************************
  1310. *
  1311. * Personal procedure
  1312. *
  1313. 'DEBP' CALC ;
  1314. 'ARGU' RVX*'TABLE' ;
  1315. *
  1316. RV = RVX . 'EQEX' ;
  1317. UN = RV . 'UN' ;
  1318. MCALC = RVX . 'MODELE' ;
  1319. *
  1320. * During the external iteration (except the first; in which
  1321. * UNM = UN of the previous step )
  1322. *
  1323. 'SI' ('NEG' 0 (RV . 'RESULTATS' . 'ITERIN')) ;
  1324.  
  1325. RN = 'REDU' ('DOMA' MCALC 'CENTRE')
  1326. ('EXCO' UN NOMDEN ('MOTS' 'SCAL')) ;
  1327. GN = 'REDU' ('DOMA' MCALC 'CENTRE')
  1328. ('EXCO' NOMMOM UN NOMVEL) ;
  1329. RETN = 'REDU' ('DOMA' MCALC 'CENTRE')
  1330. ('EXCO' NOMRET UN ('MOTS' 'SCAL')) ;
  1331. VN PN = 'PRIM' 'PERFMONO' RN GN RETN (RV . 'PGAZ' . 'GAMN') ;
  1332. *
  1333. 'SI' ('EGA' (RVX . 'COMPT') 0) ;
  1334. RVX . 'IT' = 'PROG' ;
  1335. RVX . 'ER' = 'PROG' ;
  1336. 'SINON' ;
  1337. CHPVOL = 'DOMA' MCALC 'VOLUME' ;
  1338. VOLTOT = 'XTY' CHPVOL ('MANUEL' CHPO
  1339. ('DOMA' MCALC 'CENTRE') 1 'SCAL' 1.) ('MOTS' 'SCAL')
  1340. ('MOTS' 'SCAL');
  1341. ERRO = 'ABS' (PN '-' (RVX . 'PN0')) ;
  1342. ERRO = 'XTY' ERRO CHPVOL ('MOTS' 'SCAL')
  1343. ('MOTS' 'SCAL') ;
  1344. ERRO = ERRO '/' VOLTOT ;
  1345. RVX . 'IT' = (RVX . 'IT') 'ET' ('PROG'
  1346. (RVX . 'COMPT')) ;
  1347. RVX . 'ER' = (RVX . 'ER') 'ET' ('PROG' ERRO) ;
  1348. 'FINSI' ;
  1349. RVX . 'PN0' = PN ;
  1350. RVX . 'COMPT' = (RVX . 'COMPT') '+' 1 ;
  1351. 'FINSI' ;
  1352. *
  1353. * We change the cut-off during the internal iterations
  1354. *
  1355. 'SI' FAUX ;
  1356. 'SI' ((RV . 'RESULTATS' . 'ITERIN') > 0) ;
  1357. CUMAX = RV . 'CO1MAX' ;
  1358. CUMIN = RV . 'CO1MIN' ;
  1359. DCU = (CUMIN '-' CUMAX) '/' 5 ;
  1360. CU = CUMAX '+' (DCU * (RV . 'RESULTATS' . 'ITERIN')) ;
  1361. * Take the max between CU and CUMIN
  1362. A = CUMIN '+' CU ;
  1363. B = 'ABS' (CUMIN '-' CU) ;
  1364. CU = 0.5 '*' (A '+' B) ;
  1365. *
  1366. RV . 'CO1' = CU ;
  1367. RV . 'CO2' = CU ;
  1368. 'FINSI' ;
  1369. 'FINSI' ;
  1370. *
  1371. IALPDT = 'PROG' ;
  1372. IRESU IJACO ='KOPS' 'MATRIK' ;
  1373. *
  1374. 'MENAGE' ;
  1375. *
  1376. 'SI' (RVX . 'IMPL') ;
  1377. 'RESPRO' IJACO IRESU IALPDT ;
  1378. 'SINON' ;
  1379. 'RESPRO' IRESU IALPDT ;
  1380. 'FINSI' ;
  1381. *
  1382. 'FINP' ;
  1383. *
  1384.  
  1385. ************************************************************************
  1386. ************************************************************************
  1387. ***************** FIN PARTIE PROCEDURES ********************************
  1388. ************************************************************************
  1389. ************************************************************************
  1390. ************************************************************************
  1391.  
  1392. ************************************************************************
  1393. ************************************************************************
  1394. **************************** MESH **************************************
  1395. ************************************************************************
  1396. ************************************************************************
  1397.  
  1398. NY = 5 '*' RAF ;
  1399. NX1 = 4 '*' RAF ;
  1400. NX2 = 2 '*' NX1 ;
  1401. NX3 = NX1 ;
  1402. NX = (NX1 '+' NX2 '+' NX3) ;
  1403. DX = (4.0 '/' NX) ;
  1404.  
  1405. A0 = -2.0 0.0 ;
  1406. A1 = -1.0 0.0 ;
  1407. A2 = 1.0 0.0 ;
  1408. A3 = 2.0 0.0 ;
  1409. A4 = 2.0 1.0 ;
  1410. A5 = -2.0 1.0 ;
  1411.  
  1412. *
  1413. **** LIGB
  1414. *
  1415.  
  1416. LIGB1 = A0 'DROIT' NX1 A1 ;
  1417.  
  1418. * LIGB2 (On utilise un propriete de 'ET' ; si 'ET' change ?)
  1419.  
  1420. xcel = ('COORDONNEE' 1 A1) '+' DX ;
  1421. ycel = 0.1 '*' ( 1.0 '+' ('COS' (180 '*' xcel)));
  1422. ACEL = xcel ycel ;
  1423. LIGB2 = A1 'DROIT' 1 ACEL ;
  1424. 'REPETER' BL1 (NX2 '-' 2) ;
  1425. ACEL0 = ACEL ;
  1426. xcel = xcel '+' DX ;
  1427. ycel = 0.1 '*' ( 1.0 '+' ('COS' (180 '*' xcel)));
  1428. ACEL = xcel ycel ;
  1429. LIGB2 = LIGB2 'ET' (ACEL0 'DROIT' 1 ACEL) ;
  1430. 'FIN' BL1;
  1431. LIGB2 = LIGB2 'ET' (ACEL 'DROIT' 1 A2) ;
  1432.  
  1433.  
  1434. LIGB3 = A2 'DROIT' NX3 A3 ;
  1435.  
  1436. LIGB = LIGB1 'ET' LIGB2 'ET' LIGB3 ;
  1437.  
  1438. *
  1439. **** LIGH
  1440. *
  1441.  
  1442. LIGH = A4 'DROIT' NX A5 ;
  1443.  
  1444. *
  1445. **** DOMINT
  1446. *
  1447.  
  1448. DOMINT = LIGH 'REGLER' NY ('INVERSE' LIGB) ;
  1449. LIGCON = 'CONTOUR' DOMINT ;
  1450.  
  1451. *
  1452. *** LIGG
  1453. *
  1454.  
  1455. LIGG = LIGCON 'ELEM' 'COMP' A5 A0 ;
  1456.  
  1457. *
  1458. **** LIGD
  1459. *
  1460.  
  1461. LIGD = LIGCON 'ELEM' 'COMP' A3 A4 ;
  1462.  
  1463. *
  1464. **** MODEL OBJECTS
  1465. *
  1466.  
  1467. MDOMINT = 'MODELISER' DOMINT 'EULER' ;
  1468. MLIGG = 'MODELISER' LIGG 'EULER' ;
  1469. MLIGD = 'MODELISER' LIGD 'EULER' ;
  1470.  
  1471. *
  1472. **** Creation of DOMAINE tables via the MODEL object
  1473. *
  1474.  
  1475. TDOMINT = 'DOMA' MDOMINT 'VF' ;
  1476. TLIGG = 'DOMA' MLIGG 'VF' ;
  1477. TLIGD = 'DOMA' MLIGD 'VF' ;
  1478.  
  1479. QDOMINT = TDOMINT . 'QUAF' ;
  1480. QLIGD = TLIGD . 'QUAF' ;
  1481. QLIGG = TLIGG . 'QUAF' ;
  1482.  
  1483. 'ELIMINATION' QDOMINT (DX '/' 100.) QLIGG ;
  1484. 'ELIMINATION' QDOMINT (DX '/' 100.) QLIGD ;
  1485.  
  1486. 'SI' GRAPH ;
  1487. 'TRACER' (DOMINT 'ET' (LIGG 'COULEUR' 'ROUG')
  1488. 'ET' (LIGD 'COULEUR' 'BLEU'))
  1489. 'TITRE' 'Domaine total' ;
  1490. 'FINSI' ;
  1491.  
  1492.  
  1493. *******************************************
  1494. ****** LIGNE de Post-traitement ***********
  1495. *******************************************
  1496.  
  1497. LIGB = LIGCON 'ELEM' 'COMPRIS' A0 A3 ;
  1498. POIN0 = LIGB 'POIN' 1;
  1499. X1 Y1 = 'COORDONNEE' POIN0 ;
  1500. 'REPETER' BLLIM (('NBNO' LIGB) '-' 1) ;
  1501. X0 = X1 ;
  1502. Y0 = Y1 ;
  1503. POIN0 = LIGB 'POIN' (&BLLIM '+' 1) ;
  1504. X1 Y1 = 'COORDONNEE' POIN0 ;
  1505. XFAC = (X0 '+' X1) '/' 2 ;
  1506. YFAC = (Y0 '+' Y1) '/' 2 ;
  1507. PFAC = (TDOMINT . 'FACE') 'POIN' 'PROC' (XFAC YFAC);
  1508. GEOFAC1 = (TDOMINT . 'FACEL') 'ELEM' 'APPUYE'
  1509. 'LARGEMENT' PFAC ;
  1510. *
  1511. **** Tranformation en POI1
  1512. *
  1513. GEO1POI1 = 'CHANGER' 'POI1' GEOFAC1 ;
  1514. PCEL11 = GEO1POI1 'POIN' 1 ;
  1515. PCEL12 = GEO1POI1 'POIN' 2 ;
  1516. *
  1517. **** Il faur verifier que PFAC = PCEL12 = PCEL22
  1518. * ('NBEL' GEO1POI1) = ('NBEL' GEO2POI1) = 2
  1519. *
  1520. 'SI' ( ('NBEL' GEO1POI1) 'NEG' 2);
  1521. 'MESSAGE' ;
  1522. 'MESSAGE'
  1523. 'Probleme dans la creation de la ligne pour le post.';
  1524. 'MESSAGE' ;
  1525. 'ERREUR' 21 ;
  1526. 'FINSI' ;
  1527. 'SI' ( PCEL12 'NEG' PFAC);
  1528. 'MESSAGE' ;
  1529. 'MESSAGE'
  1530. 'Probleme dans la creation de la ligne pour le post.';
  1531. 'MESSAGE' ;
  1532. 'ERREUR' 21 ;
  1533. 'FINSI' ;
  1534. *
  1535. *** Creation d'un maillage SEG2
  1536. *
  1537. 'SI' (&BLLIM 'EGA' 1);
  1538. PCEN0 = PCEL11 ;
  1539. 'SINON' ;
  1540. 'SI' (&BLLIM 'EGA' 2);
  1541. LIGPOST = 'MANUEL' 'SEG2' PCEN0 PCEL11 ;
  1542. PCEN0 = PCEL11 ;
  1543. 'SINO' ;
  1544. LIGPOST = LIGPOST 'ET' ('MANUEL' 'SEG2' PCEN0 PCEL11) ;
  1545. PCEN0 = PCEL11 ;
  1546. 'FINSI' ;
  1547. 'FINSI' ;
  1548. 'FIN' BLLIM ;
  1549.  
  1550. 'SI' GRAPH ;
  1551. 'TRACER' (DOMINT 'ET' (LIGPOST 'COULEUR' 'VERT'))
  1552. 'TITRE' 'LIGPOST' ;
  1553. 'FINSI' ;
  1554.  
  1555. ***************************************************************
  1556. ***************************************************************
  1557. ***************************************************************
  1558. ************** Initial conditions *****************************
  1559. ***************************************************************
  1560. ***************************************************************
  1561. ***************************************************************
  1562. *
  1563. *** C.L. et initiales
  1564. *
  1565.  
  1566. C_INF = GAMSCAL * P_INF '/' RO_INF ;
  1567. C_INF = C_INF '**' 0.5 ;
  1568. M_INF = U_INF '/' C_INF ;
  1569.  
  1570. *
  1571. * Names of conserved variables and others
  1572. *
  1573. NOMDEN = 'MOTS' 'RN' ;
  1574. NOMMOM = 'MOTS' 'RUX' 'RUY' ;
  1575. NOMRET = 'MOTS' 'RETN' ;
  1576. NOMVEL = 'MOTS' 'UX' 'UY' ;
  1577. * NOMPRE = 'MOTS' 'NOMPRE' ;
  1578. LISTCONS = NOMDEN 'ET' NOMMOM 'ET' NOMRET ;
  1579. *
  1580.  
  1581. GAMN = 'MANUEL' 'CHPO' (TDOMINT . 'CENTRE') 1 'SCAL' gamscal;
  1582.  
  1583.  
  1584. rek_inf = 0.5D0 * u_inf * u_inf * ro_inf ;
  1585. rei_inf = P_INF '/' (gamscal '-' 1.0D0) ;
  1586.  
  1587. RN0 = 'MANUEL' 'CHPO' (TDOMINT . 'CENTRE') 1 'SCAL' ro_inf ;
  1588. GN0 = 'MANUEL' 'CHPO' (TDOMINT . 'CENTRE') 2 'UX' (ro_inf * u_inf)
  1589. 'UY' 0.0 ;
  1590. RETN0 = 'MANUEL' 'CHPO' (TDOMINT . 'CENTRE') 1 'SCAL'
  1591. (rei_inf '+' rek_inf) ;
  1592.  
  1593. UNCONS = ('NOMC' 'RN' RN0 'NATU' 'DISCRET') 'ET' ('NOMC'
  1594. ('MOTS' 'UX' 'UY') GN0 ('MOTS' 'RUX' 'RUY') 'NATU' 'DISCRET') 'ET'
  1595. ('NOMC' 'RETN' RETN0 'NATU' 'DISCRET') ;
  1596.  
  1597. VN0 PN0 = 'PRIM' 'PERFMONO' RN0 GN0 RETN0 GAMN ;
  1598. ERRO = ('MAXIMUM' (PN0 '-' p_inf) 'ABS') / p_inf ;
  1599. 'SI' (ERRO > 1.0D-16) ;
  1600. 'ERREUR' 21 ;
  1601. 'FINSI' ;
  1602.  
  1603. aa = 'EXCO' 'UX' VN0 ;
  1604. ERRO = ('MAXIMUM' (aa '-' u_inf) 'ABS') / u_inf ;
  1605. 'SI' (ERRO > 1.0D-16) ;
  1606. 'ERREUR' 21 ;
  1607. 'FINSI' ;
  1608.  
  1609. VN2 = 'PSCAL' VN0 VN0 ('MOTS' 'UX' 'UY') ('MOTS' 'UX' 'UY') ;
  1610. C2 = GAMN '*' ( PN0 '/' RN0) ;
  1611. CN0 = C2 '**' 0.5 ;
  1612.  
  1613. MACH2 = VN2 '/' C2;
  1614. MACHN0 = MACH2 '**' 0.5;
  1615.  
  1616. *
  1617. **** Plot of IC
  1618. *
  1619.  
  1620. 'SI' GRAPH ;
  1621.  
  1622. CHM_RN = 'KCHA' MDOMINT 'CHAM' RN0 ;
  1623. CHM_PN = 'KCHA' MDOMINT 'CHAM' PN0 ;
  1624. CHM_VN = 'KCHA' MDOMINT 'CHAM' VN0 ;
  1625. CHM_MACH = 'KCHA' MDOMINT 'CHAM' MACHN0 ;
  1626.  
  1627. 'TRACER' CHM_RN MDOMINT
  1628. 'TITR' ('CHAINE' 'RN at t=' 0.0);
  1629. 'TRACER' CHM_PN MDOMINT
  1630. 'TITR' ('CHAINE' 'PN at t=' 0.0);
  1631. 'TRACER' CHM_VN MDOMINT
  1632. 'TITR' ('CHAINE' 'VN at t=' 0.0);
  1633. 'TRACER' CHM_MACH MDOMINT
  1634. 'TITR' ('CHAINE' 'MACH at t=' 0.0);
  1635.  
  1636. 'FINSI' ;
  1637.  
  1638.  
  1639. *****************************************************
  1640. *****************************************************
  1641. *****************************************************
  1642. **************** La table RV **********************
  1643. *****************************************************
  1644. *****************************************************
  1645. *****************************************************
  1646. *
  1647. RV = 'TABLE' ;
  1648. RV . 'ANOM' = FAUX ;
  1649. * Constant time step
  1650. CFLREF = 100.0 ;
  1651. UREF = u_inf ;
  1652. UREF = c_inf ;
  1653. RV . 'DTIMP' = CFLREF * DX '/' UREF ;
  1654. *
  1655. RV . 'ORDTPS' = 1 ;
  1656. *
  1657. RV . 'UN' = UNCONS ;
  1658. RV . 'LISTCONS' = LISTCONS ;
  1659. RV . 'ERROMOTS' = NOMRET ;
  1660. *
  1661. RV . 'CLIM' = FAUX ;
  1662. *
  1663. RV . 'CONS' = FAUX ;
  1664. *
  1665. RV . 'TFINAL' = 1.0E6 ;
  1666. RV . 'NITMAEX' = NITER ;
  1667. *
  1668. RV . 'NITMAIN' = 6 ;
  1669. RV . 'NITMIIN' = 6 ;
  1670. RV . 'EPSINT' = 1.0D-16 ;
  1671. *
  1672. * RV . 'FEXT' = 20 ;
  1673. * RV . 'FINT' = 1 ;
  1674. *
  1675. RV . 'LISTOPER' = 'MOTS' 'CALC' 'PKON' ;
  1676. *
  1677. CALCTAB = 'TABLE' ;
  1678. RV . '1CALC' = CALCTAB ;
  1679. PKONTAB = 'TABLE' ;
  1680. RV . '2PKON' = PKONTAB ;
  1681. *
  1682. RV . 'MATIDE' = 'KOPS' 'MATIDE' LISTCONS ('DOMA' MDOMINT 'CENTRE')
  1683. 'MATRIK' ;
  1684. *
  1685. **** Parametres de la procedure PROLIM
  1686. *
  1687. * Gas model
  1688. * Gas properties
  1689. RV . 'PGAZ' = 'TABLE' ;
  1690. RV . 'PGAZ' . 'R' = Rair ;
  1691. RV . 'PGAZ' . 'GAMN' = gamn ;
  1692. * RV . 'PGAZ' . 'MU' = 0.0 ;
  1693. * RV . 'PGAZ' . 'LAMBDA' = 0.0 ;
  1694. * Bas Mach (PKON)
  1695. RV . 'BASMACH' = FAUX ;
  1696. RV . 'CO1' = 'MANUEL' 'CHPO' ('DOMA' MDOMINT 'CENTRE')
  1697. 1 'SCAL' (10 * U_INF) ;
  1698. RV . 'CO1MAX' = 'MANUEL' 'CHPO' ('DOMA' MDOMINT 'CENTRE')
  1699. 1 'SCAL' (10 * U_INF) ;
  1700. RV . 'CO1MIN' = 'MANUEL' 'CHPO' ('DOMA' MDOMINT 'CENTRE')
  1701. 1 'SCAL' (10 * U_INF) ;
  1702. RV . 'CO2' = 'COPIER' ( RV . 'CO1') ;
  1703. * RV . 'CO2' can be Modified into PDIF
  1704. *****************
  1705. ** CALCUL *******
  1706. *****************
  1707. * Personal procedure
  1708. *
  1709. CALCTAB . 'ANOM' = FAUX ;
  1710. CALCTAB . 'EQEX' = RV ;
  1711. CALCTAB . 'MODELE' = MDOMINT ;
  1712. * We call this procedure during the external iterations ->
  1713. CALCTAB . 'IMPL' = VRAI ;
  1714. CALCTAB . 'COMPT' = 0 ;
  1715. *
  1716. *****************
  1717. * PKON **********
  1718. *****************
  1719. CHPVID MATVID = 'KOPS' 'MATRIK' ;
  1720. PKONTAB . 'CFLDTAU' = 10000. ;
  1721. PKONTAB . 'ANOM' = FAUX ;
  1722. PKONTAB . 'EQEX' = RV ;
  1723. PKONTAB . 'GAZ' = 'PERFMONO' ;
  1724. PKONTAB . 'MODELE' = MDOMINT ;
  1725. PKONTAB . 'LISTCONS' = LISTCONS ;
  1726. * PKONTAB . 'METHODE' = 'CENTERED' ;
  1727. * PKONTAB . 'METHODE' = 'RUSANOLM' ;
  1728. * PKONTAB . 'METHODE' = 'AUSMPLM' ;
  1729. PKONTAB . 'METHODE' = 'AUSMPLUS' ;
  1730. * PKONTAB . 'METHODE' = 'VLH' ;
  1731. * PKONTAB . 'METHODE' = 'ROELM' ;
  1732. * PKONTAB . 'METHODE' = 'ROE' ;
  1733. * PKONTAB . 'METHODE' = 'HLLCLM' ;
  1734. *
  1735. PKONTAB . 'IMPL' = VRAI ;
  1736. 'SI' (PKONTAB . 'IMPL') ;
  1737. PKONTAB . 'TYPEJACO' = 'AUSMPLUS' ;
  1738. * PKONTAB . 'TYPEJACO' = 'VLH' ;
  1739. * PKONTAB . 'TYPEJACO' = 'RUSANOLM' ;
  1740. * PKONTAB . 'TYPEJACO' = 'AUSMPLM' ;
  1741. 'FINSI' ;
  1742. *
  1743. PKONTAB . 'ORDREESP' = 2 ;
  1744. 'SI' ((PKONTAB . 'ORDREESP') 'EGA' 2) ;
  1745. PKONTAB . 'VLIM' = CHPVID ;
  1746. CHPENLIM = 'MANUEL' 'CHPO' (('DOMA' MLIGG 'CENTRE') 'ET'
  1747. ('DOMA' MLIGD 'CENTRE')) 1 'SCAL' 0.0 ;
  1748. CHPE2LIM = 'MANUEL' 'CHPO' (('DOMA' MLIGG 'CENTRE') 'ET'
  1749. ('DOMA' MLIGD 'CENTRE')) 2
  1750. 'UX' 1.0 'UY' 0.0 ;
  1751. TOTO TITI MCHRCON = 'PENTE' MDOMINT 'CENTRE' 'EULESCAL'
  1752. 'LIMITEUR' ('MOTS' 'SCAL') RN0 'CLIM' CHPENLIM ;
  1753. TOTO TITI MCHVCON = 'PENTE' MDOMINT 'CENTRE' 'EULEVECT'
  1754. 'LIMITEUR' ('MOTS' 'UX' 'UY') GN0 'CLIM' CHPE2LIM ;
  1755. PKONTAB . 'LIMITEUR' = 'NOLIMITE' ;
  1756. PKONTAB . 'GRADRN' = MCHRCON ;
  1757. PKONTAB . 'GRADPN' = MCHRCON ;
  1758. PKONTAB . 'GRADVN' = MCHVCON ;
  1759. 'FINSI' ;
  1760. PKONTAB . 'NFROZLIM' = 50 ;
  1761. * Gravité
  1762. * PKONTAB . 'CORRGRA' = FAUX ;
  1763. PKONTAB . 'GRAVITE' = 'MANUEL' 'CHPO' ('DOMA' MDOMINT 'CENTRE') 2
  1764. 'UX' 0.0 'UY' 0.0 ;
  1765. *
  1766. MAIVID = 'DIFF' ('DOMA' MLIGG 'CENTRE')
  1767. ('DOMA' MLIGG 'CENTRE') ;
  1768. PKONTAB . 'FACELIM' = MAIVID ;
  1769. PKONTAB . 'ALPHA' = 'INF' ;
  1770. PKONTAB . 'CLIM' = VRAI ;
  1771. PKONTAB . 'TABLIM' = TABLE ;
  1772. *
  1773. * Normalisation du profile parabolique, pour obtenir que
  1774. * le flux rentrante vaut MINJ
  1775. *
  1776. PKONTAB . 'TABLIM' . 'CHINRI' = 'MANUEL' 'CHPO' ('DOMA' MLIGG
  1777. 'CENTRE') 4 'RN' ro_inf 'UX' U_INF
  1778. 'UY' 0.0 'PN' p_inf ;
  1779. PKONTAB . 'TABLIM' . 'CHOUTR' = 'MANUEL' 'CHPO' ('DOMA' MLIGD
  1780. 'CENTRE') 4 'RN' ro_inf 'UX' U_INF
  1781. 'UY' 0.0 'PN' p_inf ;
  1782. *
  1783. ***********************************
  1784. * Inversion de la matrice *********
  1785. ***********************************
  1786. *
  1787. * RV . 'MATUPDAT' updating
  1788. * RV . 'MUPEXT' external iterations updating
  1789. * RV . 'MUPINT' internal iterations updating
  1790. * RV . 'MUPLIN' We update the matrix if in the previous
  1791. * internal iteration the number of linear
  1792. * iterations to solve the system were bigger
  1793. * than (RV . 'MUPLIN')
  1794. RV . 'MATUPDAT' = FAUX ;
  1795. 'SI' ('NON' ( RV . 'MATUPDAT')) ;
  1796. RV . 'MUPEXT' = 1 ;
  1797. RV . 'MUPINT' = 50 ;
  1798. RV . 'MUPLIN' = 4000 ;
  1799. 'FINSI' ;
  1800. RV . 'MATINV' = 'TABLE' 'METHINV' ;
  1801. MATTAB = RV . 'MATINV' ;
  1802. * MATTAB . 'TYPINV' = 1 : methode exact
  1803. * MATTAB . 'TYPINV' = 5 ; GMRES
  1804. MATTAB . 'TYPINV' = 1 ;
  1805. MATTAB . 'IMPINV' = 0 ;
  1806. *
  1807. * Matrice pour assurer que la matrice à inverser est correctement
  1808. * assemblé
  1809. *
  1810. * MATTAB . 'MATASS' definie en EXEXIM
  1811. * MATTAB . 'MAPREC' "
  1812. * MATTAB . 'XINIT' "
  1813. *
  1814.  
  1815. * Methode de numerotation de DDL
  1816. MATTAB . 'TYRENU' = 'RIEN' ;
  1817. MATTAB . 'PCMLAG' = 'APR2' ;
  1818. MATTAB . 'GMRESTRT' = 500 ;
  1819. MATTAB . 'SCALING' = 1 ;
  1820. * ILU 3
  1821. * ILUT (dual truncation) 5
  1822. * ILUTP 9
  1823. * Dans le cas ILUT il faut definir
  1824. * ILUTLFIL
  1825. * ILUTDTOL
  1826. MATTAB . 'PRECOND' = 7 ;
  1827. MATTAB . 'OUBMAT' = 0 ;
  1828. MATTAB . 'ILUTPPIV' = 0.1 ;
  1829. MATTAB . 'ILUTPMBL' = 0 ;
  1830. MATTAB . 'ILUTLFIL' = 4. ;
  1831. MATTAB . 'ILUTDTOL' = 0. ;
  1832. MATTAB . 'NITMAX' = 3000 ;
  1833. MATTAB . 'RESID' = 1.D-6 ;
  1834. *
  1835. **** Save results into a file
  1836. *
  1837. SI FAUX ;
  1838. FICHER1 = ('CHAINE' FICHER 'main' RAF
  1839. (PKONTAB . 'METHODE')
  1840. 'OE' (PKONTAB . 'ORDREESP')
  1841. 'OT' (RV . 'ORDTPS') '.sauv') ;
  1842. 'OPTION' 'SAUVER' FICHER1 ;
  1843. 'MESSAGE' 'We save results into' ;
  1844. 'MESSAGE' FICHER ;
  1845. 'MESSAGE' ;
  1846. 'FINSI' ;
  1847. *
  1848. **** Exexcution EXEXIM
  1849. *
  1850. 'SI' FAUX ;
  1851. LISTTPS = ('PROG' 100.0) ;
  1852. 'REPETER' BL1 ('DIME' LISTTPS) ;
  1853. RV . 'TFINAL' = 'EXTRAIRE' LISTTPS &BL1 ;
  1854. 'TEMPS' 'ZERO' ;
  1855. EXEXIM RV ;
  1856. 'TEMPS' 'IMPR' ;
  1857. *
  1858. **** To save memory storage
  1859. *
  1860. 'OUBLIER' MATTAB MATASS ;
  1861. 'OUBLIER' MATTAB MAPREC ;
  1862. 'MENAGE' ;
  1863. 'SI' FAUX ;
  1864. 'SAUVER' 'LABEL' ('CHAINE' &BL1) ;
  1865. 'FINSI' ;
  1866. 'FIN' BL1 ;
  1867. SINON ;
  1868. * 'TEMPS' 'ZERO' ;
  1869. EXEXIM RV ;
  1870. * 'TEMPS' 'IMPR' ;
  1871. 'FINSI' ;
  1872. *
  1873. ***************************************************************
  1874. ***************************************************************
  1875. ***************************************************************
  1876. ************** Plot of the solutions **************************
  1877. ***************************************************************
  1878. ***************************************************************
  1879. ***************************************************************
  1880. *
  1881. * GRAPH = VRAI ;
  1882. *
  1883. 'SI' FAUX ;
  1884. FICHER =
  1885. './D_sauv/main16VLHOE2OT1.sauv' ;
  1886. 'OPTION' 'RESTITUER' FICHER ;
  1887. 'RESTITUER' ;
  1888. 'FINSI' ;
  1889. *
  1890. * LOGGNP = logical. If VRAI, files for gnuplot are created
  1891. *
  1892. LOGGNP = VRAI ;
  1893. VALECH = 1 ;
  1894.  
  1895. 'OPTION' 'ECHO' VALECH 'TRAC' 'X' ;
  1896.  
  1897. TPS = RV . 'PASDETPS' . 'TPS' ;
  1898. METO = PKONTAB . 'METHODE' ;
  1899. ORD_ESP = PKONTAB . 'ORDREESP' ;
  1900. ORD_TPS = RV . 'ORDTPS' ;
  1901.  
  1902. NTOTEL = 'NBNO' ('DOMA' MDOMINT 'CENTRE') ;
  1903.  
  1904. *
  1905. **** Les variables conservatives
  1906. *
  1907.  
  1908. GAMN = 'REDU' GAMN ('DOMA' MDOMINT 'CENTRE') ;
  1909. RN = 'EXCO' NOMDEN (RV . 'UN') ('MOTS' 'SCAL') ;
  1910. GN = 'EXCO' NOMMOM (RV . 'UN') ('MOTS' 'UX' 'UY') ;
  1911. RETN = 'EXCO' NOMRET (RV . 'UN') ('MOTS' 'SCAL') ;
  1912.  
  1913. *
  1914. **** Les variables primitives
  1915. *
  1916.  
  1917. VN PN = 'PRIM' 'PERFMONO'
  1918. RN GN RETN GAMN ;
  1919.  
  1920. CSON2 = (GAMN '*' PN) '/' RN ;
  1921. VN2 = 'PSCAL' VN VN ('MOTS' 'UX' 'UY') ('MOTS' 'UX' 'UY') ;
  1922. MACHN2 = VN2 '/' CSON2 ;
  1923. MACHN = MACHN2 '**' 0.5 ;
  1924.  
  1925. TITOLO = ('CHAINE' METO ', OE = ' ORD_ESP ', OT =' ORD_TPS
  1926. ', NBEL = ' NTOTEL ' ,tps =' TPS) ;
  1927.  
  1928. EVO1 = 'EVOL' 'MANU' 'it' (CALCTAB . 'IT') 'err'
  1929. ((CALCTAB . 'ER') '+' 1.0D-16) ;
  1930.  
  1931. *
  1932. *** GRAPHIQUE DES SOLUTIONS
  1933. *
  1934.  
  1935. 'SI' GRAPH ;
  1936.  
  1937. 'TRACER' DOMINT 'TITRE' ('CHAINE' 'Maillage') ;
  1938.  
  1939. CHM_RN = 'KCHA' MDOMINT 'CHAM' RN ;
  1940. CHM_PN = 'KCHA' MDOMINT 'CHAM' PN ;
  1941. CHM_VN = 'KCHA' MDOMINT 'CHAM' VN ;
  1942. CHM_MACH = 'KCHA' MDOMINT 'CHAM' MACHN ;
  1943.  
  1944. 'TRACER' CHM_RN MDOMINT ('CONTOUR' DOMINT)
  1945. 'TITR' ('CHAINE' ' RN : ' TITOLO) ;
  1946. RNV = 'ELNO' TDOMINT ('REDU' RN TDOMINT . 'CENTRE') ;
  1947. 'OPTION' 'ISOV' 'LIGN' ;
  1948. 'TRACER' DOMINT RNV ('CONTOUR' DOMINT)
  1949. 'TITRE' ('CHAINE' 'RN : ' TITOLO) 15 ;
  1950. 'OPTION' 'ISOV' 'SULI' ;
  1951. 'TRACER' CHM_PN MDOMINT ('CONTOUR' DOMINT)
  1952. 'TITR' ('CHAINE' 'PN : ' TITOLO) ;
  1953. PNV = 'ELNO' TDOMINT ('REDU' PN TDOMINT . 'CENTRE') ;
  1954. 'OPTION' 'ISOV' 'LIGN' ;
  1955. 'TRACER' DOMINT PNV ('CONTOUR' DOMINT)
  1956. 'TITRE' ('CHAINE' 'PN : ' TITOLO) 15 ;
  1957. 'OPTION' 'ISOV' 'SULI' ;
  1958. 'TRACER' CHM_MACH MDOMINT ('CONTOUR' DOMINT)
  1959. 'TITR' ('CHAINE' 'MACHN : ' TITOLO);
  1960. MACHNV = 'ELNO' TDOMINT ('REDU' MACHN TDOMINT . 'CENTRE') ;
  1961. 'OPTION' 'ISOV' 'LIGN' ;
  1962. 'TRACER' DOMINT MACHNV ('CONTOUR' DOMINT)
  1963. 'TITRE' ('CHAINE' 'Mach : ' TITOLO) 15 ;
  1964. 'OPTION' 'ISOV' 'SULI' ;
  1965. 'TRACER' CHM_VN MDOMINT ('CONTOUR' DOMINT)
  1966. 'TITR' ('CHAINE' 'VN : ' TITOLO) ;
  1967. VECN = 'VECTEUR' VN (8. '/' RAF) 'UX' 'UY' 'JAUNE' ;
  1968. 'TRACER' DOMINT VECN ('CONTOUR' DOMINT)
  1969. 'TITRE' ('CHAINE' 'VN : ' TITOLO) ;
  1970. *
  1971. 'OPTION' 'ISOV' 'SULI' ;
  1972. 'DESSIN' EVO1 LOGY 'TITRE' 'Error' ;
  1973. *
  1974. 'FINSI' ;
  1975.  
  1976. *
  1977. **** Test de convergence
  1978. *
  1979.  
  1980. AA = 'EXTRAIRE' (CALCTAB . 'ER') ('DIME' (CALCTAB . 'ER')) ;
  1981.  
  1982. 'SI' (AA > 1.0D-8) ;
  1983. 'MESSAGE' 'Probleme' ;
  1984. 'ERREUR' 5 ;
  1985. 'FINSI' ;
  1986. *
  1987.  
  1988. XLIGPOST = 'COORDONNEE' 1 LIGPOST ;
  1989. EVCOOR = 'EVOL' 'CHPO' XLIGPOST 'SCAL' LIGPOST ;
  1990. LISTX = 'EXTRAIRE' EVCOOR 'ORDO' ;
  1991.  
  1992. EVMACH = 'EVOL' 'CHPO' MACHN 'SCAL' LIGPOST ;
  1993. LISTMACH = 'EXTRAIRE' EVMACH 'ORDO' ;
  1994. EVMACH = 'EVOL' 'MANU' 'x' LISTX 'Mach' LISTMACH ;
  1995. 'SI' GRAPH ;
  1996. 'DESSIN' EVMACH 'MIMA' 'TITRE' TITOLO ;
  1997. 'FINSI' ;
  1998.  
  1999. MMAX = 'MAXIMUM' MACHN ;
  2000. MMIN = 'MINIMUM' MACHN ;
  2001.  
  2002. MMAX_REF = 0.93624 ;
  2003. MMIN_REF = 0.42153 ;
  2004.  
  2005. ERRO = 'ABS' (MMAX_REF '-' MMAX) '/' M_INF ;
  2006. 'SI' (ERRO > 5.0D-2) ;
  2007. 'MESSAGE' 'Probleme' ;
  2008. 'ERREUR' 5 ;
  2009. 'FINSI' ;
  2010. *
  2011.  
  2012. ERRO = 'ABS' (MMIN_REF '-' MMIN) '/' M_INF ;
  2013. 'SI' (ERRO > 1.0D-2) ;
  2014. 'MESSAGE' 'Probleme' ;
  2015. 'ERREUR' 5 ;
  2016. 'FINSI' ;
  2017.  
  2018. 'FIN' ;
  2019.  
  2020.  
  2021.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales