Télécharger pressupp.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressupp.dgibi
  2. *---------------------------------------------------------
  3. * Pressurisation d'une enceinte type Phébus
  4. *
  5. * Le maillage correspond à une enceinte cylindrique
  6. * d'environ 10 m3 avec un mur en contact avec la
  7. * paroi verticale (10 cm d'acier)
  8. * Tout le volume est initialement a 1bar et 40oC
  9. * et la température du mur est mise à 60oC
  10. * au début du calcul. On calcule la pressurisation
  11. * de cette enceinte sur 50 secondes en injectant un débit
  12. * de 50g/s de vapeur à 150oC. Ce test (un peu long)
  13. * verifie le demarrage de la condensation a 20"
  14. * verifie l'evolution moyenne de la temprature gaz
  15. * verifie la pression max a 50"
  16. * verifie la vitesse max a 50" (Convection naturelle)
  17. * verifie la masse d'eau a 50"
  18. * Auteurs : E. Studer Novembre 1999
  19. * revisite Mars 2001
  20. *--------------------------------------------------------
  21. COMPLET = FAUX ;
  22. *COMPLET = VRAI ;
  23. GRAPH = VRAI ;
  24. GRAPH = FAUX ;
  25. 'OPTI' 'TRAC' 'X' ;
  26. *'OPTI' 'TRAC' 'PSC' ;
  27.  
  28. 'SI' COMPLET ;
  29.  
  30. nbit=100;
  31. DT0 = 1. ;
  32. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  33. n4 = 8 ; nn = 2 ;
  34.  
  35. 'SINON' ;
  36.  
  37. nbit= 5 ;
  38. DT0 = 10. ;
  39. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  40. n4 = 4 ; nn = 1 ;
  41.  
  42. 'FINSI' ;
  43.  
  44. *--------------------------------------------------------
  45. * Definition du maillage de l'enceinte cylindrique
  46. *
  47. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  48.  
  49. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  50.  
  51.  
  52.  
  53. epsi = 1.000e-2 ; ;
  54.  
  55. p0 = 0.000 0.000 0.000 ;
  56. px = -1000.000 0.000 0.000 ;
  57. py = 0.000 -1000.000 0.000 ;
  58. pz = 0.000 0.000 1000.000 ;
  59. cd = 0.000 0.000 -20.000 ;
  60. ph0 = 0.000 0.000 hc ;
  61. phx = ri 0.000 hc ;
  62. phy = 0.000 ri hc ;
  63.  
  64. fg1 = 0.25 ;
  65. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  66.  
  67. p1 = (ri*fg1) 0.000 0.000 ;
  68. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  69. p3 = 0.000 (ri*fg1) 0.000 ;
  70. p4 = ri 0.000 0.000 ;
  71. p5 = 0.000 ri 0.000 ;
  72. p6 = (ri+sp) 0.000 0.000 ;
  73. p7 = 0.000 (ri+sp) 0.000 ;
  74.  
  75. * Hauteur de l'enceinte
  76. h1 = 4.163 ;
  77. * Vecteur de translation
  78. v1 = 0. 0. h1 ;
  79.  
  80. l1 = 'DROI' p0 p1 n1 ;
  81. l2 = 'DROI' p1 p2 n1 ;
  82. l3 = 'DROI' p2 p3 n1 ;
  83. l4 = 'DROI' p3 p0 n1 ;
  84. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  85. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  86.  
  87. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  88. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  89. l44= cote 2 basf1;
  90. ax4= (inve l4) et l44 ;
  91. l11= cote 4 basf1;
  92. ax1= l11 et (inve l1) ;
  93.  
  94. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  95. 'ELIM' basf epsi ;
  96. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  97. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  98. 'ELIM' basf epsi ;
  99. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  100. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  101. 'ELIM' basf epsi ;
  102.  
  103. basm = 'REGL' l5 l6 n3 ;
  104. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  105. 'ELIM' basm epsi ;
  106. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  107. 'ELIM' basm epsi ;
  108.  
  109. * Creation du volume
  110.  
  111. dx = ri / 2. ;
  112. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  113.  
  114. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  115. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  116. mbas = mbas 'COUL' 'ROUG' ;
  117. plan1 = ax11 'TRAN' nz1 v1 ;
  118. plan4 = ax44 'TRAN' nz1 v1 ;
  119. 'ELIM' (bas et plan1 et plan4) epsi ;
  120.  
  121. mt = bas ;
  122. wall = mbas ;
  123. elim (mt et wall) epsi ;
  124.  
  125. * Localisation d'une brèche éventuelle au bas de l'enceinte
  126.  
  127. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  128. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  129.  
  130. *--------------------------------------------------------------------
  131. * Fin de la définition du maillage
  132. *--------------------------------------------------------------------
  133.  
  134. *--------------------------------------------------------------------
  135. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  136. *--------------------------------------------------------------------
  137.  
  138. rxt = 'TABLE' ;
  139.  
  140. *-- Nom du volume fluide
  141. rxt.'vtf' = mt ;
  142. rxt.'epsi' = epsi ;
  143.  
  144. rxt.'TCPT' = FAUX ;
  145. rxt.'TKPR' = VRAI ;
  146. rxt.'TRESOU' = FAUX ;
  147. rxt.'IMPARA' = FAUX ;
  148. * rxt.'TRrvap' = FAUX ;
  149.  
  150. *-- Definition des murs de l'enceinte : ici un seul mur
  151. *-- en ACIER dont on traitera la thermique dans l'épaisseur
  152. *-- et que l'on initialise a 40oC
  153.  
  154. *-- On definit d'abort la matériau ACIER avec sa conductivite
  155. *-- thermique LAMBDA (W/m/K) et le produit ro*Cp (J/m3/K)
  156. rxt.'THERMP' = VRAI ;
  157. rxt.'vtp' = wall ;
  158. rxt.'LAMBDA' = 15. ;
  159. rxt.'ROCP' = 3.9E6 ;
  160. rxt.'Tp0' = 60. ;
  161. rxt.'ECHAN' = 10. ;
  162.  
  163. *-- Conditions initiales dans l'enceinte de test
  164. rxt.'TF0' = 40.0 ;
  165. rxt.'PT0' = 1.00000e5 ;
  166. rxt.'Yvap0' = 0.0023 ;
  167.  
  168. *-- On positionne une brèche
  169. rxt.'breche' = jg ;
  170. rxt.'diru1' = 0 0 1 ;
  171.  
  172. *-- On definit un point interne au maillage pour imposer la valeur de
  173. *-- la pression
  174. rxt.'pi' = (0.0 0.0 0.5) ;
  175.  
  176. *-- On indique que le calcul comporte de la vapeur d'eau
  177. rxt.'VAPEUR' = VRAI ;
  178.  
  179. *-- On active le recalcul automatique du préconditionnement
  180. *-- toutes les 5 itérations
  181. rxt.'FRPREC' = 5 ;
  182. rxt.'DETMAT' = VRAI ;
  183. *rxt.'TRTF' = FAUX ;
  184.  
  185. *-- Definition du scenario thermohydraulique
  186. rxt.'scenario' = table ;
  187.  
  188. *-- Conditions a la breche (Obligatoire pour l'instant)
  189. rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  190. rxt.'scenario'.'qeau' = prog 0.050 0.050 ;
  191. rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  192. rxt.'scenario'.'tinj' = prog 150.0 150.0 ;
  193.  
  194. *-- On impose le pas de temps (s)
  195. rxt.'DT0' = DT0 ;
  196.  
  197. *-- On impose la viscosite turbulente (m2/s)
  198. rxt.'MODTURB'='NUTURB' ;
  199. rxt.'NUT' = 1.e-2 ;
  200.  
  201. *-- On lance le calcul sur 20 itérations d'une seconde
  202. rxt.'GRAPH'=GRAPH ;
  203.  
  204. EXECRXT 2 rxt ;
  205. EXECRXT (nbit - 2) rxt ;
  206. *EXECRXT nbit rxt ;
  207.  
  208.  
  209. list rxt.TIC.'Tfm' ;
  210. list rxt.TIC.'PT' ;
  211. list rxt.TIC.'Qc' ;
  212. list rxt.TIC.'LMAXU';
  213.  
  214.  
  215. Ltfm=Prog
  216. 40.000 65.434 73.516 81.090 86.291
  217. 89.532 ;
  218. LPT=Prog
  219. 1.00000E+05 1.04578E+05 1.21342E+05 1.30318E+05 1.36229E+05
  220. 1.42995E+05;
  221. Lqc= Prog
  222. 0.0000 0.0000 0.0000 1.46999E-03 5.27545E-03
  223. 8.56995E-03 ;
  224. Lmaxu=Prog
  225. 0.0000 0.81320 0.85322 1.5357 1.8768
  226. 1.9459;
  227.  
  228.  
  229. tic=rxt.'TIC' ;
  230. ERtf=somm( abs (ltfm - tic.'Tfm') )/ 80. ;
  231. ERPT=somm( abs (lPT - tic.'PT' ) ) /1.e5 ;
  232. ERQc=somm( abs (lqc - tic.'Qc' ) ) ;
  233. ERum=somm( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  234.  
  235. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  236.  
  237. Si (ERtf '>' 1.e-4) ; erreur 5 ; Finsi ;
  238. Si (ERPT '>' 1.e-3) ; erreur 5 ; Finsi ;
  239. Si (ERQc '>' 1.e-4) ; erreur 5 ; Finsi ;
  240. Si (ERum '>' 1.e-2) ; erreur 5 ; Finsi ;
  241.  
  242. Si GRAPH ;
  243.  
  244. $vtf=rxt.'GEO'.'$vtf' ;
  245. mt =doma $vtf maillage ;
  246. Mpl1=chan 'QUAF' plan1 ;
  247. Mpl4=chan 'QUAF' plan4 ;
  248. ELIM (mt et Mpl1 et Mpl4) epsi ;
  249. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  250. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  251. plan1= doma $mpl1 maillage ;
  252. plan4= doma $mpl4 maillage ;
  253. plan=plan1 et plan4 ;
  254.  
  255. paroif = rxt.'GEO'.'paroif';
  256. rho=rxt.'TIC'.'RHO';
  257. rvp=rxt.'TIC'.'RVP';
  258. tf=rxt.'TIC'.'TF';
  259. un=rxt.'TIC'.'UN' ;
  260. un1=redu un plan ;
  261. ung= vect un1 1. ux uy uz jaune ;
  262. trace ung plan ;
  263. opti isov suli ;
  264. trace rho plan 'TITRE'' Rho' ;
  265. trace rvp plan 'TITRE'' Rvp' ;
  266. trace tf plan 'TITRE'' Tf ' ;
  267.  
  268. trace rho paroif 'TITRE'' Rho' ;
  269. trace rvp paroif 'TITRE'' Rvp' ;
  270. trace Tf paroif 'TITRE'' Tf ' ;
  271. Fcond = tic.'Fcondw';
  272. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  273.  
  274. axe = p0 d nz1 (p0 plus v1) ;
  275. axe = chan axe 'QUAF' ;
  276. elim (axe et mt) epsi ;
  277.  
  278. evr= evol 'CHPO' rho axe ;
  279. dess evr 'TITRE' ' Rho axe ';
  280.  
  281. evt = evol 'CHPO' Tf axe ;
  282. dess evt 'TITRE' ' Température axe ';
  283.  
  284. evvp= evol 'CHPO' rvp axe ;
  285. dess evvp 'TITRE' ' rvp axe ';
  286.  
  287.  
  288.  
  289. 'FINSI' ;
  290.  
  291.  
  292.  
  293.  
  294.  
  295. 'FIN' ;
  296.  
  297.  
  298.  
  299.  
  300.  
  301.  
  302.  
  303.  
  304.  
  305.  
  306.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales