Télécharger relamili.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : relamili.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *---------------------------------------------------------------------*
  5. * Cas-test de l'operateur 'RELA', option 'MILI'. *
  6. * *
  7. * On deplace le coin sup. droit d'un carre (cube en 3D) decrit par un *
  8. * un element quadratique. Le deplacement des noeuds milieux est *
  9. * lineairement lie a celui des noeuds sommets ('RELA' 'MILI'). On *
  10. * s'assure que c'est le cas. *
  11. *---------------------------------------------------------------------*
  12. * *
  13. * Pour les traces, mettre ITRAC1 a VRAI : *
  14. ITRAC1 = FAUX ;
  15. * *
  16. 'OPTI' 'ECHO' 0 ;
  17. * *
  18. *---------------------------------------------------------------------*
  19. * 2D *
  20. *---------------------------------------------------------------------*
  21. * *
  22. 'OPTI' 'DIME' 2 'ELEM' 'QUA8' ;
  23. * *
  24. P1 = 0. 0. ;
  25. P2 = 1. 0. ;
  26. P4 = 0. 1. ;
  27. N1 = 1 ;
  28. L1 = P1 'DROI' N1 P2 ;
  29. S1 = L1 'TRAN' N1 P4 ;
  30. L2 = S1 'COTE' 2 ;
  31. L3 = S1 'COTE' 3 ;
  32. L4 = S1 'COTE' 4 ;
  33. P3 = S1 'POIN' 'PROC' (1. 1.) ;
  34. P4 = S1 'POIN' 'PROC' P4 ;
  35. * *
  36. MOD1 = 'MODE' S1 'MECANIQUE' 'ELASTIQUE' ;
  37. MAT1 = 'MATE' MOD1 'YOUN' 1.E9 'NU' 0.45 ;
  38. RIG1 = 'RIGI' MOD1 MAT1 ;
  39. * *
  40. CX0 = 'BLOQ' L4 'UX' 'UY' ;
  41. CY0 = 'BLOQ' L1 'UX' 'UY' ;
  42. CLXP3 = 'BLOQ' P3 'UX' ;
  43. CLYP3 = 'BLOQ' P3 'UY' ;
  44. RELA1 = 'RELA' 'MILI' S1 ;
  45. CL0 = CX0 'ET' CY0 'ET' CLXP3 'ET' CLYP3 'ET' RELA1 ;
  46. DIMPX1 = 0.1 ;
  47. DIMPY1 = 0.2 ;
  48. DCLP3 = ('DEPI' CLXP3 DIMPX1) 'ET' ('DEPI' CLYP3 DIMPY1) ;
  49. * *
  50. DEP1 = 'RESO' (RIG1 'ET' CL0) DCLP3 ;
  51. * *
  52. 'SI' ITRAC1 ;
  53. DEFO0 = 'DEFO' S1 DEP1 0. 'VERT' ;
  54. DEFO1 = 'DEFO' S1 DEP1 3. 'ROUG' ;
  55. 'TITR' 'Maillage ini. (vert), deforme (rouge).' ;
  56. 'TRAC' (DEFO0 'ET' DEFO1) ;
  57. 'FINS' ;
  58. * *
  59. P6 = S1 'POIN' 'PROC' (1. 0.5) ;
  60. UXP6 = 'EXTR' DEP1 'UX' P6 ;
  61. UYP6 = 'EXTR' DEP1 'UY' P6 ;
  62. P7 = S1 'POIN' 'PROC' (0.5 1.) ;
  63. UXP7 = 'EXTR' DEP1 'UX' P7 ;
  64. UYP7 = 'EXTR' DEP1 'UY' P7 ;
  65. * *
  66. DANAX1 = 0.5 * DIMPX1 ;
  67. DANAY1 = 0.5 * DIMPY1 ;
  68. ERR1 = ('ABS' (UXP6 - DANAX1)) + ('ABS' (UYP6 - DANAY1)) +
  69. ('ABS' (UXP7 - DANAX1)) + ('ABS' (UYP7 - DANAY1)) ;
  70. ERR1 = 'ABS' (ERR1 / ('MAXI' 'ABS' ('PROG' DIMPX1 DIMPY1))) ;
  71. * *
  72. 'SI' (ERR1 '>' 1.E-4) ;
  73. 'ERRE' 5 ;
  74. 'FINS' ;
  75. * *
  76. *---------------------------------------------------------------------*
  77. * 3D *
  78. *---------------------------------------------------------------------*
  79. * *
  80. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  81. * *
  82. V1 = S1 'VOLU' 'TRAN' N1 (0. 0. 1.) ;
  83. P7 = V1 'POIN' 'PROC' (1. 1. 1.) ;
  84. * *
  85. MOD1 = 'MODE' V1 'MECANIQUE' 'ELASTIQUE' ;
  86. MAT1 = 'MATE' MOD1 'YOUN' 1.E9 'NU' 0.45 ;
  87. RIG1 = 'RIGI' MOD1 MAT1 ;
  88. * *
  89. CLZ0 = 'BLOQ' S1 'DEPL' ;
  90. CLY0 = 'BLOQ' (V1 'POIN' 'PLAN' P1 P2 (0. 0. 1.) 1.E-3) 'DEPL' ;
  91. CLX0 = 'BLOQ' (V1 'POIN' 'PLAN' P1 P4 (0. 0. 1.) 1.E-3) 'DEPL' ;
  92. CLP7 = 'BLOQ' P7 'DEPL' ;
  93. RELA1 = 'RELA' 'MILI' V1 ;
  94. CL0 = CLX0 'ET' CLY0 'ET' CLZ0 'ET' CLP7 'ET' RELA1 ;
  95. DIMP1 = 0.1 ;
  96. DCLP7 = 'DEPI' CLP7 DIMP1 ;
  97. * *
  98. DEP1 = 'RESO' (RIG1 'ET' CL0) DCLP7 ;
  99. * *
  100. 'SI' ITRAC1 ;
  101. DEFO0 = 'DEFO' V1 DEP1 0. 'VERT' ;
  102. DEFO1 = 'DEFO' V1 DEP1 3. 'ROUG' ;
  103. 'TRAC' (100. -50. 40.) (DEFO0 'ET' DEFO1) ;
  104. 'FINS' ;
  105. * *
  106. P15 = V1 'POIN' 'PROC' (1. 1. 0.5) ;
  107. UXP15 = 'EXTR' DEP1 'UX' P15 ;
  108. UYP15 = 'EXTR' DEP1 'UY' P15 ;
  109. UZP15 = 'EXTR' DEP1 'UZ' P15 ;
  110. P18 = V1 'POIN' 'PROC' (1. 0.5 1.) ;
  111. UXP18 = 'EXTR' DEP1 'UX' P18 ;
  112. UYP18 = 'EXTR' DEP1 'UY' P18 ;
  113. UZP18 = 'EXTR' DEP1 'UZ' P18 ;
  114. P19 = V1 'POIN' 'PROC' (0.5 1. 1.) ;
  115. UXP19 = 'EXTR' DEP1 'UX' P19 ;
  116. UYP19 = 'EXTR' DEP1 'UY' P19 ;
  117. UZP19 = 'EXTR' DEP1 'UZ' P19 ;
  118. * *
  119. ERR2 = 'ABS' (UXP15 + UYP15 + UZP15 + UXP18 + UYP18 + UZP18 +
  120. UXP19 + UYP19 + UZP19 - (4.5 * DIMP1)) ;
  121. ERR2 = ERR2 / ('ABS' DIMP1) ;
  122. * *
  123. 'SI' (ERR2 '>' 1.E-4) ;
  124. 'ERRE' 5 ;
  125. 'FINS' ;
  126. * *
  127. ERRMAX = 'MAXI' ('PROG' ERR1 ERR2) ;
  128. 'SAUT' 1 'LIGN'
  129. '***** Cas-test reussi, max. erreur sur deplacements:' (ERRMAX) ;
  130. * *
  131. 'FIN' ;
  132.  
  133.  
  134.  
  135.  
  136.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales