Télécharger relaxendo.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : relaxendo.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. complet = faux;
  5. *
  6. *************************************************
  7. * pour calcul complet mettre complet à : vrai;
  8. *************************************************
  9. OPTI ECHO 0 DIME 2 ELEM QUA8 MODE AXIS;
  10. *
  11. *-----------------------------------------------------------------
  12. * MAILLAGE AXISYMETRIQUE EPROUVETTE CYLINDRIQUE
  13. * MATERIAU VISCO-PLASTIQUE ENDOMMAGEABLE AVEC MATERIAU DEPENDANT
  14. * =============
  15. * DE LA TEMPERATURE (MODULE D'YOUNG ET COEFFICIENT DE DILATATION
  16. * THERMIQUE)
  17. *-----------------------------------------------------------------
  18. P1 = 0 0; P2 = 3E-3 0; P3 = 3E-3 30E-3; P4 = 0 30E-3;
  19. *
  20. L1 = P1 P2 DROIT 1 ;
  21. L2 = P2 P3 DROIT 1 ;
  22. L3 = P3 P4 DROIT 1 ;
  23. L4 = P4 P1 DROIT 1 ;
  24. *
  25. * mesh
  26. *
  27. EPROU = L1 L2 L3 L4 DALLER PLAN ;
  28. *
  29. * boundary conditions
  30. *
  31. CL1 = BLOQ L1 UZ ;
  32. CL4 = BLOQ L4 UR ;
  33. *
  34. CL3 = BLOQ L3 UZ ;
  35. FO3 = DEPI CL3 1E-4 ;
  36. CL = CL1 ET CL4 ET CL3 ;
  37. *
  38. * MODE defines the behavior of the material and the finite element
  39. * formulation
  40. *
  41. MO = MODE EPROU MECANIQUE ELASTIQUE VISCOPLASTIQUE VISCODOMMAGE;
  42. *
  43. PROGKSI = PROG 0. 10000. ;
  44. PROGK1 = PROG 15. 15. ;
  45. CTRAC1 = EVOL MANU KSI PROGKSI K PROGK1 ;
  46. *
  47. evalph = EVOL MANU 'T' (PROG 1000 1025) 'ALPH' (PROG 1E-4 1E-3) ;
  48. EVY = EVOL MANU 'T' (PROG 1000 1025) 'YOUN' (PROG 300000 150000);
  49. MATVAR = MATE MO YOUN EVY NU 0. rho 7800. ALPH evalph talp 20. tref 1025.
  50. N 10.8 M 9.8 KK 1450. ALP1 0. BLP1 0.
  51. R 5.2 A 2511.35
  52. EVOL CTRAC1 SMAX 50. ;
  53. MAT = MATE MO YOUN 150000. NU 0. rho 7800. alph 1.E-3 talp 20. tref 1025.
  54. N 10.8 M 9.8 KK 1450. ALP1 0. BLP1 0.
  55. R 5.2 A 2511.35
  56. EVOL CTRAC1 SMAX 50. ;
  57. *
  58. * definition des cartes de temperature
  59. *
  60. TEMP0 = MANU CHPO EPROU 1 'T' 1025. ;
  61. TEMP1 = MANU CHPO EPROU 1 'T' 1000. ;
  62. *
  63. RIG = (RIGI MO MAT) ET CL ;
  64. *
  65. DEPI = RESO RIG FO3 ;
  66. SIGI = SIGMA DEPI MAT MO ;
  67. *
  68. t0 = 0. ; t1 = 8.E5 ; tf = 1E9 ;
  69. LISTT = PROG t0 tf ;
  70. LISTF = PROG 2*1. ;
  71. *
  72. EV = EVOL MANU 'TEMPS' LISTT 'FORCE' LISTF;
  73. CHA1 = CHAR DIMP FO3 EV ;
  74. *
  75. TAB = TABLE ;
  76. TEMP = TABLE ; TEMPER = TABLE;
  77. TEMP . 0 = 0.; TEMP . 1 = 8.E5;
  78. TEMPER . 0 = TEMP0 ; TEMPER . 1 = TEMP1 ;
  79. CHA2 = CHAR T TEMP TEMPER;
  80. CHA = CHA1 ET CHA2;
  81. TAB.'DEPLACEMENTS' = TABLE;
  82. TAB.'CONTRAINTES' = TABLE;
  83. TAB.'DEPLACEMENTS' . 0 = DEPI ;
  84. TAB.'CONTRAINTES' . 0 = SIGI ;
  85. si complet;
  86. LIS = prog 1E-3 pas 1E-3
  87. 1E-2 PAS 1E-2 1E-1 .2 pas 0.2 1 2 PAS 2 10 20
  88. PAS 20 100 200 pas 200 1000
  89. 2000 pas 2000 10000 PAS 1000 12000 ;
  90. sinon;
  91. LIS = prog 1E-3 pas 1E-3
  92. 6.E-3 ;
  93. finsi;
  94.  
  95. TAB.'BLOCAGES_MECANIQUES' = CL;
  96. TAB.'MODELE' = MO;
  97. TAB.'CHARGEMENT' = CHA;
  98. TAB.'TEMPS_CALCULES' = LIS;
  99. TAB.'CARACTERISTIQUES' = MATVAR;
  100. tab.maxisouspas = 200;
  101.  
  102. PASAPAS TAB ;
  103. *
  104. *
  105. *----------------------------------------------------------------
  106. * CONTROLE DES RESULTATS AVEC DE LA SOLUTION DE REFERENCE
  107. * OBTENUE PAR ALGORITHME
  108. *----------------------------------------------------------------
  109. *
  110. si complet;
  111. REF_D = PROG 7.86E-3 3.33E-2 1.254E-1 ;
  112. REF_P = PROG 4.15E-3 8.66E-3 1.55E-2 ;
  113. REF_S = PROG 231.0 242.2 230.1 ;
  114. TA = 2000.;
  115. TB = 6000.;
  116. TC = 12000.;
  117. sinon;
  118. TA= 3.e-3;
  119. TB = 5.e-3;
  120. TC = 6.e-3;
  121. REF_D = PROG 4.90537E-07 7.65936E-07 8.95267E-07 ;
  122. REF_P = PROG 2.75079E-04 3.29655E-04 3.50683E-04 ;
  123. REF_S = PROG 458.74 450.55 447.40 ;
  124. finsi;
  125. *
  126. D1 = EXTR (PECHE TAB VARIABLES_INTERNES TA) 'VHWD' 1 1 1;
  127. P1 = EXTR (PECHE TAB VARIABLES_INTERNES TA) 'EPSE' 1 1 1;
  128. S1 = EXTR (PECHE TAB CONTRAINTES TA) 'SMZZ' 1 1 1;
  129. D2 = EXTR (PECHE TAB VARIABLES_INTERNES TB) 'VHWD' 1 1 1;
  130. P2 = EXTR (PECHE TAB VARIABLES_INTERNES TB) 'EPSE' 1 1 1;
  131. S2 = EXTR (PECHE TAB CONTRAINTES TB) 'SMZZ' 1 1 1;
  132. D3 = EXTR (PECHE TAB VARIABLES_INTERNES TC) 'VHWD' 1 1 1;
  133. P3 = EXTR (PECHE TAB VARIABLES_INTERNES TC) 'EPSE' 1 1 1;
  134. S3 = EXTR (PECHE TAB CONTRAINTES TC) 'SMZZ' 1 1 1;
  135. D = PROG D1 D2 D3 ;
  136. P = PROG P1 P2 P3 ;
  137. S = PROG S1 S2 S3 ;
  138.  
  139.  
  140. *
  141. errd = MAXI (ABS ((REF_D - D) / REF_D)) ;
  142. errp = MAXI (ABS ((REF_P - P) / REF_P)) ;
  143. errs = MAXI (ABS ((REF_S - S) / REF_S)) ;
  144. *
  145. err = MAXI (prog errd errp errs) ;
  146. *
  147. temps;
  148. LIST ERR ;
  149. SI ( ERR <EG 0.05 );
  150. ERRE 0;
  151. SINON;
  152. ERRE 5;
  153. FINSI;
  154. *
  155. FIN;
  156.  
  157.  
  158.  
  159.  
  160.  
  161.  
  162.  
  163.  
  164.  
  165.  
  166.  
  167.  
  168.  
  169.  
  170.  
  171.  
  172.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales