Télécharger rupt9.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt9.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Rupt9.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. ****************************************************
  8. * *
  9. * VALIDATION DES PROCEDURE G_THETA ET T_PITETA *
  10. * D'UNE PLAQUE EN TRACTION PURE. SOLUTION *
  11. * DE REFERENCE : Compendium of STRESS INTENSITY *
  12. * FACTORS by Rooke & Cartwright. *
  13. * *
  14. * *
  15. * GEOMETRIE : *
  16. * *
  17. * longueur de la plaque : 250. MM *
  18. * largeur de la plaque : 100. MM *
  19. * lonqueur de la fissure : 50. MM *
  20. * Inclinaison de la fissure : 45.0 degrés *
  21. * *
  22. * MATERIAU : *
  23. * *
  24. * Module d'Young : 2.E5 MPA *
  25. * Coefficient de poisson : 0.3 *
  26. * *
  27. * CHARGEMENT : *
  28. * *
  29. * Traction pure : 1.0 daN/MM**2 *
  30. * *
  31. * SOLUTION ANALYTIQUE : *
  32. * *
  33. * Les facteurs d'intensité de contraintes *
  34. * K1 = 150.37 daN/mm**(-3/2) *
  35. * K2 = -71.4 daN/mm**(-3/2) *
  36. * *
  37. ****************************************************
  38. 'OPTION' 'DIME' 2 'ELEM' 'QUA8'
  39. 'MODE' 'PLAN' 'DEFO'
  40. 'ECHO' 1 ;
  41. *** Erreur géométrique pour les éliminations
  42. *** Plus petite que la fissure !
  43. egeom = 1.D-6 ;
  44. ***
  45. *** DD : Ouverture initiale de la fissure
  46. ***
  47. DD = 1.D-3 ;
  48. ddsur2 = DD '/' 2.0D0 ;
  49. p11 = (125.D0 '-' ddsur2) 0.D0 ;
  50. p12 = (125.D0 '+' ddsur2) 0.D0 ;
  51. p0 = 25.D0 0.D0 ;
  52. p2 = 275.D0 0.D0 ;
  53. p3 = 25.D0 100.D0 ;
  54. ppp = 125.D0 0.D0 ;
  55. L = 50.D0 ; theta = 45.D0 ;
  56. cth = 'COS' theta ;
  57. sth = 'SIN' theta ;
  58. tth = sth '/' cth ;
  59. pf1 = ppp 'PLUS' (L '*' (cth sth)) ;
  60. p4 = ((100.D0 '/' tth) '+' 125.D0) 100.D0 ;
  61. p5 = 275.D0 100.D0 ;
  62.  
  63. *******************************************************
  64. * CONSTRUCTION DU MAILLAGE *
  65. * AUTOUR DE LA POINTE DE FISSURE *
  66. *******************************************************
  67. pd = 'PROG' 1.D0 2.5D0 5.D0 9.D0 13.D0 19.D0 25.D0 ;
  68. cim11 = pf1 ; cim2 = pf1 ; cim3 = pf1 ;
  69. cim12 = pf1 ;
  70. plfim1 = pf1 ; plfim2 = pf1 ; pim3 = pf1 ;
  71.  
  72. *******************************************************
  73. 'REPETER' bbbb 7 ;
  74. v = 'EXTRAIRE' pd &bbbb ;
  75. dd1 = (v '/' L) '*' ddsur2 ;
  76. xx1 = v '*' cth ; mxx1 = (-1.0D0 '*' xx1) ;
  77. yy1 = v '*' sth ;
  78. xx2 = dd1 '*' sth '*' sth ;
  79. yy2 = dd1 '*' sth '*' cth ; myy2 = (-1.0D0 '*' yy2);
  80. pi1 = pf1 'MOIN' (xx1 yy1) ;
  81. pi2 = pf1 'PLUS' (mxx1 yy1) ;
  82. pi3 = pf1 'PLUS' (xx1 yy1) ;
  83. pi4 = pf1 'MOIN' (mxx1 yy1) ;
  84. plfi1 = pi1 'MOIN' (xx2 myy2) ;
  85. plfi2 = pi1 'PLUS' (xx2 myy2) ;
  86. 'SI' (&bbbb '>EG' 6) ;
  87. n = 4 ;
  88. 'SINON' ;
  89. n = 2 ;
  90. 'FINSI' ;
  91. *******************************************************
  92. ci11 = 'CERCLE' n plfi1 pf1 pi2 ;
  93. ci2 = 'CERCLE' n pi2 pf1 pi3 ;
  94. ci3 = 'CERCLE' n pi3 pf1 pi4 ;
  95. ci12 = 'CERCLE' n pi4 pf1 plfi2 ;
  96. sui11 = 'COUTURE' cim11 ci11 ;
  97. sui2 = 'COUTURE' cim2 ci2 ;
  98. sui3 = 'COUTURE' cim3 ci3 ;
  99. sui12 = 'COUTURE' cim12 ci12 ;
  100. 'ELIMINATION' egeom (sui11 'ET' sui2) ;
  101. 'ELIMINATION' egeom (sui12 'ET' sui3) ;
  102. *******************************************************
  103. cim11 = ci11 ; cim2 = ci2 ; cim3 = ci3 ;
  104. cim12 = ci12 ; plfim1 = plfi1 ;
  105. plfim2 = plfi2 ; pim3 = pi3 ;
  106. sut1 = 'ET' sui11 sui2 ;
  107. sut2 = 'ET' sui3 sui12 ;
  108. 'SI' (&bbbb 'EGA' 1) ;
  109. sutt1 = sut1 ;
  110. sutt2 = sut2 ;
  111. 'SINON' ;
  112. sutt1 = 'ET' sutt1 sut1 ;
  113. sutt2 = 'ET' sutt2 sut2 ;
  114. 'FINSI' ;
  115. 'FIN' bbbb ;
  116. 'OUBLIER' cim11 ; 'OUBLIER' cim2 ; 'OUBLIER' cim3;
  117. 'OUBLIER' cim12 ;
  118. 'OUBLIER' plfim1 ; 'OUBLIER' plfim2 ; 'OUBLIER' pim3;
  119. 'MENAGE' ;
  120.  
  121. *********************************
  122. * CONSTRUCTION DU MAILLAGE TOTAL
  123. *********************************
  124.  
  125. lg = 'DROIT' 6 p0 p3 ;
  126. ld = 'DROIT' 6 p2 p5 ;
  127. lhc = 'DROIT' -5 p4 pi3 'DINI' 65 'DFIN' 50 ;
  128. lig1 = 'ET' lg ('ET' ('DROIT' 13 p3 p4) lhc) ;
  129. lig1 = 'ET' lig1 ('INVERSE' ('ET' ci2 ci11)) ;
  130. lig1 = 'ET' lig1 ('ET' ('DROIT' 3 plfi1 p11)
  131. ('DROIT' 6 p11 p0)) ;
  132. su1 = 'SURFACE' lig1 'PLANE' ;
  133. obj1 = 'ET' su1 sutt1 ;
  134. *
  135. lig2 = 'ET' ld ('ET' ('DROIT' 3 p5 p4) lhc) ;
  136. lig2 = 'ET' lig2 ('ET' ci3 ci12) ;
  137. lig2 = 'ET' lig2 ('ET' ('DROIT' 3 plfi2 p12)
  138. ('DROIT' -9 p12 p2 'DINI' 40
  139. 'DFIN' 50)) ;
  140. su2 = 'SURFACE' lig2 'PLANE' ;
  141. obj2 = 'ET' su2 sutt2 ;
  142. *
  143. obj = 'ET' obj1 obj2 ;
  144. 'ELIMINATION' egeom obj ;
  145. cobj = 'CONTOUR' obj ;
  146. *
  147. * Levres de la fissure
  148. *
  149. ls = cobj 'ELEM' 'COMP' p11 pf1 ;
  150. li = cobj 'ELEM' 'COMP' pf1 p12 ;
  151. *-----------DEFINITION DU MATERIAU-------------------;
  152. objmod = 'MODELISER' obj 'MECANIQUE' 'ELASTIQUE'
  153. 'ISOTROPE' ;
  154. objmat = 'MATERIAU' objmod 'YOUN' 2.D5 'NU ' 0.3D0 ;
  155. *-----------MATRICE DE RIGIDITE----------------------;
  156. rig = 'RIGIDITE' objmat objmod ;
  157. *--------------CONDITIONS AUX LIMITES----------------;
  158. cal = 'ET' ('BLOQUE' 'UX' 'UY' p0)
  159. ('BLOQUE' 'UY' p2) ;
  160. rigtot = 'ET' rig cal ;
  161. *-----------DEFINITION DU CHARGEMENT-----------------;
  162. f1 = 'PRES' 'MASS' objmod -10.D0 lg ;
  163. f2 = 'PRES' 'MASS' objmod -10.D0 ld ;
  164. f0 = 'ET' f1 f2 ;
  165. *-----------RESOLUTION ET CONTRAINTES----------------;
  166. u0 = 'RESO' rigtot f0 ;
  167. sig0 = 'SIGMA' objmod objmat u0 ;
  168.  
  169. **********************************************
  170. ** fabrication de déplacements THETA et PI ***
  171. **********************************************
  172.  
  173. SUPTAB = 'TABLE' ;
  174. SUPTAB . 'OBJECTIF' = 'MOT' 'DECOUPLAGE' ;
  175. SUPTAB . 'LEVRE_SUPERIEURE' = ls ;
  176. SUPTAB . 'LEVRE_INFERIEURE' = li ;
  177. SUPTAB . 'FRONT_FISSURE' = pf1 ;
  178. SUPTAB . 'MODELE' = objmod ;
  179. SUPTAB . 'CARACTERISTIQUES' = objmat ;
  180. SUPTAB . 'SOLUTION_RESO' = u0 ;
  181. SUPTAB . 'CHARGEMENTS_MECANIQUES' = f0 ;
  182. SUPTAB . 'COUCHE' = 6 ;
  183. G_THETA SUPTAB ;
  184.  
  185. **********************************************
  186. ************ Affichage des résultats *********
  187. **********************************************
  188.  
  189. K1 = SUPTAB . 'RESULTATS' . 'I' ;
  190. K2 = SUPTAB . 'RESULTATS' . 'II' ;
  191. 'MESSAGE' 'K1 = ' K1 'K2 = ' K2 ;
  192. ER1 = 'ABS' (((K1 '-' 150.37D0) '/' 150.37D0) '*'
  193. 100.D0) ;
  194. ER2 = 'ABS' (((K2 '+' 71.4D0) '/' 71.4D0) '*'
  195. 100.D0) ;
  196. 'MESSAGE' 'ER1 = ' ER1 'ER2 = ' ER2 ;
  197. 'SI' ((ER1 '>' 2.D0) 'OU' (ER2 '>' 2.D0)) ;
  198. 'ERREUR' 5 ;
  199. 'SINON' ;
  200. 'ERREUR' 0 ;
  201. 'FINSI' ;
  202. 'FIN' ;
  203.  
  204.  
  205.  
  206.  
  207.  
  208.  
  209.  
  210.  
  211.  
  212.  
  213.  
  214.  
  215.  
  216.  
  217.  
  218.  
  219.  
  220.  
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales