Télécharger pressutq2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressutq.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *---------------------------------------------------------
  5. * Pressurisation d'une enceinte type Phébus
  6. *
  7. * Le maillage correspond à une enceinte cylindrique
  8. * d'environ 10 m3 avec un mur en contact avec la
  9. * paroi verticale (10 cm d'acier)
  10. * Tout le volume est initialement a 1.3bar et 123oC
  11. * et la température du mur est mise à 100oC
  12. * au début du calcul. On calcule la pressurisation
  13. * de cette enceinte sur 50 secondes en injectant un débit
  14. * de 10g/s de vapeur à 130oC. Ce test (un peu long)
  15. * verifie le demarrage de la condensation a 20"
  16. * verifie l'evolution moyenne de la temprature gaz
  17. * verifie la pression max a 50"
  18. * verifie la vitesse max a 50" (Convection naturelle)
  19. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  20. * revisite Avril 2002
  21. *--------------------------------------------------------
  22. COMPLET = FAUX ;
  23. *COMPLET = VRAI ;
  24. *GRAPH = VRAI ;
  25. GRAPH = FAUX ;
  26.  
  27. 'SI' COMPLET ;
  28.  
  29. nbit=100;
  30. DT0 = 1. ;
  31. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  32. n4 = 8 ; nn = 2 ;
  33.  
  34. 'SINON' ;
  35.  
  36. nbit= 5 ;
  37. DT0 = 10. ;
  38. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  39. n4 = 4 ; nn = 1 ;
  40.  
  41. 'FINSI' ;
  42.  
  43. *--------------------------------------------------------
  44. * Definition du maillage de l'enceinte cylindrique
  45. *
  46. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  47.  
  48. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  49.  
  50.  
  51.  
  52. epsi = 1.000e-2 ; ;
  53.  
  54. p0 = 0.000 0.000 0.000 ;
  55. px = -1000.000 0.000 0.000 ;
  56. py = 0.000 -1000.000 0.000 ;
  57. pz = 0.000 0.000 1000.000 ;
  58. cd = 0.000 0.000 -20.000 ;
  59. ph0 = 0.000 0.000 hc ;
  60. phx = ri 0.000 hc ;
  61. phy = 0.000 ri hc ;
  62.  
  63. fg1 = 0.25 ;
  64. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  65.  
  66. p1 = (ri*fg1) 0.000 0.000 ;
  67. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  68. p3 = 0.000 (ri*fg1) 0.000 ;
  69. p4 = ri 0.000 0.000 ;
  70. p5 = 0.000 ri 0.000 ;
  71. p6 = (ri+sp) 0.000 0.000 ;
  72. p7 = 0.000 (ri+sp) 0.000 ;
  73.  
  74. * Hauteur de l'enceinte
  75. h1 = 4.163 ;
  76. * Vecteur de translation
  77. v1 = 0. 0. h1 ;
  78.  
  79. l1 = 'DROI' p0 p1 n1 ;
  80. l2 = 'DROI' p1 p2 n1 ;
  81. l3 = 'DROI' p2 p3 n1 ;
  82. l4 = 'DROI' p3 p0 n1 ;
  83. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  84. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  85.  
  86. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  87. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  88. l44= cote 2 basf1;
  89. ax4= (inve l4) et l44 ;
  90. l11= cote 4 basf1;
  91. ax1= l11 et (inve l1) ;
  92.  
  93. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  94. 'ELIM' basf epsi ;
  95. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  96. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  97. 'ELIM' basf epsi ;
  98. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  99. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  100. 'ELIM' basf epsi ;
  101.  
  102. basm = 'REGL' l5 l6 n3 ;
  103. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  104. 'ELIM' basm epsi ;
  105. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  106. 'ELIM' basm epsi ;
  107.  
  108. * Creation du volume
  109.  
  110. dx = ri / 2. ;
  111. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  112.  
  113. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  114. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  115. mbas = mbas 'COUL' 'ROUG' ;
  116. plan1 = ax11 'TRAN' nz1 v1 ;
  117. plan4 = ax44 'TRAN' nz1 v1 ;
  118. 'ELIM' (bas et plan1 et plan4) epsi ;
  119.  
  120. mt = bas ;
  121. wall = enve bas ;
  122. mur = DIFF wall basf;
  123. mur =mur 'COUL' 'ROUG' ;
  124.  
  125. elim (mt et mur) epsi ;
  126.  
  127.  
  128. * Localisation d'une brèche éventuelle au bas de l'enceinte
  129.  
  130. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  131. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  132.  
  133. *--------------------------------------------------------------------
  134. * Fin de la définition du maillage
  135. *--------------------------------------------------------------------
  136.  
  137. *--------------------------------------------------------------------
  138. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  139. *--------------------------------------------------------------------
  140.  
  141. rxt = 'TABLE' ;
  142.  
  143. *-- Nom du volume fluide
  144. rxt.'vtf' = mt ;
  145. rxt.'epsi' = epsi ;
  146.  
  147. * Definition du bidon :
  148. rxt.'TIMP' = table ;
  149. rxt.'TIMP'.'TIMP1' = table ;
  150. rxt.'TIMP'.'TIMP1'.'MAILLAGE' = mur ;
  151. rxt.'TIMP'.'TIMP1'.'t' = prog 0.0 3000. ;
  152. rxt.'TIMP'.'TIMP1'.'TIMP' = prog 100.0 100.0 ;
  153. rxt.'TIMP'.'TIMP1'.'ECHAN' = 10. ;
  154.  
  155. *-- Conditions initiales dans l'enceinte de test
  156. rxt.'TF0' = 123.0 ;
  157. rxt.'PT0' = 1.30000e5 ;
  158. rxt.'Yvap0' = 1.0E-8 ;
  159.  
  160. *-- On positionne une brèche
  161. rxt.'breche' = jg ;
  162. rxt.'diru1' = 0. 0. 1. ;
  163.  
  164. *-- On definit un point interne au maillage pour imposer la valeur de
  165. *-- la pression
  166. rxt.'pi' = (0.0 0.0 0.5) ;
  167.  
  168. *-- On indique que le calcul comporte de la vapeur d'eau
  169. rxt.'VAPEUR' = VRAI ;
  170.  
  171. *-- On active le recalcul automatique du préconditionnement
  172. *-- toutes les 5 itérations
  173. rxt.'FRPREC' = 5 ;
  174. rxt.'DETMAT' = VRAI ;
  175.  
  176. *-- Definition du scenario thermohydraulique
  177. rxt.'scenario' = table ;
  178.  
  179. *-- Conditions a la breche (Obligatoire pour l'instant)
  180. rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  181. rxt.'scenario'.'qeau' = prog 0.010 0.010 ;
  182. rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  183. rxt.'scenario'.'tinj' = prog 130.0 130.0 ;
  184.  
  185. *-- On impose le pas de temps (s)
  186. rxt.'DT0' = DT0 ;
  187.  
  188. *-- On impose la viscosite turbulente (m2/s)
  189. rxt.'MODTURB'='NUTURB' ;
  190. rxt.'NUT' = 1.e-2 ;
  191.  
  192. *-- On lance le calcul sur 20 itérations d'une seconde
  193. rxt.'GRAPH'=GRAPH ;
  194.  
  195. execrxt 2 rxt ;
  196. *opti donn 5 ;
  197. execrxt (nbit - 2) rxt ;
  198.  
  199.  
  200. list rxt.TIC.'Tfm' ;
  201. list rxt.TIC.'PT' ;
  202. list rxt.TIC.'Qc' ;
  203. list rxt.TIC.'LMAXU';
  204.  
  205. 'SI' (NON COMPLET) ;
  206.  
  207. ltfm=Prog 123.00 120.38 122.24 118.59
  208. 116.85 115.21 ;
  209.  
  210. lPT =Prog 1.30000E+05 1.30840E+05 1.30301E+05 1.32428E+05
  211. 1.32798E+05 1.33293E+05;
  212.  
  213. Lqc =Prog 0.0000 0.0000 0.0000 0.0000
  214. 0.0000 0.0000;
  215.  
  216. Lmaxu=Prog 0.0000 0.11919 0.12541 1.5872
  217. 1.0398 1.9786 ;
  218.  
  219. tic=rxt.'TIC' ;
  220. ERtf=SOMM( abs (ltfm - tic.'Tfm') )/ 110. ;
  221. ERPT=SOMM( abs (lPT - tic.'PT' ) ) /1.e5 ;
  222. ERQc=SOMM( abs (lqc - tic.'Qc' ) ) ;
  223. ERum=SOMM( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  224.  
  225. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  226.  
  227. Si (ERtf '>' 1.e-3) ; erreur 5 ; Finsi ;
  228. Si (ERPT '>' 1.e-4) ; erreur 5 ; Finsi ;
  229. Si (ERQc '>' 1.e-4) ; erreur 5 ; Finsi ;
  230. Si (ERum '>' 1.e-2) ; erreur 5 ; Finsi ;
  231.  
  232. 'FINSI' ;
  233.  
  234. Si GRAPH ;
  235.  
  236. $vtf=rxt.'GEO'.'$vtf' ;
  237. mt =doma $vtf maillage ;
  238. Mpl1=chan 'QUAF' plan1 ;
  239. Mpl4=chan 'QUAF' plan4 ;
  240. ELIM (mt et Mpl1 et Mpl4) epsi ;
  241. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  242. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  243. plan1= doma $mpl1 maillage ;
  244. plan4= doma $mpl4 maillage ;
  245. plan=plan1 et plan4 ;
  246.  
  247. paroif = rxt.'GEO'.'mtp1';
  248. rho=rxt.'TIC'.'RHO';
  249. rvp=rxt.'TIC'.'RVP';
  250. tf=rxt.'TIC'.'TF';
  251. un=rxt.'TIC'.'UN' ;
  252. un1=redu un plan ;
  253. ung= vect un1 1. ux uy uz jaune ;
  254. trace ung plan ;
  255. opti isov suli ;
  256. trace rho plan 'TITRE'' Rho' ;
  257. trace rvp plan 'TITRE'' Rvp' ;
  258. trace tf plan 'TITRE'' Tf ' ;
  259.  
  260. trace rho paroif 'TITRE'' Rho' ;
  261. trace rvp paroif 'TITRE'' Rvp' ;
  262. trace Tf paroif 'TITRE'' Tf ' ;
  263. Fcond = rxt.'TIC'.'Fcond1';
  264. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  265.  
  266. axe = p0 d nz1 (p0 plus v1) ;
  267. axe = chan axe 'QUAF' ;
  268. elim (axe et mt) epsi ;
  269.  
  270. evr= evol 'CHPO' rho axe ;
  271. dess evr 'TITRE' ' Rho axe ';
  272.  
  273. evt = evol 'CHPO' Tf axe ;
  274. dess evt 'TITRE' ' Température axe ';
  275.  
  276. evvp= evol 'CHPO' rvp axe ;
  277. dess evvp 'TITRE' ' rvp axe ';
  278.  
  279. 'FINSI' ;
  280.  
  281. 'FIN' ;
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  
  294.  
  295.  
  296.  
  297.  
  298.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales