Télécharger pressugQ.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressugQ.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *---------------------------------------------------------
  5. * Cas test analogue a pressu.dgibi testant QUAF MSOMMET
  6. *
  7. *
  8. * Le maillage correspond à une enceinte cylindrique
  9. * d'environ 10 m3 avec un mur en contact avec la
  10. * paroi verticale (10 cm d'acier)
  11. * Tout le volume est initialement a 1bar et 40oC
  12. * et la température du mur est mise à 60oC
  13. * au début du calcul. On calcule la pressurisation
  14. * de cette enceinte sur 50 secondes en injectant un débit
  15. * de 50g/s de vapeur à 150oC. Ce test (un peu long)
  16. * verifie le demarrage de la condensation a 20"
  17. * verifie l'evolution moyenne de la temprature gaz
  18. * verifie la pression max a 50"
  19. * verifie la vitesse max a 50" (Convection naturelle)
  20. * verifie la masse d'eau a 50"
  21. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  22. * revisite Mars 2001
  23. *--------------------------------------------------------
  24. COMPLET = FAUX ;
  25. *COMPLET = VRAI ;
  26. GRAPH = VRAI ;
  27. GRAPH = FAUX ;
  28.  
  29. 'SI' COMPLET ;
  30.  
  31. nbit=100;
  32. DT0 = 1. ;
  33. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  34. n4 = 8 ; nn = 2 ;
  35.  
  36. 'SINON' ;
  37.  
  38. nbit= 5 ;
  39. DT0 = 5. ;
  40. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  41. n4 = 4 ; nn = 1 ;
  42.  
  43. 'FINSI' ;
  44.  
  45. *--------------------------------------------------------
  46. * Definition du maillage de l'enceinte cylindrique
  47. *
  48. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  49. 'OPTI' 'TRAC' 'X' ;
  50.  
  51. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  52.  
  53.  
  54.  
  55. epsi = 1.000e-2 ; ;
  56.  
  57. p0 = 0.000 0.000 0.000 ;
  58. px = -1000.000 0.000 0.000 ;
  59. py = 0.000 -1000.000 0.000 ;
  60. pz = 0.000 0.000 1000.000 ;
  61. cd = 0.000 0.000 -20.000 ;
  62. ph0 = 0.000 0.000 hc ;
  63. phx = ri 0.000 hc ;
  64. phy = 0.000 ri hc ;
  65.  
  66. fg1 = 0.25 ;
  67. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  68.  
  69. p1 = (ri*fg1) 0.000 0.000 ;
  70. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  71. p3 = 0.000 (ri*fg1) 0.000 ;
  72. p4 = ri 0.000 0.000 ;
  73. p5 = 0.000 ri 0.000 ;
  74. p6 = (ri+sp) 0.000 0.000 ;
  75. p7 = 0.000 (ri+sp) 0.000 ;
  76.  
  77. * Hauteur de l'enceinte
  78. h1 = 4.163 ;
  79. * Vecteur de translation
  80. v1 = 0. 0. h1 ;
  81.  
  82. l1 = 'DROI' p0 p1 n1 ;
  83. l2 = 'DROI' p1 p2 n1 ;
  84. l3 = 'DROI' p2 p3 n1 ;
  85. l4 = 'DROI' p3 p0 n1 ;
  86. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  87. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  88.  
  89. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  90. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  91. l44= cote 2 basf1;
  92. ax4= (inve l4) et l44 ;
  93. l11= cote 4 basf1;
  94. ax1= l11 et (inve l1) ;
  95.  
  96. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  97. 'ELIM' basf epsi ;
  98. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  99. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  100. 'ELIM' basf epsi ;
  101. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  102. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  103. 'ELIM' basf epsi ;
  104.  
  105. basm = 'REGL' l5 l6 n3 ;
  106. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  107. 'ELIM' basm epsi ;
  108. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  109. 'ELIM' basm epsi ;
  110.  
  111. * Creation du volume
  112.  
  113. dx = ri / 2. ;
  114. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  115.  
  116. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  117. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  118. mbas = mbas 'COUL' 'ROUG' ;
  119. plan1 = ax11 'TRAN' nz1 v1 ;
  120. plan4 = ax44 'TRAN' nz1 v1 ;
  121. 'ELIM' (bas et plan1 et plan4) epsi ;
  122.  
  123. mt = bas ;
  124. wall = mbas ;
  125. elim (mt et wall) epsi ;
  126.  
  127. * Localisation d'une brèche éventuelle au bas de l'enceinte
  128.  
  129. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  130. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  131.  
  132. *--------------------------------------------------------------------
  133. * Fin de la définition du maillage
  134. *--------------------------------------------------------------------
  135.  
  136. *--------------------------------------------------------------------
  137. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  138. *--------------------------------------------------------------------
  139.  
  140. rxt = 'TABLE' ;
  141.  
  142. *-- Nom du volume fluide
  143. rxt.'vtf' = mt ;
  144. rxt.'epsi' = epsi ;
  145.  
  146. rxt.'DISCR' = 'QUAF' ;
  147. rxt.'KPRE' = 'MSOMMET';
  148. *-- Definition des murs de l'enceinte : ici un seul mur
  149. *-- en ACIER dont on traitera la thermique dans l'épaisseur
  150. *-- et que l'on initialise a 40oC
  151.  
  152. *-- On definit d'abort la matériau ACIER avec sa conductivite
  153. *-- thermique LAMBDA (W/m/K) et le produit ro*Cp (J/m3/K)
  154. rxt.'THERMP' = VRAI ;
  155. rxt.'vtp' = wall ;
  156. rxt.'LAMBDA' = 15. ;
  157. rxt.'ROCP' = 3.9E6 ;
  158. rxt.'Tp0' = 60. ;
  159. rxt.'ECHAN' = 10. ;
  160.  
  161. *-- Conditions initiales dans l'enceinte de test
  162. rxt.'TF0' = 40.0 ;
  163. rxt.'PT0' = 1.00000e5 ;
  164. rxt.'Yvap0' = 0.0023 ;
  165.  
  166. *-- On positionne une brèche
  167. rxt.'breche' = jg ;
  168. rxt.'diru1' = 0 0 1 ;
  169.  
  170. *-- On definit un point interne au maillage pour imposer la valeur de
  171. *-- la pression
  172. rxt.'pi' = (0.0 0.0 0.5) ;
  173.  
  174. *-- On indique que le calcul comporte de la vapeur d'eau
  175. rxt.'VAPEUR' = VRAI ;
  176.  
  177. *-- On active le recalcul automatique du préconditionnement
  178. *-- toutes les 5 itérations
  179. rxt.'FRPREC' = 5 ;
  180. rxt.'DETMAT' = VRAI ;
  181.  
  182. *-- Definition du scenario thermohydraulique
  183. rxt.'scenario' = table ;
  184.  
  185. *-- Conditions a la breche (Obligatoire pour l'instant)
  186. rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  187. rxt.'scenario'.'qeau' = prog 0.050 0.050 ;
  188. rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  189. rxt.'scenario'.'tinj' = prog 150.0 150.0 ;
  190.  
  191. *-- On impose le pas de temps (s)
  192. rxt.'DT0' = DT0 ;
  193.  
  194. *-- On impose la viscosite turbulente (m2/s)
  195. rxt.'MODTURB'='NUTURB' ;
  196. rxt.'NUT' = 1.e-2 ;
  197.  
  198. *-- On lance le calcul sur 20 itérations d'une seconde
  199. rxt.'GRAPH'=GRAPH ;
  200.  
  201. EXECRXT 2 rxt ;
  202. EXECRXT (nbit - 2) rxt ;
  203.  
  204.  
  205. list rxt.TIC.'Tfm' ;
  206. list rxt.TIC.'PT' ;
  207. list rxt.TIC.'Qc' ;
  208. list rxt.TIC.'LMAXU';
  209.  
  210. ltfm=Prog 40.000 52.602 58.940 65.013
  211. 70.095 74.660 ;
  212. lPT =Prog 1.00000E+05 1.02840E+05 1.11066E+05 1.15670E+05
  213. 1.19173E+05 1.24263E+05;
  214. Lqc =Prog 0.0000 0.0000 0.0000 0.0000
  215. 0.0000 0.0000;
  216. Lmaxu=Prog 0.0000 0.66429 1.8602 2.3919
  217. 2.3832 2.2730;
  218.  
  219. tic=rxt.'TIC' ;
  220. ERtf=SOMM( abs (ltfm - tic.'Tfm') )/ 80. ;
  221. ERPT=SOMM( abs (lPT - tic.'PT' ) ) /1.e5 ;
  222. ERQc=SOMM( abs (lqc - tic.'Qc' ) ) ;
  223. ERum=SOMM( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  224.  
  225. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  226.  
  227. Si (ERtf '>' 2.e-2) ; erreur 5 ; Finsi ;
  228. Si (ERPT '>' 1.e-2) ; erreur 5 ; Finsi ;
  229. Si (ERQc '>' 1.e-2) ; erreur 5 ; Finsi ;
  230. Si (ERum '>' 5.e-2) ; erreur 5 ; Finsi ;
  231.  
  232. Si GRAPH ;
  233.  
  234. $vtf=rxt.'GEO'.'$vtf' ;
  235. mt =doma $vtf maillage ;
  236. Mpl1=chan 'QUAF' plan1 ;
  237. Mpl4=chan 'QUAF' plan4 ;
  238. ELIM (mt et Mpl1 et Mpl4) epsi ;
  239. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  240. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  241. plan1= doma $mpl1 maillage ;
  242. plan4= doma $mpl4 maillage ;
  243. plan=plan1 et plan4 ;
  244.  
  245. paroif = rxt.'GEO'.'paroif';
  246. rho=rxt.'TIC'.'RHO';
  247. rvp=rxt.'TIC'.'RVP';
  248. tf=rxt.'TIC'.'TF';
  249. un=rxt.'TIC'.'UN' ;
  250. un1=redu un plan ;
  251. ung= vect un1 1. ux uy uz jaune ;
  252. trace ung plan ;
  253. opti isov suli ;
  254. trace rho plan 'TITRE'' Rho' ;
  255. trace rvp plan 'TITRE'' Rvp' ;
  256. trace tf plan 'TITRE'' Tf ' ;
  257.  
  258. trace rho paroif 'TITRE'' Rho' ;
  259. trace rvp paroif 'TITRE'' Rvp' ;
  260. trace Tf paroif 'TITRE'' Tf ' ;
  261. Fcond = tic.'Fcondw';
  262. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  263.  
  264. axe = p0 d nz1 (p0 plus v1) ;
  265. axe = chan axe 'QUAF' ;
  266. elim (axe et mt) epsi ;
  267.  
  268. evr= evol 'CHPO' rho axe ;
  269. dess evr 'TITRE' ' Rho axe ';
  270.  
  271. evt = evol 'CHPO' Tf axe ;
  272. dess evt 'TITRE' ' Température axe ';
  273.  
  274. evvp= evol 'CHPO' rvp axe ;
  275. dess evvp 'TITRE' ' rvp axe ';
  276.  
  277.  
  278.  
  279. 'FINSI' ;
  280.  
  281.  
  282.  
  283.  
  284.  
  285. 'FIN' ;
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  
  294.  
  295.  
  296.  
  297.  
  298.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales