Télécharger rotor4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rotor4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. ************************************************************************
  6. * *
  7. * Mots-clés : Vibrations, calcul modal, machines tournantes, *
  8. * poutre, modes complexes *
  9. * *
  10. * *
  11. * Test de GYROSCOPIQUE, AMOR, CAMPBELL pour les elements de poutre *
  12. * Etude d'une machine tournante dans le repere inertiel (ou fixe) *
  13. * Elements: TUYAU et SECTION (fibre) *
  14. * POUT, TIMO en exemple *
  15. * *
  16. * 1-Influence des déformations de cisaillement *
  17. * 2-Etude de la stabilité avec un amortissement corotatif *
  18. * *
  19. * Modélisation d'un tube *
  20. * *
  21. * Auteur: Didier Combescure Juillet 2003 *
  22. * *
  23. ************************************************************************
  24. *GRAPH = 'Y';
  25. GRAPH = 'N';
  26. *
  27. *L1 = 0.50 ;
  28. L1 = 1.20;
  29. Re1 = 0.1 ;
  30. epa1 = 0.0012;
  31. E1 = 2.e+11 ;
  32. Nu1 = 0.2 ;
  33. Rho1 = 1600. ;
  34. Visc1 = 0.00001*E1;
  35. *Visc1 = 0.0*E1;
  36. *
  37. * Description de la section
  38. *
  39. OPTI 'DIME' 2 'ELEM' QUA4;
  40. OPTI EPSI LINEAIRE;
  41. P0S = 0. 0.;
  42. P1S = (Re1 - (0.5*epa1)) 0.;
  43. P2S = (Re1 + (0.5*epa1)) 0.;
  44. *
  45. P12S = D 1 P1S P2S;
  46. SURS = P12S ROTA 50 360. P0S;
  47. ELIM 0.0001 SURS;
  48. *
  49. OPTI 'DIME' 3 'ELEM' SEG2;
  50. *
  51. *
  52. P0 = 0. 0. 0.;
  53. P1 = L1 0. 0. ;
  54. GeoRot = D 100 P0 P1;
  55. *
  56. * OMEG=1
  57. * On donne une vitesse de rotation de 1 rad/s
  58. *
  59. * MODELE SECTION
  60. *
  61. kappa = 0.52;
  62. *kappa = 1.0;
  63. *kappB = 1.00;
  64. *
  65. MOSEC1 = MODE SURS MECANIQUE ELASTIQUE QUAS;
  66. MASEC1 = MATE MOSEC1 'YOUNG' E1 'NU' Nu1 'RHO' Rho1
  67. ALPY kappa ALPZ kappa 'VISQ' Visc1;
  68. *
  69. *
  70. * Elément TIMO - FIBRE
  71. *
  72. Mod1 = MODE GEOROT 'MECANIQUE' ELASTIQUE SECTION TIMO;
  73. Mat1 = MATE Mod1 'MODS' MOSEC1 'MATS' MASEC1
  74. 'OMEG' (2.*pi) VECT (0. 0. 1.) ;
  75. *
  76. *
  77. * Elément TUYAU
  78. *
  79. *
  80. Mod2 = MODE GEOROT 'MECANIQUE' TUYA;
  81. Mat2 = MATE Mod2 'YOUNG' E1 'NU' Nu1 'RHO' Rho1
  82. 'RAYO' Re1 'EPAI' EPA1 'OMEG' (2.*pi) 'VISQ' Visc1;
  83. *
  84. * Elément POUT
  85. *
  86. *
  87. Mod3 = MODE GEOROT 'MECANIQUE' POUT;
  88. Mat3 = MATE Mod3 'YOUNG' E1 'NU' Nu1 'RHO' Rho1
  89. 'SECT' (pi * ((Re1 ** 2)-((Re1 - epa1)**2)) )
  90. 'INRY' (pi * ((Re1 ** 4)-((Re1 - epa1)**4))/4.)
  91. 'INRZ' (pi * ((Re1 ** 4)-((Re1 - epa1)**4))/4.)
  92. 'TORS' (pi * ((Re1 ** 4)-((Re1 - epa1)**4))/2.)
  93. * 'SECY' (kappB*(pi * ((Re1 ** 2)-((Re1 - epa1)**2))) )
  94. * 'SECZ' (kappB*(pi * ((Re1 ** 2)-((Re1 - epa1)**2))) )
  95. 'OMEG' (2.*pi) 'VISQ' Visc1;
  96. *
  97. *
  98. * Timoshenko
  99. *
  100. Mod4 = MODE GEOROT 'MECANIQUE' TIMO;
  101. Car4 = CARA Mod4 'SECT' (pi * ((Re1 ** 2)-((Re1 - epa1)**2)) )
  102. 'INRY' (pi * ((Re1 ** 4)-((Re1 - epa1)**4))/4.)
  103. 'INRZ' (pi * ((Re1 ** 4)-((Re1 - epa1)**4))/4.)
  104. 'TORS' (pi * ((Re1 ** 4)-((Re1 - epa1)**4))/2.)
  105. 'SECY' (kappa*(pi * ((Re1 ** 2)-((Re1 - epa1)**2))) )
  106. 'SECZ' (kappa*(pi * ((Re1 ** 2)-((Re1 - epa1)**2))) )
  107. 'OMEG' (2.*pi);
  108. *
  109. *
  110. Mat4 = MATE Mod4 'YOUNG' E1 'NU' Nu1 'RHO' Rho1 'VISQ' Visc1;
  111. Mat4 = Mat4 et Car4;
  112. *
  113. MESH3D = POUT2MAS Mod1 Mat1 'GAUSS';
  114. SI (EGA GRAPH 'Y');
  115. OEIL = 10. 10. 10.;
  116. ELIM 0.0001 MESH3D;
  117. Titre 'Maillage poutre avec section fibre';
  118. trac OEIL MESH3D CACH;
  119. trac OEIL (MESH3D et GeoRot);
  120. FINSI;
  121. *
  122. *
  123. * Cond. limites : 2 appuis
  124. *
  125. *
  126. Blo2 = (BLOQ 'UZ' P0) ET
  127. (BLOQ 'UY' P0) ET
  128. (BLOQ 'UX' P0);
  129.  
  130. Blo3 = (BLOQ 'UZ' P1) ET
  131. (BLOQ 'UY' P1) ET
  132. (BLOQ 'UX' P1);
  133. Blo1 = BLOQ 'RX' Georot;
  134. *
  135. MMass1 = MASS Mod1 (Mat1) ;
  136. MRigi1 = RIGI Mod1 (Mat1) ;
  137. *
  138. MMass2 = MASS Mod2 (Mat2) ;
  139. MRigi2 = RIGI Mod2 (Mat2) ;
  140. *
  141. MMass3 = MASS Mod3 (Mat3) ;
  142. MRigi3 = RIGI Mod3 (Mat3) ;
  143. *
  144. MMass4 = MASS Mod4 (Mat4) ;
  145. MRigi4 = RIGI Mod4 (Mat4) ;
  146. *
  147. * Matrice de couplage gyroscopique
  148. *
  149. CG1 = GYROSCOPIQUE Mod1 Mat1;
  150. CG2 = GYROSCOPIQUE Mod2 Mat2;
  151. CG3 = GYROSCOPIQUE Mod3 Mat3;
  152. CG4 = GYROSCOPIQUE Mod4 Mat4;
  153. *
  154. CDAM1 CDAH1 = 'AMOR' Mod1 Mat1 'COROTATIF';
  155. CDAM2 CDAH2 = 'AMOR' Mod2 Mat2 'COROTATIF';
  156. CDAM3 CDAH3 = 'AMOR' Mod3 Mat3 'COROTATIF';
  157. CDAM4 CDAH4 = 'AMOR' Mod4 Mat4 'COROTATIF';
  158. *
  159. TBasR1 = VIBR 'PROCHE' (prog 100.) (lect 2)
  160. (MRigi1 ET Blo1 ET Blo2 et Blo3)
  161. MMass1 ;
  162. TBasR2 = VIBR 'PROCHE' (prog 100.) (lect 2)
  163. (MRigi2 ET Blo1 ET Blo2 et Blo3)
  164. MMass2 ;
  165. TBasR3 = VIBR 'PROCHE' (prog 100.) (lect 2)
  166. (MRigi3 ET Blo1 ET Blo2 et Blo3)
  167. MMass3 ;
  168. TBasR4 = VIBR 'PROCHE' (prog 100.) (lect 2)
  169. (MRigi4 ET Blo1 ET Blo2 et Blo3)
  170. MMass4 ;
  171. *
  172. TMod1 = TBasR1 . 'MODES' ;
  173. TMod2 = TBasR2 . 'MODES' ;
  174. TMod3 = TBasR3 . 'MODES' ;
  175. TMod4 = TBasR4 . 'MODES' ;
  176. NbMod3 = (DIME TMod3) - 2 ;
  177. TInd3 = INDEX (TMod3 . 1) ;
  178. *
  179. SI (EGA GRAPH 'Y');
  180. oeil = 100. 1. 0. ;
  181. REPETER bbb1 NbMod3 ;
  182. i = &bbb1 ;
  183. Frq1 = TMod1 . i . 'FREQUENCE' ;
  184. Def1 = TMod1 . i . 'DEFORMEE_MODALE' ;
  185. Frq2 = TMod2 . i . 'FREQUENCE' ;
  186. Def2 = TMod2 . i . 'DEFORMEE_MODALE' ;
  187. Frq3 = TMod3 . i . 'FREQUENCE' ;
  188. Def3 = TMod3 . i . 'DEFORMEE_MODALE' ;
  189. Frq4 = TMod4 . i . 'FREQUENCE' ;
  190. Def4 = TMod4 . i . 'DEFORMEE_MODALE' ;
  191. TITRE Frq1 ;
  192. trac oeil (defo georot def1);
  193. TITRE Frq2 ;
  194. trac oeil (defo georot def2);
  195. TITRE Frq3 ;
  196. trac oeil (defo georot def3);
  197. TITRE Frq4 ;
  198. trac oeil (defo georot def4);
  199. FIN bbb1 ;
  200. FINSI;
  201. *
  202. * On teste pour le modele a fibre
  203. *
  204. MAmor1 = CDAM1;
  205. MAmor2 = CDAM2;
  206. MAmor3 = CDAM3;
  207. MAmor4 = CDAM4;
  208. *
  209. *-Projection des matrices assemblées sur la base réelle
  210. *
  211. MMasP1 = PJBA TBasR1 MMass1 ;
  212. MRigP1 = PJBA TBasR1 MRigi1 ;
  213. MAmoP1 = PJBA TBasR1 MAmor1 ;
  214. MAmHP1 = PJBA TBasR1 CDAH1;
  215. Cg1P = PJBA TBasR1 Cg1 ;
  216. *
  217. MMasP2 = PJBA TBasR2 MMass2 ;
  218. MRigP2 = PJBA TBasR2 MRigi2 ;
  219. MAmoP2 = PJBA TBasR2 MAmor2 ;
  220. MAmHP2 = PJBA TBasR2 CDAH2;
  221. Cg2P = PJBA TBasR2 Cg2 ;
  222. *
  223. MMasP3 = PJBA TBasR3 MMass3 ;
  224. MRigP3 = PJBA TBasR3 MRigi3 ;
  225. MAmoP3 = PJBA TBasR3 MAmor3 ;
  226. MAmHP3 = PJBA TBasR3 CDAH3;
  227. Cg3P = PJBA TBasR3 Cg3 ;
  228. *
  229. MMasP4 = PJBA TBasR4 MMass4 ;
  230. MRigP4 = PJBA TBasR4 MRigi4 ;
  231. MAmoP4 = PJBA TBasR4 MAmor4 ;
  232. MAmHP4 = PJBA TBasR4 CDAH4;
  233. Cg4P = PJBA TBasR4 Cg4 ;
  234. *
  235. * Vitesse de rotation (0 Hz)
  236. *
  237. Omeg1 =0.;
  238. *
  239. * Calcul des modes complexes avec VIBC - Bernoulli
  240. *
  241. BasCi1 = VIBC MMasP4 (MRigP4 et (Omeg1*MAmHP4))
  242. (MAmoP4 et (Omeg1*Cg4P)) TBasR4 ;
  243. *
  244. ModBasC = BasCi1.'MODES';
  245. NbMod1 = (DIME ModBasC) - 2;
  246. *
  247. FRQR = TABLE;
  248. FRQI = TABLE;
  249. FRQ = TABLE;
  250. AMOR= TABLE;
  251. *
  252. mess 'Frequences et amortissement au repos';
  253. *
  254. REPETER bbb2 NbMod1 ;
  255. i2 = &bbb2 ;
  256. FrqR1 = BasCi1.'MODES'.i2.'FREQUENCE_REELLE' ;
  257. FrqI1 = BasCi1.'MODES'.i2.'FREQUENCE_IMAGINAIRE' ;
  258. DefR1 = BasCi1.'MODES'.i2.'DEFORMEE_MODALE_REELLE';
  259. DefI1 = BasCi1.'MODES'.i2.'DEFORMEE_MODALE_IMAGINAIRE';
  260. FRQR.i2 = FrqR1;
  261. FRQI.i2 = FrqI1;
  262. FRQ.i2 = ((FrqR1 ** 2) + (FrqI1 ** 2)) ** 0.5 ;
  263. AMOR.i2 = FrqI1 /(FRQ.i2 );
  264. mess 'Valeur propre réelle';
  265. list (FrqR.i2);
  266. mess 'Valeur propre imaginaire';
  267. list (FrqI.i2);
  268. mess 'Fréquence';
  269. list (FRQ.i2);
  270. mess 'Amortissement';
  271. list (AMOR.i2);
  272. FIN bbb2;
  273. *
  274. *
  275. * Vitesse de rotation (1000 Hz)
  276. *
  277. Omeg1 =1000.;
  278. *
  279. * Calcul des modes complexes avec VIBC - Timoshenko
  280. *
  281. BasCi1 = VIBC MMasP4 (MRigP4 et (Omeg1*MAmHP4))
  282. (MAmoP4 et (Omeg1*Cg4P)) TBasR4;
  283. *
  284. ModBasC = BasCi1.'MODES';
  285. NbMod1 = (DIME ModBasC) - 2;
  286. *
  287. FRQR = TABLE;
  288. FRQI = TABLE;
  289. FRQ = TABLE;
  290. AMOR= TABLE;
  291. *
  292. mess 'Frequences et amortissement a 1000 Hz';
  293. *
  294. REPETER bbb2 NbMod1 ;
  295. i2 = &bbb2 ;
  296. FrqR1 = BasCi1.'MODES'.i2.'FREQUENCE_REELLE' ;
  297. FrqI1 = BasCi1.'MODES'.i2.'FREQUENCE_IMAGINAIRE' ;
  298. DefR1 = BasCi1.'MODES'.i2.'DEFORMEE_MODALE_REELLE';
  299. DefI1 = BasCi1.'MODES'.i2.'DEFORMEE_MODALE_IMAGINAIRE';
  300. FRQR.i2 = FrqR1;
  301. FRQI.i2 = FrqI1;
  302. FRQ.i2 = ((FrqR1 ** 2) + (FrqI1 ** 2)) ** 0.5 ;
  303. AMOR.i2 = FrqI1 /(FRQ.i2);
  304. mess 'Valeur propre réelle';
  305. list (FrqR.i2);
  306. mess 'Valeur propre imaginaire';
  307. list (FrqI.i2);
  308. mess 'Fréquence';
  309. list (FRQ.i2);
  310. mess 'Amortissement';
  311. list (AMOR.i2);
  312. FIN bbb2;
  313. *
  314. * Calcul du diagramme de Campbell - Bernoulli
  315. *
  316. TAB1 = TABLE;
  317. TAB1.'BASE_MODALE' = TBasR3;
  318. TAB1.'MASS_PROJ' = MMasP3;
  319. TAB1.'RIGI_PROJ' = MRigP3;
  320. TAB1.'GYRO_PROJ' = Cg3P;
  321. TAB1.'AMOR_PROJ' = MAmoP3;
  322. TAB1.'KROT_PROJ' = MAmHP3;
  323. TAB1.'AFFICHAGE' = VRAI;
  324. *PRFREQ = (prog 0. pas 2.5 100.)*100/(2.*pi);
  325. PRFREQ = (prog 0. pas 25 100.)*100/(2.*pi);
  326. CAMPBELL TAB1 PRFREQ;
  327. *
  328. EVFRb1 = (TAB1. 1). 'FREQUENCE_MODULE' ;
  329. EVFRb2 = (TAB1. 4). 'FREQUENCE_MODULE' ;
  330. EVAMb1 = (TAB1. 1). 'AMORTISSEMENT' ;
  331. EVAMb2 = (TAB1. 4). 'AMORTISSEMENT' ;
  332. *
  333. SI (EGA GRAPH 'Y');
  334. dess (EVFRb1 et EVFRb2 );
  335. dess (EVAMb1 et EVAMb2);
  336. FINSI;
  337. *
  338. * Calcul du diagramme de Campbell - Timoshenko
  339. *
  340. TAB1 = TABLE;
  341. TAB1.'BASE_MODALE' = TBasR4 ;
  342. TAB1.'MASS_PROJ' = MMasP4;
  343. TAB1.'RIGI_PROJ' = MRigP4;
  344. TAB1.'GYRO_PROJ' = Cg4P;
  345. TAB1.'AMOR_PROJ' = MAmoP4;
  346. TAB1.'KROT_PROJ' = MAmHP4;
  347. TAB1.'AFFICHAGE' = VRAI;
  348. *PRFREQ = (prog 0. pas 2.5 100.)*100/(2.*pi);
  349. PRFREQ = (prog 0. pas 25. 100.)*100/(2.*pi);
  350. CAMPBELL TAB1 PRFREQ;
  351. *
  352. EVFRT1 = ((TAB1. 1). 'FREQUENCE_MODULE') COUL rouge ;
  353. EVFRT2 = ((TAB1. 4). 'FREQUENCE_MODULE') COUL rouge ;
  354. EVAMT1 = ((TAB1. 1). 'AMORTISSEMENT') COUL rouge ;
  355. EVAMT2 = ((TAB1. 4). 'AMORTISSEMENT') COUL rouge ;
  356. *
  357. EvFreOme = evol manu (prog 0. 1600.) (prog 0. (1600.));
  358. EvFreZer = evol manu (prog 0. 1600.) (prog 0. 0.);
  359. *
  360. SI (EGA GRAPH 'Y');
  361. 'DESS' (EVFRT1 et EVFRT2 et EvFreOme)
  362. 'TITR' 'Frequences' 'TITX' 'Freq rot (Tour/s)'
  363. 'TITY' 'Frequences (Hz)';
  364. 'DESS' (EVFRT1 et EVFRT2)
  365. 'TITR' 'Frequences' 'TITX' 'Freq rot (Tour/s)'
  366. 'TITY' 'Frequences (Hz)';
  367. 'DESS' (EVAMT1 et EVAMT2 et EvFreZer)
  368. 'TITR' 'Amortissement' 'TITX' 'Freq rot (Tour/s)'
  369. 'TITY' 'Amortissement (%)';
  370. *
  371. dess (EVFRT1 et EVFRT2 et EVFRB1 et EVFRB2 et EvFreOme);
  372. dess (EVAMT1 et EVAMT2 et EVAMB1 et EVAMB2);
  373. *
  374. finsi;
  375. *
  376. mess 'Frequences à 0 Hz et 1000 Hz';
  377. mess 'Poutre de Bernoulli';
  378. FR1b = extr (IPOL (prog 0.01 1000.) (extr EVFRB1 absc)
  379. (extr EVFRB2 ordo)) 1;
  380. AM1b = extr (IPOL (prog 0.01 1000.) (extr EVAMB1 absc)
  381. (extr EVAMB1 ordo)) 1;
  382. FR2b = extr (IPOL (prog 0.01 1000.) (extr EVFRB1 absc)
  383. (extr EVFRB2 ordo)) 2;
  384. AM2b = extr (IPOL (prog 0.01 1000.) (extr EVAMB1 absc)
  385. (extr EVAMB1 ordo)) 2;
  386. mess 'Poutre de Timoshenko';
  387. FR1T = extr (IPOL (prog 0.01 1000.) (extr EVFRT1 absc)
  388. (extr EVFRT2 ordo)) 1;
  389. AM1T = extr (IPOL (prog 0.01 1000.) (extr EVAMT1 absc)
  390. (extr EVAMT1 ordo)) 1;
  391. FR2T = extr (IPOL (prog 0.01 1000.) (extr EVFRT1 absc)
  392. (extr EVFRT2 ordo)) 2;
  393. AM2T = extr (IPOL (prog 0.01 1000.) (extr EVAMT1 absc)
  394. (extr EVAMT1 ordo)) 2;
  395.  
  396. *
  397. * On norme
  398. *
  399. EVFRb1N = EVOL MANU (extr EVFRb1 absc)
  400. ((extr EVFRb1 ordo)/FR1b );
  401. EVFRb2N = EVOL MANU (extr EVFRb1 absc)
  402. ((extr EVFRb2 ordo)/FR1b );
  403. EVFRT1N = EVOL MANU (extr EVFRT1 absc)
  404. ((extr EVFRT1 ordo)/FR1T );
  405. EVFRT2N = EVOL MANU (extr EVFRT1 absc)
  406. ((extr EVFRT2 ordo)/FR1T );
  407. *
  408. SI (EGA GRAPH 'Y');
  409. TA= table;
  410. ta.1 = 'TIRR';
  411. ta.2 = 'TIRR';
  412. titre 'Diagramme de Campbell
  413. (Frequence = f(Fréquence rotation en Hz)';
  414. DESS (EVFRb1 et EVFRb2 et EVFRT1 et EVFRT2) ta ybord 0. 4000.;
  415. DESS (EVFRb1 et EVFRb2 et EVFRT1 et EVFRT2) ta ;
  416. titre 'Diagramme de Campbell
  417. (F/F0 = f(Fréquence rotation en Hz)';
  418. DESS (EVFRb1N et EVFRb2N et EVFRT1N et EVFRT2N) ta ybord 0. 2.;
  419. DESS (EVFRb1N et EVFRb2N et EVFRT1N et EVFRT2N) ta;
  420. FINSI;
  421. *
  422. *
  423. FR1Th = 787.3;
  424. FR2Th = 812.7;
  425. AM1Th = 2.48E-02;
  426. AM2Th = -0.559E-02;
  427. Errfrq = 0.01*FR1Th;
  428. Erramo = 0.01*AM1Th;
  429. *
  430. SI ((ABS(FR1T - FR1Th) > Errfrq ) OU
  431. (ABS(FR2T - FR2Th) > Errfrq ) OU
  432. (ABS(AM1T - AM1Th) > Erramo ) OU
  433. (ABS(AM2T - AM2Th) > Erramo ));
  434. ERRE 5;
  435. SINON;
  436. ERRE 0;
  437. FINSI;
  438. *
  439. FIN;
  440. *
  441.  
  442.  
  443.  
  444.  
  445.  
  446.  
  447.  
  448.  
  449.  
  450.  
  451.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales