Télécharger pressuw.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressuw.dgibi
  2. *---------------------------------------------------------
  3. * Pressurisation d'une enceinte type Phébus
  4. *
  5. * Le maillage correspond à une enceinte cylindrique
  6. * d'environ 10 m3 avec un mur en contact avec la
  7. * paroi verticale (10 cm d'acier)
  8. * Tout le volume est initialement a 1bar et 40oC
  9. * et la température du mur est mise à 60oC
  10. * au début du calcul. On calcule la pressurisation
  11. * de cette enceinte sur 50 secondes en injectant un débit
  12. * de 50g/s de vapeur à 150oC. Ce test (un peu long)
  13. * verifie le demarrage de la condensation a 20"
  14. * verifie l'evolution moyenne de la temprature gaz
  15. * verifie la pression max a 50"
  16. * verifie la vitesse max a 50" (Convection naturelle)
  17. * verifie la masse d'eau a 50"
  18. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  19. * revisite Mars 2001
  20. *--------------------------------------------------------
  21. COMPLET = FAUX ;
  22. *COMPLET = VRAI ;
  23. GRAPH = VRAI ;
  24. GRAPH = FAUX ;
  25. 'OPTI' 'TRAC' 'X' ;
  26. 'OPTI' 'TRAC' 'PSC' ;
  27. TPAROI=VRAI;
  28.  
  29. 'SI' COMPLET ;
  30.  
  31. nbit=100;
  32. DT0 = 1. ;
  33. n1 = 1 ; n2 = 4 ; n3 = 2 ;
  34. n4 = 8 ; nn = 2 ;
  35.  
  36. 'SINON' ;
  37.  
  38. nbit= 5 ;
  39. DT0 = 10. ;
  40. n1 = 1 ; n2 = 2 ; n3 = 2 ;
  41. n4 = 4 ; nn = 1 ;
  42.  
  43. 'FINSI' ;
  44.  
  45. *--------------------------------------------------------
  46. * Definition du maillage de l'enceinte cylindrique
  47. *
  48. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  49.  
  50. ri = 1.052 ; sp = 0.05 ; hc = 4.163 ;
  51. sp2 = 0.05 ;
  52.  
  53.  
  54. epsi = 1.000e-4 ; ;
  55.  
  56. p0 = 0.000 0.000 0.000 ;
  57. px = -1000.000 0.000 0.000 ;
  58. py = 0.000 -1000.000 0.000 ;
  59. pz = 0.000 0.000 1000.000 ;
  60. cd = 0.000 0.000 -20.000 ;
  61. ph0 = 0.000 0.000 hc ;
  62. phx = ri 0.000 hc ;
  63. phy = 0.000 ri hc ;
  64.  
  65. fg1 = 0.25 ;
  66. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  67.  
  68. p1 = (ri*fg1) 0.000 0.000 ;
  69. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  70. p3 = 0.000 (ri*fg1) 0.000 ;
  71. p4 = ri 0.000 0.000 ;
  72. p5 = 0.000 ri 0.000 ;
  73. p6 = (ri+sp) 0.000 0.000 ;
  74. p7 = 0.000 (ri+sp) 0.000 ;
  75. p8 = (ri+sp+sp2) 0.000 0.000 ;
  76. p9 = 0.000 (ri+sp+sp2) 0.000 ;
  77.  
  78. * Hauteur de l'enceinte
  79. h1 = 4.163 ;
  80. * Vecteur de translation
  81. v1 = 0. 0. h1 ;
  82.  
  83. l1 = 'DROI' p0 p1 n1 ;
  84. l2 = 'DROI' p1 p2 n1 ;
  85. l3 = 'DROI' p2 p3 n1 ;
  86. l4 = 'DROI' p3 p0 n1 ;
  87. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  88. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  89. l7 = 'CERC' p8 p0 p9 (2*n1) ;
  90.  
  91. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  92. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  93. l44= cote 2 basf1;
  94. ax4= (inve l4) et l44 ;
  95. l11= cote 4 basf1;
  96. ax1= l11 et (inve l1) ;
  97.  
  98. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  99. 'ELIM' basf epsi ;
  100. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  101. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  102. 'ELIM' basf epsi ;
  103. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  104. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  105. 'ELIM' basf epsi ;
  106.  
  107. basm1= 'REGL' l5 l6 n3 ;
  108. basm2= 'REGL' l6 l7 n3 ;
  109. basm1= basm1 'ET' ('SYME' basm1 'DROI' p0 p3) ;
  110. 'ELIM' basm1 epsi ;
  111. basm1 = basm1 'ET' ('SYME' basm1 'DROI' p0 p1) ;
  112. basm2= basm2 'ET' ('SYME' basm2 'DROI' p0 p3) ;
  113. 'ELIM' basm1 epsi ;
  114. basm2 = basm2 'ET' ('SYME' basm2 'DROI' p0 p1) ;
  115.  
  116. basm=basm1 et basm2;
  117. 'ELIM' basm epsi ;
  118. *trace basm;
  119.  
  120. * Creation du volume
  121.  
  122. dx = ri / 2. ;
  123. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  124.  
  125. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  126. mbas1 = basm1 'VOLU' nz1 'TRAN' v1 ;
  127. mbas1 = mbas1 'COUL' 'ROUG' ;
  128. mbas2 = basm2 'VOLU' nz1 'TRAN' v1 ;
  129. mbas2 = mbas2 'COUL' 'VERT' ;
  130. mbas=mbas1 et mbas2;
  131. plan1 = ax11 'TRAN' nz1 v1 ;
  132. plan4 = ax44 'TRAN' nz1 v1 ;
  133. 'ELIM' (bas et plan1 et plan4) epsi ;
  134.  
  135. mt = bas ;
  136. wall = mbas ;
  137. elim (mt et wall) epsi ;
  138.  
  139. * Localisation d'une brèche éventuelle au bas de l'enceinte
  140.  
  141. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  142. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  143.  
  144. *--------------------------------------------------------------------
  145. * Fin de la définition du maillage
  146. *--------------------------------------------------------------------
  147.  
  148. *--------------------------------------------------------------------
  149. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  150. *--------------------------------------------------------------------
  151.  
  152. rxt = 'TABLE' ;
  153.  
  154. *-- Nom du volume fluide
  155. rxt.'vtf' = mt ;
  156. rxt.'epsi' = epsi ;
  157.  
  158. *-- Definition des murs de l'enceinte : ici un seul mur
  159. *-- en ACIER dont on traitera la thermique dans l'épaisseur
  160. *-- et que l'on initialise a 40oC
  161.  
  162. *trace wall cache ;
  163.  
  164. *-- On definit d'abort la matériau ACIER avec sa conductivite
  165. *-- thermique LAMBDA (W/m/K) et le produit ro*Cp (J/m3/K)
  166. SI TPAROI ;
  167. rxt.'PAROIS'=table ;
  168. rxt.'PAROIS'.'Peinture'=table ;
  169. rxt.'PAROIS'.'Peinture'.'vtp' = mbas1 ;
  170. rxt.'PAROIS'.'Peinture'.'LAMBDA' = 15. ;
  171. rxt.'PAROIS'.'Peinture'.'ROCP' = 3.9E6 ;
  172. rxt.'PAROIS'.'Peinture'.'Tp0' = 60. ;
  173. rxt.'PAROIS'.'Acier'=table ;
  174. rxt.'PAROIS'.'Acier'.'vtp' = mbas2 ;
  175. rxt.'PAROIS'.'Acier'.'LAMBDA' = 15. ;
  176. rxt.'PAROIS'.'Acier'.'ROCP' = 3.9E6 ;
  177. rxt.'PAROIS'.'Acier'.'Tp0' = 60. ;
  178. rxt.'ECHAN' = 10. ;
  179. SINON ;
  180. rxt.'THERMP' = VRAI ;
  181. rxt.'vtp' = wall ;
  182. rxt.'LAMBDA' = 15. ;
  183. rxt.'ROCP' = 3.9E6 ;
  184. rxt.'Tp0' = 60. ;
  185. rxt.'ECHAN' = 10. ;
  186. FINSI ;
  187.  
  188. *-- Conditions initiales dans l'enceinte de test
  189. rxt.'TF0' = 40.0 ;
  190. rxt.'PT0' = 1.00000e5 ;
  191. rxt.'Yvap0' = 0.0023 ;
  192.  
  193. *-- On positionne une brèche
  194. rxt.'breche' = jg ;
  195. rxt.'diru1' = 0 0 1 ;
  196.  
  197. *-- On definit un point interne au maillage pour imposer la valeur de
  198. *-- la pression
  199. rxt.'pi' = (0.0 0.0 0.5) ;
  200.  
  201. *-- On indique que le calcul comporte de la vapeur d'eau
  202. rxt.'VAPEUR' = VRAI ;
  203.  
  204. *-- On active le recalcul automatique du préconditionnement
  205. *-- toutes les 5 itérations
  206. rxt.'FRPREC' = 5 ;
  207. rxt.'DETMAT' = VRAI ;
  208.  
  209. *-- Definition du scenario thermohydraulique
  210. rxt.'scenario' = table ;
  211.  
  212. *-- Conditions a la breche (Obligatoire pour l'instant)
  213. rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  214. rxt.'scenario'.'qeau' = prog 0.050 0.050 ;
  215. rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  216. rxt.'scenario'.'tinj' = prog 150.0 150.0 ;
  217.  
  218. *-- On impose le pas de temps (s)
  219. rxt.'DT0' = DT0 ;
  220.  
  221. *-- On impose la viscosite turbulente (m2/s)
  222. rxt.'MODTURB'='NUTURB' ;
  223. rxt.'NUT' = 1.e-2 ;
  224.  
  225. *-- On lance le calcul sur 20 itérations d'une seconde
  226. rxt.'GRAPH'=GRAPH ;
  227.  
  228. EXECRXT 2 rxt ;
  229. *FIN ;
  230. *opti donn 5 ;
  231. EXECRXT (nbit - 2) rxt ;
  232.  
  233.  
  234. list rxt.TIC.'Tfm' ;
  235. list rxt.TIC.'PT' ;
  236. list rxt.TIC.'Qc' ;
  237. list rxt.TIC.'LMAXU';
  238.  
  239. ltfm=Prog 40.000 65.434 73.712 81.158 86.800
  240. 90.634;
  241.  
  242. lPT =Prog 1.00000E+05 1.06009E+05 1.21199E+05 1.29592E+05
  243. 1.36458E+05 1.43948E+05;
  244.  
  245. Lqc =Prog 0.0000 0.0000 0.0000 4.41098E-04
  246. 3.03436E-03 5.60231E-03;
  247.  
  248. Lmaxu=Prog 0.0000 0.81320 2.0813 2.6901
  249. 2.2350 2.5277;
  250.  
  251. tic=rxt.'TIC' ;
  252. ERtf=somm( abs (ltfm - tic.'Tfm') )/ 80. ;
  253. ERPT=somm( abs (lPT - tic.'PT' ) ) /1.e5 ;
  254. ERQc=somm( abs (lqc - tic.'Qc' ) ) ;
  255. ERum=somm( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  256.  
  257. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  258.  
  259. Si (ERtf '>' 1.e-4) ; erreur 5 ; Finsi ;
  260. Si (ERPT '>' 1.e-3) ; erreur 5 ; Finsi ;
  261. Si (ERQc '>' 1.e-4) ; erreur 5 ; Finsi ;
  262. Si (ERum '>' 1.e-2) ; erreur 5 ; Finsi ;
  263.  
  264. Si GRAPH ;
  265.  
  266. $vtf=rxt.'GEO'.'$vtf' ;
  267. mt =doma $vtf maillage ;
  268. Mpl1=chan 'QUAF' plan1 ;
  269. Mpl4=chan 'QUAF' plan4 ;
  270. ELIM (mt et Mpl1 et Mpl4) epsi ;
  271. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  272. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  273. plan1= doma $mpl1 maillage ;
  274. plan4= doma $mpl4 maillage ;
  275. plan=plan1 et plan4 ;
  276.  
  277. paroif = rxt.'GEO'.'paroif';
  278. rho=rxt.'TIC'.'RHO';
  279. rvp=rxt.'TIC'.'RVP';
  280. tf=rxt.'TIC'.'TF';
  281. un=rxt.'TIC'.'UN' ;
  282. un1=redu un plan ;
  283. ung= vect un1 1. ux uy uz jaune ;
  284. trace ung plan ;
  285. opti isov suli ;
  286. trace rho plan 'TITRE'' Rho' ;
  287. trace rvp plan 'TITRE'' Rvp' ;
  288. trace tf plan 'TITRE'' Tf ' ;
  289.  
  290. trace rho paroif 'TITRE'' Rho' ;
  291. trace rvp paroif 'TITRE'' Rvp' ;
  292. trace Tf paroif 'TITRE'' Tf ' ;
  293. Fcond = tic.'Fcondw';
  294. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  295.  
  296. axe = p0 d nz1 (p0 plus v1) ;
  297. axe = chan axe 'QUAF' ;
  298. elim (axe et mt) epsi ;
  299.  
  300. evr= evol 'CHPO' rho axe ;
  301. dess evr 'TITRE' ' Rho axe ';
  302.  
  303. evt = evol 'CHPO' Tf axe ;
  304. dess evt 'TITRE' ' Température axe ';
  305.  
  306. evvp= evol 'CHPO' rvp axe ;
  307. dess evvp 'TITRE' ' rvp axe ';
  308.  
  309.  
  310.  
  311. 'FINSI' ;
  312.  
  313.  
  314.  
  315.  
  316.  
  317. 'FIN' ;
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales