Télécharger rupt6.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Rupt6.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. *******************************************************
  8. *** CALCUL DU FACTEUR D'INTENSITE DE CONTRAINTES ****
  9. *** PAR LA METHODE DES DEPLACEMENTS ET PAR LA ****
  10. *** METHODE G_THETA POUR UNE FISSURE CIRCULAIRE ****
  11. *** PLANE DANS UN MILIEU INFINI CHARGE EN ****
  12. *** TRACTION UNIFORME ****
  13. *** HAUTEUR DU CYLINDRE : 200 mm ; ****
  14. *** RAYON : 100 mm ****
  15. *** RAYON DE FISSURE : 8 mm ; ****
  16. *** CONTRAINTE UNIFORME : 200 daN / mm2 ****
  17. *** MODELISATION : TRANCHE DE 15° DE LA 1/2 ****
  18. *** HAUTEUR DU CYLINDRE ****
  19. *******************************************************
  20. option echo 1 dime 3 elem cu20 mode trid ;
  21.  
  22. **----------------- MAILLAGE ------------------;
  23. dens 0.5 ;
  24. oeilz = -500 500 -500 ;
  25. oeilx = -500 00 00 ;
  26. a0 = 8 ;
  27. c0 = 16. ;
  28. b0 = 100. ;
  29. p0 = 0 0 0 ;
  30. pa = a0 0 0 ;
  31. pb = 0 a0 0 ;
  32. pa1 =(1.5*a0) 0 0 ;
  33. pa0 =(0.5*a0) 0 0 ;
  34. pb0 = 0 (0.5*a0) 0 ;
  35. pb1 = 0 (1.5*a0) 0 ;
  36.  
  37. * nbrz nombre d element autour du front de fissu;
  38. nbrz = 6 ;
  39.  
  40. *MAILLAGE DU FRONT DE FISURE ;
  41.  
  42. pbz= (0. a0 (0.5*a0)) ;
  43. pbz1=(0. (a0 *(1.- (0.5 / nbrz))) 0.) ;
  44. pbz2=(0. a0 (0.5*a0/ nbrz)) ;
  45. pbz3=(0. (a0 *(1.+ (0.5 / nbrz))) 0.) ;
  46. aa = a0*0.5 * (2**-0.5) ;
  47. pmi1= 0. (a0 + aa) aa ;
  48. pmi2= 0. (a0 - aa) aa ;
  49.  
  50. cc11a = c (2) pb1 pb pmi1 ;
  51. cc11b = c (2) pmi1 pb pbz ;
  52. cc11 = cc11a et cc11b ;
  53.  
  54.  
  55. cc12a = c (2) pbz pb pmi2 ;
  56. cc12b = c (2) pmi2 pb pb0 ;
  57. cc12 = cc12a et cc12b ;
  58.  
  59. cc1 = cc11 et cc12 ;
  60.  
  61. cc21 = c (4) pbz1 pb pbz2 ;
  62. cc22 = c (4) pbz2 pb pbz3 ;
  63. cc2 = cc21 et cc22 ;
  64.  
  65. ligz = d (nbrz - 1) pb0 pbz1 ;
  66. ligz1= d (nbrz - 1) pbz3 pb1 ;
  67. ligz2= d (nbrz - 1) pbz pbz2 ;
  68. scz1 = dall cc11 ligz2 cc22 ligz1 ;
  69. scz2 = dall cc12 ligz cc21 (inve ligz2) ;
  70.  
  71. scz1=scz1 et (cout cc22 pb) ;
  72. scz2=scz2 et (cout cc21 pb) ;
  73. scz =scz1 et scz2 ;
  74. elim (scz1 et scz2) 0.001 ;
  75.  
  76. * SURFACE YZ ;
  77. pfinay = 0. b0 0. ;
  78. pfinaz = 0. 2.5 b0 ;
  79. pfinayz= 0. b0 b0 ;
  80. pinter = 0. (2*c0) b0 ;
  81. pp = 0. a0 a0 ;
  82. pz = 0. 2.5 a0 ;
  83. p00= 0. 2.5 0. ;
  84. ppp= 0. (2*a0) 0. ;
  85. ppyz= 0. (2*a0) a0 ;
  86.  
  87. l0a= d (1) pb1 ppp ;
  88. l0b= d (6) ppp pfinay ;
  89. l0 = l0a et l0b ;
  90. l1 = d (2) pfinay pfinayz ;
  91. l1bisa = d (6) pfinayz ppyz ;
  92. l1bisb = d (1) ppyz pmi1 ;
  93. l1bis = l1bisa et l1bisb ;
  94. l2 = d (2) pfinayz pinter ;
  95. l3a = d (6) pinter pp ;
  96. l3b = d (1) pp pbz ;
  97. l3 = l3a et l3b ;
  98. zaa = dall (inve cc11a) l0 l1 l1bis ;
  99. zab = dall l1bis cc11b (inve l3) (inve l2) ;
  100. za = zaa et zab ;
  101.  
  102. g2= d (1) pb0 p00 ;
  103. g3= d (2) p00 pz ;
  104. g4= d (2) pz pp ;
  105. zb =dall (g4 et g3) g2 cc12 l3b ;
  106.  
  107. h1 = d (2) pinter pfinaz ;
  108. h2 = d (6) pfinaz pz ;
  109. zc = dall h2 g4 l3a h1 ;
  110.  
  111. scr1 = h2 et (inve g3) ;
  112.  
  113. *CREATION DU VOLUME ;
  114. scr1 = scr1 rota 1 (15) (0. 0 -500)
  115. (0 0 500.) coul roug ;
  116.  
  117. geo1 = za volu 1 'ROTA' (15)
  118. (0. 0. -500) (0. 0. 500.) ;
  119.  
  120. geo2 = (zb et zc) volu 1 'ROTA' (15)
  121. (0. 0. -500) (0. 0. 500.) ;
  122.  
  123. geo3 = scz1 volu 1 'ROTA' (15)
  124. (0. 0. -500) (0. 0. 500.) ;
  125. geo4 = scz2 volu 1 'ROTA' (15)
  126. (0. 0. -500) (0. 0. 500.) ;
  127. i = face 3 geo3 ;
  128. i = i et (face 3 geo4) ;
  129.  
  130. pppp = i poin cylin (0 0 -100) (0 0 100) pb ;
  131. aa0= elem i appu larg pppp ;
  132. aa1= poin aa0 plan p0 (0. 100 0.) (100 0 0) ;
  133. cfis = elem aa0 appu stric aa1 ;
  134. a1 = enve geo3 ;
  135. a2 = enve geo4 ;
  136. aa1= poin a1 plan p0 (0. 100 0.) (100 0 0) ;
  137. aa2= poin a2 plan p0 (0. 100 0.) (100 0 0) ;
  138. aa11 = elem a1 appu stric aa1 ;
  139. aa21 = elem a2 appu stric aa2 ;
  140. aa12 = cont aa11 ;
  141. aa22 = cont aa21 ;
  142. elim (aa12 et aa22) 0.001 ;
  143. cfissure = elem aa12 appu stric aa22;
  144.  
  145. geo = geo1 et geo2 et geo3 et geo4 ;
  146.  
  147. elim (geo et scr1 et cfissure et cfis) 0.001 ;
  148.  
  149. *FINITION DU MAILLAGE ;
  150. *pres de l axe z ;
  151. c1 = cote (2) scr1 ;
  152. pfi = c1 poin final ;
  153. c1x = droi (1) pfi p0 ;
  154. b1 = droi (1) p00 p0 ;
  155.  
  156. su0 = surf ( c1x et c1 et b1) plane ;
  157. su1 = su0 volu (2) tran (0. 0. a0) ;
  158. ss = su0 plus (0. 0. b0) ;
  159. su2= ss volu (6) tran (0. 0. (a0 - b0)) ;
  160. su = su1 et su2 coul vert ;
  161.  
  162. *le cylindre en entier ;
  163. cub = geo et su ;
  164. elim cub 0.001 ;
  165. cub = rege cub ;
  166. tot = enve cub ;
  167.  
  168. *surface yz ;
  169. poyz = poin tot plan p0 (0. 100 100) (0. 0. 100);
  170. suryz = elem tot appu stric poyz ;
  171.  
  172. *surface z=100 ;
  173. poz100= poin tot plan (0. 0. 100)
  174. (100 0. 100) (0. 100 100) ;
  175. surzz = elem tot appu stric poz100 ;
  176.  
  177. *surfac xy ;
  178. poxy = poin tot plan p0 (0. 100 0.) (100 0 0) ;
  179. surxy= elem tot appu stric poxy ;
  180. az = geo2 et geo4 et su ;
  181. az = enve az ;
  182. aze= az poin plan p0 (0. 100 0.) (100 0 0) ;
  183. aze=elem az appu stric aze ;
  184. co = cont aze;
  185. aze = surxy incl aze;
  186. facxy = surxy diff aze;
  187.  
  188. *--------------CONDITION DE SYMETRIE------------;
  189. p = ((-1 * b0 * (sin 15)) (b0 * (cos 15)) 0.);
  190. condi1 =symt depl p0 (0. 0. b0) p cub 0.01;
  191. condi2 =symt depl p0 pfinay pfinayz suryz;
  192. condi3 =symt depl p0 (b0 b0 0.) (b0 0. 0.) facxy;
  193. condit = condi1 et condi2 et condi3 ;
  194.  
  195. *----------- CREATION DU MODELE ----------------;
  196.  
  197. affe1 = MODE geo1 mecanique elastique isotrope;
  198. affe2 = MODE geo2 mecanique elastique isotrope;
  199. affe3 = MODE geo3 mecanique elastique isotrope;
  200. affe4 = MODE geo4 mecanique elastique isotrope;
  201. affe5 = MODE su mecanique elastique isotrope;
  202.  
  203. affetot = affe1 et affe2 et
  204. affe3 et affe4 et affe5 ;
  205.  
  206. *---------DEFINITION DU MATERIAU ---------------;
  207.  
  208. mate1 = MATE affe1
  209. young 20000.
  210. nu 0.3 ;
  211. mate2 = MATE affe2
  212. young 20000.
  213. nu 0.3 ;
  214. mate3 = MATE affe3
  215. young 20000.
  216. nu 0.3 ;
  217. mate4 = MATE affe4
  218. young 20000.
  219. nu 0.3 ;
  220. mate5 = MATE affe5
  221. young 20000.
  222. nu 0.3 ;
  223. matot = mate1 et mate2 et
  224. mate3 et mate4 et mate5 ;
  225.  
  226. *----------------RIGIDITE-----------------------;
  227.  
  228. rig1 = (rigidite matot affetot) et condit ;
  229. rig2 = bloque uz surzz ;
  230. fo1 = depi rig2 1. ;
  231.  
  232. *------------RESOLUTION ET CONTRAINTES----------;
  233. dep = resou (rig1 et rig2) fo1 ;
  234. sig = sigma matot affetot dep ;
  235.  
  236.  
  237. *----CALCUL DU FACTEUR D'INTENSITE DE CONTRAINTES----*
  238. *----initialisations des paramètres de procedure-----*
  239. SUPTAB = TABLE;
  240. SUPTAB.'MAILLAGE' = cub;
  241. SUPTAB.'PSF1' = P0;
  242. SUPTAB.'FRTFISS' = elem aa12 appu stri aa22;
  243.  
  244. *-----APPEL DE LA PROCEDURE SIF ----------------------*
  245. SIF SUPTAB MATOT dep;
  246.  
  247. *-----APPEL DE LA PROCEDURE G_THETA ------------------*
  248.  
  249. TABG1 = TABLE;
  250. TABG1.'OBJECTIF' = MOT 'J';
  251. TABG1.'COUCHE' = 3;
  252. TABG1.'FRONT_FISSURE' = cfissure;
  253. TABG1.'LEVRE_SUPERIEURE' = aa21 ;
  254. TABG1.'MODELE' = affetot;
  255. TABG1.'SOLUTION_RESO' = dep;
  256. TABG1.'CHARGEMENTS_MECANIQUES' = fo1;
  257. TABG1.'CARACTERISTIQUES' = matot;
  258. G_THETA TABG1;
  259. SAUT 1 LIGNE;
  260. *******************************************************
  261. ******** DEPOUILLEMENT PROCEDURE SIF *************
  262. *******************************************************
  263. T = INDEX (SUPTAB.K1);
  264. MESS 'K1 NOEUD 1 DU FRONT DE FISSURE (NOEUD SOMMET) : '
  265. SUPTAB.K1.(T.1);
  266. MESS 'K1 NOEUD 2 DU FRONT DE FISSURE (NOEUD MILIEU) : '
  267. SUPTAB.K1.(T.2);
  268. *---------TEST D'ERREUR-----------------------------*
  269. EC1 = ((SUPTAB.K1.(T.1)) - 638.47) /
  270. (SUPTAB.K1.(T.1)) * 100;
  271. EC2 = ((SUPTAB.K1.(T.2)) - 638.47) /
  272. (SUPTAB.K1.(T.2)) * 100;
  273.  
  274. SI ((EC1 < 5.5) ET (EC2 < 11)) ;
  275. MESS 'PROCEDURE <SIF> ERR 0';
  276. ERRE 0;
  277. SINON;
  278. MESS 'PROCEDURE <SIF> ERR 5';
  279. ERRE 5;
  280. FINSI;
  281. *******************************************************
  282. ******** DEPOUILLEMENT PROCEDURE G_THETA *********
  283. *******************************************************
  284. TBG = TABG1.'RESULTATS';
  285. IND1 = INDE TBG;
  286. GSOM = TBG.(IND1.1);
  287. GMIL = TBG.(IND1.2);
  288. EPRI = 20000. / 0.91;
  289. KSOM = (GSOM * EPRI) ** 0.5;
  290. KMIL = (GMIL * EPRI) ** 0.5;
  291. SAUT 1 LIGNE;
  292. MESS 'K1 NOEUD 1 DU FRONT DE FISSURE (NOEUD SOMMET) : '
  293. KSOM;
  294. MESS 'K1 NOEUD 2 DU FRONT DE FISSURE (NOEUD MILIEU) : '
  295. KMIL;
  296. *---------TEST D'ERREUR-----------------------------*
  297. EC1 = ABS (((KSOM - 638.47) / KSOM) * 100);
  298. EC2 = ABS (((KMIL - 638.47) / KMIL) * 100);
  299.  
  300. SI ((EC1 < 0.9) ET (EC2 < 0.8)) ;
  301. MESS 'PROCEDURE <G_THETA> ERR 0';
  302. ERRE 0;
  303. SINON;
  304. MESS 'PROCEDURE <G_THETA> ERR 5';
  305. ERRE 5;
  306. FINSI;
  307. FIN;
  308.  
  309.  
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales