Télécharger pressutq.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressutq.dgibi
  2. *---------------------------------------------------------
  3. * Pressurisation d'une enceinte type Phébus
  4. *
  5. * Le maillage correspond à une enceinte cylindrique
  6. * d'environ 10 m3 avec un mur en contact avec la
  7. * paroi verticale (10 cm d'acier)
  8. * Tout le volume est initialement a 1.3bar et 123oC
  9. * et la température du mur est mise à 100oC
  10. * au début du calcul. On calcule la pressurisation
  11. * de cette enceinte sur 50 secondes en injectant un débit
  12. * de 10g/s de vapeur à 130oC. Ce test (un peu long)
  13. * verifie le demarrage de la condensation a 20"
  14. * verifie l'evolution moyenne de la temprature gaz
  15. * verifie la pression max a 50"
  16. * verifie la vitesse max a 50" (Convection naturelle)
  17. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  18. * revisite Avril 2002
  19. *--------------------------------------------------------
  20. COMPLET = FAUX ;
  21. *COMPLET = VRAI ;
  22. GRAPH = VRAI ;
  23. GRAPH = FAUX ;
  24.  
  25. 'SI' COMPLET ;
  26.  
  27. nbit=100;
  28. DT0 = 1. ;
  29. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  30. n4 = 8 ; nn = 2 ;
  31.  
  32. 'SINON' ;
  33.  
  34. nbit= 5 ;
  35. DT0 = 10. ;
  36. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  37. n4 = 4 ; nn = 1 ;
  38.  
  39. 'FINSI' ;
  40.  
  41. *--------------------------------------------------------
  42. * Definition du maillage de l'enceinte cylindrique
  43. *
  44. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  45.  
  46. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  47.  
  48.  
  49.  
  50. epsi = 1.000e-2 ; ;
  51.  
  52. p0 = 0.000 0.000 0.000 ;
  53. px = -1000.000 0.000 0.000 ;
  54. py = 0.000 -1000.000 0.000 ;
  55. pz = 0.000 0.000 1000.000 ;
  56. cd = 0.000 0.000 -20.000 ;
  57. ph0 = 0.000 0.000 hc ;
  58. phx = ri 0.000 hc ;
  59. phy = 0.000 ri hc ;
  60.  
  61. fg1 = 0.25 ;
  62. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  63.  
  64. p1 = (ri*fg1) 0.000 0.000 ;
  65. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  66. p3 = 0.000 (ri*fg1) 0.000 ;
  67. p4 = ri 0.000 0.000 ;
  68. p5 = 0.000 ri 0.000 ;
  69. p6 = (ri+sp) 0.000 0.000 ;
  70. p7 = 0.000 (ri+sp) 0.000 ;
  71.  
  72. * Hauteur de l'enceinte
  73. h1 = 4.163 ;
  74. * Vecteur de translation
  75. v1 = 0. 0. h1 ;
  76.  
  77. l1 = 'DROI' p0 p1 n1 ;
  78. l2 = 'DROI' p1 p2 n1 ;
  79. l3 = 'DROI' p2 p3 n1 ;
  80. l4 = 'DROI' p3 p0 n1 ;
  81. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  82. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  83.  
  84. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  85. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  86. l44= cote 2 basf1;
  87. ax4= (inve l4) et l44 ;
  88. l11= cote 4 basf1;
  89. ax1= l11 et (inve l1) ;
  90.  
  91. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  92. 'ELIM' basf epsi ;
  93. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  94. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  95. 'ELIM' basf epsi ;
  96. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  97. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  98. 'ELIM' basf epsi ;
  99.  
  100. basm = 'REGL' l5 l6 n3 ;
  101. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  102. 'ELIM' basm epsi ;
  103. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  104. 'ELIM' basm epsi ;
  105.  
  106. * Creation du volume
  107.  
  108. dx = ri / 2. ;
  109. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  110.  
  111. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  112. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  113. mbas = mbas 'COUL' 'ROUG' ;
  114. plan1 = ax11 'TRAN' nz1 v1 ;
  115. plan4 = ax44 'TRAN' nz1 v1 ;
  116. 'ELIM' (bas et plan1 et plan4) epsi ;
  117.  
  118. mt = bas ;
  119. wall = enve bas ;
  120. mur = DIFF wall basf;
  121. mur =mur 'COUL' 'ROUG' ;
  122.  
  123. elim (mt et mur) epsi ;
  124.  
  125.  
  126. * Localisation d'une brèche éventuelle au bas de l'enceinte
  127.  
  128. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  129. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  130.  
  131. *--------------------------------------------------------------------
  132. * Fin de la définition du maillage
  133. *--------------------------------------------------------------------
  134.  
  135. *--------------------------------------------------------------------
  136. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  137. *--------------------------------------------------------------------
  138.  
  139. rxt = 'TABLE' ;
  140.  
  141. *-- Nom du volume fluide
  142. rxt.'vtf' = mt ;
  143. rxt.'epsi' = epsi ;
  144.  
  145. * Definition du bidon :
  146. rxt.'TIMP1' = table ;
  147. rxt.'TIMP1'.'MAILLAGE' = mur ;
  148. rxt.'TIMP1'.'t' = prog 0.0 3000. ;
  149. rxt.'TIMP1'.'TIMP' = prog 100.0 100.0 ;
  150. rxt.'TIMP1'.'ECHAN' = 10. ;
  151.  
  152. *-- Conditions initiales dans l'enceinte de test
  153. rxt.'TF0' = 123.0 ;
  154. rxt.'PT0' = 1.30000e5 ;
  155. rxt.'Yvap0' = 1.0E-8 ;
  156.  
  157. *-- On positionne une brèche
  158. rxt.'breche' = jg ;
  159. rxt.'diru1' = 0. 0. 1. ;
  160.  
  161. *-- On definit un point interne au maillage pour imposer la valeur de
  162. *-- la pression
  163. rxt.'pi' = (0.0 0.0 0.5) ;
  164.  
  165. *-- On indique que le calcul comporte de la vapeur d'eau
  166. rxt.'VAPEUR' = VRAI ;
  167.  
  168. *-- On active le recalcul automatique du préconditionnement
  169. *-- toutes les 5 itérations
  170. rxt.'FRPREC' = 5 ;
  171. rxt.'DETMAT' = VRAI ;
  172.  
  173. *-- Definition du scenario thermohydraulique
  174. rxt.'scenario' = table ;
  175.  
  176. *-- Conditions a la breche (Obligatoire pour l'instant)
  177. rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  178. rxt.'scenario'.'qeau' = prog 0.010 0.010 ;
  179. rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  180. rxt.'scenario'.'tinj' = prog 130.0 130.0 ;
  181.  
  182. *-- On impose le pas de temps (s)
  183. rxt.'DT0' = DT0 ;
  184.  
  185. *-- On impose la viscosite turbulente (m2/s)
  186. rxt.'MODTURB'='NUTURB' ;
  187. rxt.'NUT' = 1.e-2 ;
  188.  
  189. *-- On lance le calcul sur 20 itérations d'une seconde
  190. rxt.'GRAPH'=GRAPH ;
  191.  
  192. execrxt 2 rxt ;
  193. execrxt (nbit - 2) rxt ;
  194.  
  195.  
  196. list rxt.TIC.'Tfm' ;
  197. list rxt.TIC.'PT' ;
  198. list rxt.TIC.'Qc' ;
  199. list rxt.TIC.'LMAXU';
  200.  
  201. 'SI' (NON COMPLET) ;
  202.  
  203. ltfm=Prog 123.00 120.38 122.24 118.51
  204. 116.67 115.06;
  205. lPT =Prog 1.30000E+05 1.30840E+05 1.30301E+05 1.32429E+05
  206. 1.32769E+05 1.33224E+05;
  207. Lqc =Prog 0.0000 0.0000 0.0000 0.0000
  208. 0.0000 0.0000;
  209. Lmaxu=Prog 0.0000 0.11919 0.12541 1.5872
  210. 1.0398 1.9797;
  211.  
  212. tic=rxt.'TIC' ;
  213. ERtf=somm( abs (ltfm - tic.'Tfm') )/ 110. ;
  214. ERPT=somm( abs (lPT - tic.'PT' ) ) /1.e5 ;
  215. ERQc=somm( abs (lqc - tic.'Qc' ) ) ;
  216. ERum=somm( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  217.  
  218. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  219.  
  220. Si (ERtf '>' 1.e-3) ; erreur 5 ; Finsi ;
  221. Si (ERPT '>' 1.e-4) ; erreur 5 ; Finsi ;
  222. Si (ERQc '>' 1.e-4) ; erreur 5 ; Finsi ;
  223. Si (ERum '>' 1.e-2) ; erreur 5 ; Finsi ;
  224.  
  225. 'FINSI' ;
  226.  
  227. Si GRAPH ;
  228.  
  229. $vtf=rxt.'GEO'.'$vtf' ;
  230. mt =doma $vtf maillage ;
  231. Mpl1=chan 'QUAF' plan1 ;
  232. Mpl4=chan 'QUAF' plan4 ;
  233. ELIM (mt et Mpl1 et Mpl4) epsi ;
  234. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  235. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  236. plan1= doma $mpl1 maillage ;
  237. plan4= doma $mpl4 maillage ;
  238. plan=plan1 et plan4 ;
  239.  
  240. paroif = rxt.'GEO'.'mtp1';
  241. rho=rxt.'TIC'.'RHO';
  242. rvp=rxt.'TIC'.'RVP';
  243. tf=rxt.'TIC'.'TF';
  244. un=rxt.'TIC'.'UN' ;
  245. un1=redu un plan ;
  246. ung= vect un1 1. ux uy uz jaune ;
  247. trace ung plan ;
  248. opti isov suli ;
  249. trace rho plan 'TITRE'' Rho' ;
  250. trace rvp plan 'TITRE'' Rvp' ;
  251. trace tf plan 'TITRE'' Tf ' ;
  252.  
  253. trace rho paroif 'TITRE'' Rho' ;
  254. trace rvp paroif 'TITRE'' Rvp' ;
  255. trace Tf paroif 'TITRE'' Tf ' ;
  256. Fcond = rxt.'TIC'.'Fcond1';
  257. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  258.  
  259. axe = p0 d nz1 (p0 plus v1) ;
  260. axe = chan axe 'QUAF' ;
  261. elim (axe et mt) epsi ;
  262.  
  263. evr= evol 'CHPO' rho axe ;
  264. dess evr 'TITRE' ' Rho axe ';
  265.  
  266. evt = evol 'CHPO' Tf axe ;
  267. dess evt 'TITRE' ' Température axe ';
  268.  
  269. evvp= evol 'CHPO' rvp axe ;
  270. dess evvp 'TITRE' ' rvp axe ';
  271.  
  272. 'FINSI' ;
  273.  
  274. 'FIN' ;
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales