Télécharger rupt10.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt10.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ****************************************************
  6. * *
  7. * VALIDATION DE LA METHODE DES DFEPLACEMENTS *
  8. * DANS LE CAS D'UNE PLAQUE EN FLEXION PURE. *
  9. * SOLUTION DE REFERENCE : *
  10. * Compendium of STRESS INTENSITY FACTORS *
  11. * by Rooke & Cartwright. Section Plates *
  12. * and Shells "Central crack in a finite width *
  13. * plate : uniform bending moment" *
  14. * *
  15. * *
  16. * GEOMETRIE : *
  17. * *
  18. * longueur de la fissure : 2a = 2 x 17.5 MM *
  19. * largeur de la plaque : 2b = 2 x 70 MM *
  20. * Hauteur de la plaque : 2h = 2 x 280 MM *
  21. * Epaisseur de la plaque : e = 0.7 MM *
  22. * *
  23. * MATERIAU : *
  24. * *
  25. * Module d'Young : E = 200000 MPa *
  26. * Coefficient de poisson : NU = 0.3 *
  27. * *
  28. * CHARGEMENT : *
  29. * *
  30. * Flexion pure : M = 114.3 N.MM *
  31. * soit SIGf=10MPa *
  32. * *
  33. * SOLUTION ANALYTIQUE : *
  34. * *
  35. * Fact d'int. de contr : K1 = 30.349 MPa(MM)**0.5 *
  36. * *
  37. ****************************************************
  38.  
  39.  
  40. opti echo 1 dime 2 elem TRI3 ;
  41.  
  42. *****************************************
  43. * SAISSIE DES PARAMETRES DE MAILLAGE *
  44. *****************************************
  45. *
  46. * Epaisseur de l'eprouvette
  47.  
  48. epa1 = .7;
  49.  
  50. * ---------------- A/W :
  51.  
  52. rap1 = 0.25 ;
  53.  
  54. * ---------------- H/W :
  55.  
  56. rap2 = 4. ;
  57.  
  58. * ---------------- W :
  59.  
  60. w = 70. ;
  61.  
  62. * largeur de bande deposee (pour un metal biphase)
  63.  
  64. ldep = 10. ;
  65.  
  66. *eprouvette SENB ou CCP ? (val = 0 ou val = 1) ;
  67.  
  68. val = 1 ;
  69.  
  70. *taille de maille en pointe de fissure
  71.  
  72. tm = .2 ;
  73.  
  74. *nombre de decouge sur 45 degres ;
  75.  
  76. n = 4 ;
  77.  
  78. *introduction d'un pave de quadrangle en pointe de fissure ?
  79. *(non : rep = 0 oui : rep = 1)
  80.  
  81. rep = 1 ;
  82.  
  83. ***************************************
  84. ******* parametres intermediaires *****
  85. ***************************************
  86.  
  87. lcritw = (w * (1. - rap1)) ;
  88. lcrita = w * rap1 ;
  89. *demi-cote du carre
  90. c = mini (prog (w / 5.) ldep lcrita lcritw) ;
  91.  
  92. *rayon du disque
  93. r = c / 2. ;
  94.  
  95. *densite en peripherie de disque
  96. *te = r / 10. ;
  97. te = 1.5 * ((pi * r) / (4. * n)) ;
  98.  
  99. *densite au premier arc
  100. si (ega rep 1) ;
  101. ta = tm * 2. ;
  102. sinon ;
  103. ta = tm ;
  104. finsi ;
  105.  
  106.  
  107. *******************************************
  108. * MAILLAGE *
  109. *******************************************
  110.  
  111. *----------------------------------------------------*
  112. *** partie circulaire autour de la pointe de fissure *
  113. *----------------------------------------------------*
  114.  
  115. p0 = 0. 0. ;
  116. p1 = (rap1 * w) 0. ;
  117. dens ta ;
  118. si (rep ega 0) ;
  119. p2 = p1 plus (tm 0.) ;
  120. sinon ;
  121. p2 = p1 plus ((tm * n * 2.) 0.) ;
  122. si ((tm * n * 2.) > r) ;
  123. nc = r / 2. ;
  124. opti echo 0 ;
  125. mess 'Le produit (tm * n) doit etre inferieur a' nc ;
  126. opti echo 1 ;
  127. opti donn 5 ;
  128. finsi ;
  129. finsi ;
  130. dens te ;
  131. p10 = p1 plus (r 0.) ;
  132.  
  133. ligam0 = p2 d p10 ;
  134.  
  135. su21 = ligam0 rota n 45. p1 ;
  136. l21 = su21 cote 4 ;
  137. c21 = su21 cote 2 ;
  138. su22 = (su21 cote 3) rota n 45. p1 ;
  139. l22 = su22 cote 2 ;
  140. c22 = su22 cote 4 ;
  141. su23 = (su22 cote 3) rota n 45. p1 ;
  142. l23 = su23 cote 4 ;
  143. c23 = su23 cote 2 ;
  144. su24 = (su23 cote 3) rota n 45. p1 ;
  145. l24 = su24 cote 2 ;
  146. c24 = su24 cote 4 ;
  147.  
  148. rac = l21 et l22 et l23 et l24 ;
  149. su2 = su21 et su22 et su23 et su24 ;
  150.  
  151. si (ega rep 0) ;
  152. su0 = cout p1 rac ;
  153. su0l = chan su0 ligne ;
  154. p01 = (p1 plus p2) / 2. ;
  155. lig0 = su0l elem appuye strictement (p1 et (su0 poin proc p01)
  156. et p2) ;
  157. ligam0 = ligam0 et lig0 ;
  158. l1 = ligam0 ;
  159. sinon ;
  160. dens tm ;
  161. qad = p1 plus ((tm * n) 0.) ;
  162. qag = p1 moin ((tm * n) 0.) ;
  163. basd = p1 d n qad ;
  164. basg = p1 d n qag ;
  165. bas = ordo (basg et basd) ;
  166. pave = bas trans n (0. (tm * n)) ;
  167. copav1 = pave cote 2 ;
  168. copav2 = pave cote 3 ;
  169. copav3 = pave cote 4 ;
  170. copav = copav1 et copav2 et copav3 ;
  171. dec = (enti (n / 1.2)) * (-1) ;
  172. joncd = qad d p2 ;
  173. joncg = qag d (su24 poin proc qag) ;
  174. sujon = dall copav joncd rac joncg plan ;
  175. su0 = sujon et pave ;
  176. lig0 = basd et joncd ;
  177. ligam0 = ligam0 et lig0 ;
  178. l1 = ligam0 ;
  179. finsi ;
  180.  
  181.  
  182. *---------------------------------------------*
  183. *** carre exterieur autour du fond de fissure *
  184. *---------------------------------------------*
  185.  
  186. dens (2. * te) ;
  187. pdb = p1 plus (c 0.) ;
  188. pdh = p1 plus (c c) ;
  189. pmh = p1 plus (0. c) ;
  190. pgh = p1 plus (((-1) * c) c) ;
  191. pgb = p1 plus (((-1) * c) 0.) ;
  192.  
  193. card = pdb d n pdh ;
  194. carhd = pdh d n pmh ;
  195. carhg = pmh d n pgh ;
  196. carg = pgh d n pgb ;
  197.  
  198. decc = ((-1) * (enti ((c - r) / (1. * te)))) - 1 ;
  199.  
  200. diad = (c21 poin initial) d decc pdb ;
  201. diadh = (c22 poin final) d decc pdh ;
  202. diam = (c23 poin initial) d decc pmh ;
  203. diagh = (c24 poin final) d decc pgh ;
  204. diag = (c24 poin initial) d decc pgb ;
  205.  
  206. su3 = dall c21 diadh card diad plan;
  207. su4 = (dall c22 diam carhd diadh plan) et
  208. (dall c23 diagh carhg diam plan) ;
  209. su5 = dall c24 diag carg diagh plan ;
  210.  
  211. carre = su0 et su2 et su3 et su4 et su5 ;
  212. ligam1 = ligam0 et diad ;
  213.  
  214.  
  215. *-------------------------*
  216. *** partie metal depose *
  217. *-------------------------*
  218.  
  219.  
  220. clcritw = (c < (lcritw + 0.01)) et (c > (lcritw - 0.01)) ;
  221. clcrita = (c < (lcrita + 0.01)) et (c > (lcrita - 0.01)) ;
  222. cldep = (c < (ldep + 0.01)) et (c > (ldep - 0.01)) ;
  223.  
  224. si ((non clcritw ) et (non clcrita)) ;
  225. * mess 'cas general' ;
  226.  
  227. vtl = 0. (ldep - c) ;
  228. vtg = (((-1) * (lcrita - c)) 0.) ;
  229. vtd = (lcritw - c) 0. ;
  230. nfl = enti ((ldep - c) / (mesu (carhd elem 1) long)) ;
  231. nfg = enti ((lcrita - c) / (mesu (carg elem 1) long)) ;
  232. nfd = enti ((lcritw - c) / (mesu (card elem 1) long)) ;
  233. si (nfg ega 0) ;
  234. nfg = 1 ;
  235. su7 = carg tran nfg vtg ;
  236. sinon ;
  237. densi = (mesu (carg elem 1) long) ;
  238. densf = densi * (1 + (nfg / 20.)) ;
  239. su7 = carg tran 'DINI' densi 'DFIN' densf vtg ;
  240. finsi ;
  241. si (nfd ega 0) ;
  242. nfd = 1 ;
  243. su6 = card tran nfd vtd ;
  244. sinon ;
  245. densi = (mesu (card elem 1) long) ;
  246. densf = densi * (1 + (nfd / 20.)) ;
  247. su6 = card tran 'DINI' densi 'DFIN' densf vtd ;
  248. finsi ;
  249. l8 = (su7 cote 4) et (su6 cote 2) et carhd et carhg ;
  250. l8 = ordo l8 ;
  251. si (cldep) ;
  252. * mess 'cas critique ldep' ;
  253. mdep = carre et su6 et su7 ;
  254. l8b = inve l8 ;
  255. ligam = ligam1 et (su6 cote 4) ;
  256. lsym1 = (su7 cote 3) ;
  257. sinon ;
  258. si (nfl ega 0) ;
  259. nfl = 1 ;
  260. su8 = l8 tran nfl vtl ;
  261. sinon ;
  262. densi = (mesu (carhd elem 1) long) ;
  263. densf = densi * (1 + (nfl / 10.)) ;
  264. su8 = l8 tran 'DINI' densi 'DFIN' densf vtl ;
  265. finsi ;
  266. mdep = carre et su6 et su7 et su8 ;
  267. l8b = su8 cote 3 ;
  268. ligam = ligam1 et (su6 cote 4) ;
  269. lsym1 = (su7 cote 3) et (su8 cote 4) ;
  270. finsi ;
  271.  
  272. finsi ;
  273.  
  274. si (clcritw) ;
  275. * mess 'cas critique W' ;
  276. vtl = 0. (ldep - c) ;
  277. vtt = (((-1) * (lcrita - c)) 0.) ;
  278. nfl = enti ((ldep - c) / (mesu (carhd elem 1) long)) ;
  279. nft = enti ((lcrita - c) / (mesu (carg elem 1) long)) ;
  280. si (nft ega 0) ;
  281. nft = 1 ;
  282. su7 = carg tran nft vtt ;
  283. sinon ;
  284. densi = (mesu (carg elem 1) long) ;
  285. densf = densi * (1 + (nft / 20.)) ;
  286. su7 = carg tran 'DINI' densi 'DFIN' densf vtt ;
  287. finsi ;
  288. l8 = (su7 cote 4) et carhd et carhg ;
  289. l8 = ordo l8 ;
  290. si (cldep) ;
  291. * mess 'cas critique ldep et lcritw' ;
  292. mdep = carre et su7 ;
  293. l8b = inve l8 ;
  294. ligam = ligam1 ;
  295. lsym1 = (su7 cote 3) ;
  296. sinon ;
  297. si (nfl ega 0) ;
  298. nfl = 1 ;
  299. su8 = l8 tran nfl vtl ;
  300. sinon ;
  301. densi = (mesu (carhd elem 1) long) ;
  302. densf = densi * (1 + (nfl / 10.)) ;
  303. su8 = l8 tran 'DINI' densi 'DFIN' densf vtl ;
  304. finsi ;
  305. mdep = carre et su7 et su8 ;
  306. l8b = su8 cote 3 ;
  307. ligam = ligam1 ;
  308. lsym1 = (su7 cote 3) et (su8 cote 4) ;
  309. finsi ;
  310. finsi ;
  311.  
  312. si (clcrita) ;
  313. * mess 'cas critique A' ;
  314. vtl = 0. (ldep - c) ;
  315. vtt = (lcritw - c) 0. ;
  316. nfl = enti ((ldep - c) / (mesu (carhd elem 1) long)) ;
  317. nft = enti ((lcritw - c) / (mesu (card elem 1) long)) ;
  318. si (nft ega 0) ;
  319. nft = 1 ;
  320. su6 = card tran nft vtt ;
  321. sinon ;
  322. densi = (mesu (card elem 1) long) ;
  323. densf = densi * (1 + (nft / 20.)) ;
  324. su6 = card tran 'DINI' densi 'DFIN' densf vtt ;
  325. finsi ;
  326. l8 = (su6 cote 2) et carhd et carhg ;
  327. l8 = ordo l8 ;
  328. si (cldep) ;
  329. * mess 'cas critique ldep et lcrita' ;
  330. mdep = carre et su6 ;
  331. l8b = l8 ;
  332. ligam = ligam1 et (su6 cote 4) ; ;
  333. lsym1 = carg ;
  334. sinon ;
  335. si (nfl ega 0) ;
  336. nfl = 1 ;
  337. su8 = l8 tran nfl vtl ;
  338. sinon ;
  339. densi = (mesu (carhd elem 1) long) ;
  340. densf = densi * (1 + (nfl / 10.)) ;
  341. su8 = l8 tran 'DINI' densi 'DFIN' densf vtl ;
  342. finsi ;
  343. mdep = carre et su6 et su8 ;
  344. l8b = su8 cote 3 ;
  345. l8b = inve l8b ;
  346. ligam = ligam1 et (su6 cote 4) ;
  347. lsym1 = (su8 cote 2) et carg ;
  348. finsi ;
  349. finsi ;
  350.  
  351. *-------------------------*
  352. *** partie metal de base *
  353. *-------------------------*
  354.  
  355. l8b = ordo l8b ;
  356. ppi = l8b poin initial ;pf = l8b poin final ;
  357. lu = (mesu l8b long) / (nbel l8b) * 1.2 ;
  358. fron1 = (ppi plus (0. lu)) d (enti ((nbel l8b) / 1.5))
  359. (pf plus (0. lu)) ;
  360. lub = ((mesu fron1 long) / (nbel fron1)) * 1.2 ;
  361. pib = fron1 poin initial ;pfb = fron1 poin final ;
  362. fron2 = (pib plus (0. lub)) d (enti ((nbel fron1) / 1.5))
  363. (pfb plus (0. lub)) ;
  364.  
  365. join1 = cout l8b fron1 ;
  366. join2 = cout fron1 fron2 ;
  367. join = join1 et join2 ;
  368. joinl = chan join ligne ;
  369. joinp = joinl poin droit p0 (p0 plus (0. 10.)) (tm / 10.) ;
  370. lsym2 = joinl elem appuye strictement joinp ;
  371.  
  372. lrest = ((w * rap2) / 2.) - (ldep + lu + lub) ;
  373. vt = 0. lrest ;
  374. le = mesu (fron2 elem 1) long ;
  375. corp = fron2 tran (enti (lrest / le)) vt ;
  376. lsym3 = corp cote 2 ;
  377.  
  378. pinif = ligam poin initial;
  379.  
  380. *---------------------------*
  381. *particularite pour un CCP *
  382. *---------------------------*
  383.  
  384. si (val ega 1) ;
  385. mbas = corp et join ;
  386. *plan verticale de symetrie
  387. lsym = lsym1 et lsym2 et lsym3 ;
  388. lsym = lsym coul vert ;
  389. *face de chargement
  390. schar = corp cote 3 ;
  391. schar = schar coul roug ;
  392. *ligament
  393. ligam = ligam coul bleu ;
  394. *maillage complet
  395. ccp = mbas et mdep ;
  396. titr 'eprouvette CCP' ;
  397. * trac (ccp et ligam et lsym et schar) ;
  398. finsi ;
  399.  
  400. *----------------------------*
  401. *particularite pour un SENB *
  402. *----------------------------*
  403.  
  404. si (val ega 0) ;
  405. lresid = corp cote 3 ;
  406. resid = lresid tran 1 (0. le) ;
  407. mbas = corp et join et resid ;
  408. *appui
  409. pap = p0 plus (0. ((rap2 / 2.) * w)) ;
  410. pap = mbas poin proc pap ;
  411. pap = manu pap poi1 vert ;
  412. *point d'application de la force
  413. pchar = p0 plus (w 0.) ;
  414. pchar = mdep poin proc pchar ;
  415. pchar = manu pchar poi1 roug ;
  416. *ligament
  417. ligam = ligam coul bleu ;
  418. *maillage complet
  419. senb = mbas et mdep ;
  420. titr 'eprouvette SENB' ;
  421. trac (senb et ligam et pap et pchar) ;
  422. finsi ;
  423. *
  424. *trac (cont ccp);
  425. *
  426. * FIN DE LA DÉFINITION DE LA GÉOMÉTRIE
  427. *
  428. *
  429. opti dime 3 mode trid;
  430. *
  431. * Définition des modèles et du matériau
  432. *
  433. MO1 = MODELE CCP MECANIQUE ELASTIQUE COQ3;
  434. MA0 = MATER MO1 YOUNG 2.E11 NU 0.3 EPAI epa1;
  435. RIG0 = RIGI MO1 MA0;
  436. *
  437. * Définition des conditions aux limites
  438. *
  439. BL1 = BLOQ UY RX ligam;
  440. BL2 = BLOQ UX RY lsym;
  441. BL3 = BLOQ UZ schar;
  442. RIG1 = RIG0 ET BL1 ET BL2 ET BL3;
  443. *
  444. * Chargement : Moment de flexion
  445. *
  446. pinich = schar poin initial;
  447. pfinch = schar poin final;
  448. schar=schar chan poi1;
  449. PMILCH = schar diff (pinich et pfinch);
  450. MOEXT = 10.*(w * (epa1** 2) / 3. / 2.) / ((NBNO schar) - 1);
  451. MOMIL = MOEXT * (NBNO PMILCH);
  452. FO1 = (MOME MX MOEXT (PINICH ET PFINCH)) ET (MOME MX MOMIL PMILCH);
  453. *
  454. * Résolution
  455. *
  456. DEP1 = RESO RIG1 FO1;
  457. *
  458. * Calcul du facteur d'intensité de contrainte
  459. *
  460. pfisin = lsym poin init;
  461. ct1 = cont ccp;
  462. psup = (ct1 diff (ligam et lsym)) poin droi pfisin p1;
  463. ct2 = chan 'SEG2' ct1;
  464. lifis1 = ct2 elem appu stri psup;
  465. *
  466. SUPTAB = TABLE;
  467. SUPTAB.'MODMIXT' = FAUX;
  468. SUPTAB.'LIFIS1' = lifis1;
  469. SUPTAB.'FRTFISS' = p1;
  470. SUPTAB.'MEMBRANE' = FAUX;
  471. SUPTAB.'FLEXION' = VRAI;
  472. SUPTAB.'EPAI' = EPA1;
  473. *
  474. K1TH = 30.3486;
  475. *
  476. SIF SUPTAB MA0 DEP1;
  477. K1MOY = SUPTAB.K1.TOTAL;
  478. MESS ' K1 analytique = 'K1TH;
  479. MESS ' K1 calculé par SIF = 'K1MOY;
  480. err1 = 100.*(K1TH - K1MOY)/K1TH;err1=abs err1;
  481. mess ' Erreur : 'err1' en %';
  482. *
  483. SI (err1 < 2.) ;
  484. MESS 'PROCEDURE <SIF> ERR 0';
  485. ERRE 0;
  486. SINON;
  487. MESS 'PROCEDURE <SIF> ERR 5';
  488. ERRE 5;
  489. FINSI;
  490. fin;
  491.  
  492.  
  493.  
  494.  
  495.  
  496.  
  497.  
  498.  
  499.  
  500.  
  501.  
  502.  
  503.  
  504.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales