Télécharger raff05.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************
  2. ** raff05.dgibi
  3. ************************************************************
  4. * *
  5. * Calcul elastique 2D avec un changement de niveau de *
  6. * raffinement dans une zonne X-FEM *
  7. * Test : Raff , MODLI, FPMASS, RIGI1, RIGIX, RIGIXR, *
  8. * RUSRUR, RIGSUX, TRIELE *
  9. * *
  10. * ^ ^ ^ ^ ^ ^ ^ *
  11. * | | | | | | | *
  12. * ------------- CL de Dirichlet *
  13. * | | *
  14. * | | *
  15. * | | *
  16. * | | *
  17. * | -=====- | Fissure horizontale *
  18. * | | *
  19. * | | *
  20. * | | *
  21. * | | *
  22. * > ------------- CL de Dirichlet *
  23. * ^ ^ ^ ^ ^ ^ ^ *
  24. * *
  25. * creation gg le *
  26. ************************************************************
  27. ************************************************************
  28. TITRE 'raff05.dgibi' ;
  29.  
  30. OPTI DIME 2 ELEM QUA4 MODE PLAN DEFO ;
  31.  
  32. OPTI 'POTR' 'HELVETICA_16';
  33.  
  34. *graph = vrai;
  35. graph = faux ;
  36.  
  37. * dimention du caree
  38. l=10.;
  39. *paramètres de raffinement
  40.  
  41.  
  42. dens1min=(l/4.0);
  43. *d1min=dens1min**1.5;
  44. dens2min=(l/8.0);
  45. *d2min=dens2min**1.5;
  46. dens3min=(l/64.0);
  47.  
  48. densmax=(l/2)*1.000001 ;
  49. densma4= 8*densmax;
  50. dmin=0.00001;
  51. *dmin = (3*l/8);
  52. dmax=(l/2)*0.99999 ;
  53. dmax2=(l)*0.99999 ;
  54.  
  55. * Points
  56. p1 = 0. (-1.0*l) ;
  57. p2 = l (-1.0*l). ;
  58. p3 = l l ;
  59. p4 = 0. l ;
  60. p5 = (-1.0*l) (-1.0*l);
  61. p6 = (-1.0*l) l;
  62.  
  63.  
  64. * Lignes
  65. l12 = p1 DROI 2 p2;
  66. l23 = p2 DROI 4 p3;
  67. l34 = p3 DROI 2 p4;
  68. l41 = p4 DROI 4 p1;
  69. l14 = p1 DROI 2 p4;
  70. l45 = p4 DROI 2 p5;
  71. l51 = p5 DROI 2 p1;
  72.  
  73. * Surface
  74. s0 = DALL l12 l23 l34 l41;
  75. t0 = surf (l14 et l45 et l51);
  76. st0= s0 et t0 ;
  77.  
  78.  
  79. * Premier raffinement
  80.  
  81. x0 y0 = coor s0 ;
  82.  
  83. DF0= abs y0;
  84.  
  85. aff2 = ((((densmax) - dens2min)*(DF0 - dmax))/(dmax - dmin)) + densmax ;
  86. dens2 = born aff2 'SCAL' 'COMPRIS'
  87. (dens2min*1.000001) (densmax*1.000001);
  88.  
  89. aff2 = ((((densmax) - (dens3min/64))*(DF0 - (dmax)))/
  90. ((dmax) - (2*dmin))) + densmax ;
  91. dens2 = born aff2 'SCAL' 'COMPRIS'
  92. (dens2min*1.000001) (densmax*1.000001);
  93.  
  94. s02 = raff s0 dens2;
  95.  
  96.  
  97.  
  98. *----------- rafinement d'un maillage isssue de 2 it de raff ---------*
  99. x2 y2 = coor s02 ;
  100.  
  101. DF2= (((y2**2)+(((X2 - (l*2/7))/8)**2))**0.5);
  102.  
  103.  
  104. aff23 = (((densmax - dens3min)*(DF2 - dmax))/(dmax - dmin)) + densmax ;
  105. dens23 = born aff23 'SCAL' 'COMPRIS'
  106. (dens3min*1.000001) (densmax*1.000001);
  107. s23 = raff s02 dens23;
  108. *s23 =s02;
  109.  
  110. *--------- Propriété materiau ---*
  111.  
  112.  
  113. E1=2.09086E+11;
  114. nu1=0.3;
  115.  
  116.  
  117. *Courbe de traction matériau éprouvette
  118. EPS1 = PROG 0. 2.50007E-3 5.39261E-3 1.40558E-2 2.28078E-2 3.17654E-2
  119. 4.1161E-2 5.14294E-2 6.33414E-2 7.82031E-2 9.81451E-2 0.12653 0.1685
  120. 0.23177 0.32756 0.47195 0.68754 1.0056 1.4685 2.1336 3.0765 4.3966
  121. 6.223 8.7212 12.102 16.633 22.647 30.56 40.883 54.247 71.419 93.330
  122. 121.10 ;
  123.  
  124. SG1 = PROG 0. 522.73 532.73 562.73 592.73 622.73 652.73 682.73 712.73
  125. 742.73 772.73 802.73 832.73 862.73 892.73 922.73 952.73 982.73 1012.7
  126. 1042.7 1072.7 1102.7 1132.7 1162.7 1192.7 1222.7 1252.7 1282.7 1312.7
  127. 1342.7 1372.7 1402.7 1432.7 ;
  128. SG1=SG1*1.0E+6;
  129.  
  130. EVTRAC = EVOL 'MANU' EPS1 SG1 ;
  131.  
  132.  
  133. *-----------geometrie fissure -----------------------------------------*
  134.  
  135. pf1 = (l*2/7) (l*3/64);
  136. pf2 = (l*5/7) (l*3/64);
  137. pmilieu = (l/2) (l*3/64);
  138.  
  139. lfiss = pf1 DROI 10 pf2;
  140.  
  141.  
  142. *----------modelisation xfem ------------------------------------------*
  143. x23 y23 = coor s23 ;
  144. PSI1 PHI1 = PSIPHI s23 LFISS 'DEUX' pf1 pf2;
  145.  
  146. *PTX = POIN (abs(y23)) 'INFERIEUR' (L/4) ;
  147. PTX = POIN (abs(y23)) 'INFERIEUR' (L/8) ;
  148.  
  149.  
  150. SURFX = S23 ELEM 'APPUYE' 'LARGEMENT' PTX ;
  151. SURFFEM = S23 DIFF SURFX ;
  152.  
  153.  
  154. *MODX = MODE SURFX MECANIQUE ELASTIQUE PLASTIQUE EPSI LINEAIRE XQ4R ;
  155. MODX = MODE SURFX MECANIQUE ELASTIQUE EPSI LINEAIRE XQ4R ;
  156.  
  157.  
  158. *list modx;
  159. MATX = MATE MODX 'YOUN' E1 'NU' nu1 ;
  160. *MNLX = MATE MODX YOUN E1 NU nu1 TRAC EVTRAC ;
  161.  
  162. *MODFEM = MODE SURFFEM MECANIQUE ELASTIQUE PLASTIQUE EPSI LINEAIRE ;
  163. MODFEM = MODE SURFFEM MECANIQUE ELASTIQUE EPSI LINEAIRE ;
  164.  
  165.  
  166. MATFEM = MATE MODFEM 'YOUN' E1 'NU' nu1 ;
  167. *MNLFEM = MATE MODFEM YOUN E1 NU nu1 TRAC EVTRAC ;
  168.  
  169. *CHPENR REL1 = TRIE (MODX) PSI1 PHI1 'DESE' ;
  170. CHPENR = TRIE (MODX) PSI1 PHI1 ;
  171.  
  172. * constructionsion des blocages des ddl X-fem non actifs dans
  173. * les éléments de transition.
  174. * Ainsi que des relations de conformité dues au raffinement.
  175. REL1 = RELA MODX;
  176. *---------Rigidite ---------------------------------------------*
  177.  
  178. RigX = RIGI(MODX et MODFEM) (MATX et MATFEM);
  179. *RNLX = RIGI(MODX et MODFEM) (MNLX et MNLFEM);
  180.  
  181. *---------condition aux limite et chargement ----------------*
  182.  
  183.  
  184. lb23 = s23 POIN 'DROI' p1 p2 0.001;
  185. cl23 = BLOQ lb23 uy;
  186. clx = BLOQ p1 ux;
  187.  
  188. lp23 = (cont s23) elem 'APPUYE' 'STRICTEMENT' l34;
  189. presX = PRES 'MASS' (modX et modfem) -2.0E10 lp23 ;
  190.  
  191. clp = bloq lp23 uy ;
  192. f1 = depi clp 1. ;
  193. LI1 = PROG 0. 1. ;
  194. LI2 = PROG 0. 1. ;
  195.  
  196. CHPO1 = MANU 'CHPO' lp23 'FY' -2.0E11 ;
  197. EV1 = EVOL MANU T LI1 F(T) LI2 ;
  198. CHA1 = CHAR 'DIMP' F1 EV1 ;
  199.  
  200. *---------- resolution d'un pb linéaire sur le maillage X-FEM----------*
  201.  
  202. resX = reso (rigX et cl23 et clx et CLP et REL1) F1;
  203. SIGX = SIGM (MODX et MODFEM ) (MATX et MATFEM) resx;
  204. defX = defo 1.0 resX s23 ;
  205. FOR1 = BSIG (MODX et MODFEM) SIGX;
  206. EPS1 = EPSI (MODX et MODFEM) resX ;
  207.  
  208. resXR = XFEM 'RECO' resx (MODX et MODFEM) ;
  209. defXR = defo 1.0 resXr s23 ;
  210. DPSUP DPINF = XFEM 'FISS' lfiss resX (MODX et MODFEM) ;
  211. DEFfiss = (DEFO 1. DPSUP lfiss'VERT') et
  212. (DEFO 1. DPINF lfiss 'ROUG') ;
  213.  
  214. si (graph);
  215. trac (s23 et (coul bleu surfX) et (coul roug Lfiss))
  216. (vect presx 'FORC' 'ROUG') TITR ' Maillage raffine et enrichi' ;
  217. trac (DEFfiss et defxR) TITR 'Deformee';
  218. trac resx (surfx et lfiss) TITR 'Champ de deplacement XFEM';
  219. trac sigx (modx) TITR 'Champ de contraintes ';
  220. trac FOR1 S23 TITR 'Forces Nodales';
  221. trac EPS1 (MODX et MODFEM) TITR 'DEFORMATIONS';
  222. trac resxR (surfx et lfiss) TITR 'Champ de deplacement FEM' ;
  223. finsi ;
  224.  
  225. *---------- resolution d'un pb non linéaire sur le maillage X-FEM------*
  226.  
  227. *Résolution PASAPAS
  228. TABPAP = TABLE ;
  229. TABPAP . 'TEMPS_CALCULES' = PROG 0. pas 0.1 1. ;
  230. TABPAP . 'CARACTERISTIQUES' = (MATX et MATFEM) ;
  231. TABPAP . 'CHARGEMENT' = CHA1 ;
  232. TABPAP . 'BLOCAGES_MECANIQUES' = cl23 et clx ET CLP et REL1;
  233. TABPAP . 'MODELE' = (MODX et MODFEM) ;
  234. TABPAP . 'LAGRANGIEN' = mot 'REACTUALISE' ;
  235. PASAPAS TABPAP ;
  236.  
  237. Udiff = resx - (tabpap.deplacements.10);
  238. diffy = exco Udiff 'UY';
  239. diffy2 = chan 'CHAM' (diffy **2) s23;
  240. si (graph);
  241. trac Udiff (surfx et lfiss) TITR 'différence entre reso et pasapas';
  242. finsi ;
  243.  
  244. * geometrie pour le post traitement
  245. phaut = (L/2) L;
  246. pbas = (L/2) 0;
  247.  
  248. * symetrie
  249.  
  250. uy1 = exco resx 'UY';
  251. S23sym uysym1 = s23 uy1 SYME 'DROIT' phaut pbas;
  252. * passage a un chamelem aux noeuds
  253. uysym2 = chan 'CHAM' uysym1 S23sym;
  254. * projection
  255. uysym3 = PROI uysym2 s23;
  256.  
  257. * passage de uproj en chpoin
  258. uy3= chan 'CHAM' uy1 s23;
  259.  
  260. diffy = (uysym3-uy1)**2;
  261. diffy1 = chan 'CHAM' diffy s23;
  262.  
  263. unor = CHAN 'CHAM' ((uy1)**2) s23;
  264.  
  265. erry1 = (INTG (MODX) diffy1) / (INTG (MODX) unor);
  266. list erry1;
  267.  
  268. si (graph);
  269. trac (uysym3 - uy1) s23 TITR 'Defaut de symetrie de la composante Uy';
  270. finsi ;
  271.  
  272. SI (erry1 < (5.0E-3));
  273. 'MESS' ' ----------------------' ;
  274. 'MESS' ' SUCCES DU CAS-TEST !' ;
  275. 'MESS' ' ----------------------' ;
  276. Erre 0;
  277. Sinon ;
  278. 'MESS' ' ---------------------' ;
  279. 'MESS' ' ECHEC DU CAS-TEST !' ;
  280. 'MESS' ' ---------------------' ;
  281. Erre 5;
  282. finsi ;
  283.  
  284. erry2 = (INTG (MODX) diffy2) / (INTG (MODX) unor);
  285. list erry2;
  286. SI (erry2 < (1.0E-15)) ;
  287. 'MESS' ' ----------------------' ;
  288. 'MESS' ' SUCCES DU CAS-TEST !' ;
  289. 'MESS' ' ----------------------' ;
  290. Erre 0 ;
  291. Sinon ;
  292. 'MESS' ' ---------------------' ;
  293. 'MESS' ' ECHEC DU CAS-TEST !' ;
  294. 'MESS' ' ---------------------' ;
  295. Erre 5;
  296. finsi;
  297. FIN;
  298.  
  299.  
  300.  
  301.  
  302.  
  303.  
  304.  
  305.  
  306.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales