Télécharger rotor1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rotor1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. ************************************************************************
  6. * *
  7. * Mots-clés : Vibrations, calcul modal, machines tournantes, *
  8. * poutre, modes complexes, reponse frequentielle *
  9. * *
  10. * Test de GYROSCOPIQUE et CAMPBELL pour les elements de poutre *
  11. * Etude d'une machine tournante dans le repere inertiel (ou fixe) *
  12. * Elements: POUT, TIMO et TUYAU *
  13. * **
  14. * Volant d'inertie sur 2 appuis isotropes et anisotropes *
  15. * Exemple Axisa Tome 4 P.92 *
  16. * *
  17. * Auteur: Didier Combescure Août 2003 *
  18. * *
  19. ************************************************************************
  20. * GRAPH = 'Y'; OPTI 'TRAC' 'PSC' 'EPTR' 6 'POTR' 'HELVETICA_16';
  21. GRAPH = 'N';
  22. OPTI EPSI LINEAIRE;
  23. *
  24. *-------------------------------------------------------
  25. * Donnees, Maillage
  26. *-------------------------------------------------------
  27.  
  28. * Caractéristiques de l'arbre et du volant d'inertie
  29. *
  30. L1 = 1.5 ;
  31. L2 = L1;
  32. *
  33. Re1 = 0.5 ;
  34. Lvol = 0.20 ;
  35. E1 = 2.e+11 ;
  36. Nu1 = 0.3 ;
  37. Rho1 = 7800. ;
  38. *
  39. S0 = pi*(Re1**2);
  40. Mtot = rho1 * S0 * Lvol;
  41. Inx = pi*(Re1**4)/2.;
  42. Iny = pi*(Re1**4)/4.;
  43. *
  44. InXtot = Inx*Lvol*Rho1;
  45. *
  46. * Raideur et amortissement des supports
  47. *
  48. Ky = 100000.;
  49. Kz = 1.00*Ky;
  50. Cy = 100.;
  51. Cz = Cy;
  52. *
  53. OPTI 'DIME' 3 'ELEM' SEG2;
  54. *
  55. * Volant et arbre avec même section mais masse différente
  56. *
  57. *
  58. P0 = 0. 0. 0.;
  59. P1 = (L1-(0.5*Lvol)) 0. 0. ;
  60. P2 = (L1+(0.5*Lvol)) 0. 0. ;
  61. P3 = (L1+L2) 0. 0. ;
  62. GeoArbre = (D 1 P0 P1) et (D 1 P2 P3);
  63. GeoVolan = (D 1 P1 P2);
  64. *
  65. Geotot = GeoArbre et GeoVolan;
  66. *
  67. *-------------------------------------------------------
  68. * Modele (element POUT de Bernoulli) , materiau
  69. *-------------------------------------------------------
  70. *
  71. Mod1a = MODELI GeoArbre 'MECANIQUE' POUT;
  72. Mat1a = MATE Mod1a 'YOUNG' E1 'NU ' Nu1 'RHO' 0.
  73. 'SECT' S0 'INRY' Iny 'INRZ' Iny 'TORS' Inx
  74. 'OMEG' (2.*pi);
  75. Mod1b = MODELI GeoVolan 'MECANIQUE' POUT;
  76. Mat1b = MATE Mod1b 'YOUNG' E1 'NU ' Nu1 'RHO' Rho1
  77. 'SECT' S0 'INRY' Iny 'INRZ' Iny 'TORS' Inx
  78. 'OMEG' (2.*pi);
  79. *
  80. mod1 = mod1a et mod1b;
  81. mat1 = mat1a et mat1b;
  82. *
  83. *-------------------------------------------------------
  84. * Matrices
  85. *-------------------------------------------------------
  86.  
  87. * Cond. limites : 2 appuis
  88. *
  89. Blo2 = (BLOQ 'UX' P0);
  90. Blo3 = (BLOQ 'UX' P3);
  91. Blo1 = BLOQ 'RX' Geotot;
  92. *
  93. Kxp= (APPUI UY KY p0) et (APPUI UY KY p3);
  94. Kyp= (APPUI UZ KZ p0) et (APPUI UZ KZ p3);
  95. Cxp= (APPUI UY CY p0) et (APPUI UY CY p3);
  96. Cyp= (APPUI UZ CZ p0) et (APPUI UZ CZ p3);
  97. *
  98. Kappui = Kxp et Kyp;
  99. Cappui = Cxp et Cyp;
  100. *
  101. MMass1 = MASS Mod1 (Mat1) ;
  102. MRigi1 = RIGI Mod1 (Mat1) ;
  103. *
  104. * Matrice de couplage gyroscopique
  105. *
  106. CG1 = GYROSCOPIQUE Mod1 Mat1;
  107. *
  108. * Si on voulait créer une matrice de couplage gyroscopique
  109. * d'un volant d'inertie, on ferait :
  110. *
  111. * GeoVolan= MANU POI1 Pvol;
  112. * CG1 = MANU RIGI 'TYPE' AMORTISSEMENT GeoVolan
  113. * (MOTS 'RX ' 'RY ' 'RZ ')
  114. * (prog 0. 0. 0.
  115. * 0. 0. (2.*pi*InxTot)
  116. * 0. ((-2.)*pi.*InxTot) 0.);
  117.  
  118. * assemblage de matrices
  119. *
  120. RIGT = (MRigi1 ET Kappui ET Blo1 ET Blo2 ET Blo3);
  121. MAST = MMass1;
  122.  
  123. *-------------------------------------------------------
  124. * calcul des modes reels
  125. *-------------------------------------------------------
  126. *
  127. TBasR1 = VIBR 'PROCHE' (prog 12.) (lect 4) RIGT MAST 'TBAS' ;
  128. *
  129. TMod1 = TBasR1 . 'MODES' ;
  130. NbMod1 = (DIME TMod1) - 2 ;
  131. TInd1 = INDEX (TMod1 . 1) ;
  132. *
  133. SI (EGA GRAPH 'Y');
  134. oeil = 1. 10. 0. ;
  135. REPETER bbb1 NbMod1 ;
  136. i = &bbb1 ;
  137. Frq1 = TMod1 . i . 'FREQUENCE' ;
  138. Def1 = TMod1 . i . 'DEFORMEE_MODALE' ;
  139. MESS 'Mode ' i ':' Frq1 'Hz' ;
  140. TITRE Frq1 ;
  141. trac oeil ((defo geotot def1) et (defo geotot def1 0.));
  142. FIN bbb1 ;
  143. *
  144. TABR = TABLE;
  145. TABR. 'POUTRE' = TABLE;
  146. (TABR. 'POUTRE'). 'CIRCULAIRE' = VRAI;
  147. (TABR. 'POUTRE'). 'NCIRC' = 20;
  148. TABR. 'TUYAU' = TABLE;
  149. (TABR. 'TUYAU'). 'NCIRC' = 20;
  150. (TABR. 'TUYAU'). 'NEPAI' = 1;
  151. TABR.'DEPLACEMENTS' = TABLE;
  152. (TABR.'DEPLACEMENTS'). 1 = (TMod1 . 1) . 'DEFORMEE_MODALE' ;
  153. *
  154. MESHVOL = POUT2MAS mod1 mat1 GAUSS TABR;
  155. trac (defo MESHVOL ((TABR.'DEPLACEMENTS'). 1)) cach;
  156. *
  157. FINSI;
  158. *
  159. *-Projection des matrices assemblées sur la base réelle
  160. *
  161. MMasP1 = PJBA TBasR1 MMass1 ;
  162. MRigP1 = PJBA TBasR1 MRigi1 ;
  163. Cg1P = PJBA TBasR1 Cg1 ;
  164. KApp1p = PJBA TBasR1 (Kappui et Blo1 ET Blo2 et Blo3);
  165. CApp1p = PJBA TBasR1 Cappui;
  166.  
  167. *-------------------------------------------------------
  168. * Calcul du diagramme de Campbell via CAMPBELL
  169. *--------------------------------------------------------
  170. TAB1 = TABLE;
  171. TAB1.'BASE_MODALE' = TBasR1 ;
  172. TAB1.'MASS_PROJ' = MMasP1;
  173. TAB1.'RIGI_PROJ' = MRigP1 et KApp1p;
  174. TAB1.'AMOR_PROJ' = CApp1p;
  175. TAB1.'GYRO_PROJ' = Cg1P;
  176. *TAB1.'AFFICHAGE' = VRAI;
  177. PRFREQ = ((prog 0. pas 1. 100.)**2)*(0.01);
  178. CAMPBELL TAB1 PRFREQ;
  179. *
  180. TMod1 = (TAB1.'BASE_MODALE') . 'MODES' ;
  181. NbModR = (DIME ((TAB1.'BASE_MODALE').'MODES')) - 2 ;
  182. NbModC = 2*NbModR;
  183. repeter lab1 NbModC;
  184. i1= &lab1;
  185. si (i1 ega 1);
  186. EVTOT = (TAB1. i1). 'FREQUENCE_REELLE' ;
  187. EVAMOT = (TAB1. i1). 'AMORTISSEMENT';
  188. sinon;
  189. EVTOT = EVTOT et
  190. ((TAB1. i1). 'FREQUENCE_REELLE' );
  191. EVAMOT = EVAMOT et
  192. ((TAB1. i1). 'AMORTISSEMENT');
  193. finsi;
  194. FIN lab1;
  195. *
  196. *
  197. SI (EGA GRAPH 'Y');
  198. dess (evtot et (evol rouge manu (prog 0. 25.) (prog 0. 25.) ))
  199. xbord 0. 25. ybord 0. 60.
  200. TITRE 'Diagramme de Campbell';
  201. dess EVAMOT xbord 0. 100. ;
  202. FINSI;
  203.  
  204. *-------------------------------------------------------
  205. * Calcul du diagramme de Campbell via VIBR IRAM
  206. *--------------------------------------------------------
  207.  
  208. * preparation de objets resultats
  209. TIRAM = tabl;
  210. TIRAM . 'FR' = tabl;
  211. TIRAM . 'FI' = tabl;
  212. Tdess = tabl;
  213. Tdess . 'TITRE' = tabl;
  214. ic = 0;
  215. REPE BMODC NbModC; ic = ic + 1;
  216. TIRAM . 'FR' . ic = prog;
  217. TIRAM . 'FI' . ic = prog;
  218. Tdess . 'TITRE' . ic = MOT 'PAS DE LEGENDE';
  219. Tdess . 'TITRE' . (NbModC + ic) = MOT 'PAS DE LEGENDE';
  220. Tdess . (NbModC + ic) = mot 'NOLI MARQ PLUS';
  221. FIN BMODC;
  222. Tdess . 'TITRE' . 1 = MOT 'VIBC';
  223. Tdess . 'TITRE' . (NbModC + 1) = MOT 'VIBR IRAM';
  224.  
  225. * on fait le calcul sur quelques frequences
  226. * sans projeter sur base modale reelle (contrairement a VIBC)
  227. PRFREQ2 = prog 0. pas 25. 100.;
  228. NFREQ2 = DIME PRFREQ2;
  229. I=0;
  230. REPE BOU2 NFREQ2; I = I + 1;
  231.  
  232. OMEGA = EXTR PRFREQ2 I;
  233. AMOT = Cappui et (OMEGA * Cg1);
  234.  
  235. RES1 = VIBR 'IRAM' 0. NbModC RIGT MAST AMOT 'TBAS';
  236.  
  237. ic = 0;
  238. REPE BMODC NbModC; ic = ic + 1;
  239. TIRAM . 'FR' . ic = TIRAM . 'FR' . ic
  240. et (RES1 . 'MODES' . ic . 'FREQUENCE_REELLE');
  241. TIRAM . 'FI' . ic = TIRAM . 'FI' . ic
  242. et (RES1 . 'MODES' . ic . 'FREQUENCE_IMAGINAIRE');
  243. FIN BMODC;
  244.  
  245. FIN BOU2;
  246.  
  247. * trace pour comparaison graphique
  248. Xevtot = VIDE 'EVOLUTIO';
  249. Xevtoti = VIDE 'EVOLUTIO';
  250. Xamotot = VIDE 'EVOLUTIO';
  251. ic = 0;
  252. REPE BMODC NbModC; ic = ic + 1;
  253. Xevtot = Xevtot et (EVOL 'ORAN' MANU PRFREQ2 TIRAM . 'FR' . ic);
  254. Xevtoti = Xevtoti et (EVOL 'ORAN' MANU PRFREQ2 TIRAM . 'FI' . ic);
  255. Xmod = ((TIRAM . 'FR' . ic ** 2) + (TIRAM . 'FI' . ic ** 2))**0.5;
  256. Xamotot = Xamotot
  257. et (EVOL 'ORAN' MANU PRFREQ2 (TIRAM . 'FI' . ic / Xmod));
  258. FIN BMODC;
  259.  
  260. SI (EGA GRAPH 'Y');
  261. dess (evtot et Xevtot)
  262. TITRE 'Diagramme de Campbell' Tdess;
  263. dess (EVAMOT et Xamotot) Tdess;
  264. FINSI;
  265.  
  266.  
  267. *-------------------------------------------------------
  268. * Test de bon fonctionnement
  269. *-------------------------------------------------------
  270.  
  271. * VIBC (via Campbell)
  272. EVTOT1 = extr evtot cour 8;
  273. EVAMOT1 = extr evamot cour 8;
  274. FR1et2 = IPOL (prog 0. 25.) (extr EVTOT1 absc) (extr EVTOT1 ordo);
  275. AM1et2 = IPOL (prog 0. 25.) (extr EVTOT1 absc) (extr EVAMOT1 ordo);
  276. FR1 = extr FR1et2 1;
  277. FR2 = extr FR1et2 2;
  278. AM1 = extr AM1et2 1;
  279. AM2 = extr AM1et2 2;
  280.  
  281. * VIBR IRAM
  282. freq8R = TIRAM . 'FR' . 8;
  283. freq8I = TIRAM . 'FI' . 8;
  284. freq8A = freq8I / (((freq8R**2) + (freq8I**2))**0.5);
  285. XFR1 = extr freq8R 1;
  286. XFR2 = extr freq8R 2;
  287. XAM1 = extr freq8A 1;
  288. XAM2 = extr freq8A 2;
  289.  
  290. * valeurs de reference
  291. FR1Th = 11.879;
  292. FR2Th = 50.278;
  293. AM1Th = 3.73456E-02;
  294. AM2Th = 1.67227E-02;
  295. Errfrq = 0.01*FR1Th;
  296. Erramo = 0.01*AM1Th;
  297. *
  298. opti echo 0;
  299. MESS ' Theorie | Campbell | VIBR IRAM ';
  300. MESS FR1Th FR1 XFR1;
  301. MESS FR2Th FR2 XFR2;
  302. MESS AM1Th AM1 XAM1;
  303. MESS AM2Th AM2 XAM2;
  304. opti echo 1;
  305.  
  306. SI ((ABS(FR1 - FR1Th) > Errfrq ) OU (ABS(FR2 - FR2Th) > Errfrq ) OU
  307. (ABS(AM1 - AM1Th) > Erramo ) OU (ABS(AM2 - AM2Th) > Erramo ) OU
  308. (ABS(XFR1 - FR1Th) > Errfrq ) OU (ABS(XFR2 - FR2Th) > Errfrq ) OU
  309. (ABS(XAM1 - AM1Th) > Erramo ) OU (ABS(XAM2 - AM2Th) > Erramo ));
  310. ERRE 5
  311. SINON;
  312. ERRE 0;
  313. FINSI;
  314. *
  315. FIN;
  316. *
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales