Télécharger pore1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pore1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Pore1.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. SAUT PAGE;
  8. *
  9. *******************************************************
  10. * *
  11. * TEST PORE1 *
  12. * *
  13. * CYLINDRE EPAIS EN MILIEU POREUX *
  14. * *
  15. * REFERENCE : Benchmark INTERCLAY 1.1 Variante 2 *
  16. * *
  17. * Le milieu est elastoplastique, modele *
  18. * Drucker-Prager non associe *
  19. * On decharge la contrainte a l'interieur du trou *
  20. * *
  21. * On se propose de caculer la convergence du trou *
  22. * valeur de reference : -0.266 m *
  23. * ainsi que la contrainte circonferentielle au *
  24. * bord du trou *
  25. * valeur de reference : -3.47E6 Pa *
  26. * Il s'agit de valeurs calculees par castem2000 *
  27. * et en accord avec les resultats de INTERCLAY *
  28. * *
  29. *******************************************************
  30. *
  31. OPTI ECHO 0;
  32. * ajout de option epsilon lineaire pour la precision des test!
  33. OPTION epsilon lineaire;
  34. TITRE ' TEST PORE1 ' ;
  35. GRAPH = 'N';
  36. OPTIO DIME 2 MODEL AXIS ELEM QUA8 ;
  37. *
  38. *=====================================================*
  39. * geometrie : maillage *
  40. *=====================================================*
  41. *
  42. * Dimension en metres
  43. *
  44. DENS 0.5;
  45. P1 = 2.5 0. ; P2 = 25. 0. ; Q1 = 2.5 0.5 ;
  46. Q2 = 25. 0.5; PP1 = 5 0. ; QQ1 = 5 0.5 ;
  47. LI1 = P1 D P2 'DINI' 0.25 'DFIN' 2.5 ;
  48. LI2 = P2 D Q2 ;
  49. LI3 = INVE ( Q1 D Q2 'DINI' 0.25 'DFIN' 2.5 );
  50. LI4 = Q1 D P1 ;
  51. LI = LI1 ET LI2 ET LI3 ET LI4 ;
  52. CADRE = DALLER LI1 LI2 LI3 LI4 PLAN ;
  53. SI (NEG GRAPH 'N');
  54. TRAC CADRE ;
  55. FINSI;
  56. *
  57. *=====================================================*
  58. * modele - materiau - caracteristiques en Pa *
  59. * conditions aux limites *
  60. *=====================================================*
  61. *
  62. MO=MODE CADRE POREUX ELASTIQUE PLASTIQUE
  63. DRUCKER_PRAGER ;
  64. *
  65. MAT=MATE MO YOUNG 200.13E6 NU 0.25 MOB 7500E6 COB 1.
  66. PERM 4.E-12 VISCO 4.
  67. ALPH 0. KF 0. RHOF 0. ALPF 0. ALPM 0. RHO 0.
  68. ALFA 0.1270509 BETA 0.57735027 K 0.
  69. GAMM 0. DELT 0.57735027
  70. ETA 0.1270509 MU 0.57735027 KL 0. H 0. ;
  71. *
  72. * on bloque les faces superieure et inferieure
  73. *
  74. BL1=BLOQ UZ LI1 ;
  75. BL2=BLOQ UZ LI3 ;
  76. CL = BL1 ET BL2 ;
  77. *
  78. *=====================================================*
  79. * Chargement *
  80. *=====================================================*
  81. *
  82. * contraintes initiales
  83. *
  84. ZOZO = MANU CHML MO SMRZ 0.
  85. SMRR -5.E6 SMTT -5.E6 SMZZ -5.E6 MSR0 0.
  86. TYPE CONTRAINTES STRESSES ;
  87. ZUZU = MANU CHML MO GARZ 0.
  88. EPRR 0. EPTT 0. EPZZ 0. PRES 2.5E6
  89. TYPE DEFORMATIONS STRESSES ;
  90. FF = BSIGMA MO ZOZO;
  91. EVT1= EVOL MANU 'TEMPS' (PROG 0 14 )
  92. 'CHARGE' (PROG 1 1 );
  93. CHA1 = CHAR MECA FF EVT1 ;
  94. *
  95. * pression
  96. *
  97. FPI2 = PRESS MASS MO -1.E6 LI4 ;
  98. EVT2= EVOL MANU 'TEMPS' (PROG 0 PAS 1 14 )
  99. 'CHARGE' (PROG 0 PAS 0.25 3.5) ;
  100. CHA2 = CHAR MECA FPI2 EVT2 ;
  101. CHATT = CHA1 ET CHA2 ;
  102. *
  103. *=====================================================*
  104. * Initialisation de la table pour appel a PASAPAS *
  105. *=====================================================*
  106. *
  107. TAB1 = TABLE;
  108. TAB1 . 'CONTRAINTES' = TABLE;
  109. TAB1 . 'DEFORMATIONS' = TABLE;
  110. TAB1 . 'DEPLACEMENTS' = TABLE;
  111. TAB1.'CONTRAINTES' . 0 = ZOZO;
  112. TAB1.'DEFORMATIONS' . 0 = ZUZU;
  113. TAB1.'DEPLACEMENTS' . 0 = MANU CHPO CADRE 1 P 2.5E6 ;
  114. LREE = PROG 0 PAS 1 14;
  115. TAB1.'CARACTERISTIQUES' = MAT;
  116. TAB1.'CHARGEMENT' = CHATT;
  117. TAB1.'MODELE' = MO;
  118. TAB1.'TEMPS_CALCULES' = LREE;
  119. TAB1.'BLOCAGES_MECANIQUES' = CL;
  120. *
  121. PASAPAS TAB1;
  122. *=====================================================*
  123. * affichage des resultats *
  124. *=====================================================*
  125. *
  126. MESS ' RESULTATS TEST PORE1 ';
  127. MESS ' -------------------- ';
  128. ' On cherche la convergence du trou et la contrainte';
  129. ' circonferentielle ';
  130. ' Elles sont comparees a des valeurs de reference ';
  131. CONVTH = -0.266 ;
  132. SIGTTH = -3.47E6 ;
  133. LEDEP = PECHE TAB1 DEPLACEMENTS 14 ;
  134. SIGAA = PECHE TAB1 CONTRAINTES 14 ;
  135. SIGAB = CHAN 'CHPO' MO SIGAA ;
  136. CONVXX = EXTR LEDEP UR P1 ;
  137. SIGTXX = EXTR SIGAB SMTT P1 ;
  138. ERGXXA = ( CONVXX - CONVTH ) / CONVTH ;
  139. ERGXXA = ABS ERGXXA ;
  140. ERGXXB = ( SIGTXX - SIGTTH ) / SIGTTH ;
  141. ERGXXB = ABS ERGXXB ;
  142. *
  143. MESS ' Convergence de reference :' CONVTH 'm';
  144. MESS ' Convergence calculee :' CONVXX 'm';
  145. MESS ' Soit un ecart relatif de :' ERGXXA ;
  146. MESS ' Contrainte circonferentielle de reference :'
  147. SIGTTH 'Pa';
  148. MESS ' Contrainte circonferentielle calculee :'
  149. SIGTXX 'Pa';
  150. MESS ' Soit un ecart relatif de :' ERGXXB ;
  151. *
  152. *
  153. *=====================================================*
  154. * code fonctionnement *
  155. *=====================================================*
  156. *
  157. * L'ecart maximum entre valeur theorique et calculee
  158. * doit etre inferieure a 2%.
  159. *
  160. SAUT 2 LIGNE;
  161. SI (ERGXXA <EG 5) ;
  162. SI (ERGXXB <EG 5) ;
  163. ERRE 0;
  164. SINON;
  165. ERRE 5;
  166. FINSI;
  167. SINON;
  168. ERRE 5;
  169. FINSI;
  170. *
  171. *
  172. FIN;
  173.  
  174.  
  175.  
  176.  
  177.  
  178.  
  179.  
  180.  
  181.  
  182.  
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales