Télécharger rotor3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rotor3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. ************************************************************************
  6. * *
  7. * Mots-clés : Vibrations, calcul modal, machines tournantes, *
  8. * poutre, modes complexes, reponse frequntielle *
  9. * *
  10. * *
  11. * Test de GYROSCOPIQUE, CAMPBELL et BALOURD pour les elements de poutre*
  12. * Etude d'une machine tournante dans le repere inertiel (ou fixe) *
  13. * Elements: POUT *
  14. * *
  15. * 1-Influence des déformations de cisaillement *
  16. * 2-Etude de la stabilité avec un amortissement corotatif *
  17. * *
  18. * 3 Volants d'inertie sur 2 appuis anisotropes (Exemple Lalanne P.68)*
  19. * Modélisation d'un tube *
  20. * *
  21. * Auteur: Didier Combescure Juillet 2003 *
  22. * *
  23. ************************************************************************
  24. *
  25. OPTI EPSI LINEAIRE;
  26. *GRAPH = 'Y';
  27. GRAPH = 'N';
  28. *
  29. * Caractéristiques de l'arbre et du volant d'inertie
  30. *
  31. Ltot = 0.40 ;
  32. L1 = 0.2;
  33. L2 = 0.3 + L1;
  34. L3 = 0.5 + L2;
  35. L4 = 0.3 + L3;
  36. *
  37. ReRot = 0.05 ;
  38. Re1 = 0.12 ;
  39. Re2 = 0.20 ;
  40. Re3 = 0.20 ;
  41. h1 = 0.05;
  42. h2 = 0.05;
  43. h3 = 0.06;
  44. *
  45. E1 = 2.e+11 ;
  46. Nu1 = 0.3 ;
  47. Rho1 = 7800. ;
  48. *
  49. Sarbre = pi*(ReRot**2);
  50. Inxarb = pi*(ReRot**4)/2.;
  51. Inyarb = pi*(ReRot**4)/4.;
  52. *
  53. Svol1 = pi*(Re1**2);
  54. Inxvol1 = pi*(Re1**4)/2.;
  55. Inyvol1 = pi*(Re1**4)/4.;
  56. *
  57. Svol2 = pi*(Re2**2);
  58. Inxvol2 = pi*(Re2**4)/2.;
  59. Inyvol2 = pi*(Re2**4)/4.;
  60. *
  61. Svol3 = pi*(Re3**2);
  62. Inxvol3 = pi*(Re3**4)/2.;
  63. Inyvol3 = pi*(Re3**4)/4.;
  64. *
  65. * Raideur et amortissement des supports
  66. *
  67. Ky = 70000000.;
  68. Kz = 50000000.;
  69. Cy = 700.;
  70. Cz = 500.;
  71. *
  72. * Maillage de poutre
  73. *
  74. OPTI 'DIME' 3 'ELEM' SEG2;
  75. *
  76. P0 = 0. 0. 0.;
  77. P1volm = (L1 - (0.5*h1)) 0. 0. ;
  78. P1 = (L1) 0. 0. ;
  79. P1volp = (L1 + (0.5*h1)) 0. 0. ;
  80. P1 = L1 0. 0. ;
  81. P2volm = (L2 - (0.5*h2)) 0. 0. ;
  82. P2 = L2 0. 0. ;
  83. P2volp = (L2 + (0.5*h2)) 0. 0. ;
  84. P3volm = (L3 - (0.5*h3)) 0. 0. ;
  85. P3 = L3 0. 0. ;
  86. P3volp = (L3 + (0.5*h3)) 0. 0. ;
  87. P4 = L4 0. 0. ;
  88. *
  89. GeoArbre = (D 5 P0 P1volm) et (D 5 P1volp P2volm) et (D 5 P2volp P3volm)
  90. et (D 5 P3volp P4);
  91. GeoVol1 = (D 1 P1volm P1) et (D 1 P1 P1volp);
  92. GeoVol2 = (D 1 P2volm P2) et (D 1 P2 P2volp);
  93. GeoVol3 = (D 1 P3volm P3) et (D 1 P3 P3volp);
  94. *
  95. Geotot = GeoArbre et GeoVol1 et GeoVol2 et GeoVol3;
  96. *
  97. * Elément POUT
  98. *
  99. Mod1a = MODELI GeoArbre 'MECANIQUE' POUT;
  100. Mat1a = MATE Mod1a 'YOUNG' E1 'NU' Nu1 'RHO' Rho1
  101. 'SECT' Sarbre 'INRY' Inyarb 'INRZ' Inyarb 'TORS' Inxarb
  102. 'OMEG' 1.;
  103. Mod1b = MODELI GeoVol1 'MECANIQUE' POUT;
  104. Mat1b = MATE Mod1b 'YOUNG' E1 'NU' Nu1 'RHO' Rho1
  105. 'SECT' Svol1 'INRY' Inyvol1 'INRZ' Inyvol1
  106. 'TORS' Inxvol1 'OMEG' 1.;
  107. Mod1c = MODELI GeoVol2 'MECANIQUE' POUT;
  108. Mat1c = MATE Mod1c 'YOUNG' E1 'NU' Nu1 'RHO' Rho1
  109. 'SECT' Svol2 'INRY' Inyvol2 'INRZ' Inyvol2
  110. 'TORS' Inxvol2 'OMEG' 1.;
  111. Mod1d = MODELI GeoVol3 'MECANIQUE' POUT;
  112. Mat1d = MATE Mod1d 'YOUNG' E1 'NU' Nu1 'RHO' Rho1
  113. 'SECT' Svol3 'INRY' Inyvol3 'INRZ' Inyvol3
  114. 'TORS' Inxvol3 'OMEG' 1.;
  115. *
  116. mod1 = mod1a et mod1b et mod1c et mod1d;
  117. mat1 = mat1a et mat1b et mat1c et mat1d;
  118. *
  119. * Visualisation avec POUT2MAS
  120. *
  121. TAB1 =TABLE;
  122. TAB1.'POUTRE' = table;
  123. (TAB1.'POUTRE').'CIRCULAIRE' = VRAI ;
  124. (TAB1.'POUTRE').'NCIRC' = 40 ;
  125. *
  126. SI (EGA GRAPH 'Y');
  127. MESHVOL = POUT2MAS mod1 mat1 GAUSS TAB1;
  128. trac MESHVOL cach;
  129. MESHVOL = POUT2MAS mod1 mat1 MASSIF TAB1;
  130. elim 0.0001 (MESHVOL);
  131. trac MESHVOL cach;
  132. FINSI;
  133. *
  134. * Cond. limites : 2 appuis
  135. *
  136. Blo1 = (BLOQ 'RX' Geotot) et (BLOQ 'UX' Geotot);
  137. *
  138. Kxp= (APPUI UY KY p0) et (APPUI UY KY p4);
  139. Kyp= (APPUI UZ KZ p0) et (APPUI UZ KZ p4);
  140. Cxp= (APPUI UY CY p0) et (APPUI UY CY p4);
  141. Cyp= (APPUI UZ CZ p0) et (APPUI UZ CZ p4);
  142. *
  143. Kappui = Kxp et Kyp;
  144. Cappui = Cxp et Cyp;
  145. *
  146. MMass1 = MASS Mod1 (Mat1) ;
  147. MRigi1 = RIGI Mod1 (Mat1) ;
  148. *
  149. * Matrice de couplage gyroscopique
  150. *
  151. CG1 = GYROSCOPIQUE Mod1 Mat1;
  152. *
  153. * Calcul des modes propres réels
  154. *
  155. TBasR1 = VIBR 'PROCHE' (prog 100.) (lect 12)
  156. (MRigi1 ET Blo1 et Kappui)
  157. MMass1 ;
  158. *
  159. TMod1 = TBasR1 . 'MODES' ;
  160. NbMod1 = (DIME TMod1) - 2 ;
  161. TInd1 = INDEX (TMod1 . 1) ;
  162. *
  163. SI (EGA GRAPH 'Y');
  164. oeil = 1. 10. 0. ;
  165. REPETER bbb1 NbMod1 ;
  166. i = &bbb1 ;
  167. Frq1 = TMod1 . i . 'FREQUENCE' ;
  168. Def1 = TMod1 . i . 'DEFORMEE_MODALE' ;
  169. MESS 'Mode ' i ':' Frq1 'Hz' ;
  170. TITRE Frq1 ;
  171. trac oeil ((defo geotot def1) et (defo geotot def1 0.));
  172. FIN bbb1 ;
  173. *
  174. TAB1 =TABLE;
  175. TAB1.'POUTRE' = table;
  176. (TAB1.'POUTRE').'CIRCULAIRE' = VRAI ;
  177. (TAB1.'POUTRE').'NCIRC' = 40 ;
  178. TAB1.'DEPLACEMENTS' = TABLE;
  179. (TAB1.'DEPLACEMENTS'). 1 = (TMod1 . 4) . 'DEFORMEE_MODALE' ;
  180. *
  181. MESHVOL = POUT2MAS mod1 mat1 GAUSS TAB1;
  182. trac (defo MESHVOL ((TAB1.'DEPLACEMENTS'). 1)) cach;
  183. FINSI;
  184. *
  185. *-Projection des matrices assemblées sur la base réelle
  186. *
  187. MMasP1 = PJBA TBasR1 MMass1 ;
  188. MRigP1 = PJBA TBasR1 MRigi1 ;
  189. Cg1P = PJBA TBasR1 Cg1 ;
  190. KApp1p = PJBA TBasR1 (Kappui et Blo1);
  191. CApp1p = PJBA TBasR1 Cappui;
  192. *
  193. * Calcul des fréquences à 25000 tours/min
  194. *
  195. Omega1 = 25000.*2.*pi/60.;
  196. BasCiB = VIBC MMasP1 (MRigP1 et KApp1p)
  197. ((Omega1*Cg1P) et CApp1p) TBasR1 ;
  198. Repeter Lab0 (2*NbMod1);
  199. i2 = &lab0;
  200. si (i2 ega 1);
  201. F25Reel = PROG (BasCiB.'MODES'. i2 . 'FREQUENCE_REELLE');
  202. F25Imag = PROG (BasCiB.'MODES'. i2 . 'FREQUENCE_IMAGINAIRE');
  203. F25Modul = PROG
  204. ((((BasCiB.'MODES'. i2 . 'FREQUENCE_REELLE')**2) +
  205. ((BasCiB.'MODES'. i2 . 'FREQUENCE_IMAGINAIRE')**2))**0.5);
  206. Am25Val = PROG ((extr F25Imag 1)/(extr F25Modul 1));
  207. sinon;
  208. F25Reel = F25Reel et
  209. (prog (BasCiB.'MODES'. i2 . 'FREQUENCE_REELLE'));
  210. F25Imag = F25Imag et
  211. (prog (BasCiB.'MODES'. i2 . 'FREQUENCE_IMAGINAIRE'));
  212. F25Modul = F25Modul et (PROG
  213. ((((BasCiB.'MODES'. i2 . 'FREQUENCE_REELLE')**2) +
  214. ((BasCiB.'MODES'. i2 . 'FREQUENCE_IMAGINAIRE')**2))**0.5));
  215. Am25Val = Am25Val et
  216. (PROG ((extr F25Imag i2)/(extr F25Modul i2)));
  217. finsi;
  218. FIN lab0;
  219. *
  220. F25Reel = ORDONNER CROISSANT F25Reel;
  221. F25Imag = ORDONNER CROISSANT F25Imag;
  222. F25Modul = ORDONNER CROISSANT F25Modul;
  223. Am25Val = ORDONNER CROISSANT Am25Val;
  224. *-------------------------------------------------------*
  225. *
  226. * Calcul du diagramme de Campbell - Modèle 1 (POUTRE)
  227. *
  228. *-------------------------------------------------------*
  229. TAB1 = TABLE;
  230. TAB1.'BASE_MODALE' = TBasR1 ;
  231. TAB1.'MASS_PROJ' = MMasP1;
  232. TAB1.'RIGI_PROJ' = MRigP1 et KApp1p;
  233. TAB1.'AMOR_PROJ' = CApp1p;
  234. TAB1.'GYRO_PROJ' = Cg1P;
  235. TAB1.'AFFICHAGE' = VRAI;
  236. PRFREQ = ((35000./60.)*0.2*pi)*(prog 0. pas 10. 100.);
  237. CAMPBELL TAB1 PRFREQ;
  238. *
  239. FacUnite = (60./(2.*pi));
  240. *
  241. TMod1 = (TAB1.'BASE_MODALE') . 'MODES' ;
  242. NbModR = (DIME ((TAB1.'BASE_MODALE').'MODES')) - 2 ;
  243. NbModC = 2*NbModR;
  244. repeter lab1 NbModC;
  245. i1= &lab1;
  246. si (i1 ega 1);
  247. EVTOT = EVOL MANU (FacUnite*PRFREQ )
  248. ((EXTR ((TAB1. i1). 'FREQUENCE_REELLE') ORDO)) ;
  249. EVAMOT = EVOL MANU (FacUnite*PRFREQ )
  250. ((EXTR ((TAB1. i1). 'AMORTISSEMENT') ORDO)) ;
  251. sinon;
  252. EVTOT = EVTOT et
  253. (EVOL MANU (FacUnite*PRFREQ )
  254. ((EXTR ((TAB1. i1). 'FREQUENCE_REELLE') ORDO)) );
  255. EVAMOT = EVAMOT et
  256. (EVOL MANU (FacUnite*PRFREQ )
  257. ((EXTR ((TAB1. i1). 'AMORTISSEMENT') ORDO)) );
  258. finsi;
  259. FIN lab1;
  260. *
  261. SI (EGA GRAPH 'Y');
  262. Titre 'Diagramme de Campbell';
  263. dess (evtot et
  264. (evol rouge manu (prog 0. 35000.) ((prog 0. 35000.)/60.))
  265. et (evol rouge manu (prog 0. 35000.) ((prog 0. 35000.)/120.)) )
  266. xbord 0. 35000. ybord 0. 1200. ;
  267. dess (EVAMOT) xbord 0. 35000.;
  268. FINSI;
  269. *---------------------------*
  270. *
  271. * Réponse à un balourd
  272. *
  273. *----------------------------*
  274. md = 0.0002;
  275. FbalReel = FORCE ( 0. (md) 0. ) P2;
  276. FbalImag = FORCE ( 0. 0. ((-1.)*md) ) P2;
  277. promeg = prog ((100./60.)*2.*pi) pas ((100./60.)*2.*pi)
  278. ((3200./60.)*2.*pi) pas ((2./60.)*2.*pi) ((4200./60.)*2.*pi)
  279. pas ((100./60.)*2.*pi) ((35000./60.).*2.*pi);
  280. *
  281. TAB1 = TABLE;
  282. TAB1.'BASE_MODALE' = TBasR1 ;
  283. TAB1.'MASS_PROJ' = MMasP1;
  284. TAB1.'RIGI_PROJ' = MRigP1 et KApp1p;
  285. TAB1.'GYRO_PROJ' = Cg1P;
  286. TAB1.'AMOR_PROJ' = CApp1p;
  287. TAB1.'AFFICHAGE' = VRAI;
  288. TAB1.'FBALOURD' = FbalReel;
  289. *TAB1.'FBALREEL' = FbalReel;
  290. *TAB1.'FBALIMAG' = FbalImag;
  291. TAB1.'SAUVDEFO' = FAUX;
  292. TAB1.'REPONSE' = TABLE;
  293. (TAB1.'REPONSE'). 1 = TABLE;
  294. ((TAB1.'REPONSE'). 1 ). 'POINT' = P2;
  295. BALOURD TAB1 promeg;
  296. *
  297. EvUYbal = EVOL MANU (60.*promeg/(2.*pi))
  298. (extr (((TAB1.'REPONSE'). 1) . 'UY' ) ordo);
  299. EvUZbal = EVOL MANU (60.*promeg/(2.*pi))
  300. (extr (((TAB1.'REPONSE'). 1) . 'UZ' ) ordo);
  301. EvGabal = EVOL MANU (60.*promeg/(2.*pi))
  302. (extr (((TAB1.'REPONSE'). 1) . 'GAXE') ordo);
  303. EvPabal = EVOL rouge MANU (60.*promeg/(2.*pi))
  304. (extr (((TAB1.'REPONSE'). 1) . 'PAXE') ordo);
  305. EvAngEl = EVOL MANU (60.*promeg/(2.*pi))
  306. (extr (((TAB1.'REPONSE'). 1) . 'ANGLEGAXE') ordo);
  307. *
  308. SI (EGA GRAPH 'Y');
  309. TITRE 'Amplitude suivant le grand axe';
  310. DESS EvGabal LOGY xbord 0. 35000. ybord 1.E-7 1.E-1;
  311. TITRE 'Amplitude suivant le grand et le petit axe';
  312. DESS (EvGabal et EvPabal) LOGY xbord 0. 35000. ybord 1.E-7 1.E-1;
  313. TITRE 'Amplitude suivant le grand axe - 1ere fréquence critique';
  314. dess EvGabal LOGY xbord 0. 7000. ybord 1.E-7 1.E-1;
  315. 'DESS' (EvUYbal) LOGY xbord 0. 7000. ybord 1.E-7 1.E-1;
  316. 'DESS' (EvUZbal) LOGY xbord 0. 7000. ybord 1.E-7 1.E-1;
  317. FINSI;
  318. *
  319. AmpBal=extr (ipol (prog 30000.) (extr EvGabal absc)
  320. (extr EvGabal ordo)) 1;
  321. AmpBaTh = 1.6736D-5;
  322. SI (ABS((AmpBal - AmpBaTh)/AmpBaTh) < 5.D-2);
  323. ERRE 0;
  324. SINON;
  325. ERRE 5;
  326. FINSI;
  327. *
  328. FIN;
  329. *
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  
  340.  
  341.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales