Télécharger rupt14-weib.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt14-weib.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------
  5. *----------------------------------------------------------------
  6. * *
  7. * Test du critère de Weibull pour un cylindre *
  8. * en traction modelisé en axisymétrique et en 3D *
  9. * *
  10. *----------------------------------------------------------------
  11. *----------------------------------------------------------------
  12. * *
  13. opti echo 1 ; monop=faux; ;
  14. * paramètres pour calculer sigma w *
  15. m = 22. ; v0 = 0.000125 ; sigu = 2530. ; ic = 1. ; n = 2. ;
  16. * *
  17. *****************************************************************
  18. * *
  19. * MODELE AXISYMETRIQUE *
  20. * *
  21. *****************************************************************
  22. *
  23. *****************************************************************
  24. * Maillage *
  25. *****************************************************************
  26. opti elem qua8 dime 2 mode axis ;
  27. * *
  28. * densites utilisees *
  29. l1 = 0.25 ;d1 = 50e-3 ; d2 = 120e-3 ; d11 = d1/10. ;
  30. * *
  31. * coordonnees des points *
  32. po = 0. 0. ; pb = l1 0. ; pc = 0. d1 ; pd = 0. l1 ;
  33. pa = d1 0. ;
  34. * *
  35. * definition des lignes *
  36. ligoa = droi po pa 1 ;
  37. ligab = droi pa pb 'DINI' 0.08 'DFIN' 0.12 ;
  38. ligob = ligoa et ligab ;
  39. surf1 = ligob tran 1 pc ;
  40. *
  41. lig1 = cote 3 surf1 ;
  42. * *
  43. * création de la surface *
  44. surf3 = lig1 tran 'DINI' 0.08 'DFIN' 0.12 (0. (l1-d1)) ;
  45. surf2 = surf1 et surf3 ;
  46. * *
  47. * extraction des lignes *
  48. lib = cote 1 surf2 ;
  49. lic = cote 3 surf2 ;
  50. * *
  51. elim surf2 1e-3 ;
  52. * *
  53. *****************************************************************
  54. * création du modéle *
  55. *****************************************************************
  56. mod1 = mode surf2 mecanique elastique plastique ;
  57. * *
  58. *****************************************************************
  59. * définition du matériau *
  60. *****************************************************************
  61. * *
  62. * courbe de traction *
  63. peps = prog 0. 0.0026 0.0027 0.0030 0.0035 0.0045 0.0065 0.0085
  64. 0.0105 0.0125 0.0176 0.0227 0.0329 ;
  65. psig = prog 0. 503. 503. 503. 503. 503. 503. 503. 503. 516. 538.
  66. 557. 594. ;
  67. tracevt = evol manu 'eps' peps 'sig' psig ;
  68. * *
  69. mat1 = mate mod1 youn (503./0.0026) nu 0.3 tract tracevt ;
  70. * *
  71. *****************************************************************
  72. * rigidité *
  73. *****************************************************************
  74. cdl0 = bloq uz lib ;
  75. cdl2 = bloq uz lic ;
  76. dep1 = depi cdl2 4e-3 ;
  77. forcevt = evol manu abs (prog 0. 1.) ord (prog 0. 1.) ;
  78. fo1 = char 'DIMP' dep1 forcevt ;
  79. * *
  80. *****************************************************************
  81. * definition de la table d'entree *
  82. *****************************************************************
  83. tab1 = table ;
  84. tab1.caracteristiques = mat1 ;
  85. tab1.modele = mod1 ;
  86. tab1.blocages_mecaniques = cdl0 et cdl2 ;
  87. tab1.chargement = fo1 ;
  88. tab1.temps_calcules = (prog 0. pas 0.5 1.) ;
  89. * *
  90. *****************************************************************
  91. * procedure de calcul *
  92. *****************************************************************
  93. TMASAU=table;
  94. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  95. TMASAU .'DEFTO'=VRAI;
  96. TMASAU .'DEFIN'=VRAI;
  97. tab1.'NB_EL_PARA'= 2;
  98. pasapas tab1 ;
  99. * *
  100. *****************************************************************
  101. * Calcul de la contrainte de Weibull axi *
  102. *****************************************************************
  103. * *
  104. * zone du critere *
  105. surfcrit = elem surf2 1 ;
  106. zone1 = redu mod1 surfcrit;
  107. * *
  108. enttab1 = table ;
  109. enttab1.'XMULT' = 2. ;
  110. enttab1.'OBJMO' = zone1 ;
  111. enttab1.'WEIBULL' = vrai ;
  112. enttab1.'TNONL' = tab1 ;
  113. enttab1.'M' = m ; enttab1.'V0' = v0 ; enttab1.'SIGU' = sigu ;
  114. enttab1.'IC' = ic ; enttab1.'N' = n ;
  115. enttab1.'TEMPER' = 0 ;
  116. * *
  117. sortab1 = critloc enttab1;
  118. * *
  119. sigwaxi = (sortab1.'SIGW').1. ;
  120. * *
  121. *****************************************************************
  122. * *
  123. * MODELE 3D *
  124. * *
  125. *****************************************************************
  126. *
  127. *****************************************************************
  128. * Maillage *
  129. *****************************************************************
  130. opti dime 3 elem cu20 mode trid ;
  131. * *
  132. * variables *
  133. a1 = 2**(-0.5) ;
  134. l1 = 50e-3 ; l2 = 250e-3 ; oeil = 2 -1000 300 ;
  135. * *
  136. * coordonnees des points *
  137. pb1 = 0. 0. 0. ; pba = l1 0. 0. ; pbc = 0. l1 0. ;
  138. pbb = l1 l1 0. ; pb2 = l2 0. 0. ; pb3 = (l2*a1) (l2*a1) 0. ;
  139. pb4 = 0. l2 0.; ph1 = 0. 0. l2 ;
  140. * *
  141. * densites utilisees *
  142. d1 = 80e-3 ; d2 = 120e-3 ;
  143. * *
  144. * definition des lignes *
  145. ligb1a = droit 1 pb1 pba ;
  146. ligbab = droit 1 pba pbb ;
  147. ligbbc = droit 1 pbb pbc ;
  148. ligbc1 = droit 1 pbc pb1 ;
  149. ligba2 = droit pba pb2 dini d1 dfin d2 ;
  150. ligb3b = droit 2 pb3 pbb ;
  151. ligbc4 = droit pbc pb4 dini d1 dfin d2 ;
  152. arcb23 = cerc 1 pb2 pb1 pb3 ;
  153. arcb43 = cerc 1 pb4 pb1 pb3 ;
  154. * *
  155. * definition de la surface du bas *
  156. surfb1 = dall ligb1a ligbab ligbbc ligbc1 plan ;
  157. surfb2 = dall ligb3b ligbbc ligbc4 arcb43 plan ;
  158. surfb3 = dall ligba2 arcb23 ligb3b ligbab plan ;
  159. surfbas = surfb1 et surfb2 et surfb3 ;
  160. * *
  161. * creation du volume *
  162. volu1 = surfbas volu dini l1 dfin d2 tran ph1 ;
  163. surfhaut = face 2 volu1 ;
  164. surflat = face 3 volu1 ;
  165. * *
  166. * extraction des surfaces laterales *
  167. *surface oxz *
  168. poxz = poin surflat plan pb1 (2. 0. 2.) (0. 0. 2.) (1e-3) ;
  169. surfl1 = elem surflat appu strict poxz ;
  170. *surface poyz *
  171. poyz = poin surflat plan pb1 pb4 ph1 (1e-3) ;
  172. surfl2 = elem surflat appu strict poyz ;
  173. * *
  174. elim volu1 (1e-3) ;
  175. elim (surfbas et surfhaut et surfl1 et surfl2) (1e-3) ;
  176. * *
  177. *****************************************************************
  178. * conditions de symetrie *
  179. *****************************************************************
  180. condi1 = symt depl pb1 ph1 pb2 volu1 (1e-3) ;
  181. condi2 = symt depl pb1 ph1 pb4 volu1 (1e-3) ;
  182. condi3 = symt depl pb1 pb2 pb4 volu1 (1e-3) ;
  183. condit = condi1 et condi2 et condi3 ;
  184. * *
  185. *****************************************************************
  186. * creation du modele *
  187. *****************************************************************
  188. mod2 = MODE volu1 mecanique elastique plastique ;
  189. * *
  190. *****************************************************************
  191. * definition du materiau *
  192. *****************************************************************
  193. * *
  194. mate2 = MATE mod2 young (503./0.0026) nu 0.3 tract tracevt ;
  195. * *
  196. *****************************************************************
  197. * rigidite *
  198. *****************************************************************
  199. blo1 = bloq uz surfbas ;
  200. rig1 = condit et blo1 ;
  201. rig2 = bloq uz surfhaut ;
  202. rigt = rig1 et rig2 ;
  203. dep2 = depi rig2 (4e-3) ;
  204. forcevt = evol manu abs (prog 0. 1.) ord (prog 0. 1.) ;
  205. fo2 = char 'DIMP' dep2 forcevt ;
  206. * *
  207. *****************************************************************
  208. * definition de la table d'entree *
  209. *****************************************************************
  210. tab2 = table ;
  211. tab2.'CARACTERISTIQUES' = mate2 ;
  212. tab2.'MODELE' = mod2 ;
  213. tab2.'BLOCAGES_MECANIQUES' = rigt ;
  214. tab2.'CHARGEMENT' = fo2 ;
  215. tab2.'TEMPS_CALCULES' = (prog 0. pas 0.5 1.) ;
  216. * *
  217. *****************************************************************
  218. * procedure de calcul ;
  219. *****************************************************************
  220. TMASAU=table;
  221. tab2 . 'MES_SAUVEGARDES'=TMASAU;
  222. TMASAU .'DEFTO'=VRAI;
  223. TMASAU .'DEFIN'=VRAI;
  224.  
  225. pasapas tab2 ;
  226. * *
  227. *****************************************************************
  228. * Calcul de la contrainte de Weibull 3D *
  229. *****************************************************************
  230. * *
  231. * zone du critere *
  232. volucrit = volu1 elem contenant pb1 ;
  233. zone2 = redu mod2 volucrit;
  234. * *
  235. enttab2 = table ;
  236. enttab2.'XMULT' = 8. ;
  237. enttab2.'OBJMO' = zone2 ;
  238. enttab2.'WEIBULL' = vrai ;
  239. enttab2.'TNONL' = tab2 ;
  240. enttab2.'M' = m ; enttab2.'V0' = v0 ; enttab2.'SIGU' = sigu ;
  241. enttab2.'IC' = ic ; enttab2.'N' = n ;
  242. enttab2.'TEMPER' = 0 ;
  243. * *
  244. sortab2 = critloc enttab2 ;
  245. * *
  246. sigw3d = (sortab2.'SIGW').1. ;
  247. * *
  248. *****************************************************************
  249. * Test d'erreur *
  250. *****************************************************************
  251. ecart = ( abs(sigwaxi-sigw3d) ) / sigwaxi ;
  252. mess 'ecart relatif : ' (ecart*100.) '%' ;
  253. si (ecart < 0.1 ) ;
  254. erre 0 ;
  255. sinon ;
  256. erre 5 ;
  257. finsi ;
  258. * *
  259. fin ;
  260. *----------------------------------------------------------------
  261.  
  262.  
  263.  
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales