Télécharger rupt11.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt11.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ****************************************************
  5. * *
  6. * VALIDATION DES PROCEDURES GTHETA ET T_PITETA *
  7. * PAR UNE PLAQUE EN TRACTION PURE. SOLUTION *
  8. * DE REFERENCE : ISIDA, On the tension of a *
  9. * strip with a central elliptical hole. *
  10. * Tran. Jap. Soc. Mec. Engng., vol. 21 (1955). *
  11. * *
  12. * GEOMETRIE : *
  13. * *
  14. * longueur totale de la plaque : 700 MM *
  15. * largeur totale de la plaque : 200 MM *
  16. * longueur totale de la fissure : 100 MM *
  17. * *
  18. * MATERIAU : *
  19. * *
  20. * Module d'Young : 19775 Kgf/mm² *
  21. * Coefficient de poisson : 0,3 *
  22. * *
  23. * CHARGEMENT : *
  24. * *
  25. * Traction pure : 100 Kgf/mm² *
  26. * *
  27. * SOLUTION ANALYTIQUE : *
  28. * *
  29. * Le taux de restitution d'énergie (G_THETA) : *
  30. * G = 102,23 Kgf/mm *
  31. * La dérivée seconde de l'énergie (T_PITETA) : *
  32. * dG/da = 3,650 Kgf/mm² *
  33. * *
  34. ****************************************************
  35. DEBP PRMAIL P0*POINT LI11*MAILLAGE LI12*MAILLAGE LI13*MAILLAGE
  36. LI14*MAILLAGE NVTAI*FLOTTANT NDC*ENTIER;
  37. P21=P0 MOIN (NVTAI 0.);P22=P21 PLUS (0. NVTAI);
  38. P23=P22 PLUS (NVTAI 0.);P24=P23 PLUS (NVTAI 0.);
  39. P25=P24 MOIN (0. NVTAI);
  40. LI21=P21 D NDC P22;LI22=P22 D NDC P23;
  41. LI23=P23 D NDC P24;LI24=P24 D NDC P25;
  42. SU21=COUT LI11 LI21;SU22=COUT LI12 LI22;
  43. SU23=COUT LI13 LI23;SU24=COUT LI14 LI24;
  44. SUT=SU21 ET SU22 ET SU23 ET SU24;
  45. FINP LI21 LI22 LI23 LI24 SUT;
  46. *
  47. OPTI DIME 2 ELEM QUA8 MODE PLAN DEFO;
  48. PB=50. 0.; VTAI=0.5; TVTAI=TABLE;
  49. ***************************************
  50. * MAILLAGE CARRE EN POINTE DE FISSURE *
  51. ***************************************
  52. CVTAI=10. * VTAI; TVTAI=TABL; TNDC=TABL;
  53. TVTAI.1= 12. * VTAI; TNDC.1=8;
  54. TVTAI.2= 15. * VTAI; TNDC.2=6;
  55. TVTAI.3= 20. * VTAI; TNDC.3=5;
  56. TVTAI.4= 28. * VTAI; TNDC.4=4;
  57. TVTAI.5= 40. * VTAI; TNDC.5=3;
  58. TVTAI.6= 58. * VTAI; TNDC.6=3;
  59. TVTAI.7= 78. * VTAI; TNDC.7=3;
  60. TVTAI.8=100. * VTAI; TNDC.8=2;
  61. P11=PB MOIN (CVTAI 0.); P12=P11 PLUS (0. CVTAI);
  62. MCARR1=(P11 D 10 P12) TRAN 10 (CVTAI 0.);
  63. MCARR2=(INVE (COTE 3 MCARR1)) TRAN 10 (CVTAI 0.);
  64. MCARR0=MCARR1 ET MCARR2;
  65. PB=MCARR0 POIN PROCH PB;
  66. MFOND=MCARR0;
  67. *********************************************
  68. * ON ELARGIT ET ON MET A LA PLACE DE SUFISS *
  69. *********************************************
  70. LI11=COTE 1 MCARR1;LI12=COTE 2 MCARR1;
  71. LI13=COTE 2 MCARR2;LI14=COTE 3 MCARR2;
  72. I=0;
  73. REPETER BCOU (DIME TVTAI);
  74. I=I + 1;
  75. NVTAI=TVTAI.I;NDC=TNDC.I;
  76. LI11 LI12 LI13 LI14 SUT2=PRMAIL PB LI11 LI12 LI13 LI14 NVTAI NDC;
  77. MFOND=MFOND ET SUT2;
  78. FIN BCOU;
  79. ELIM 0.01 MFOND;
  80. SUT = (LI12 ET LI13) TRAN -12 DINI 8 DFIN 30 (0. (350. - 50.));
  81. SUT = SUT ET MFOND;
  82. CSUT = CONT SUT;
  83. ELIM 0.01 SUT;
  84. *******************************************
  85. * PREPARATION POUR CALCUL SUR MAILLES 1MM *
  86. *******************************************
  87. LICOT=CSUT ELEM COMP (SUT POIN PROC (0. 350.)) (SUT POIN PROC (0. 0.));
  88. LIGAM=CSUT ELEM COMP (SUT POIN PROC (50. 0.)) (SUT POIN PROC (100. 0.));
  89. LIFIS=CSUT ELEM COMP (SUT POIN PROC (0. 0.)) (SUT POIN PROC (50. 0.));
  90. LIHAU=CSUT ELEM COMP (SUT POIN PROC (100. 350.))
  91. (SUT POIN PROC (0. 350.));
  92. OB1= modeli sut mecanique elastique;
  93. MA1=MATE OB1 YOUN 19775. NU 0.3 ALPHA 1.5E-5;
  94. RI1=RIGI MA1 OB1;
  95. CDL1=(BLOQ UX LICOT) ET (BLOQ UY LIGAM);
  96. FO1=PRES MASS OB1 -100. LIHAU;
  97. U=RESO (RI1 ET CDL1) FO1;
  98. SIG=SIGM MA1 U OB1 'LINE';
  99. titr 'Fissure deformee sous la pression';
  100. vec1=vect fo1 fx fy 0.01 roug;
  101. *trac (defo sut u vec1) face (cont sut);
  102. ***** Solution analytique ******
  103. COE1 = (0.91/19775.)*100.*100.*pi;
  104. COE2 = pi*50./200;
  105. COS1 = cos (COE2*180./pi); SIN1 = sin (COE2*180./pi);
  106. G_ANA = COE1*50.*(1./COS1);
  107. DGDA_ANA = COE1*((1./COS1) + (COE2*SIN1/(COS1*COS1)));
  108. ********************************
  109. * Appel à la procédure G_THETA *
  110. ********************************
  111. TAB = TABLE ;
  112. TAB.'MAILLAGE'= SUT;
  113. TAB.'FISSURE' = LIFIS;
  114. TAB.'FONDFISS' = PB;
  115. AFF = TABLE; AFF.1 = OB1;
  116. TAB2=TABLE;
  117. TAB2.'DEPLACEMENT'=U;
  118. TAB2.'CONTRAINTE'=SIG;
  119.  
  120. SUPTAB = TABLE ;
  121. SUPTAB.'OBJECTIF' = MOT 'J';
  122. SUPTAB.'LEVRE_SUPERIEURE' = lifis;
  123. SUPTAB.'FRONT_FISSURE' = PB ;
  124. SUPTAB.'MODELE' = ob1;
  125. SUPTAB.'CARACTERISTIQUES' = ma1;
  126. SUPTAB.'SOLUTION_RESO' = u;
  127. SUPTAB.'CHARGEMENTS_MECANIQUES' = FO1;
  128. i = 5;
  129. repeter bbbb 1;
  130. i = i + 1;
  131. SUPTAB.'COUCHE' = i;
  132. G_THETA SUPTAB;
  133. G_NUM = SUPTAB.'RESULTATS';
  134. ERR1 = (ABS ((G_NUM - G_ANA)/G_ANA))*100.;
  135. MESS 'G_NUM =' G_NUM 'Erreur =' (CHAI ERR1 ' %');
  136. fin bbbb;
  137. *********************************
  138. * Appel à la procédure T_PITETA *
  139. *********************************
  140. SUPTAB.'OBJECTIF' = MOT 'DJ/DA';
  141. SUPTAB.'BLOCAGES_MECANIQUES'=CDL1 ;
  142. i = 5;
  143. repeter bbbb 1;
  144. i = i + 1;
  145. SUPTAB.'COUCHE' = i;
  146. G_THETA SUPTAB;
  147. DGDA_NUM = SUPTAB.'RESULTATS';
  148. ERR2 = (ABS ((DGDA_NUM - DGDA_ANA)/DGDA_ANA))*100.;
  149. MESS 'DGDA_NUM =' DGDA_NUM 'Erreur =' (CHAI ERR2 ' %');
  150. fin bbbb;
  151. **************************************
  152. ************ Arrêt du calcul *********
  153. **************************************
  154. SI ((ERR1 > 0.65) OU (ERR2 > 0.5));
  155. ERRE 5;
  156. SINO;
  157. ERRE 0;
  158. FINSI;
  159. FIN;
  160.  
  161.  
  162.  
  163.  
  164.  
  165.  
  166.  
  167.  
  168.  
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  
  176.  
  177.  
  178.  
  179.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales