Télécharger pressu.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressu.dgibi
  2. *
  3. * Containment pressurization (Phebus size)
  4. *
  5. * 3D mesh of a 14.5 m3 cylindrical containment with a 10cm in depth vertical wall.
  6. * Initial pressure and temperature are 1bar and 40oC with the wall at 60oC.
  7. * Steam is injected at a constant 50g/s mass flow rate and a temperature of 150oC.
  8. *
  9. * Transient is computed for 50s. We check the pressure, the averaged temperature,
  10. * the velocity ans the condensation mass flow rate (that starts at 20s) evolutions.
  11. *
  12. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  13. *
  14. 'OPTI' 'DIME' 3 'ELEM' 'CU20' 'TRAC' 'PSC' ;
  15. 'DENS' 1. ;
  16. *
  17. COMPLET = FAUX ;
  18. GRAPH = FAUX ;
  19. 'SI' COMPLET ;
  20. nbit = 100 ;
  21. DT0 = 1. ;
  22. n1 = 1 ;
  23. n2 = 4 ;
  24. n3 = 4 ;
  25. nn = 2 ;
  26. 'SINO' ;
  27. nbit = 5 ;
  28. DT0 = 10. ;
  29. n1 = 1 ;
  30. n2 = 2 ;
  31. n3 = 4 ;
  32. nn = 1 ;
  33. 'FINS' ;
  34. epsi = 1.D-2 ;
  35. *
  36. *
  37. * Mesh
  38. *
  39. *
  40. * ri=cavity radius, h1=cavity height, sp=wall depth,
  41. * fg1=break to cavity radius ratio
  42. ri = 1.052 ;
  43. h1 = 4.163 ;
  44. sp = 0.10 ;
  45. fg1 = 0.25 ;
  46. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  47. *
  48. p0 = 0.000 0.000 0.000 ;
  49. p1 = (ri*fg1) 0.000 0.000 ;
  50. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  51. p3 = 0.000 (ri*fg1) 0.000 ;
  52. p4 = ri 0.000 0.000 ;
  53. p5 = 0.000 ri 0.000 ;
  54. p6 = (ri+sp) 0.000 0.000 ;
  55. p7 = 0.000 (ri+sp) 0.000 ;
  56. *
  57. * Fluid and structure basement surfaces
  58. * (built by symetry)
  59. l1 = 'DROI' p0 p1 n1 ;
  60. l2 = 'DROI' p1 p2 n1 ;
  61. l3 = 'DROI' p2 p3 n1 ;
  62. l4 = 'DROI' p3 p0 n1 ;
  63. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  64. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  65. basf0 = 'DALL' l1 l2 l3 l4 'PLAN' ;
  66. basf1 = ('REGL' (l2 'ET' l3) l5 n2) ;
  67. *
  68. l44 = 'COTE' 2 basf1;
  69. ax4 = ('INVE' l4) 'ET' l44 ;
  70. l11 = 'COTE' 4 basf1;
  71. ax1 = l11 'ET' ('INVE' l1) ;
  72. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  73. 'ELIM' basf epsi ;
  74. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  75. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' ('INVE' ax1) ;
  76. 'ELIM' basf epsi ;
  77. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  78. ax44 = ('INVE' ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  79. 'ELIM' basf epsi ;
  80. basm = 'REGL' l5 l6 n3 ;
  81. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  82. 'ELIM' basm epsi ;
  83. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  84. 'ELIM' basm epsi ;
  85. *
  86. * Fluid and structure volumes
  87. * (built by translation)
  88. nz1 = ('ENTI' (h1 '/' (ri '/' 2.))) '*' nn ;
  89. v1 = 0. 0. h1 ;
  90. mt = basf 'VOLU' nz1 'TRAN' v1 ;
  91. wall = (basm 'VOLU' nz1 'TRAN' v1) 'COUL' 'ROUG' ;
  92. plan1 = ax11 'TRAN' nz1 v1 ;
  93. plan4 = ax44 'TRAN' nz1 v1 ;
  94. 'ELIM' (mt et wall 'ET' plan1 'ET' plan4) epsi ;
  95. *
  96. * Break at the basement if any
  97. pjg = 'POIN' basf 'PROC' (0. 0. 0.) ;
  98. breche = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  99. *
  100. *
  101. * Data for execrxt.procedur
  102. *
  103. *
  104. rxt = 'TABLE' ;
  105. rxt . 'VERSION' = 'V0' ;
  106. rxt . 'vtf' = mt ;
  107. rxt . 'epsi' = epsi ;
  108. rxt . 'pi' = 0. 0. 0.5 ;
  109. *
  110. rxt . 'DISCR' = 'MACRO';
  111. rxt . 'KPRE' = 'CENTRE';
  112. rxt . 'DT0' = DT0 ;
  113. *
  114. rxt . 'MODTURB' = 'NUTURB' ;
  115. rxt . 'NUT' = 1.D-2 ;
  116. *
  117. rxt . 'THERMP' = VRAI ;
  118. rxt . 'vtp' = wall ;
  119. rxt . 'LAMBDA' = 15. ;
  120. rxt . 'ROCP' = 3.9E6 ;
  121. rxt . 'Tp0' = 60. ;
  122. rxt . 'ECHAN' = 10. ;
  123. *
  124. rxt . 'VAPEUR' = VRAI ;
  125. rxt . 'TF0' = 40.0 ;
  126. rxt . 'PT0' = 1.0e5 ;
  127. rxt . 'Yvap0' = 0.0023 ;
  128. *
  129. rxt . 'breche' = breche ;
  130. rxt . 'diru1' = 0. 0. 1. ;
  131. rxt . 'scenario' = 'TABLE' ;
  132. rxt . 'scenario' . 't' = 'PROG' 0.0 1000.0 ;
  133. rxt . 'scenario' . 'qeau' = 'PROG' 0.050 0.050 ;
  134. rxt . 'scenario' . 'qair' = 'PROG' 0.000 0.000 ;
  135. rxt . 'scenario' . 'tinj' = 'PROG' 150.0 150.0 ;
  136. *
  137. rxt . 'GRAPH' = GRAPH ;
  138. rxt . 'DETMAT' = VRAI ;
  139. rxt . 'FRPREC' = 5 ;
  140. rxt . 'RENU' = 'RIEN' ;
  141. *
  142. *
  143. * Transient (with restart after 2 time steps)
  144. *
  145. *
  146. EXECRXT 2 rxt ;
  147. EXECRXT (nbit - 2) rxt ;
  148. *
  149. *
  150. * Tests
  151. *
  152. *
  153. 'SI' ('NON' COMPLET) ;
  154. ERR1 = 0 ;
  155. 'LIST' rxt.TIC.'Tfm' ;
  156. 'LIST' rxt.TIC.'PT' ;
  157. 'LIST' rxt.TIC.'Qc' ;
  158. 'LIST' rxt.TIC.'LMAXU';
  159.  
  160. ltfm = 'PROG' 40.000 65.434 73.712 81.158 86.814 90.738 ;
  161.  
  162. lPT = 'PROG' 1.00000E+05 1.06009E+05 1.21199E+05 1.29592E+05
  163. 1.36462E+05 1.43998E+05 ;
  164.  
  165. Lqc = 'PROG' 0.0000 0.0000 0.0000 3.81471E-04 2.57962E-03
  166. 4.78997E-03;
  167.  
  168. Lmaxu = 'PROG' 0.0000 0.81320 2.0813 2.6901 2.2350 2.5277 ;
  169.  
  170. tic = rxt . 'TIC' ;
  171. ERtf = 'SOMM' ('ABS'(ltfm - tic . 'Tfm')) '/' 80. ;
  172. ERPT = 'SOMM' ('ABS'(lPT - tic . 'PT' )) '/' 1.e5 ;
  173. ERQc = 'SOMM' ('ABS'(lqc - tic . 'Qc' )) ;
  174. ERum = 'SOMM' ('ABS'(Lmaxu - tic . 'LMAXU')) '/' 2. ;
  175. 'MESS' 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  176. 'SI' (ERtf '>' 1.e-4) ; err1 = err1 '+' 1 ; 'FINS' ;
  177. 'SI' (ERPT '>' 1.e-3) ; err1 = err1 '+' 1 ; 'FINS' ;
  178. 'SI' (ERQc '>' 1.e-4) ; err1 = err1 '+' 1 ; 'FINS' ;
  179. 'SI' (ERum '>' 1.e-2) ; err1 = err1 '+' 1 ; 'FINS' ;
  180. 'SI' ('NEG' ERR1 0) ;
  181. 'ERRE' 5 ;
  182. 'FINS' ;
  183. 'FINS' ;
  184. *
  185. *
  186. * Plots devoted to pressu... cases
  187. *
  188. *
  189. 'SI' GRAPH ;
  190. tbt = rxt . 'TBT' ;
  191. tic = rxt . 'TIC' ;
  192. *
  193. $vtf = rxt . 'GEO' . '$vtf' ;
  194. vtf = 'DOMA' $vtf 'MAILLAGE' ;
  195. *
  196. Mpl1 = 'CHAN' 'QUAF' plan1 ;
  197. Mpl4 = 'CHAN' 'QUAF' plan4 ;
  198. 'ELIM' (vtf 'ET' Mpl1 'ET' Mpl4) epsi ;
  199. $mpl1 = 'MODE' Mpl1 'NAVIER_STOKES' 'MACRO' ;
  200. $mpl4 = 'MODE' Mpl4 'NAVIER_STOKES' 'MACRO' ;
  201. plan1 = 'DOMA' $mpl1 'MAILLAGE' ;
  202. plan4 = 'DOMA' $mpl4 'MAILLAGE' ;
  203. plan = plan1 'ET' plan4 ;
  204. cplan = 'CONT' plan ;
  205. *
  206. 'SI' ('EXIS' tic 'TP') ;
  207. $vtp = rxt . 'GEO' . '$vtp' ;
  208. vtp = 'DOMA' $vtp 'MAILLAGE' ;
  209. 'FINS' ;
  210. paroif = rxt . 'GEO' . 'paroif';
  211. cparoif = 'CONT' paroif ;
  212. *
  213. axe = p0 d nz1 (p0 plus v1) ;
  214. axe = 'CHAN' axe 'QUAF' ;
  215. 'ELIM' (axe 'ET' mt) epsi ;
  216. *
  217. un = tic . 'UN';
  218. unp = 'REDU' un plan ;
  219. ung = 'VECT' un 0.5 'UX' 'UY' 'UZ' 'JAUN' ;
  220. ungp = 'VECT' unp 0.5 'UX' 'UY' 'UZ' 'JAUN' ;
  221. tf = tic . 'TF' ;
  222. rho = tic . 'RHO' ;
  223. rair = tic . 'RAIR' ;
  224. 'SI' tbt . 'THE' ; rhe = tic . 'RHE' ; 'FINS' ;
  225. 'SI' tbt . 'TH2' ; rh2 = tic . 'RH2' ; 'FINS' ;
  226. 'SI' tbt . 'TCO' ; rco = tic . 'RCO' ; 'FINS' ;
  227. 'SI' tbt . 'TCO2' ; rco2 = tic . 'RCO2' ; 'FINS' ;
  228. 'SI' tbt . 'VAPEUR' ; rvp = tic . 'RVP' ; 'FINS' ;
  229. *
  230. evauz = 'EVOL' 'CHPO' ('EXCO' un 'UZ') axe ;
  231. 'DESS' evauz
  232. 'TITR' 'Velocity with the z axis' 'MIMA'
  233. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' m/s' ;
  234. 'TRAC' ung plan ('CONT' plan) 'TITR' ' Velocity' ;
  235. *
  236. evatf = 'EVOL' 'CHPO' tf axe ;
  237. 'DESS' evatf
  238. 'TITR' 'Gas temperature with the z axis' 'MIMA'
  239. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' C' ;
  240. 'TRAC' tf plan cplan 'TITR' ' Temperature' ;
  241. 'TRAC' tf paroif cparoif 'TITR' ' Temperature' ;
  242. *
  243. evarh = 'EVOL' 'CHPO' rho axe ;
  244. 'DESS' evarh
  245. 'TITR' 'Gas density with the z axis' 'MIMA'
  246. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  247. 'TRAC' rho plan ('CONT' plan) ungp 'TITR' ' Density & velocity' ;
  248. 'TRAC' rho paroif cparoif 'TITR' ' Density' ;
  249. *
  250. evavap = 'EVOL' 'CHPO' rvp axe ;
  251. 'DESS' evavap
  252. 'TITR' 'Steam density with the z axis' 'MIMA'
  253. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  254. 'TRAC' rvp plan cplan 'TITR' ' Steam density' ;
  255. *
  256. Fcond = rxt . 'TIC' . 'Fcondw';
  257. 'TRAC' fcond paroif cparoif 'TITR' ' Fcond kg/m**2' ;
  258. *
  259. * Wall temperature
  260. 'SI' ('EXIS' tic 'TP') ;
  261. 'TRAC' tic . 'TP' vtp 'TITR' ' Wall temperature' ;
  262. 'FINS' ;
  263. 'FINSI' ;
  264.  
  265. 'FIN' ;
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales