Télécharger pret_wall.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pret_wall.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *********************************************************************
  5. **** APPROCHE VF "Cell-Centred Formulation" pour la solution des ****
  6. **** Equations d'Euler pour un gaz parfait ****
  7. **** OPERATEURS PRIM et PRET ****
  8. **** Gaz monoespece "calorically perfect" ****
  9. **** Etat mur ****
  10. **** ****
  11. **** A. BECCANTINI DRN/DMT/SEMT/TTMF NOVEMBRE 1998 ****
  12. *********************************************************************
  13.  
  14. 'OPTION' 'DIME' 2 ;
  15. 'OPTION' 'ELEM' QUA4 ;
  16. 'OPTION' 'ECHO' 0 ;
  17. 'OPTION' 'TRAC' 'PS' ;
  18.  
  19. GRAPH = FAUX ;
  20. * GRAPH = VRAI ;
  21.  
  22. ***************************
  23. ***** DOMAINE SPATIAL ****
  24. ***************************
  25.  
  26.  
  27. A1 = 0.0D0 0.0D0;
  28. A2 = 1.0D0 0.0D0;
  29. A3 = 1.0D0 1.0D0;
  30. A4 = 0.0D0 1.0D0;
  31.  
  32. L12 = A1 'DROIT' 1 A2 ;
  33. L23 = A2 'DROIT' 1 A3 ;
  34. L34 = A3 'DROIT' 1 A4 ;
  35. L41 = A4 'DROIT' 1 A1 ;
  36.  
  37. DOM10 = 'DALL' L12 L23 L34 L41 'PLANE';
  38.  
  39. *
  40. *** Point ou on controlle l'etat
  41. *
  42.  
  43. P10 = 1.0 0.5 ;
  44.  
  45. *
  46. *** Etat centre
  47. *
  48.  
  49. ro = 1.0D0 ;
  50. un = 1.0D0 ;
  51. ut = 10.0D0 ;
  52. p = 1.0D0 ;
  53. gam = 1.4D0 ;
  54.  
  55. roet = (p '/' (gam '-' 1.0)) '+'
  56. ( 0.5 '*' ro '*' ((un '*' un) '+' (ut '*' ut))) ;
  57.  
  58.  
  59. ****************************************************
  60. ****************************************************
  61. ******** Boucle sur les angles *********
  62. ****************************************************
  63. ****************************************************
  64.  
  65. DANGLE = 360 '/' 7.15;
  66. ANGLE = 11.3 ;
  67.  
  68. 'REPETER' BLOC 8;
  69.  
  70. *
  71. *** Rotation
  72. *
  73.  
  74. ANGLE = ANGLE '+' DANGLE;
  75. ORIG = 0.0D0 0.0D0;
  76.  
  77. MESSAGE;
  78. MESSAGE (CHAIN 'Angle de rotation= ' ANGLE);
  79. MESSAGE;
  80.  
  81. DOM1 = DOM10 'TOURNER' ANGLE ORIG;
  82. P1 = P10 'TOURNER' ANGLE ORIG;
  83.  
  84. DOMTOT = DOM1;
  85. 'ELIMINATION' DOMTOT 1D-6;
  86.  
  87.  
  88. $DOMTOT = 'MODELISER' DOMTOT 'EULER';
  89. TDOMTOT = 'DOMA' $DOMTOT 'VF';
  90. MDOMTOT = TDOMTOT . 'QUAF' ;
  91.  
  92. 'SI' GRAPH ;
  93. 'TRACER' (('DOMA' $DOMTOT 'MAILLAGE') 'ET' ('DOMA' $DOMTOT 'FACEL')
  94. 'ET' P1) 'TITRE' 'Domaine et FACEL';
  95. 'FINSI' ;
  96.  
  97.  
  • *
  • **** Redefinition de P1 dans $DOMTOT 'FACE'
  • *
  •  
  • P1 = ('DOMA' $DOMTOT 'FACE') 'POIN' 'PROC' P1;
  •  
  • ***********************
  • **** Les CHPOINTs ****
  • ***********************
  •  
  • ux = (un '*' ('COS' ANGLE)) '-' (ut '*' ('SIN' ANGLE));
  • uy = (un '*' ('SIN' ANGLE)) '+' (ut '*' ('COS' ANGLE));
  •  
  • GAMMA = 'KCHT' $DOMTOT 'SCAL' 'CENTRE' gam ;
  •  
  • RN = 'KCHT' $DOMTOT 'SCAL' 'CENTRE' ro ;
  • GN = 'KCHT' $DOMTOT 'VECT' 'CENTRE' ((ro '*' ux) (ro '*' uy));
  • EN = 'KCHT' $DOMTOT 'SCAL' 'CENTRE' roet ;
  •  
  •  
  • ***************************
  • **** L'operateur PRIM****
  • ***************************
  •  
  • VITESSE PRES = 'PRIM' 'PERFMONO' RN GN EN GAMMA;
  •  
  • ***************************
  • **** L'operateur PRET****
  • ***************************
  •  
  • ORDESP = 1;
  • ORDTEM = 1;
  •  
  • ROF VITF PF GAMF = 'PRET' 'PERFMONO' ORDESP ORDTEM
  • $DOMTOT RN VITESSE PRES GAMMA;
  •  
  • *********************************************************
  • *** Control des etats sur la surface qui contient P1 ****
  • *********************************************************
  •  
  • GEOP1 = ('DOMA' $DOMTOT 'FACEL') 'ELEM' 'CONTENANT' P1;
  • GEOP2 = ('DOMA' $DOMTOT 'FACE') 'ELEM' 'CONTENANT' P1;
  •  
  •  
  • ROGEOP1 = 'REDU' ROF GEOP1;
  • VGEOP1 = 'REDU' VITF GEOP1;
  • PGEOP1 = 'REDU' PF GEOP1;
  • GAMGEOP1 = 'REDU' GAMF GEOP1;
  • REFGEOP1 = 'REDU' VITF GEOP2;
  •  
  •  
  • rog = 'EXTRAIRE' ROGEOP1 'SCAL' 1 1 1;
  • rod = 'EXTRAIRE' ROGEOP1 'SCAL' 1 1 3;
  • ung = 'EXTRAIRE' VGEOP1 'UN ' 1 1 1;
  • und = 'EXTRAIRE' VGEOP1 'UN ' 1 1 3;
  • utg = 'EXTRAIRE' VGEOP1 'UT ' 1 1 1;
  • utd = 'EXTRAIRE' VGEOP1 'UT ' 1 1 3;
  • pg = 'EXTRAIRE' PGEOP1 'SCAL' 1 1 1;
  • pd = 'EXTRAIRE' PGEOP1 'SCAL' 1 1 3;
  •  
  •  
  • *
  • **** Sur le mur: Gauche = etat reel
  • * Droit = etat mirroir
  • *
  •  
  • LOG1 = ('ABS' (rog '-' ro)) > 1.0D-12 ;
  • LOG1 = 'OU' LOG1 (('ABS' (rod '-' ro)) > 1.0D-12) ;
  • LOG1 = 'OU' LOG1 (('ABS' (un '-' ung)) > 1.0D-12) ;
  • LOG1 = 'OU' LOG1 (('ABS' (un '+' und)) > 1.0D-12) ;
  • LOG1 = 'OU' LOG1 (('ABS' (ut '-' utg)) > 1.0D-12) ;
  • LOG1 = 'OU' LOG1 (('ABS' (ut '-' utd)) > 1.0D-12) ;
  • LOG1 = 'OU' LOG1 (('ABS' (p '-' pg)) > 1.0D-12) ;
  • LOG1 = 'OU' LOG1 (('ABS' (p '-' pd)) > 1.0D-12) ;
  •  
  • 'SI' LOG1 ;
  • 'MESSAGE' ;
  • 'MESSAGE' 'Probleme en PRET ou en PRIM ' ;
  • 'MESSAGE' ;
  • 'ERREUR' 5;
  • 'FINSI' ;
  •  
  • 'FIN' BLOC ;
  •  
  • 'FIN' ;
  •  
  •  
  •  
  •  
  •  
  •  
  •  
  •  
  •  
  •  
  •  
  • © Cast3M 2003 - Tous droits réservés.
    Mentions légales