Télécharger pore3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pore3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Pore3.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. complet =faux;
  8. *
  9. *************************************************
  10. * pour calcul complet mettre complet à : vrai;
  11. *************************************************
  12. *******************************************************
  13. * *
  14. * TEST PORE3 *
  15. * *
  16. * CONSOLIDATION UNIDIMENSIONNELLE *
  17. * *
  18. * REFERENCE : Probleme de Terzaghi *
  19. * *
  20. * Le milieu est poroélastique *
  21. * On charge à la surface par une pression *
  22. * On compare avec la solution analytique *
  23. * *
  24. *******************************************************
  25. *
  26. OPTI ECHO 1 ;
  27.  
  28. TITRE ' TEST PORE3 ' ;
  29. GRAPH = 'N';
  30. OPTIO DIME 2 ELEM QUA8 MODE PLAN DEFO ;
  31. MOTP = MOTS 'P' ;
  32. LREP = PROG 1.E6 ;
  33. OPTI NORM MOTP LREP ;
  34. *
  35. *=====================================================*
  36. * geometrie : maillage *
  37. *=====================================================*
  38. *
  39. DENS 1. ;
  40. *
  41. H = 10. ;H2 = H * H ;
  42. P1 = 0. 0. ; P2 = 1. 0. ; P3 = 1. 10. ; P4 = 0. 10. ;
  43. LI1= P1 D 1 P2 ;
  44. LI2= P2 D P3 DINI 1. DFIN 0.1 ;
  45. LI3= P3 D 1 P4 ;
  46. LI4= P4 D P1 DINI 0.1 DFIN 1. ;
  47. LI = LI1 ET LI2 ET LI3 ET LI4 ;
  48. CADRE = DALLER LI1 LI2 LI3 LI4 PLAN ;
  49. SI (NEG GRAPH 'N');
  50. TRAC CADRE ;
  51. FINSI;
  52. *
  53. *=====================================================*
  54. * modele - materiau *
  55. * rigidite - conditions aux limites *
  56. *=====================================================*
  57. *
  58. MO=MODE CADRE POREUX;
  59. *
  60. LAM = 1.D10 ;
  61. MU = 2.5D9 ;
  62. PK = 1.D-9 ;
  63. *
  64. MAT=MATE MO YOUNG 7000D6 NU 0.4 MOB 1.D18
  65. COB 1. PERM PK VISCO 1.
  66. ALPH 0. KF 1. RHOF 0. ALPF 0. ALPM 0. RHO 0. ;
  67. BL1=BLOQ UY LI1 ;
  68. BL2=BLOQ UX (LI2 ET LI4) ;
  69. BLP = BLOQ P LI3 ;
  70. *
  71. * on impose une pression sur le dessus
  72. *
  73. P0 = 4.D3 ;
  74. FPP = PRESSION MASS MO P0 LI3;
  75. *
  76. *=====================================================*
  77. * consolidation *
  78. *=====================================================*
  79. *
  80. PER = PERM MO MAT;
  81. ev = evol manu t ( prog 0 1.D-5 1000) F ( PROG 0 1 1);
  82. CHA = CHAR 'MECA' FPP EV ;
  83. si complet;
  84. LETEMP= PROG 0 PAS 1.D-2 1.D-1 PAS 1.D-1 1.D0
  85. PAS 5.D-1 1.D1;
  86. sinon;
  87. letemp = prog 0 PAS 1.D-2 1.D-1 PAS 1.D-1 5.d-1;
  88. finsi;
  89.  
  90. NBT = DIME LETEMP ;
  91. TFINAL = EXTR LETEMP NBT;
  92.  
  93. *
  94. *======================================================
  95. * remplissage de la table
  96. *======================================================
  97. *
  98. TAB1 = TABLE ;
  99. TAB1.'MODELE' = MO;
  100. TAB1.'CARACTERISTIQUES' = MAT;
  101. TAB1.'BLOCAGES_MECANIQUES' = BL1 ET BL2 ET BLP;
  102. TAB1.'TEMPS_CALCULES' = LETEMP;
  103. TAB1.'CHARGEMENT' = CHA;
  104. TAB1.'CONSOLIDATION' = VRAI;
  105. TAB1.'TETA' = 0.55 ;
  106. TAB1.'PERMEABILITE' = PER ;
  107. TAB1.'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  108. *
  109. * appel a PASAPAS
  110. *
  111. PASAPAS TAB1;
  112. *
  113. *=====================================================*
  114. * affichage des resultats *
  115. *=====================================================*
  116. *
  117. MESS ' RESULTATS TEST PORE3 ';
  118. MESS ' -------------------- ';
  119. ' On cherche le deplacement vertical et la pression ';
  120. ' on compare aux solutions analytiques ';
  121. *
  122. TTA = INDEX ( TAB1.DEPLACEMENTS);
  123. NT = DIME TTA ;
  124. LIST NT;
  125. IT = 0 ;
  126. REPETER BOPI NT;
  127. IT = IT + 1 ;
  128. LET = TTA . IT;
  129. DD= TAB1.DEPLACEMENTS.LET;
  130. SI ( EGA IT 1 ) ;
  131. PRT = PROG LET ;
  132. PRD = PROG ( EXTR DD UY P3);
  133. EV = EVOL CHPO DD P LI2 ;
  134. SINON;
  135. PRT = PRT ET (PROG LET) ;
  136. PRD = PRD ET (PROG ( EXTR DD UY P3)) ;
  137. EV = EV ET (EVOL CHPO DD P LI2) ;
  138. FINSI;
  139. FIN BOPI ;
  140. FV = EVOL ROSE MANU 'T' PRT 'UY' PRD;
  141. *
  142. DD= PECHE TAB1 DEPLACEMENTS ;
  143. EV1= EVOL ROSE CHPO DD P LI2 ;
  144. EVD1= EVOL ROSE CHPO DD UY LI2 ;
  145. *
  146. *=====================================================*
  147. * determination de la solution analytique
  148. *=====================================================*
  149. *
  150. X = COOR 2 LI2;
  151. XX = ( MANU CHPO LI2 1 SCAL 1 ) - (X / H) ;
  152. XX = NOMC XX P ;
  153. FACT = (LAM + ( 2. * MU )) * ( PK / H2 ) ;
  154. FACU = -1. * ( (LAM + ( 2. * MU )) / ( P0 * H ) ) ;
  155. PI = 3.141592654D0;
  156. PI2 = PI / 2.D0 ;
  157. DEGPI = 180. / PI ;
  158. *
  159. ITT = 0 ;
  160. REPE BOUT NBT;
  161. ITT = ITT + 1 ;
  162. T= EXTR LETEMP ITT ;
  163. PP = MANU CHPO LI2 1 P 0. ;
  164. UU = X / H ;
  165. UU = NOMC UU P ;
  166. TT = FACT * T;
  167. N = 0;
  168. si complet ;
  169. nfoi = 50;
  170. sinon;
  171. nfoi = 10;
  172. finsi;
  173. REPE BOU nfoi;
  174. M = PI2 * ( (2. * N ) + 1. ) ;
  175. M2 = M*M ;
  176. EX = EXP ( ( -1. * M2) * TT ) ;
  177. SSI = SIN ( (M * DEGPI) * XX ) ;
  178. CCO = COS ( (M * DEGPI) * XX ) ;
  179. PP = PP + ( ( ( 2. / M ) * EX) * SSI) ;
  180. UU = UU - ( ( ( 2. / M2) * EX) * CCO) ;
  181. N=N + 1 ;
  182. FIN BOU ;
  183. PP = PP * P0 ;
  184. UU = UU / FACU ;
  185. SI ( EGA ITT 1 ) ;
  186. PGT = PROG T ;
  187. PGU = PROG ( EXTR UU 'P' P3) ;
  188. SINON ;
  189. PGT = PGT ET (PROG T) ;
  190. PGU = PGU ET (PROG ( EXTR UU 'P' P3)) ;
  191. FINSI;
  192. *
  193. SI ( EGA ITT NBT ) ;
  194. EV2= EVOL TURQ CHPO PP 'P' LI2;
  195. SI (NEG GRAPH 'N');
  196. TITRE ' COMPARAISON DES PROFILS DE PRESSION ' ;
  197. DESS (EV1 ET EV2 );
  198. FINSI;
  199. EVD2= EVOL TURQ CHPO UU 'P' LI2;
  200. SI (NEG GRAPH 'N');
  201. TITRE
  202. ' COMPARAISON DES PROFILS DE DEPLACEMENT VERTICAL';
  203. DESS (EVD1 ET EVD2 );
  204. FINSI;
  205. FINSI;
  206.  
  207. FIN BOUT;
  208. FVT= EVOL TURQ MANU 'T' PGT 'UY' PGU;
  209. SI (NEG GRAPH 'N');
  210. DESS ( FV ET FVT) ;
  211. FINSI;
  212. *
  213. * ecarts
  214. *
  215. EVY1 = EXTR EV1 ORDO ;
  216. EVY2 = EXTR EV2 ORDO ;
  217. EVDY1 = EXTR EVD1 ORDO ;
  218. EVDY2 = EXTR EVD2 ORDO ;
  219. ERPP =(MAXI ABS ( EVY1 - EVY2 ))/(MAXI ABS EVY2 );
  220. ERDUY =( MAXI ABS (EVDY1 - EVDY2 ))/(MAXI ABS EVDY2);
  221. *
  222. *
  223. 'Ecart relatif en pression :' ERPP ;
  224. 'Ecart relatif en profil de deplacement vertical :' ERDUY ;
  225. *
  226. *
  227. *=====================================================*
  228. * code fonctionnement *
  229. *=====================================================*
  230. *
  231. * L'ecart maximum entre valeurs de reference et
  232. * calculee doit etre inferieur a 6.d-3
  233. *
  234. SAUT 2 LIGNE;
  235. SI (ERDUY <EG 0.1) ;
  236. SI (ERPP <EG 0.1) ;
  237. ERRE 0;
  238. SINON;
  239. ERRE 5;
  240. FINSI;
  241. SINON;
  242. ERRE 5;
  243. FINSI;
  244. *
  245. *
  246. FIN ;
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  
  265.  
  266.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales