Télécharger reprise_1.dgibi

Retour à la liste

Numérotation des lignes :

  1. OPTI 'ECHO' 0 ;
  2. ************* Cas test d'une reprise de calcul avec PASAPAS ************
  3. * *
  4. * On teste la possibilite de faire une reprise de calcul avec PASAPAS. *
  5. * Il s'agit d'un calcul mecanique simple en elasticite lineaire avec *
  6. * chargement thermique (dilatation d'une barre) *
  7. * *
  8. * - On effectue un premier calcul (reference) en appelant PASAPAS une *
  9. * seule fois *
  10. * - On effectue un second calcul (de test) avec le memes donnees que *
  11. * le premier mais en faisant 2 appels a PASAPAS (sur la moitie des *
  12. * pas de temps, puis sur l'autre moitie). *
  13. * - On post-traite le deplacement de la barre, celui-ci doit etre le *
  14. * meme a l'issue des deux calculs *
  15. * *
  16. ************************************************************************
  17.  
  18.  
  19. ** Options generales
  20. OPTI 'DIME' 2 'ELEM' 'QUA4' ;
  21. logtrac = FAUX ;
  22.  
  23.  
  24. ** Maillage
  25. p1 = 0. 0. ;
  26. p2 = 1. 0. ;
  27. l1 = DROI 5 p1 p2 ;
  28. s1 = l1 TRAN 1 (0. 0.2) ;
  29. l2 = s1 COTE 4 ;
  30.  
  31.  
  32. ** Modele et materiau
  33. mo = MODE s1 'MECANIQUE' ;
  34. ma = MATE mo 'YOUN' 200.E9 'NU' 0.3 'ALPH' 1.E-4 ;
  35.  
  36.  
  37. ** Blocages
  38. bl1 = BLOQ 'UX' l2 ;
  39. bl2 = BLOQ 'UY' p1 ;
  40.  
  41.  
  42. ** Chargement de temperature impose
  43. cht = MANU 'CHPO' s1 1 'T' 1. ;
  44. ev1 = EVOL 'MANU' (PROG 0. 1.) (PROG 0. 1000.) ;
  45. cha1 = CHAR 'T' cht ev1 ;
  46.  
  47.  
  48. ** Calcul de reference avec 1 seul appel a PASAPAS
  49. t1 = TABL ;
  50. t1 . MODELE = mo ;
  51. t1 . CARACTERISTIQUES = ma ;
  52. t1 . BLOCAGES_MECANIQUES = bl1 ET bl2 ;
  53. t1 . CHARGEMENT = cha1 ;
  54. t1 . TEMPS_CALCULES = PROG 0.1 'PAS' 0.1 1. ;
  55. t2 = COPI t1 ;
  56. PASAPAS t1 ;
  57.  
  58.  
  59. ** Calcul du meme probleme mecanique mais avec 2 appels a PASAPAS
  60. t2 . TEMPS_CALCULES = PROG 0.1 'PAS' 0.1 0.5 ;
  61. PASAPAS t2 ;
  62. t2 . TEMPS_CALCULES = PROG 0.6 'PAS' 0.1 1. ;
  63. PASAPAS t2 ;
  64.  
  65.  
  66. ** Post traitement : evolution temporelle du deplacement de l'extremite
  67. * libre du barreau
  68. evt1 = EVOL 'ROUG' 'TEMP' t1 'DEPLACEMENTS' 'UX' p2 ;
  69. evt2 = EVOL 'VERT' 'TEMP' t2 'DEPLACEMENTS' 'UX' p2 ;
  70. SI logtrac ;
  71. DESS (evt1 ET evt2) 'TITR' 'Deplacement du barreau vs Temps' ;
  72. FINSI ;
  73.  
  74.  
  75. ** Ecart relatif entre les deux calcul
  76. umax = MAXI (EXTR evt1 'ORDO') ;
  77. evd = ABS ((evt1 - evt2) / umax) ;
  78. SI logtrac ;
  79. DESS evd 'TITR' 'Ecart relatif vs Temps' ;
  80. FINSI ;
  81.  
  82.  
  83. ** Test sur l'ecart relatif
  84. err1 = MAXI 'ABS' (EXTR evd 'ORDO') ;
  85. SI (err1 > 1.E-15) ;
  86. ERRE (CHAI 'Les deux calculs PASAPAS ne donnent pas des resultats'
  87. ' identiques !') ;
  88. FINSI ;
  89.  
  90.  
  91. FIN ;
  92.  
  93.  
  94.  
  95.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales