Télécharger ricrag_3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : ricrag_3d.dgibi
  2. *******************************************************
  3. ************************************************************************
  4. ************************************************************************
  5. * Cas test de l'implantation numérique du modele
  6. * RICRAG 3D LOCAL/NON LOCAL
  7. *******************************************************
  8. * Développé par :
  9. * Benjamin Richard
  10. *******************************************************
  11. * Les cas de charges sont entrés :
  12. * - 1 : Traction monotone
  13. * - 2 : Compression monotone
  14. * - 3 : Traction cyclique
  15. * - 4 : Compression cyclique
  16. * - 5 : Traction/compression cyclique
  17. *******************************************************
  18. * Choix du cas de charge
  19. ncas = 5;
  20. graph=mot 'N';
  21. * Test du fichier compatible avec le non local
  22. * nloc0 = 0; Cas local
  23. * nloc0 = 1; Cas non local
  24.  
  25. nloc0 = 0;
  26. *******************************************************
  27.  
  28. *
  29. *-------------- Options de calcul ---------------------
  30. *
  31. OPTION DIME 3 ELEM CUB8;
  32.  
  33. *
  34. *-------------- Definition de la geometrie ------------
  35. *
  36. P1 = 0. 0. 0.;
  37. P2 = 1. 0. 0.;
  38. P3 = 1. 1. 0.;
  39. P4 = 0. 1. 0.;
  40. P5 = 0. 0. 1. ;
  41.  
  42. L1 = P1 DROIT 1 P2 ;
  43. L2 = P2 DROIT 1 P3 ;
  44. L3 = P3 DROIT 1 P4 ;
  45. L4 = P4 DROIT 1 P1 ;
  46.  
  47. LTOT = L1 ET L2 ET L3 ET L4 ;
  48. SURF1 = SURF LTOT PLANE;
  49. VOLTO =VOLU SURF1 1 TRANS P5;
  50. SURF2= FACE VOLTO 2;
  51.  
  52. VOLTOT = VOLTO;
  53.  
  54. *
  55. *------- Définition des conditions aux limites --------
  56. *----------- et des déplacements imposés --------------
  57. *
  58. CL = BLOQ SURF1 UZ;
  59. CLL = BLOQ P1 'DEPL';
  60. CLL = CLL ET (BLOQ UY P2);
  61. CL1 = BLOQ SURF2 Uz;
  62.  
  63. D1 = DEPI CL1 1;
  64.  
  65. *
  66. *----- Définition du modèle ---------------------------
  67. *
  68. SI (EGA nloc0 1);
  69. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE
  70. ENDOMMAGEMENT RICRAG
  71. 'NON_LOCAL' 'MOYE' 'V_MOYENNE' (MOTS 'EPTI') ;
  72. SINON;
  73. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE
  74. ENDOMMAGEMENT RICRAG;
  75. FINSI ;
  76. *
  77. *----- Paramètres matériaux ---------------------------
  78. *
  79.  
  80. * Module d'Young
  81. youngn = 36000E+6;
  82.  
  83. * Coefficient de Poisson
  84. nun = 0.2;
  85.  
  86. * Résistance en traction
  87. ftn = 3.6e6;
  88.  
  89. * Fragilité en traction
  90. aldin = 1.0e-2;
  91.  
  92. * Fragilité en compression
  93. alinn = 9.0e-5;
  94.  
  95. * Module d'écrouissage 1
  96. gam1n = 7.0e9;
  97.  
  98. * Moduke d'écrouissage 2
  99. a1n = 7.0e-7;
  100.  
  101. mat1 =MATE mod1 YOUN youngn NU nun
  102. FT ftn ALIN alinn
  103. GAM1 gam1n A1 a1n
  104. ALDI aldin;
  105.  
  106. *
  107. *----- Définition des cas de charge -------------------
  108. *
  109.  
  110. SI (EGA ncas 1) ;
  111. LI1 = PROG 0. 1.;
  112. LI2 = PROG 0. 4.0e-4;
  113. LIS1 = PROG 0. PAS 0.02 1.;
  114. FINSI;
  115.  
  116. SI (EGA ncas 2) ;
  117. LI1 = PROG 0. 1.;
  118. LI2 = PROG 0. -8.0e-3;
  119. LIS1 = PROG 0. PAS 0.02 1.;
  120. FINSI;
  121.  
  122. SI (EGA ncas 3) ;
  123. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  124. LI2 = PROG 0. 1.5e-4 9.5e-6 2.0E-4 3.0E-5 2.5E-4;
  125. LIS1 = PROG 0. PAS 0.02 5.;
  126. FINSI;
  127.  
  128. SI (EGA ncas 4) ;
  129. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  130. LI2 = PROG 0. -3.0e-3 -1.5e-4 -5.0E-3 -3.5E-4 -8.0E-3;
  131. LIS1 = PROG 0. PAS 0.02 5.;
  132. FINSI;
  133.  
  134. SI (EGA ncas 5) ;
  135. LI1 = PROG 0. 1. 2. 3. 4. 5. 6.;
  136. LI2 = PROG 0. 1.3e-4 -3.0e-3 -1.5E-4 -5.0E-3 -3.5E-4 -8.0E-3;
  137. LIS1 = PROG 0. PAS 0.02 6;
  138. FINSI;
  139.  
  140. EV = EVOL MANU LI1 LI2 ;
  141. CHA1 = CHAR 'DIMP' D1 EV ;
  142.  
  143. *
  144. *----------- Calcul par l'operateur PASAPAS ------------
  145. *
  146. LC = 1.0e-10;
  147. CO1 = CONNEC mod1 LC NORMAL;
  148.  
  149. TAB1 = TABLE ;
  150. TAB1.'BLOCAGES_MECANIQUES' = CL ET CLL ET CL1;
  151. TAB1.'MODELE' = MOD1;
  152. TAB1.'MOVA' = 'D ';
  153. TAB1.'CHARGEMENT' = CHA1;
  154. TAB1.'TEMPS_CALCULES' = LIS1;
  155. TAB1.'MAXITERATION' = 10;
  156.  
  157. SI (EGA nloc0 1);
  158. TAB1.CONN = CO1;
  159. MAT1 = MAT1 ET (MATE MOD1 'LCAR' LC);
  160. FINSI;
  161.  
  162. TAB1.'CARACTERISTIQUES' = MAT1;
  163.  
  164. PASAPAS TAB1 ;
  165.  
  166. *
  167. *----------- Courbe effort-deplacement -----------------
  168. *
  169. ev2=@global tab1 CL1 EV fz;
  170. ee = extr ev2 ordo 1;
  171. aa = extr ee ( dime ee);
  172. list aa;
  173. err = abs (aa + 1.48500E+07 ) / 1.48500E+07 ;
  174. message ' erreur relative ' err;
  175. si (err > 1.e-3);
  176. erreur (5);
  177. finsi;
  178.  
  179. si ( ega graph 'O');
  180. DESS EV2;
  181. finsi;
  182. *@excel1 ev2 'cas_5.dat';
  183. list ev2;
  184. fin;
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  
  191.  
  192.  
  193.  
  194.  
  195.  
  196.  
  197.  
  198.  
  199.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales