Télécharger poudre4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : poudre4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. complet = faux ;
  5. *
  6. *************************************************
  7. * pour calcul complet mettre complet à : vrai;
  8. ***************************************************
  9. *
  10. ************************************************************
  11. * *
  12. * Cas test pour la loi poudre_A *
  13. * *
  14. * par Christophe DELLIS (CEREM) *
  15. * *
  16. ************************************************************
  17. * cas isotrope log(A)
  18. * un cylindre est densifié par mise en pression
  19. * la densite initial est uniforme la densite finale
  20. * est connue analytiquement
  21. *
  22. *
  23. opti echo 0;
  24. *
  25. option dime 2 elem qua8 mode axis ;
  26. *
  27. * parametres du maillage
  28. *
  29. rayon_1 = 10.0 ;
  30. *
  31. haute_1 = 15.0 ;
  32. *
  33. * definition des coordonnees des points
  34. *
  35. xa0 = 0.0 ;
  36. ya0 = 0.0 ;
  37. *
  38. xa1 = rayon_1 ;
  39. ya1 = ya0 ;
  40. *
  41. xa2 = xa1 ;
  42. ya2 = ya1 + haute_1 ;
  43. *
  44. xa3 = 0.0 ;
  45. ya3 = ya2 ;
  46. *
  47. * definition des densites
  48. *
  49. dena0 = 10.0 ;
  50. dena1 = 10.0 ;
  51. dena2 = 10.0 ;
  52. dena3 = 10.0 ;
  53. *
  54. * definition des points
  55. *
  56. densite dena0 ;
  57. a0 = xa0 ya0 ;
  58. *
  59. densite dena1 ;
  60. a1 = xa1 ya1 ;
  61. *
  62. densite dena2 ;
  63. a2 = xa2 ya2 ;
  64. *
  65. densite dena3 ;
  66. a3 = xa3 ya3 ;
  67. *
  68. * definition des lignes
  69. *
  70. la0a1 = a0 droi 2 a1 ;
  71. la1a2 = a1 droi 2 a2 ;
  72. la2a3 = a2 droi 2 a3 ;
  73. la3a0 = a3 droi 2 a0 ;
  74. *
  75. la3a2 = inve la2a3 ;
  76. la2a1 = inve la1a2 ;
  77. *
  78. * lignes pour les conditions limites
  79. *
  80. l_symz = la0a1 ;
  81. l_symx = la3a0 ;
  82. l_ext1 = la1a2 ;
  83. l_ext2 = la2a3 ;
  84. *
  85. * definition des surfaces
  86. *
  87. elmat1 = surf ( la0a1 et la1a2 et la2a3 et la3a0 ) plan ;
  88. *
  89. piece_1 = coul elmat1 bleu ;
  90. *
  91. tot = piece_1 ;
  92. elim (tot et a2) 0.001 ;
  93. *
  94. *
  95. ************************************************************
  96. * *
  97. * calcul *
  98. * *
  99. ************************************************************
  100. *
  101. T0TEMPE = 925.0 ;
  102. T1TEMPE = 925.0 ;
  103. T0TEMPS = 0.0 ;
  104. T1TEMPS = 1200.0 ;
  105. T2TEMPS = 2400.0 ;
  106. T3TEMPS = 3600.0 ;
  107. *
  108. *******************************************
  109. * Champ-point de temperature
  110. *******************************************
  111. *
  112. clth0001 = BLOQ 'T' (l_ext1 et l_ext2) ;
  113. p_bloth1 = DEPI clth0001 1. ;
  114. p_temps1 = prog T0TEMPS T1TEMPS T2TEMPS T3TEMPS ;
  115. p_theta1 = prog T0TEMPE T1TEMPE T1TEMPE T0TEMPE ;
  116. ev_ther1 = EVOL MANU TEMPS p_temps1 'T' p_theta1 ;
  117. ch_ther1 = CHAR TIMP p_bloth1 ev_ther1 ;
  118. *
  119. ************************************************************
  120. * *
  121. * materiau *
  122. * *
  123. ************************************************************
  124. P1MODEL = MODE piece_1 MECANIQUE ELASTIQUE
  125. VISCOPLASTIQUE POUDRE_A CONS DEUX;
  126. *
  127. V1YOUNG = 118.0E+03 ;
  128. V1NU = 0.33 ;
  129. V1ALPHA = 10.0E-10 ;
  130. V1A = -14.11 ;
  131. V1N = 4.55 ;
  132. V1QSRT = 0.0 ;
  133. V1RHOR = 0.68 ;
  134. V1F0 = 0.1098 ;
  135. V1F1 = 1.0168 ;
  136. V1F2 = -0.2591 ;
  137. V1F3 = 0.0 ;
  138. V1F4 = 1.0 ;
  139. V1F5 = 0.66 ;
  140. V1C0 = 2.10851 ;
  141. V1C1 = 1.21767 ;
  142. V1C2 = -0.43081 ;
  143. V1C3 = 0.0 ;
  144. V1C4 = 0.0 ;
  145. V1C5 = 50.0 ;
  146. *
  147. P1MATER = MATER P1MODEL YOUNG V1YOUNG NU V1NU ALPH V1ALPHA TALP 20. TREF 0.
  148. A V1A N V1N QSRT V1QSRT F0 V1F0 F1 V1F1 F2 V1F2 F3 V1F3
  149. F4 V1F4 F5 V1F5 C0 V1C0 C1 V1C1 C2 V1C2 C3 V1C3 C4 V1C4
  150. C5 V1C5 RHOR V1RHOR ;
  151. *
  152. P2MODEL = MODE piece_1 THERMIQUE ISOTROPE CONS UN ;
  153. *
  154. P2MATER = MATER P2MODEL 'C' 460 'K' 14.6 'RHO' 4.54 ;
  155. *
  156. ************************************************************
  157. * *
  158. * chargement *
  159. * *
  160. ************************************************************
  161. *
  162. p0bloca = bloque uz l_symz ;
  163. p1bloca = bloque ur l_symx ;
  164. *
  165. p_bloca = p0bloca et p1bloca ;
  166. *
  167. t0pres = 0.0 ;
  168. t1pres = 100.0 ;
  169. *
  170. li_tps = prog t0temps t1temps t2temps t3temps ;
  171. li_pres = prog t0pres t1pres t1pres t0pres ;
  172. ev_pres = evol manu temps li_tps pression li_pres ;
  173. *dess ev_pres titr 'Evolution du chargement en pression' nclk ;
  174. *
  175. p2force = pres mass p1model 1.0 l_ext1 ;
  176. p3force = pres mass p1model 1.0 l_ext2 ;
  177. titr 'Force appliquees' ;
  178. vec1 = vect (p2force et p3force) 'FR' 'FZ' 0.1;
  179. *trac vec1 piece_1 nclk ;
  180. *
  181. p2charg = char p2force ev_pres 'MECA';
  182. p3charg = char p3force ev_pres 'MECA';
  183. *
  184. p_charg = p2charg et p3charg ;
  185. *
  186. ************************************************************
  187. * *
  188. * calcul *
  189. * *
  190. ************************************************************
  191. *
  192. p_model = p1model et p2model ;
  193. p_mater = p1mater et p2mater ;
  194. *
  195. * Initialisation de la table pour la procedure PASAPAS
  196. *
  197. TAB1 = TABLE ;
  198. TAB1 . 'CHARGEMENT' = (p_charg et ch_ther1) ;
  199. TAB1 . 'MODELE' = p_model ;
  200. TAB1 . 'CARACTERISTIQUES' = p_mater ;
  201. TAB1 . 'BLOCAGES_MECANIQUES' = p_bloca ;
  202. TAB1 . 'BLOCAGES_THERMIQUES' = clth0001 ;
  203. si complet ;
  204. tfin = 2400.;
  205. sinon;
  206. tfin = 400.;
  207. finsi;
  208. TAB1 . 'TEMPS_CALCULES' = PROG 0.0
  209. PAS 50.0 tfin ;
  210. TAB1 . 'TEMPS_SAUVES' = PROG tfin;
  211. TAB1 . 'MAXITERATION' = 49 ;
  212. TAB1 . 'MAXISOUSPAS' = 500 ;
  213. TAB1 . 'MOVA' = 'MOT' 'VHOR' ;
  214. TAB1 . 'PRECISION' = 1.0E-4 ;
  215. TAB1 . 'PROCEDURE_THERMIQUE' = 'MOT' 'LINEAIRE' ;
  216. PASAPAS TAB1 ;
  217. *
  218. ************************************************************
  219. * *
  220. * Test de validation *
  221. * *
  222. ************************************************************
  223. *
  224. ind1 = index (TAB1 . 'VARIABLES_INTERNES') ;
  225. nb1 = dime ind1 ;
  226. *
  227. * densite finale
  228. *
  229. vm1 = TAB1 . 'VARIABLES_INTERNES' .(ind1.nb1) ;
  230. vm2 = exco VHOR vm1 ;
  231. vm3 = redu vm2 piece_1 ;
  232. rhof1 = maxi vm3 ;list rhof1;
  233. *
  234. * Calcul theorique analytique de la densite finale :
  235. *
  236. si complet;
  237. rhof2 = 0.7418622 ;
  238. sinon;
  239. rhof2 = 0.68006;
  240. finsi;
  241. *
  242. * Lecture des deplacements du noeud au coin de l'echantillon :
  243. *
  244. ind2 = index (TAB1 . 'DEPLACEMENTS' ) ;
  245. nb2 = dime ind2 ;
  246. ur1 = (extr TAB1 .'DEPLACEMENTS'.(ind2.nb2) ur a2) ;
  247. uz1 = (extr TAB1 .'DEPLACEMENTS'.(ind2.nb2) uz a2) ;
  248. *
  249. * Calcul analytique des deplacements pour une densification isotrope :
  250. *
  251. si complet;
  252. ur2 = rayon_1 * ((v1rhor/rhof1)**(1./3.) - 1.) ;
  253. uz2 = haute_1 * ((v1rhor/rhof1)**(1./3.) - 1.) ;
  254. sinon;
  255. ur2= -1.25306E-03;
  256. uz2 = -1.88243E-03;
  257. finsi;
  258. list ur2 ;list ur1;
  259. list uz2 ;list uz1;
  260. *
  261. * Calcul des erreurs sur les deplacements et la densite :
  262. *
  263. erho1 = abs ((rhof1 - rhof2 )/rhof2);
  264. eur1 = abs ((ur1 - ur2) / ur2) ;
  265. euz1 = abs ((uz1 - uz2) / uz2) ;
  266. *
  267. * Ecriture des erreurs a l'ecran :
  268. *
  269. opti echo 0 ;
  270. sauter 3 lignes ;
  271. mess 'Calcul en isotrope :' ;
  272. mess 'Erreur sur le deplacement radial : ' eur1 ;
  273. mess 'Erreur sur le deplacement vertical : ' euz1 ;
  274. mess 'Erreur sur la densite finale: ' erho1 ;
  275. sauter 3 lignes ;
  276.  
  277. *
  278. si ( (eur1 + euz1 + erho1 ) >eg 0.05 ) ;
  279. mess '---------RESULTATS INCORRECTS-------------' ;
  280. sauter 3 lignes ;
  281. erreur 5;
  282. sinon ;
  283. mess '---------RESULTATS CORRECTS-------------' ;
  284. sauter 3 lignes ;
  285. finsi ;
  286. *
  287. fin ;
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  
  294.  
  295.  
  296.  
  297.  
  298.  
  299.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales