Télécharger rupt2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Rupt2.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. OPTION echo 1 ;
  8. GRAPH = 'N' ;
  9. SAUT PAGE ;
  10. * ;
  11. ******************************************************;
  12. * ;
  13. * ;
  14. * QUALIFICATION DU CALCUL DE G ;
  15. * EN THERMO-ELASTICITE LINEAIRE ;
  16. * SUR UNE PLAQUE A FISSURE LATERALE ;
  17. * EVALUATION DU FACTEUR DE FORME ;
  18. * ;
  19. * ;
  20. * le calcul est compare a celui obtenu par ;
  21. * WILSON et YU ;
  22. * dans The use of J-Integral in thermal stress crack ;
  23. * problems international Journal of Fracture (1979) ;
  24. * ;
  25. ******************************************************;
  26. * ;
  27. OPTION DIME 2 ELEM QUA8 MODE PLAN DEFO ;
  28. * ;
  29. *----------------- DEFINITION DU MAILLAGE ------------;
  30. * ;
  31. a = 100. ; b = 200. ; h = 400. ;t = a / 100. ;
  32. densite t ; pf = (a 0.) ;
  33. c1 = (c ( pf moin (t 0.)) pf ( pf plus (0. t)))
  34. c pf ( pf plus (t 0.)) ;
  35. sf = cout pf c1;
  36. r1 = t ; rr1 = t ;
  37. repeter bhomo 7;
  38. ri = r1 + ( 0.3 * r1 ) ;
  39. rri = rr1 + ri ;
  40. dens ri ;
  41. ci = ( c ( pf moin (rri 0.)) pf ( pf plus (0. rri)))
  42. c pf ( pf plus (rri 0.)) ;
  43. sf = sf et ( cout c1 ci ) ;
  44. c1 = ci ; r1 = ri ; rr1 = rri ;
  45. fin bhomo ;
  46. dens (a / 3.) ;
  47. p0 = (0. 0.) ; p1 = (b 0.) ;
  48. p2 = p0 plus (0. a) ; p3 = p1 plus (0. a) ;
  49. pi1 = ci poin 1 ; l1 = pi1 d p0 ;
  50. n = (nbel l1) * -1 ;
  51. pi2 = ci poin 4 ; l2 = pi2 d n p2 ;
  52. pi3 = ci poin 10 ; l3 = pi3 d n p3 ;
  53. pi4 = ci poin 13 ; l4 = pi4 d p1 ;
  54. ci = inve ci ;ligh = p2 d p3 ;
  55. sc1 = dall l1 (p0 d p2) (inve l2) (ci ELEM comp pi2 pi1) ;
  56. sc2 = dall l2 ligh (inve l3) (ci ELEM comp pi3 pi2) ;
  57. sc3 = dall l3 (p3 d p1) (inve l4) (ci ELEM comp pi4 pi3) ;
  58. sc = sc1 et sc2 et sc3 ;
  59. dens (a / 2.) ;
  60. mrest = ligh tran (0. (h - a)) dini (a / 2.) ;
  61. lihaut = mrest cote 3 ;
  62. phd = lihaut poin init ;
  63. ccp = sf et sc et mrest ;
  64. elim ccp 0.001 ;
  65. cccp = cont ccp ;
  66. lifis = cccp ELEM comp pf p0 ;
  67. libas = cccp ELEM comp p1 pf ;
  68. * ;
  69. *------------------- CREATION DU MODELE --------------;
  70. * ;
  71. objaf = MODE ccp mecanique elastique isotrope ;
  72. * ;
  73. *---------- DEFINITION DES CARACTERISTIQUES ----------;
  74. *---------- MATERIELLES ET GEOMETRIQUES ----------;
  75. * ;
  76. mat = MATE objaf YOUN 2.e4 NU 0.3 ALPH 5.e-6 ;
  77. * ;
  78. *---------- CALCUL DES RIGIDITES ELEMENTAIRES --------;
  79. *--------- ET DEFINITION DES BLOCAGES ---------;
  80. * ;
  81. rig = rigi objaf mat ;
  82. cdl1 = bloq Uy libas ;
  83. cdl2 = bloq Uy lihaut ;
  84. cdl3 = bloq Ux phd ;
  85. * ;
  86. *-------- DEFINITION DU CHAMP DE TEMPERATURES --------;
  87. * ;
  88. chx = coor 1 ccp ;
  89. cha = manu chpo ccp 1 scal a ;
  90. chx = nomc 'T' (chx - cha) ;
  91. cht = chx * (100. / a) ;
  92. ch0 = 0 * cht ;
  93. sigth = thet MAT objaf cht ;
  94.  
  95. * ;
  96. *-------- RESOLUTION ET CALCUL DES CONTRAINTES -------;
  97. * ;
  98. U = reso (rig et cdl1 et cdl2 et cdl3 )
  99. (bsig objaf sigth) ;
  100. SIG = sigm mat objaf U ;
  101. SIG = SIG - sigth ;
  102. sigy = exco SIG smyy ;
  103. SI ( NEG GRAPH 'N' ) ;
  104. TRAC CCP ;
  105. TRAC SIGY OBJAF CCP ;
  106. FINSI ;
  107. * ;
  108. *------ INITIALISATION DE LA TABLE EN ENTREE ---------;
  109. *---- DE LA PROCEDURE G_THETA ----------;
  110. * ;
  111. SUPTAB = TABLE ;
  112. SUPTAB.'OBJECTIF' = MOT 'J';
  113. SUPTAB.'LEVRE_SUPERIEURE' = lifis;
  114. SUPTAB.'FRONT_FISSURE' = PF ;
  115. SUPTAB.'MODELE' = objaf;
  116. SUPTAB.'CARACTERISTIQUES' = mat;
  117. SUPTAB.'SOLUTION_RESO' = u;
  118. SUPTAB.'TEMPERATURES' = cht;
  119. SUPTAB.'COUCHE' = 4;
  120. * ;
  121. *----------- APPEL A LA PROCEDURE G_THETA ------------;
  122. * ;
  123. SAUT PAGE ;
  124. G_THETA suptab ;
  125. * ;
  126. *------ RECUPERATION DU RESULTAT ET COMPARAISONS -----;
  127. * ;
  128. G = suptab.'RESULTATS' ;
  129. K = (20000. * G / (1 - (0.3**2)))**0.5 ;
  130. F = K * (1 - 0.3) /
  131. ( 20000 * 5.e-6 * 100 * ((100*pi)**0.5)) ;
  132. mess 'taux de restitution energetique G :' G ;
  133. mess 'coefficient d intensite de contrainte K :' K ;
  134. mess 'facteur de forme calcule Fcal :' F ;
  135. 'facteur de forme analytique Fthe :' 0.514 ;
  136. * CODE FONCTIONNEMENT ;
  137. RESI = abs (( F - 0.514 ) / 0.514 ) ;
  138. SI (RESI < 5E-2) ;
  139. ERRE 0 ;
  140. SINO ;
  141. ERRE 5 ;
  142. FINSI ;
  143. fin;
  144.  
  145.  
  146.  
  147.  
  148.  
  149.  
  150.  
  151.  
  152.  
  153.  
  154.  
  155.  
  156.  
  157.  
  158.  
  159.  
  160.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales