Télécharger rupt17.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt17.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. **************************************************************
  5. *
  6. * rupt17.dgibi
  7. *
  8. * CAS TEST SUR LE CALCUL DE J EN THERMOPLASTICITE
  9. * POUR FISSURE PROCHE (ou SUR) INTERFACE LIAISON BIMETALLIQUE
  10. *
  11. * CREATION : BP, 11 Aout 2011
  12. * MODIFS :
  13. *
  14. * REM : - la presence de decharges induit une legere dependance au contour
  15. * - fissure parallele a linterface => pas besoin du 'MODELES_COMPOSITES'
  16. *
  17. **************************************************************
  18.  
  19.  
  20. *******************************************************
  21. *** Options de calcul et de tracés
  22.  
  23. OPTI DIME 2 ELEM QUA8 MODE plan defo ;
  24.  
  25.  
  26. *calcul elastique?
  27. * calel = vrai ;
  28. calel = faux ;
  29.  
  30. * Complet => modif de la finesse du maillage + du pas de chargement
  31. COMPLET = faux;
  32. * COMPLET = vrai;
  33.  
  34. * options de tracé
  35. GRAPH = faux ;
  36. *opti 'TRAC' 'PSC' 'EPTR' 5;
  37.  
  38.  
  39. *******************************************************
  40. *** Géométrie
  41.  
  42. dxelim = 1e-6 ;
  43. h = 100. ;
  44. W = 100. ;
  45. hint = 50. ;
  46. hfis = 34. ;
  47. * hfis = 50. ;
  48. * avec hfis = 50., on a la fissure dans l'interface (à tester + tard)
  49. asW = 0.5 ;
  50.  
  51.  
  52. **********************************************************************
  53. *** Données matériau
  54.  
  55. *--- Données de l'acier inox 304L (20 et 350°C)
  56. lT11 = prog 20. 350. ;
  57. lE1 = prog 197. 172. ;
  58. evE1 = evol manu 'T' lT11 'YOUN' (lE1*1e3) ;
  59. *
  60. lep201 = prog 0. 0.0006935 0.00104 0.00140
  61. 0.00198 0.00305 0.00511 0.00716 0.0112 0.0163 0.0315
  62. 0.0516 0.1020 0.152 0.303 0.503 1.004 5.006 ;
  63. lsi201 = prog 0. 136.6 165.6 178.0 192.5 207.0
  64. 219.4 227.7 240.1 254.6 287.7 323.2 391.8 456.2 545.3
  65. 630.4 767.5 1212.0 ;
  66. * Conversion courbe traction > ecrouissage
  67. lsi201 = lsi201 enle 1 ;
  68. lep201 = (lep201 enle 1) - (lsi201 / (eve1 ipol 20.)) born mini 0. ;
  69. ta201 = evol manu lep201 lsi201 ;
  70. *
  71. le3501 = prog 0. 0.0006347 0.00087 0.00119
  72. 0.00171 0.00274 0.00478 0.00682 0.0109 0.0159 0.0311
  73. 0.0513 0.1017 0.152 0.303 0.503 1.004 5.006 ;
  74. ls3501 = prog 0. 109.2 115.6 118.1 121.9 127.0
  75. 134.6 141.0 151.1 161.3 189.2 221.8 290.5 354.8 443.9
  76. 529.0 666.1 1110.6 ;
  77. * Conversion courbe traction > ecrouissage
  78. ls3501 = ls3501 enle 1 ;
  79. le3501 = (le3501 enle 1) - (ls3501 / (eve1 ipol 350.)) born mini 0. ;
  80. ta3501 = evol manu le3501 ls3501 ;
  81. *
  82. CTrac1 = NUAGE 'COMP' 'T' 20. 350.
  83. 'COMP' 'ECRO' ta201 ta3501 ;
  84.  
  85. *--- Données des aciers 16 et 18MND5 (20 - 350°C)
  86. lT12 = prog 20. 350. ;
  87. lE2 = prog 204. 180. ;
  88. evE2 = evol manu 'T' lT12 'YOUN' (lE2*1e3) ;
  89. * dans le cas COMPLET pb avec la pente de lsi202
  90. * lep202 = prog 0. 0.001691 0.001891 0.00219 0.00269
  91. * 0.00369 0.00569 0.00769 0.00969 0.0117 0.0168 0.0219
  92. * 0.0320 0.0421 0.0522 0.0623 0.0723 0.0823 0.0924
  93. * 0.102 0.303 1.00 5.00 ;
  94. * lsi202 = prog 0. 345 345 345 345 345 345 345 345 355.4
  95. * 372.6 386.4 410.6 434.2 448.1 461.2 470.8 477.7
  96. * 484.6 491.6 570.9 671.5 834.2 ;
  97. * lep202 = prog 0. 0.001691 0.00969 0.0117 0.0168 0.0219
  98. * 0.0320 0.0421 0.0522 0.0623 0.0723 0.0823 0.0924
  99. * 0.102 0.303 1.00 5.00 ;
  100. * lsi202 = prog 0. 345 346 355.4
  101. * 372.6 386.4 410.6 434.2 448.1 461.2 470.8 477.7
  102. * 484.6 491.6 570.9 671.5 834.2 ;
  103. lep202 = prog 0. (0.300/204.) 0.002 0.0025 0.008 0.0117
  104. 0.0168 0.0219
  105. 0.0320 0.0421 0.0522 0.0623 0.0723 0.0823 0.0924
  106. 0.102 0.303 1.00 5.00 ;
  107. lsi202 = prog 0. 300. 320. 330. 345. 355.4
  108. 372.6 386.4 410.6 434.2 448.1 461.2 470.8 477.7
  109. 484.6 491.6 570.9 671.5 834.2 ;
  110. * Conversion courbe traction > ecrouissage
  111. lsi202 = lsi202 enle 1 ;
  112. lep202 = (lep202 enle 1) - (lsi202 / (eve1 ipol 20.)) born mini 0. ;
  113. ta202 = evol manu lep202 lsi202 ;
  114. *
  115. le3502 = prog 0. 0.001423 0.001679 0.00206 0.0026
  116. 0.00366 0.00573 0.00778 0.00983 0.0119 0.0169 0.0220
  117. 0.0321 0.0422 0.0523 0.0623 0.0724 0.0824 0.0925
  118. 0.102 0.303 1.00 5.00 ;
  119. ls3502 = prog 0. 256.2 266.1 281.0 290.0 299.0 310.9
  120. 319.9 328.9 334.9 349.8 364.8 385.7 400.2 412.3 422.9
  121. 429.0 435.0 441.0 447.0 509.0 586.7 709.3 ;
  122. * Conversion courbe traction > ecrouissage
  123. ls3502 = ls3502 enle 1 ;
  124. le3502 = (le3502 enle 1) - (ls3502 / (eve1 ipol 350.)) born mini 0. ;
  125. ta3502 = evol manu le3502 ls3502 ;
  126. *
  127. CTrac2 = NUAGE 'COMP' 'T' 20. 350.
  128. 'COMP' 'ECRO' ta202 ta3502 ;
  129.  
  130. si(GRAPH);
  131. titr ' Courbes d ecrouissage ' ;
  132. tleg1 = table ;
  133. tleg1 . titre = table ;
  134. tleg1 . titre . 1 = ' 304L a 20 degC' ;
  135. tleg1 . titre . 2 = ' 304L a 350 degC' ;
  136. tleg1 . titre . 3 = ' 18MND5 a 20 degC' ;
  137. tleg1 . titre . 4 = ' 18MND5 a 20 degC' ;
  138. dess ((coul ta201 bleu) et (ta3501 coul roug)
  139. et (coul ta202 turq) et (ta3502 coul rose)) lege tleg1 ;
  140. dess ((coul ta201 bleu) et (ta3501 coul roug)
  141. et (coul ta202 turq) et (ta3502 coul rose))
  142. 'XBOR' 0. 0.02 lege tleg1 ;
  143. fins;
  144.  
  145.  
  146. *******************************************************
  147. *** Maillage
  148.  
  149. si(COMPLET); nW = 50 ;
  150. sino; nW = 24;
  151. fins;
  152. nhF = enti (nW * (h - hint) / h) ;
  153.  
  154. P1 = 0. (-0.5 * h) ;
  155. P2 = W (-0.5 * h) ;
  156. l1 = P1 d nW p2 ;
  157.  
  158. si (hfis ega hint) ;
  159. nhA = enti (nW * hint / h) ;
  160. SA = l1 tran nhA (0. hint) ;
  161. l2 = l1 plus (0. hint) ;
  162. SF = l2 tran nhF (0. (h - hint)) ;
  163. pfis = l2 point proc ((asW * W) (hint - (0.5 * h))) ;
  164. p3 = l2 point proc (W (hint - (0.5 * h))) ;
  165. llig = l2 elem comp pfis p3 ;
  166. elim dxelim (llig et SA) ;
  167. l3 = l1 plus (0. h) ;
  168. elim dxelim (SF et l3) ;
  169. levF = diff l2 llig ;
  170. levA = levF plus (0. 0.) ;
  171. elim dxelim (SA et levA) ;
  172. sinon ;
  173. nhA = enti (nW * hfis / h) ;
  174. SA1 = l1 tran nhA (0. hfis) ;
  175. l2 = l1 plus (0. hfis) ;
  176. SA2 = l2 tran (nhF - nhA) (0. (hint - hfis)) ;
  177. l4 = l1 plus (0. hint) ;
  178. SF = l4 tran nhF (0. (h - hint)) ;
  179. pfis = l2 point proc ((asW * W) (hint - (0.5 * h))) ;
  180. p3 = l2 point proc (W (hint - (0.5 * h))) ;
  181. llig = l2 elem comp pfis p3 ;
  182. elim dxelim (llig et SA1) ;
  183. l3 = l1 plus (0. h) ;
  184. elim dxelim (SF et l3) ;
  185. levF = diff l2 llig ;
  186. levA = levF plus (0. 0.) ;
  187. elim dxelim (SA1 et levA) ;
  188. elim dxelim (SA2 et SF) ;
  189. SA = SA1 et SA2 ;
  190. finsi ;
  191.  
  192. plaq = (SA coul bleu) et (SF coul roug) ;
  193. si(GRAPH);trac plaq ;fins;
  194.  
  195.  
  196. *******************************************************
  197. *** MODELE MECANIQUE
  198.  
  199.  
  200. *--- Modèle elastique ou elasto plastique ?
  201. si calel ;
  202. mo316 = MODELE sa MECANIQUE ELASTIQUE ISOTROPE ;
  203. mo508 = MODELE sf MECANIQUE ELASTIQUE ISOTROPE ;
  204. ma316 = materiau mo316 young evE1 nu 0.3 alph 1E-5 talp 0. tref 20. ;
  205. ma508 = materiau mo508 young evE2 nu 0.3 alph 1E-5 talp 0. tref 20. ;
  206. sinon ;
  207. mo316 = MODELE sa MECANIQUE ELASTIQUE plastique ;
  208. mo508 = MODELE sf MECANIQUE ELASTIQUE plastique ;
  209. ma316 = materiau mo316 young evE1 nu 0.3 alph 1E-5 talp 0. tref 20. ecro CTrac1 ;
  210. ma508 = materiau mo508 young evE2 nu 0.3 alph 1E-5 talp 0. tref 20. ecro CTrac2 ;
  211. finsi ;
  212. mo = mo316 et mo508 ;
  213. ma = ma316 et ma508 ;
  214.  
  215. * ----- CONDITIONS LIMITES
  216. cd1 = bloq l1 UY ;
  217. cd2 = RELA ENSE UY l3 ;
  218. cd3 = bloq pfis UX ;
  219. cdl = cd1 et cd2 et cd3 ;
  220.  
  221. *----- Chargement
  222. lx1 = prog 0. 1. ;
  223. ly1 = prog 0. 1. ;
  224. ev1 = evol manu lx1 ly1 ;
  225. PRES1 = PRES MASS mo (-100.) l3 ;
  226. *PRES1 = PRES MASS mo dxelim l3 ;
  227. CHAP = CHAR MECA PRES1 ev1 ;
  228.  
  229. * ----- Définition de la temperature
  230. Ti = 20. ; Tf = 350. ;
  231. chT1 = manu chpo plaq 1 'T' Ti ;
  232. chx = plaq coor 1 ;
  233. chT2 = chT1 - (nomc 'T' (chx / W * (Ti - Tf))) ;
  234. TT1 = table ; TT1 . 0 = 0. ; TT1 . 1 = 1. ;
  235. TT2 = table ; TT2 . 0 = chT1 ; TT2 . 1 = chT2 ;
  236. CHAT = CHAR 'T' TT1 TT2 ;
  237.  
  238. * si (COMPLET); tcha = prog 0. 0.1 pas 0.05 1. ;
  239. si (COMPLET); tcha = prog 0. pas 0.05 1. ;
  240. sino; tcha = prog 0. pas 0.20 1. ;
  241. fins;
  242.  
  243.  
  244. *******************************************************
  245. *** PROCEDURE PAS A PAS
  246.  
  247. TAB2 = TABLE;
  248. TAB2.'MODELE' = mo ;
  249. TAB2.'CARACTERISTIQUES' = ma ;
  250. TAB2.'BLOCAGES_MECANIQUES' = cdl ;
  251. TAB2.'CHARGEMENT'= CHAP et CHAT ;
  252. TAB2.'TEMPS_CALCULES' = tcha ;
  253. TAB2.'HYPOTHESE_DEFORMATIONS' = 'LINEAIRE' ;
  254.  
  255. PASAPAS TAB2 ;
  256.  
  257. si(GRAPH);
  258.  
  259. ii = (dime tcha) - 1 ;
  260. def = defo tab2.deplacements.ii plaq ;
  261. trac chT2 def 'TITR' 'T et deformee finale';
  262.  
  263. si (non calel);
  264. var2 = TAB2 . 'VARIABLES_INTERNES' . ii;
  265. var2prg = (prog 0.) et (exp ((prog -3. PAS 0.1 -1.) * (log 10.)));
  266. trac var2 mo def var2prg 'TITR' 'variables_internes finales';
  267. fins;
  268.  
  269. fins;
  270.  
  271.  
  272. *******************************************************
  273. *** CALCUL DU TAUX DE RESTITUTION D'ENERGIE
  274.  
  275. *--- boucle sur les contours lnc ----------------------
  276. si(COMPLET);
  277. lnc = lect 1 2 3 5 7 8 9 11 ;
  278. lcoul = mots VIOL BLEU TURQ VERT OLIV JAUN ORAN ROUG;
  279. sino;
  280. lnc = lect 1 2 3 5 7 ;
  281. lcoul = mots BLEU TURQ VERT JAUN ROUG;
  282. fins;
  283. nlc = dime lnc ; i = 0 ;
  284. tath = table ;
  285. lJM = prog ;
  286. tath.0 = tcha ;
  287.  
  288. repeter bloc1 nlc ;
  289. i = i + 1 ;
  290. ncou = extr lnc i;
  291.  
  292. SUPTAB = TABLE ;
  293. SUPTAB.'OBJECTIF'= 'J';
  294. SUPTAB.'LEVRE_SUPERIEURE' = levF ;
  295. SUPTAB.'LEVRE_INFERIEURE' = levA;
  296. SUPTAB.'COUCHE' = ncou ;
  297. SUPTAB.'FRONT_FISSURE' = pfis ;
  298. SUPTAB.'SOLUTION_PASAPAS' = TAB2;
  299. G_THETA SUPTAB ;
  300.  
  301. si graph ;
  302. dess suptab.EVOLUTION_RESULTATS
  303. 'TITR' (chai i 'couche' ncou'(G_THETA)');
  304. fins ;
  305.  
  306. mocoul1 = extr lcoul i;
  307. si(ega i 1);
  308. evotot = coul suptab.EVOLUTION_RESULTATS mocoul1;
  309. sino;
  310. evotot = evotot et (coul suptab.EVOLUTION_RESULTATS mocoul1);
  311. fins;
  312.  
  313. tath.i = extr (suptab.EVOLUTION_RESULTATS) ordo ;
  314. Jmaxi = extr tath.i (dime tath.i);
  315. lJM = lJM et Jmaxi ;
  316.  
  317. fin bloc1 ;
  318. *--- fin de boucle sur les contours lnc ----------------------
  319.  
  320.  
  321. lel = W / nW ;
  322. evJ = evol 'BLEU' manu 'dimcouche' (lel*lnc) 'J' lJM ;
  323. si graph ;
  324. dess (evJ) 'TITR' (chai 'stabilite de J');
  325.  
  326. ybor0 = 0.;
  327. ybor1 = maxi (extr evJ 'ORDO');
  328. ybor1 = (1.1 * ybor1);
  329. tdess1 = tabl;
  330. tdess1 . 1 = mot 'MARQ PLUS';
  331. dess evJ 'YBOR' ybor0 ybor1 tdess1
  332. 'TITR' (chai 'stabilite de J');
  333.  
  334. dess evotot 'YBOR' ybor0 ybor1 'TITR' (chai 'evolution de J');
  335. fins ;
  336.  
  337. * opti donn 5 trac X ;
  338.  
  339.  
  340. *******************************************************
  341. *** TEST DE BON FONCTIONNEMENT
  342.  
  343. * valeurs testees
  344. Jmax1 = maxi lJM; Jmin1 = mini lJM;
  345. mess 'Jmax1 Jmin1=' Jmax1 Jmin1;
  346.  
  347. * bornes de references (au 11 aout 2011)
  348. si(COMPLET); Jmax0 = 75.; Jmin0 = 65.;
  349. sino; Jmax0 = 80.; Jmin0 = 70.;
  350. fins;
  351.  
  352. *test
  353. SI ((Jmax1 < Jmax0) et (Jmin1 > Jmin0));
  354. ERRE 0;
  355. SINON;
  356. ERRE 5;
  357. FINSI;
  358.  
  359.  
  360.  
  361. FIN ;
  362.  
  363.  
  364.  
  365.  
  366.  
  367.  
  368.  
  369.  
  370.  
  371.  
  372.  
  373.  
  374.  
  375.  
  376.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales