Télécharger riccoq.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : riccoq.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *******************************************************
  5. * Cas test de l'implantation numerique du modele
  6. * RICCOQ - Formulation COQUE Mince
  7. *
  8. *******************************************************
  9. * Développé par :
  10. * Benjamin Richard
  11. * Contact :
  12. * Benjamin.Richard@lmt.ens-cachan.fr
  13. * Institution :
  14. * CEA\DEN\DANS\DM2S\SEMT\EMSI
  15. *******************************************************
  16. * Choix du cas de charge
  17. * - 1 : Traction/compression - charge dech. (membrane)
  18. * - 2 : Idem - sens oppose
  19.  
  20. * - 3 : Traction/compression - charge dech. (flexion )
  21. * - 4 : Idem - sens oppose
  22. * - 5 : Idem avec le deux cycle en plus
  23.  
  24. * - 6 : Distorsion et cisaillement pur plan
  25.  
  26. * - 7 : Couplage traction/compression
  27. * - 8 :
  28. * - 9 :
  29. *******************************************************
  30. * Choix du cas de charge
  31. ncas = 1;
  32.  
  33. *******************************************************
  34. * Choix du modle
  35. *******************************************************
  36. ric0 = VRAI;
  37. sme0 = FAUX;
  38.  
  39. *sme0 = VRAI;
  40. *ric0 = FAUX;
  41.  
  42. *graph0 = VRAI;
  43. graph0 = FAUX;
  44.  
  45. rndm = 0;
  46. *rndm = 1;
  47.  
  48. *******************************************************
  49. * Parametres matŽriaux
  50. *******************************************************
  51.  
  52. * Paramtres physiquement accessibles------------------
  53.  
  54. * Proprietes elastiques du beton
  55. EBN = 36000E6;
  56. NUBN = 0.2;
  57.  
  58. * Epaisseur de la coque
  59. THN = 1.0;
  60.  
  61. * Resistance en traction
  62. ftn = 3.6E6;
  63.  
  64. * Energie de fissuration
  65. gft = 160;
  66.  
  67. * Resistance en compression
  68. fcn = 10E6;
  69. *fcn = 36E6;
  70.  
  71. * Energie de fissuration
  72. gfc = 2000;
  73.  
  74. *******************************************************
  75. * Options de calcul
  76. *******************************************************
  77. OPTION DIME 3 MODE TRID ELEM QUA4;
  78. DENSITE (0.25);
  79. NAME = 'f_delta_fin.txt';
  80.  
  81. *******************************************************
  82. * Maillage
  83. *******************************************************
  84. P1 = 0. 0. 0.;
  85. P2 = 2. 0. 0.;
  86. P3 = 2. 1. 0.;
  87. P4 = 0. 1. 0.;
  88.  
  89. L1 = P1 DROIT 13 P2 ;
  90. L2 = P2 DROIT P3 ;
  91. L3 = P3 DROIT 13 P4 ;
  92. L4 = P4 DROIT P1 ;
  93.  
  94. LTOT = L1 ET L2 ET L3 ET L4 ;
  95.  
  96. S1 = SURF LTOT PLANE;
  97.  
  98. SI (graph0);
  99. TRAC s1;
  100. FINSI;
  101.  
  102. *******************************************************
  103. * Conditions aux limites
  104. *******************************************************
  105.  
  106. * Conditions selon le chargement-----------------------
  107.  
  108. SI (ET (> ncas 0) (< ncas 3));
  109. CL1 = BLOQ L4 UX;
  110. CL2 = BLOQ P1 DEPL ROTA;
  111. CL3 = BLOQ L2 UX;
  112. CLTOT = CL1 ET CL2 ET CL3;
  113. D1 = DEPI CL3 1;
  114. FINSI;
  115.  
  116. SI (ET (> ncas 2) (< ncas 6));
  117. CL1 = BLOQ L4 RY UX;
  118. CL2 = BLOQ P1 DEPL ROTA;
  119. CL3 = BLOQ L2 RY;
  120. CLTOT = CL1 ET CL2 ET CL3;
  121. D1 = DEPI CL3 1;
  122. FINSI;
  123.  
  124. SI (ET (> ncas 5) (< ncas 7));
  125.  
  126. CL1 = BLOQ P1 DEPL ROTA;
  127. NN = NBEL L4;
  128. D0 = 3.0E-4;
  129. CHPO1 = MANU CHPO (INVE L4) 1 'UX'
  130. (PROG 0. PAS (1.0 / NN) 1.0);
  131. CHPO1 = CHPO1 * D0;
  132. CL21 = BLOQ L4 UY;
  133. CL22 = BLOQ L4 UX;
  134. D2 = DEPI CL22 CHPO1;
  135.  
  136. NN = NBEL L1;
  137. CHPO2 = MANU CHPO (L1) 1 'UY'
  138. (PROG 0. PAS (1.0 / NN) 1.0);
  139. CHPO2 = CHPO2 * D0;
  140. CL31 = BLOQ L1 UX;
  141. CL32 = BLOQ L1 UY;
  142. D3 = DEPI CL32 CHPO2;
  143.  
  144. NN = NBEL L2;
  145. CHPO3 = MANU CHPO (L2) 1 'UX'
  146. (PROG 0. PAS (1.0 / NN) 1.0);
  147. CHPO3 = CHPO3 * D0;
  148. CL41 = BLOQ L2 UX;
  149. CL42 = BLOQ L2 UY;
  150. D41 = DEPI CL41 CHPO3;
  151. D42 = DEPI CL42 D0;
  152.  
  153. NN = NBEL L3;
  154. CHPO4 = MANU CHPO (INVE L3) 1 'UY'
  155. (PROG 0. PAS (1.0 / NN) 1.0);
  156. CHPO4 = CHPO4 * D0;
  157. CL51 = BLOQ L3 UX;
  158. CL52 = BLOQ L3 UY;
  159. D51 = DEPI CL51 D0;
  160. D52 = DEPI CL52 CHPO4;
  161.  
  162. DF1 = FORCE ((-1 * D0) 0 0) L1;
  163. DF2 = FORCE (0 D0 0) L2;
  164. DF3 = FORCE (D0 0 0) L3;
  165. DF4 = FORCE (0 (-1 * D0) 0) L4;
  166. DFT = DF1 ET DF2 ET DF3 ET DF4;
  167.  
  168. SI (graph0);
  169. vect1 = vect chpo1 50 'DEPL' ROUG;
  170. vect2 = vect chpo2 50 'DEPL' VERT;
  171. vect3 = vect chpo3 50 'DEPL' BLEU;
  172. vect4 = vect chpo4 50 'DEPL' JAUN;
  173. TRAC S1 (VECT1 ET VECT2 ET VECT3 ET VECT4);
  174. FINSI;
  175.  
  176. CLTOT = CL1 ET CL21 ET CL22 ET CL31 ET CL32 ET CL41 ET
  177. CL42 ET CL51 ET CL52;
  178.  
  179. DTOT = D2 ET D3 ET D41 ET D42 ET D51 ET D52;
  180. FINSI;
  181.  
  182. SI (ET (> ncas 6) (< ncas 10));
  183. CL1 = BLOQ P1 DEPL ROTA;
  184. CL2 = BLOQ L4 UX RY;
  185. CL3 = BLOQ L2 RY;
  186. CL4 = BLOQ L2 UX;
  187. CLTOT = CL1 ET CL2 ET CL3 ET CL4;
  188. D1 = DEPI CL3 6.0E-3;
  189. D2 = DEPI CL4 2.0E-4;
  190. DTOT = D1 ET D2;
  191. FINSI;
  192.  
  193. *******************************************************
  194. * Choix des modles et des matŽriaux associŽs
  195. *******************************************************
  196.  
  197. * Cas du modle BA-------------------------------------
  198. SI (ric0);
  199.  
  200. * Modle-----------------------------------------------
  201. MODTOT = MODE S1 MECANIQUE ELASTIQUE ISOTROPE
  202. ENDOMMAGEMENT RICCOQ DKT COQ4 CONS COUCHE1;
  203.  
  204. * Materiaux--------------------------------------------
  205.  
  206. SI (EGA rndm 1);
  207. ftn = ALEA BANDES_TOURNANTES MODTOT EXPO SIGMA
  208. (0.001*ftn) MOYENNE ftn LAMBDA 0.1;
  209.  
  210. fcn = ALEA BANDES_TOURNANTES MODTOT EXPO SIGMA
  211. (0.001*fcn) MOYENNE fcn LAMBDA 0.1;
  212.  
  213. *TRAC ftn MODTOT;
  214. *TRAC fcn MODTOT;
  215.  
  216. FINSI;
  217.  
  218. CHAM1 = MANU CHML MODTOT BTRA 1. TYPE CARACTERISTIQUES RIGIDITE;
  219. CHAM2 = INTG CHAM1 MODTOT ELEM BTRA;
  220. TAIL1 = (2 ** (1.0 / 2.0)) * CHAM2 ** (1.0 / 2.0);
  221.  
  222. GFT = GFT / THN;
  223. EPSUT = (TAIL1) / GFT;
  224.  
  225. GFC = GFC / THN;
  226. EPSUC = (TAIL1) / GFC;
  227.  
  228. MATTOT = MATE MODTOT YOUN EBN NU NUBN
  229. FT ftn EPUT EPSUT
  230. FC fcn EPUC EPSUC;
  231.  
  232. CAR1 = CARA MODTOT EPAI THN EXCE 0.0;
  233. MATTOT = MATTOT ET CAR1;
  234. FINSI;
  235.  
  236. * Cas du modle multicouche----------------------------
  237. SI (sme0);
  238. MOD1 = MODE S1 MECANIQUE ELASTIQUE
  239. ISOTROPE DKT COQ4 CONS BETO;
  240.  
  241. MODTOT = MOD1;
  242.  
  243. mat1 = MATE mod1 YOUN EBN NU NUBN;
  244. car1 = CARA MOD1 EPAI THN ;
  245. mat1 = mat1 et car1;
  246.  
  247. mattot = mat1;
  248. FINSI;
  249.  
  250. *******************************************************
  251. * Choix des cas de charge
  252. *******************************************************
  253. SI (EGA NCAS 1);
  254. LI1 = PROG 0. 1. 2. 3. 4.;
  255. LI2 = PROG 0. 1E-3 0. -5E-3 1.5E-3;
  256. LIS1 = PROG 0. pas 0.01 1;
  257. FINSI;
  258.  
  259. SI (EGA NCAS 2);
  260. LI1 = PROG 0. 1. 2. 3. 4.;
  261. LI2 = PROG 0. -5E-4 0. 2E-4 0.;
  262. LIS1 = PROG 0. pas 0.05 4;
  263. FINSI;
  264.  
  265. SI (EGA NCAS 3);
  266. LI1 = PROG 0. 1. 2. 3. 4.;
  267. LI2 = PROG 0. 6E-3 0. -6E-3 0.;
  268. LIS1 = PROG 0. pas 0.05 4;
  269. FINSI;
  270.  
  271. SI (EGA NCAS 4);
  272. LI1 = PROG 0. 1. 2. 3. 4.;
  273. LI2 = PROG 0. -6E-3 0. 6E-3 0.;
  274. LIS1 = PROG 0. pas 0.05 4;
  275. FINSI;
  276.  
  277. SI (EGA NCAS 5);
  278. LI1 = PROG 0. PAS 1 8;
  279. LI2 = PROG 0. -6E-3 0. 6E-3 0. -6E-3 0. 6E-3 0.;
  280. LIS1 = PROG 0. pas 0.05 8;
  281. FINSI;
  282.  
  283. SI (EGA NCAS 6);
  284. LI1 = PROG 0. 1. 2. 3. 4.;
  285. LI2 = PROG 0. -1. 0. 1. 0.;
  286. LIS1 = PROG 0. pas 0.01 4;
  287. FINSI;
  288.  
  289. SI (EGA NCAS 7);
  290. LI1 = PROG 0. 1. 2. 3. 4.;
  291. LI2 = PROG 0. 1. 0. -1. 0.;
  292. LIS1 = PROG 0. pas 0.05 4;
  293. EV = EVOL MANU LI1 LI2;
  294. CHA1 = CHAR MECA DTOT EV;
  295. CHATOT = CHA1;
  296. FINSI;
  297.  
  298. SI (EGA NCAS 8);
  299. LI1 = PROG 0. 1. 2. 3. 4.;
  300. LI2 = PROG 0. -1. 0. 1. 0.;
  301. LIS1 = PROG 0. pas 0.05 4;
  302. EV = EVOL MANU LI1 LI2;
  303. CHA1 = CHAR MECA DTOT EV;
  304. CHATOT = CHA1;
  305. FINSI;
  306.  
  307. SI (EGA NCAS 9);
  308. LI1 = PROG 0. PAS 1 8;
  309. LI2 = PROG 0. 1 0. -1 0. 1 0. -1 0.;
  310. LIS1 = PROG 0. pas 0.05 8;
  311. EV = EVOL MANU LI1 LI2;
  312. CHA1 = CHAR MECA DTOT EV;
  313. CHATOT = CHA1;
  314. FINSI;
  315.  
  316. SI (< ncas 6);
  317. EV = EVOL MANU LI1 LI2 ;
  318. CHA1 = CHAR 'DIMP' D1 EV ;
  319. CHATOT = CHA1;
  320. FINSI;
  321.  
  322. SI (ET (> ncas 5) (< ncas 7));
  323. EV = EVOL MANU LI1 LI2 ;
  324. CHA1 = CHAR 'DIMP' DTOT EV ;
  325. CHA2 = CHAR 'MECA' DFT EV ;
  326. CHATOT = CHA1 ET CHA2;
  327. FINSI;
  328.  
  329. *******************************************************
  330. * Preparation au calcul
  331. *******************************************************
  332. TAB1 = TABLE ;
  333. TAB1.BLOCAGES_MECANIQUES = CLTOT ;
  334. TAB1.MODELE = MODTOT ;
  335. TAB1.MOVA = RIEN ;
  336. TAB1.CHARGEMENT = CHATOT ;
  337. TAB1.CARACTERISTIQUES = MATTOT ;
  338. TAB1.TEMPS_CALCULES = LIS1 ;
  339. *******************************************************
  340. * Calcul
  341. *******************************************************
  342. PASAPAS TAB1 ;
  343.  
  344. *******************************************************
  345. * Post traitement
  346. *******************************************************
  347. nn=dime tab1.deplacements;
  348. nn=nn-1;
  349.  
  350. SI (graph0);
  351. SI (ric0);
  352. trac modtot (exco tab1.variables_internes.nn 'DT ');
  353. trac modtot (exco tab1.variables_internes.nn 'DC ');
  354. trac modtot (exco tab1.variables_internes.nn 'XYDC');
  355. FINSI;
  356.  
  357. SI (sme0);
  358. *trac modtot (exco tab1.variables_internes.nn 'D ');
  359. FINSI;
  360. FINSI;
  361.  
  362. SI (OU (EGA ncas 1) (EGA ncas 2));
  363. ev2=@global tab1 CL3 EV FX;
  364. SI (graph0);
  365. EV2 = EV2 / THN;
  366. *@EXCEL1 EV2 name;
  367. DESS EV2;
  368. FINSI;
  369. FINSI;
  370.  
  371. SI ( ET (> ncas 2) (< ncas 6));
  372. evm = prog 0;
  373. I = 1;
  374. REPETER BOU1 nn;
  375. var0 = tab1.contraintes.I;
  376. var1 = chan chpo modtot var0;
  377. tot = @total var1 L4 'M22 ';
  378. evm = evm et (prog tot);
  379. I = I + 1;
  380. FIN BOU1;
  381. evg=@global tab1 CL3 EV FX;
  382. lis1 = extr evg 'ABSC';
  383. ev2 = evol manu lis1 evm;
  384. SI (graph0);
  385. dess ev2;
  386. FINSI;
  387. FINSI;
  388.  
  389. SI (ega ncas 6);
  390. evm = prog 0;
  391. dep0 = prog 0;
  392. I = 1;
  393. REPETER BOU1 nn;
  394. var0 = tab1.contraintes.I;
  395. dep1 = tab1.deplacements.I;
  396. tot = EXTR VAR0 'N12 ' 1 1 1;
  397. evm = evm et (prog tot);
  398. dep0 = dep0 et (prog (EXTR dep1 'UX ' P3));
  399. I = I + 1;
  400. FIN BOU1;
  401. ev2 = evol manu dep0 evm;
  402. SI (graph0);
  403. ev2 = ev2 / thn;
  404. dess ev2;
  405. FINSI;
  406. FINSI;
  407.  
  408. SI (ET (> ncas 6) (< ncas 10));
  409. EVG1 = @GLOBAL TAB1 EV CL4 FX;
  410. LISG1 = EXTR EVG1 ABSC;
  411. LISG1 = (LISG1 * 2.0E-4);
  412.  
  413. EVG2 = @GLOBAL TAB1 EV CL3 FX;
  414. LISG2 = EXTR EVG2 ABSC;
  415. LISG2 = (LISG2 * 6E-3);
  416.  
  417. evm1 = prog 0;
  418. I = 1;
  419. REPETER BOU1 nn;
  420. var0 = tab1.reactions.I;
  421. tot = @total var0 L4 'FX ';
  422. evm1 = evm1 et (prog tot);
  423. I = I + 1;
  424. FIN BOU1;
  425.  
  426. evm2 = prog 0;
  427. I = 1;
  428. REPETER BOU1 nn;
  429. var0 = tab1.reactions.I;
  430. tot = @total var0 L4 'MY ';
  431. evm2 = evm2 et (prog tot);
  432. I = I + 1;
  433. FIN BOU1;
  434.  
  435. EV21 = EVOL MANU LISG1 evm1;
  436. EV22 = EVOL MANU LISG2 evm2;
  437.  
  438. SI (graph0);
  439. DESS EV21;
  440. DESS EV22;
  441. FINSI;
  442.  
  443. FINSI;
  444.  
  445. SI (graph0);
  446. def0 = defo s1 tab1.deplacements.nn 1 bleu;
  447. def1 = defo s1 tab1.deplacements.nn 2000 rouge;
  448. trac modtot def1 (exco tab1.variables_internes.nn 'DT ');
  449. trac modtot def1 (exco tab1.variables_internes.nn 'DC ');
  450. FINSI;
  451.  
  452. var0 = tab1.variables_internes.nn;
  453. ee = extr var0 'DT ' 1 1 1;
  454. list ee;
  455.  
  456. message 'erreur relative : ';
  457. err = (ee - 0.97549) / 0.97549;
  458. list err;
  459. si (> err 1.0E-3);
  460. erreur(5);
  461. finsi;
  462.  
  463. *******************************************************
  464. * FIN DE L ANALYSE
  465. *******************************************************
  466.  
  467. FIN;
  468.  
  469.  
  470.  
  471.  
  472.  
  473.  
  474.  
  475.  
  476.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales