Télécharger rupt13.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt13.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. OPTION echo 1 ;
  5. GRAPH = 'N' ;
  6. SAUT PAGE ;
  7. * ;
  8. ** LE TAUX G DANS L'EPAISSEUR DE COQUE : NOUVELLE TECHNIQUE
  9. ** ICOQU = 1 ELEMENTS 'DKT'
  10. ** ICOQU = 2 ELEMENTS 'DST'
  11. ** ICOQU = 3 ELEMENTS 'COQ6'
  12. ** ICOQU = 4 ELEMENTS 'COQ4'
  13. ** ICOQU = 5 ELEMENTS 'COQ8'
  14.  
  15. ** ICHAR = 1 FLEXION PURE
  16. ** ICHAR = 2 FLEXION + MENBRANE
  17. ** ICHAR = 3 FORCE SUR LA FISSURE
  18. ** ICHAR = 4 CHARGEMENTS MECANIQUES
  19. ** ICHAR = 5 CHARGEMENTS 3 + 4
  20.  
  21. ** IMATE = 1 ELASTICITE
  22. ** IMATE = 2 ELASTO PLASTICITE
  23.  
  24. ** IELEM = NUMEO DE L ELEMENT PROCHE DE LA FISSURE
  25. *****************************************
  26. * SAISSIE DES PARAMETRES DE MAILLAGE *
  27. *****************************************
  28. *
  29. * CHOIX DES CHAMPS SINGULIERS
  30.  
  31. IELEM = 53;
  32. *
  33. * TYPE DE CHARGEMENT
  34.  
  35. ICHAR = 1;
  36. *
  37. * TYPE DE MATERIAU
  38.  
  39. IMATE = 1;
  40. *
  41. * EPAISSEUR TOTALE DE L'EPROUVETTE
  42.  
  43. EPAI_T = .7 * 40;
  44. *
  45. * TYPE D'ELEMENTS DE COQUE
  46.  
  47. ICOQU = 4;
  48. *
  49. * NOMBRE DE MULTICOUCHES
  50.  
  51. NB_MUL = 21;
  52. *
  53. * EPAISSEUR DE LA COUCHE POUR DETERMINER LE RAPPORT D'ENERGIE
  54.  
  55. EPAI_C = EPAI_T * 1.E-6;
  56. *
  57. * ---------------- A/W :
  58.  
  59. RAP1 = 0.25 ;
  60. *
  61. * ---------------- H/W :
  62.  
  63. RAP2 = 4. ;
  64. *
  65. * ---------------- W :
  66.  
  67. W = 70. ;
  68. *
  69. * LARGEUR DE BANDE DEPOSEE (POUR UN METAL BIPHASE)
  70.  
  71. LDEP = 10. ;
  72. *
  73. *EPROUVETTE SENB OU CCP ? (VAL = 0 OU VAL = 1) ;
  74.  
  75. VAL = 1 ;
  76. *
  77. * TAILLE DE MAILLE EN POINTE DE FISSURE
  78.  
  79. TM = .2 ;
  80. *
  81. * NOMBRE DE DECOUGE SUR 45 DEGRES ;
  82.  
  83. N = 4 ;
  84. ***************************************
  85. ******* ELEMENTS ET FORMULATIONS ******
  86. ***************************************
  87.  
  88. SI (EGA ICOQU 1);
  89. MOT_E = TEXT 'TRI3'; REP = 0 ; MOT_S = TEXT 'SEG2';
  90. MOT_F1 = TEXT 'DKT'; MOT_F2 = TEXT ' ';
  91. FINSI;
  92. SI (EGA ICOQU 2);
  93. MOT_E = TEXT 'TRI3'; REP = 0 ; MOT_S = TEXT 'SEG2';
  94. MOT_F1 = TEXT 'DST'; MOT_F2 = TEXT ' ';
  95. FINSI;
  96. SI (EGA ICOQU 3);
  97. MOT_E = TEXT 'TRI6'; REP = 0 ; MOT_S = TEXT 'SEG3';
  98. MOT_F1 = TEXT 'COQ6'; MOT_F2 = TEXT ' ';
  99. FINSI;
  100. SI (EGA ICOQU 4);
  101. MOT_E = TEXT 'QUA4'; REP = 1 ; MOT_S = TEXT 'SEG2';
  102. MOT_F1 = TEXT 'COQ4'; MOT_F2 = TEXT 'DST';
  103. FINSI;
  104. SI (EGA ICOQU 5);
  105. MOT_E = TEXT 'QUA8'; REP = 1 ; MOT_S = TEXT 'SEG3';
  106. MOT_F1 = TEXT 'COQ8'; MOT_F2 = TEXT 'COQ6';
  107. FINSI;
  108.  
  109. ***************************************
  110. ******* PARAMETRES INTERMEDIAIRES *****
  111. ***************************************
  112.  
  113. LCRITW = (W * (1. - RAP1)) ;
  114. LCRITA = W * RAP1 ;
  115. *DEMI-COTE DU CARRE
  116. C = MINI (PROG (W / 5.) LDEP LCRITA LCRITW) ;
  117.  
  118. *RAYON DU DISQUE
  119. R = C / 2. ;
  120.  
  121. *DENSITE EN PERIPHERIE DE DISQUE
  122. *TE = R / 10. ;
  123. TE = 1.5 * ((PI * R) / (4. * N)) ;
  124.  
  125. *DENSITE AU PREMIER ARC
  126. SI (EGA REP 1) ;
  127. TA = TM * 2. ;
  128. SINON ;
  129. TA = TM ;
  130. FINSI ;
  131.  
  132. *MOMENT D'INERTI
  133. IX = W * (EPAI_T ** 3) / 12;
  134.  
  135. *******************************************
  136. * MAILLAGE *
  137. *******************************************
  138.  
  139. *----------------------------------------------------*
  140. *** PARTIE CIRCULAIRE AUTOUR DE LA POINTE DE FISSURE *
  141. *----------------------------------------------------*
  142.  
  143. OPTI ECHO 1 DIME 2 ELEM MOT_E ;
  144. P0 = 0. 0. ;
  145. P1 = (RAP1 * W) 0. ;
  146. DENS TA ;
  147. SI (REP EGA 0) ;
  148. P2 = P1 PLUS (TM 0.) ;
  149. SINON ;
  150. P2 = P1 PLUS ((TM * N * 2.) 0.) ;
  151. SI ((TM * N * 2.) > R) ;
  152. NC = R / 2. ;
  153. OPTI ECHO 0 ;
  154. MESS 'LE PRODUIT (TM * N) DOIT ETRE INFERIEUR A' NC ;
  155. OPTI ECHO 1 ;
  156. FINSI ;
  157. FINSI ;
  158. DENS TE ;
  159. P10 = P1 PLUS (R 0.) ;
  160.  
  161. LIGAM0 = P2 D P10 ;
  162.  
  163. SU21 = LIGAM0 ROTA N 45. P1 ;
  164. L21 = SU21 COTE 4 ;
  165. C21 = SU21 COTE 2 ;
  166. SU22 = (SU21 COTE 3) ROTA N 45. P1 ;
  167. L22 = SU22 COTE 2 ;
  168. C22 = SU22 COTE 4 ;
  169. SU23 = (SU22 COTE 3) ROTA N 45. P1 ;
  170. L23 = SU23 COTE 4 ;
  171. C23 = SU23 COTE 2 ;
  172. SU24 = (SU23 COTE 3) ROTA N 45. P1 ;
  173. L24 = SU24 COTE 2 ;
  174. C24 = SU24 COTE 4 ;
  175.  
  176. RAC = L21 ET L22 ET L23 ET L24 ;
  177. SU2 = SU21 ET SU22 ET SU23 ET SU24 ;
  178.  
  179. SI (EGA REP 0) ;
  180. SU0 = COUT P1 RAC ;
  181. SU0L = CHAN SU0 LIGNE ;
  182. P01 = (P1 PLUS P2) / 2. ;
  183. LIG0 = SU0L ELEM APPUYE STRICTEMENT (P1 ET (SU0 POIN PROC P01)
  184. ET P2) ;
  185. LIGAM0 = LIGAM0 ET LIG0 ;
  186. L1 = LIGAM0 ;
  187. SINON ;
  188. DENS TM ;
  189. QAD = P1 PLUS ((TM * N) 0.) ;
  190. QAG = P1 MOIN ((TM * N) 0.) ;
  191. BASD = P1 D N QAD ;
  192. BASG = P1 D N QAG ;
  193. BAS = ORDO (BASG ET BASD) ;
  194. PAVE = BAS TRANS N (0. (TM * N)) ;
  195. COPAV1 = PAVE COTE 2 ;
  196. COPAV2 = PAVE COTE 3 ;
  197. COPAV3 = PAVE COTE 4 ;
  198. COPAV = COPAV1 ET COPAV2 ET COPAV3 ;
  199. DEC = (ENTI (N / 1.2)) * (-1) ;
  200. JONCD = QAD D P2 ;
  201. JONCG = QAG D (SU24 POIN PROC QAG) ;
  202. SUJON = DALL COPAV JONCD RAC JONCG PLAN ;
  203. SU0 = SUJON ET PAVE ;
  204. LIG0 = BASD ET JONCD ;
  205. LIGAM0 = LIGAM0 ET LIG0 ;
  206. L1 = LIGAM0 ;
  207. FINSI ;
  208.  
  209. *---------------------------------------------*
  210. *** CARRE EXTERIEUR AUTOUR DU FOND DE FISSURE *
  211. *---------------------------------------------*
  212.  
  213. DENS (2. * TE) ;
  214. PDB = P1 PLUS (C 0.) ;
  215. PDH = P1 PLUS (C C) ;
  216. PMH = P1 PLUS (0. C) ;
  217. PGH = P1 PLUS (((-1) * C) C) ;
  218. PGB = P1 PLUS (((-1) * C) 0.) ;
  219.  
  220. CARD = PDB D N PDH ;
  221. CARHD = PDH D N PMH ;
  222. CARHG = PMH D N PGH ;
  223. CARG = PGH D N PGB ;
  224.  
  225. DECC = ((-1) * (ENTI ((C - R) / (1. * TE)))) - 1 ;
  226.  
  227. DIAD = (C21 POIN INITIAL) D DECC PDB ;
  228. DIADH = (C22 POIN FINAL) D DECC PDH ;
  229. DIAM = (C23 POIN INITIAL) D DECC PMH ;
  230. DIAGH = (C24 POIN FINAL) D DECC PGH ;
  231. DIAG = (C24 POIN INITIAL) D DECC PGB ;
  232.  
  233. SU3 = DALL C21 DIADH CARD DIAD PLAN;
  234. SU4 = (DALL C22 DIAM CARHD DIADH PLAN) ET
  235. (DALL C23 DIAGH CARHG DIAM PLAN) ;
  236. SU5 = DALL C24 DIAG CARG DIAGH PLAN ;
  237.  
  238. CARRE = SU0 ET SU2 ET SU3 ET SU4 ET SU5 ;
  239. LIGAM1 = LIGAM0 ET DIAD ;
  240.  
  241. *-------------------------*
  242. *** PARTIE METAL DEPOSE *
  243. *-------------------------*
  244.  
  245. CLCRITW = (C < (LCRITW + 0.01)) ET (C > (LCRITW - 0.01)) ;
  246. CLCRITA = (C < (LCRITA + 0.01)) ET (C > (LCRITA - 0.01)) ;
  247. CLDEP = (C < (LDEP + 0.01)) ET (C > (LDEP - 0.01)) ;
  248.  
  249. SI ((NON CLCRITW ) ET (NON CLCRITA)) ;
  250. * MESS 'CAS GENERAL' ;
  251.  
  252. VTL = 0. (LDEP - C) ;
  253. VTG = (((-1) * (LCRITA - C)) 0.) ;
  254. VTD = (LCRITW - C) 0. ;
  255. NFL = ENTI ((LDEP - C) / (MESU (CARHD ELEM 1) LONG)) ;
  256. NFG = ENTI ((LCRITA - C) / (MESU (CARG ELEM 1) LONG)) ;
  257. NFD = ENTI ((LCRITW - C) / (MESU (CARD ELEM 1) LONG)) ;
  258. SI (NFG EGA 0) ;
  259. NFG = 1 ;
  260. SU7 = CARG TRAN NFG VTG ;
  261. SINON ;
  262. DENSI = (MESU (CARG ELEM 1) LONG) ;
  263. DENSF = DENSI * (1 + (NFG / 20.)) ;
  264. SU7 = CARG TRAN 'DINI' DENSI 'DFIN' DENSF VTG ;
  265. FINSI ;
  266. SI (NFD EGA 0) ;
  267. NFD = 1 ;
  268. SU6 = CARD TRAN NFD VTD ;
  269. SINON ;
  270. DENSI = (MESU (CARD ELEM 1) LONG) ;
  271. DENSF = DENSI * (1 + (NFD / 20.)) ;
  272. SU6 = CARD TRAN 'DINI' DENSI 'DFIN' DENSF VTD ;
  273. FINSI ;
  274. L8 = (SU7 COTE 4) ET (SU6 COTE 2) ET CARHD ET CARHG ;
  275. L8 = ORDO L8 ;
  276. SI (CLDEP) ;
  277. * MESS 'CAS CRITIQUE LDEP' ;
  278. MDEP = CARRE ET SU6 ET SU7 ;
  279. L8B = INVE L8 ;
  280. LIGAM = LIGAM1 ET (SU6 COTE 4) ;
  281. LSYM1 = (SU7 COTE 3) ;
  282. SINON ;
  283. SI (NFL EGA 0) ;
  284. NFL = 1 ;
  285. SU8 = L8 TRAN NFL VTL ;
  286. SINON ;
  287. DENSI = (MESU (CARHD ELEM 1) LONG) ;
  288. DENSF = DENSI * (1 + (NFL / 10.)) ;
  289. SU8 = L8 TRAN 'DINI' DENSI 'DFIN' DENSF VTL ;
  290. FINSI ;
  291. MDEP = CARRE ET SU6 ET SU7 ET SU8 ;
  292. L8B = SU8 COTE 3 ;
  293. LIGAM = LIGAM1 ET (SU6 COTE 4) ;
  294. LSYM1 = (SU7 COTE 3) ET (SU8 COTE 4) ;
  295. FINSI ;
  296.  
  297. FINSI ;
  298.  
  299. SI (CLCRITW) ;
  300. * MESS 'CAS CRITIQUE W' ;
  301. VTL = 0. (LDEP - C) ;
  302. VTT = (((-1) * (LCRITA - C)) 0.) ;
  303. NFL = ENTI ((LDEP - C) / (MESU (CARHD ELEM 1) LONG)) ;
  304. NFT = ENTI ((LCRITA - C) / (MESU (CARG ELEM 1) LONG)) ;
  305. SI (NFT EGA 0) ;
  306. NFT = 1 ;
  307. SU7 = CARG TRAN NFT VTT ;
  308. SINON ;
  309. DENSI = (MESU (CARG ELEM 1) LONG) ;
  310. DENSF = DENSI * (1 + (NFT / 20.)) ;
  311. SU7 = CARG TRAN 'DINI' DENSI 'DFIN' DENSF VTT ;
  312. FINSI ;
  313. L8 = (SU7 COTE 4) ET CARHD ET CARHG ;
  314. L8 = ORDO L8 ;
  315. SI (CLDEP) ;
  316. * MESS 'CAS CRITIQUE LDEP ET LCRITW' ;
  317. MDEP = CARRE ET SU7 ;
  318. L8B = INVE L8 ;
  319. LIGAM = LIGAM1 ;
  320. LSYM1 = (SU7 COTE 3) ;
  321. SINON ;
  322. SI (NFL EGA 0) ;
  323. NFL = 1 ;
  324. SU8 = L8 TRAN NFL VTL ;
  325. SINON ;
  326. DENSI = (MESU (CARHD ELEM 1) LONG) ;
  327. DENSF = DENSI * (1 + (NFL / 10.)) ;
  328. SU8 = L8 TRAN 'DINI' DENSI 'DFIN' DENSF VTL ;
  329. FINSI ;
  330. MDEP = CARRE ET SU7 ET SU8 ;
  331. L8B = SU8 COTE 3 ;
  332. LIGAM = LIGAM1 ;
  333. LSYM1 = (SU7 COTE 3) ET (SU8 COTE 4) ;
  334. FINSI ;
  335. FINSI ;
  336.  
  337. SI (CLCRITA) ;
  338. * MESS 'CAS CRITIQUE A' ;
  339. VTL = 0. (LDEP - C) ;
  340. VTT = (LCRITW - C) 0. ;
  341. NFL = ENTI ((LDEP - C) / (MESU (CARHD ELEM 1) LONG)) ;
  342. NFT = ENTI ((LCRITW - C) / (MESU (CARD ELEM 1) LONG)) ;
  343. SI (NFT EGA 0) ;
  344. NFT = 1 ;
  345. SU6 = CARD TRAN NFT VTT ;
  346. SINON ;
  347. DENSI = (MESU (CARD ELEM 1) LONG) ;
  348. DENSF = DENSI * (1 + (NFT / 20.)) ;
  349. SU6 = CARD TRAN 'DINI' DENSI 'DFIN' DENSF VTT ;
  350. FINSI ;
  351. L8 = (SU6 COTE 2) ET CARHD ET CARHG ;
  352. L8 = ORDO L8 ;
  353. SI (CLDEP) ;
  354. * MESS 'CAS CRITIQUE LDEP ET LCRITA' ;
  355. MDEP = CARRE ET SU6 ;
  356. L8B = L8 ;
  357. LIGAM = LIGAM1 ET (SU6 COTE 4) ; ;
  358. LSYM1 = CARG ;
  359. SINON ;
  360. SI (NFL EGA 0) ;
  361. NFL = 1 ;
  362. SU8 = L8 TRAN NFL VTL ;
  363. SINON ;
  364. DENSI = (MESU (CARHD ELEM 1) LONG) ;
  365. DENSF = DENSI * (1 + (NFL / 10.)) ;
  366. SU8 = L8 TRAN 'DINI' DENSI 'DFIN' DENSF VTL ;
  367. FINSI ;
  368. MDEP = CARRE ET SU6 ET SU8 ;
  369. L8B = SU8 COTE 3 ;
  370. L8B = INVE L8B ;
  371. LIGAM = LIGAM1 ET (SU6 COTE 4) ;
  372. LSYM1 = (SU8 COTE 2) ET CARG ;
  373. FINSI ;
  374. FINSI ;
  375.  
  376. *-------------------------*
  377. *** PARTIE METAL DE BASE *
  378. *-------------------------*
  379.  
  380. L8B = ORDO L8B ;
  381. PPI = L8B POIN INITIAL ;PF = L8B POIN FINAL ;
  382. LU = (MESU L8B LONG) / (NBEL L8B) * 1.2 ;
  383. FRON1 = (PPI PLUS (0. LU)) D (ENTI ((NBEL L8B) / 1.51))
  384. (PF PLUS (0. LU)) ;
  385. LUB = ((MESU FRON1 LONG) / (NBEL FRON1)) * 1.2 ;
  386. PIB = FRON1 POIN INITIAL ;PFB = FRON1 POIN FINAL ;
  387. FRON2 = (PIB PLUS (0. LUB)) D (ENTI ((NBEL FRON1) / 1.51))
  388. (PFB PLUS (0. LUB)) ;
  389.  
  390. JOIN1 = COUT L8B FRON1 ;
  391. JOIN2 = COUT FRON1 FRON2 ;
  392. JOIN = JOIN1 ET JOIN2 ;
  393. JOINL = CHAN JOIN LIGNE ;
  394. JOINP = JOINL POIN DROIT P0 (P0 PLUS (0. 10.)) (TM / 10.) ;
  395. LSYM2 = JOINL ELEM APPUYE STRICTEMENT JOINP ;
  396.  
  397. LREST = ((W * RAP2) / 2.) - (LDEP + LU + LUB) ;
  398. VT = 0. LREST ;
  399. LE = MESU (FRON2 ELEM 1) LONG ;
  400. CORP = FRON2 TRAN (ENTI (LREST / LE)) VT ;
  401. LSYM3 = CORP COTE 2 ;
  402. PINIF = LIGAM POIN INITIAL;
  403.  
  404. *---------------------------*
  405. *PARTICULARITE POUR UN CCP *
  406. *---------------------------*
  407.  
  408. SI (VAL EGA 1) ;
  409. MBAS = CORP ET JOIN ;
  410. *PLAN VERTICALE DE SYMETRIE
  411. LSYM = LSYM1 ET LSYM2 ET LSYM3 ;
  412. LSYM = LSYM COUL VERT ;
  413. *FACE DE CHARGEMENT
  414. SCHAR = CORP COTE 3 ;
  415. SCHAR = SCHAR COUL ROUG ;
  416. *LIGAMENT
  417. LIGAM = LIGAM COUL BLEU ;
  418. *MAILLAGE COMPLET
  419. CCP = MBAS ET MDEP ;
  420. TITR 'EPROUVETTE CCP' ;
  421. * TRAC (CCP ET LIGAM ET LSYM ET SCHAR) ;
  422. FINSI ;
  423.  
  424. *----------------------------*
  425. *PARTICULARITE POUR UN SENB *
  426. *----------------------------*
  427.  
  428. SI (VAL EGA 0) ;
  429. LRESID = CORP COTE 3 ;
  430. RESID = LRESID TRAN 1 (0. LE) ;
  431. MBAS = CORP ET JOIN ET RESID ;
  432. *APPUI
  433. PAP = P0 PLUS (0. ((RAP2 / 2.) * W)) ;
  434. PAP = MBAS POIN PROC PAP ;
  435. PAP = MANU PAP POI1 VERT ;
  436. *POINT D'APPLICATION DE LA FORCE
  437. PCHAR = P0 PLUS (W 0.) ;
  438. PCHAR = MDEP POIN PROC PCHAR ;
  439. PCHAR = MANU PCHAR POI1 ROUG ;
  440. *LIGAMENT
  441. LIGAM = LIGAM COUL BLEU ;
  442. *MAILLAGE COMPLET
  443. SENB = MBAS ET MDEP ;
  444. TITR 'EPROUVETTE SENB' ;
  445. TRAC (SENB ET LIGAM ET PAP ET PCHAR) ;
  446. FINSI ;
  447. *
  448. PFISIN = LSYM POIN INIT;
  449. CT1 = CONT CCP;
  450. PSUP = (CT1 DIFF (LIGAM ET LSYM)) POIN DROI PFISIN P1;
  451. CT2 = CHAN MOT_S CT1;
  452. LIFIS1 = CT2 ELEM APPU STRI PSUP;
  453. LLBB = ORDO (LIGAM ET LIFIS1); LLBB = INVE LLBB;
  454. CCP = ORIE CCP ;
  455. *
  456. * PREMIERE COUCHE D'ELEMENT AUTOUR DE LA FISSURE
  457. *
  458. ELEFIS = CCP ELEM MOT_E IELEM;
  459. *
  460. * FIN DE LA DÉFINITION DE LA GÉOMÉTRIE
  461. *
  462. OPTI DIME 3 MODE TRID;
  463. *
  464. * COURBE DE TRACTION
  465. *
  466. YOUN1 = 2.E05;
  467. NU1 = 0.3;
  468. ALPH1 = 1.E-6;
  469. YIEL1 = 4.E02;
  470. ALPH1 = 0.5;
  471. NEXPO1 = 7;
  472. SIG0 = 1.E02;
  473. EPS0 = SIG0 / YOUN1;
  474. LSIGM = PROG 0. SIG0;
  475. LEPSI = PROG 0. EPS0;
  476. NPOIN = 50;
  477. EPSTOT = 5.;
  478. SS1 = (EPSTOT*YOUN1/YIEL1/ALPH1)**(1./NEXPO1);
  479. SS1 = YIEL1 * SS1 / NPOIN;
  480. REPETER BC1 NPOIN;
  481. SIG1 = SS1*&BC1;
  482. SI (< SIG1 SIG0); ITER BC1; FINSI;
  483. EPS1 = (((SIG1/YIEL1)**(NEXPO1 - 1))*ALPH1) + 1.;
  484. EPS1 = EPS1 * SIG1 / YOUN1;
  485. LSIGM = LSIGM ET (PROG SIG1);
  486. LEPSI = LEPSI ET (PROG EPS1);
  487. FIN BC1;
  488. TRAC1 = EVOL MANU 'EPSI' LEPSI 'SIGM' LSIGM;
  489. SI (EGA IMATE 2); DESS TRAC1; FINSI;
  490. *
  491. * EPAISSEUR ET EXCENTREMENT
  492. *
  493. EPAI_I = (EPAI_T - (EPAI_C*NB_MUL))/(NB_MUL - 1);
  494. TBEPAI = TABLE; TBEXCE = TABLE;
  495. REPETER BC_MUL1 ((2*NB_MUL) - 1);
  496. III = (&BC_MUL1 - NB_MUL) / 2.;
  497. TBEXCE.&BC_MUL1 = (EPAI_I + EPAI_C)*III;
  498. SI (EGA 0. ((&BC_MUL1/2.) - (&BC_MUL1/2)) 1.E-10);
  499. TBEPAI.&BC_MUL1 = EPAI_I;
  500. SINON;
  501. TBEPAI.&BC_MUL1 = EPAI_C;
  502. FINSI;
  503. FIN BC_MUL1;
  504. *
  505. * DFINITION DES MODLES ET DU MATRIAU
  506. *
  507. SI (EGA IMATE 1);
  508. MPL1 = TEXT ' '; MTR1 = TEXT ' '; MTR2 = TEXT ' ';
  509. FINSI;
  510. SI (EGA IMATE 2);
  511. MPL1 = TEXT 'PLASTIQUE'; MTR1 = TEXT 'TRAC'; MTR2 = TRAC1;
  512. EVO1 = EVOL MANU 'Temps' (PROG 0 1.E10) 'F(t)' (PROG 0 1.E10);
  513. FINSI;
  514. REPETER BC_MUL2 ((2*NB_MUL) - 1);
  515. SI (EGA &BC_MUL2 1);
  516. MOD_MUL = MODE ELEFIS MECANIQUE ELASTIQUE
  517. MPL1 MOT_F1 MOT_F2 CONS (CHAI &BC_MUL2);
  518. MAT_MUL = MATE MOD_MUL YOUN YOUN1 NU NU1 ALPH ALPH1 TALP 0. TREF 0. MTR1
  519. MTR2 EPAI TBEPAI.&BC_MUL2 EXCE TBEXCE.&BC_MUL2;
  520. SINON;
  521. MOD_MU1 = MODE ELEFIS MECANIQUE ELASTIQUE
  522. MPL1 MOT_F1 MOT_F2 CONS (CHAI &BC_MUL2);
  523. MAT_MU1 = MATE MOD_MU1 YOUN YOUN1 NU NU1 ALPH ALPH1 TALP 0. TREF 0. MTR1
  524. MTR2 EPAI TBEPAI.&BC_MUL2 EXCE TBEXCE.&BC_MUL2;
  525. MOD_MUL = MOD_MUL ET MOD_MU1;
  526. MAT_MUL = MAT_MUL ET MAT_MU1;
  527. FINSI;
  528. FIN BC_MUL2;
  529. MOD_R = MODE (CCP DIFF ELEFIS) MECANIQUE ELASTIQUE MPL1 MOT_F1 MOT_F2;
  530. MAT_R = MATE MOD_R YOUN YOUN1 NU NU1 ALPH ALPH1 TALP 0. TREF 0. MTR1 MTR2 EPAI EPAI_T;
  531. MO1 = MOD_MUL ET MOD_R;
  532. MA0 = MAT_MUL ET MAT_R;
  533. RIG0 = RIGI MO1 MA0;
  534. *
  535. * DéFINITION DES CONDITIONS AUX LIMITES
  536. *
  537. BL1 = BLOQ UY RX RZ LIGAM;
  538. BL2 = BLOQ UX RY RZ LSYM;
  539. BL3 = BLOQ UZ SCHAR;
  540. BLT = BL1 ET BL2 ET BL3;
  541. *
  542. * CHARGEMENT : MOMENT DE FLEXION
  543. *
  544. SIGMAX = 10. ;
  545. MOMTOT = SIGMAX * (W * (EPAI_T ** 2) / 6.);
  546. ROTATI = (MOMTOT / (YOUN1 * IX)) * (2 * W);
  547. PINICH = SCHAR POIN INITIAL;
  548. PFINCH = SCHAR POIN FINAL;
  549. SCHAR = SCHAR CHAN POI1;
  550. PMILCH = SCHAR DIFF (PINICH ET PFINCH);
  551. MOEXT = MOMTOT / ((NBNO SCHAR) - 1);
  552. MOMIL = MOEXT * (NBNO PMILCH);
  553. FO1 = (MOME MX MOEXT (PINICH ET PFINCH)) ET (MOME MX MOMIL PMILCH);
  554. FYTOT = SIGMAX * W * EPAI_T;
  555. FYEXT = FYTOT / ((NBNO SCHAR) - 1);
  556. FYMIL = FYEXT * (NBNO PMILCH);
  557. FO2 = (FORC FY FYEXT (PINICH ET PFINCH)) ET (FORC FY FYMIL PMILCH);
  558. LFOR1 = LIFIS1 ELEM APPU LARG P1;
  559. LFOR1 = LIFIS1 ELEM APPU LARG LFOR1;
  560. LFOR1 = LIFIS1 ELEM APPU LARG LFOR1;
  561. FO3 = FORC (0 1000. 800.) (LIFIS1 DIFF LFOR1);
  562. EV1 = EVOL MANU 'X1' (PROG 0 70) (PROG -0.0005 0);
  563. TEMP1 = VARI EV1 (COOR 1 CCP) 'T';
  564. TEMP2 = VARI EV1 (COOR 1 CCP) 'TINF';
  565. TEMP3 = VARI EV1 (COOR 1 CCP) 'TSUP';
  566. TT = TEMP1 ET TEMP2 ET TEMP3;
  567. SIGT1 = THET TT MO1 MA0;
  568. FO4 = BSIG SIGT1 MO1 MA0 ;
  569. SI (EGA ICHAR 1); FOEXT = FO1; FINSI;
  570. SI (EGA ICHAR 2); FOEXT = FO1 ET FO2; FINSI;
  571. SI (EGA ICHAR 3); FOEXT = FO3; FINSI;
  572. SI (EGA ICHAR 4); FOEXT = FO4; FINSI;
  573. SI (EGA ICHAR 5); FOEXT = FO4 ET FO3; FINSI;
  574. *
  575. * RéSOLUTION
  576. *
  577. SI (EGA IMATE 1);
  578. DEP1 = RESO (RIG0 ET BLT) FOEXT;
  579. FINSI;
  580. SI (EGA IMATE 2);
  581. SI (EGA ICHAR 4); FOEXT = FOEXT * 0.; FINSI;
  582. TBTEMP = TABLE;
  583. TBTEMP.0 = TT * 0.; TBTEMP.1 = TT * 2.; TBTEMP.2 = TT * 5.;
  584. TBTEMP.3 = TT * 8.; TBTEMP.4 = TT * 12.;TBTEMP.5 = TT * 20.;
  585. TBTIME = TABLE;
  586. TBTIME.0 = 0.; TBTIME.1 = 0.5; TBTIME.2 = 1.3;
  587. TBTIME.3 = 3.6; TBTIME.4 = 4.7; TBTIME.2 = 8.;
  588. CHA1 = (CHAR 'MECA' EVO1 FOEXT) ET (CHAR 'T ' TBTIME TBTEMP);;
  589. LIST1 = PROG 1. 3. 5;
  590. TABTOUT = TABLE;
  591. TABTOUT.BLOCAGES_MECANIQUES = BLT;
  592. TABTOUT.CARACTERISTIQUES = MA0;
  593. TABTOUT.MODELE = MO1;
  594. TABTOUT.CHARGEMENT = CHA1;
  595. TABTOUT.TEMPS_CALCULES = LIST1;
  596. TABTOUT.MAXITERATION = 99;
  597. PASAPAS TABTOUT;
  598. FINSI;
  599. ******
  600. ****** SOLUTION NUMERIQUE DE G (PROCEDURE G_THETA)
  601. ******
  602. SUPTAB = TABLE;
  603. SUPTAB.'OBJECTIF' = MOT 'J';
  604. SUPTAB.'LEVRE_SUPERIEURE' = LIFIS1;
  605. SUPTAB.'FRONT_FISSURE' = P1;
  606. SUPTAB.'ELEMENT_MULTICOUCHE' = ELEFIS ;
  607. *
  608. SI (EGA IMATE 1);
  609. SUPTAB.'SOLUTION_RESO' = DEP1;
  610. SUPTAB.'CARACTERISTIQUES' = MA0;
  611. SUPTAB.'MODELE' = MO1;
  612. SUPTAB.'CHARGEMENTS_MECANIQUES' = FOEXT;
  613. SI ((EGA ICHAR 4) OU (EGA ICHAR 5));
  614. SUPTAB.'TEMPERATURES' = (TEMP1 ET TEMP2 ET TEMP3);
  615. SI (EGA ICHAR 4);
  616. SUPTAB.'CHARGEMENTS_MECANIQUES' = FOEXT *0.;
  617. FINSI;
  618. SI (EGA ICHAR 5);
  619. SUPTAB.'CHARGEMENTS_MECANIQUES' = FO3;
  620. FINSI;
  621. FINSI;
  622. FINSI;
  623. SI (EGA IMATE 2);
  624. SUPTAB.'SOLUTION_PASAPAS' = TABTOUT;
  625. FINSI;
  626. NBCOUCH = 1; PC = PROG; PG = PROG;
  627. ******
  628. REPETER SUO1 NBCOUCH;
  629. SUPTAB.'COUCHE' = 6 ;
  630. G_THETA SUPTAB;
  631. FIN SUO1;
  632. G_COQUE = EXTR SUPTAB.EPAISSEUR_RESULTATS ORDO;
  633. COQUE05 = EXTR G_COQUE 21;
  634. COQUE025 = EXTR G_COQUE 16;
  635. mess ' ' ;
  636. mess ' ' ;
  637. mess ' ' ;
  638. mess ' Integral J par elements coques en peau (z=h/2) :' COQUE05 ;
  639. mess ' Solution SIF par elements massifs en peau : 1.77858E-02 ' ;
  640. mess ' ' ;
  641. mess ' Integral J par elements coques a z=h/4 :' COQUE025 ;
  642. mess ' Solution SIF par elements massifs a z=h/4 : 4.38290E-03 ' ;
  643. *CODE FONCTIONNEMENT ;
  644. ERR1 = ABS ((COQUE05 - 1.77858E-02)/1.77858E-02);
  645. ERR2 = ABS ((COQUE025 - 4.38290E-03)/4.38290E-03);
  646. mess ' ' ;
  647. SI ((ERR1 < 6.5E-2) et (ERR2 < 9.7E-2)) ;
  648. ERRE 0 ;
  649. SINO ;
  650. ERRE 5 ;
  651. FINSI ;
  652. fin;
  653.  
  654.  
  655.  
  656.  
  657.  
  658.  
  659.  
  660.  
  661.  
  662.  
  663.  
  664.  
  665.  
  666.  
  667.  
  668.  
  669.  
  670.  
  671.  
  672.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales