Télécharger plas7.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas7.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas7.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  8.  
  9. *******************************************************
  10. * Test plas7.dgibi: Jeux de données *
  11. * --------------------------------- *
  12. *******************************************************
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22. OPTI ECHO 1 ;
  23. OPTI TRAC X ;
  24. SINO ;
  25. OPTI ECHO 0 ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29. *
  30. *******************************************************
  31. * *
  32. * TEST PLAS7 *
  33. * *
  34. * RECTANGLE EN FLEXION PURE (DEFORMATIONS PLANES, *
  35. * PLASTICITE PARFAITE) *
  36. * *
  37. * Test V.P.C.S. numero SSNP11/89 *
  38. * *
  39. * References : R. Hill, Mathematical theory of *
  40. * plasticity, Oxford, Oxford Clavendon Press, 1950. *
  41. * *
  42. * Description : *
  43. * ----------- *
  44. * *
  45. * axe y *
  46. * D | A *
  47. * |----- ---- UA epaisseur a = 12.5 mm *
  48. * | | / hauteur b = 100.0 mm *
  49. * | | / *
  50. * | | / *
  51. * | |/ *
  52. * O |-----/-----> axe x *
  53. * | /| *
  54. * | / | *
  55. * | / | *
  56. * | / | *
  57. * ----- *
  58. * C UB B *
  59. * *
  60. * Chargement : Deplacement impose variant *
  61. * lineairement de UA a -UA entre A et B, *
  62. * UA croissant jusqu'a : UAmax = 0.5 mm . *
  63. * *
  64. * Conditions aux limites : *
  65. * sur CD : u = 0. *
  66. * au point O : v = 0. *
  67. * *
  68. * Proprietes des materiaux : *
  69. * Materiau elastique, parfaitement plastique *
  70. * E = 210 000 MPa , NU = 0.3 , SIGY = 483 MPa *
  71. * *
  72. *******************************************************
  73.  
  74. *
  75. OPTI ECHO 1;
  76. *
  77. OPTI MODE PLAN DEFO;
  78. OPTI ELEM QUA4;
  79. *
  80. TEMPS;
  81. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  82. * geometrie : maillage *
  83. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  84. *
  85. PA = 12.5E-3 50.E-3;
  86. PB = 12.5E-3 -50.E-3;
  87. PC = 0. -50.E-3;
  88. PD = 0. 50.E-3;
  89. *
  90. NB1 = 32; NB2 = 4;
  91. D1 = PA DROI NB1 PB;
  92. D2 = PB DROI NB2 PC;
  93. D3 = PC DROI NB1 PD;
  94. D4 = PD DROI NB2 PA;
  95. *
  96. SUR1 = DALL D1 D2 D3 D4 PLAN;
  97. *
  98. SI (NEG GRAPH 'N');
  99. TITR 'PLAS7 : MAILLAGE';
  100. TRAC 'QUAL' SUR1;
  101. FINSI;
  102. *
  103. NBNO1 = NBNO SUR1;
  104. NBEL1 = NBEL SUR1;
  105. *
  106. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  107. * definition du modele, des caracteristiques *
  108. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  109. *
  110. MOD1 = MODE SUR1 MECANIQUE ELASTIQUE PLASTIQUE
  111. PARFAIT QUA4;
  112. MAT1 = MATE MOD1 YOUN 2.1E11 NU 0.3 SIGY 483.E6;
  113. *
  114. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  115. * conditions aux limites *
  116. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  117. *
  118. CL1 = BLOQ UX D3;
  119. CL2 = BLOQ UY (SUR1 POIN PROC (0. 0.));
  120. CL3 = BLOQ UX D1;
  121. CL = CL1 ET CL2 ET CL3;
  122. *
  123. * Creation du chpoint de deplacement impose variable :
  124. * deplacement impose variant lineairement de u a -u
  125. * entre A et B, u croissant jusqu'a 0.5 mm .
  126. *
  127. I = 0.;
  128. LISD1 = PROG 1.;
  129. REPETER BLOC10 NB1;
  130. I = I + 1.;
  131. YY = 1. - (2. * (I / NB1));
  132. LISD1 = LISD1 ET (PROG YY);
  133. FIN BLOC10;
  134. *
  135. LISD1 = LISD1 * 1.E-3;
  136. CHPO1 = MANU CHPO (CHAN 'POI1' D1) 1 UX LISD1;
  137. *
  138. CHA1 = DEPI CL3 CHPO1;
  139. *
  140. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  141. * objets relatifs a la procedure PASAPAS *
  142. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  143. *
  144. TAB1 = TABLE;
  145. *
  146. * On prend comme liste des pseudo-temps
  147. * le deplacement u.
  148. *
  149. LREEL1 = PROG 0.029435 0.1 0.2 0.3 0.4 0.5 1.0;
  150. *
  151. * Chargement
  152. *
  153. EVOL1 = EVOL MANU UA LREEL1 COEFF LREEL1;
  154. CHAR1 = CHAR DIMP CHA1 EVOL1;
  155. *
  156. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  157. * resolution *
  158. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  159. *
  160. TAB1.'CARACTERISTIQUES' = MAT1;
  161. TAB1.'CHARGEMENT' = CHAR1;
  162. TAB1.'MODELE' = MOD1;
  163. TAB1.'TEMPS_CALCULES' = LREEL1;
  164. TAB1.'BLOCAGES_MECANIQUES' = CL;
  165. PASAPAS TAB1;
  166. *
  167. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  168. * extraction des resultats *
  169. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  170. *
  171. * Initialisation
  172. *
  173. MOM1 = TABL;
  174. LISD2 = LISD1 * 50.;
  175. MOM2 = TABL;
  176. ERG = TABL;
  177. *
  178. MOM2.1 = 90.57;
  179. MOM2.2 = 135.2;
  180. MOM2.3 = 138.4;
  181. MOM2.4 = 139.0;
  182. MOM2.5 = 139.2;
  183. MOM2.6 = 139.3;
  184. MOM2.7 = 139.4;
  185. *
  186. MOM2.8 = 543.4;
  187. MOM2.9 = 557.7;
  188.  
  189. *Boucle pour chaque pas de chargement : fonction de UA.
  190. I = 0;
  191. REPETER BLOC1 7;
  192. I = I + 1;
  193. CONT1 = TAB1.CONTRAINTES.I;
  194. DEPL1 = TAB1.DEPLACEMENTS.I;
  195. CHPO10 = CHAN CHPO MOD1 CONT1;
  196.  
  197. * Trace facultatif de la deformee
  198. * (verification du chargement)
  199. SI (I EGA 7);
  200. SI (NEG GRAPH 'N');
  201. TITR 'PLAS7 : DEFORMEE Increment :' I;
  202. DEF0 = DEFO SUR1 DEPL1 0.;
  203. DEF1 = DEFO SUR1 DEPL1 2. VERT;
  204. TRAC SUR1 (DEF0 ET DEF1);
  205. FINSI;
  206. FINSI;
  207.  
  208. * Calcul du moment de flexion du aux contraintes
  209. * smxx s'exercant le long de AB.
  210. LIST2 = PROG;
  211. J = 0;
  212. NB = NB1 + 1;
  213. REPETER BLOC4 NB;
  214. J = J + 1;
  215. D = EXTR LISD2 J;
  216. POI1 = SUR1 POIN PROC (12.5E-3 D);
  217. SM = EXTRA CHPO10 SMXX POI1;
  218. LIST2 = LIST2 ET (PROG SM);
  219. FIN BLOC4;
  220.  
  221. LIST3 = LIST2 * LISD2;
  222. TITR 'CONTRAINTE SMXX Increment :' I;
  223. ESMXX = EVOL MANU Y LISD2 SMXX LIST2;
  224. TITR 'PRODUIT Y * SMXX Increment :' I;
  225. EYSMXX = EVOL MANU Y LISD2 YSMXX LIST3;
  226.  
  227. SI (I EGA 7);
  228. SI (NEG GRAPH 'N');
  229. DESS ESMXX;
  230. DESS EYSMXX;
  231. FINSI;
  232. FINSI;
  233.  
  234. MOM1.I = INTG EYSMXX;
  235. MOM1.I = EXTR MOM1.I 1;
  236. MOM1.I = -1.E-4 * MOM1.I;
  237.  
  238. * Calcul de l'ecart entre theorie et calcul.
  239. ERG.I = 100. * (ABS ((MOM1.I - MOM2.I) / MOM2.I));
  240.  
  241. * Extraction de la contrainte maximale SMXX
  242. * pour les pas 1 et 7.
  243. SI (I EGA 1);
  244. MOM1.8 = EXTR CHPO10 SMXX PA;
  245. MOM1.8 = MOM1.8 / 1.E6;
  246. ERG.8 = 100. * (ABS ((MOM1.8 - MOM2.8) / MOM2.8));
  247. FINSI;
  248.  
  249. SI (I EGA 7);
  250. MOM1.9 = EXTR CHPO10 SMXX (D1 POIN 2);
  251. MOM1.9 = MOM1.9 / 1.E6;
  252. ERG.9 = 100. * (ABS ((MOM1.9 - MOM2.9) / MOM2.9));
  253. FINSI;
  254.  
  255. SI (NEG GRAPH 'N');
  256. TITR 'SMXX Increment :' I;
  257. TRAC MOD1 (EXCO CONT1 SMXX);
  258. FINSI;
  259.  
  260. FIN BLOC1;
  261.  
  262. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  263. * affichage des resultats *
  264. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  265. MESS 'RESULTATS : PLAS7';
  266. MESS '-------------------';
  267.  
  268. MESS 'Moment de flexion du aux contraintes SMXX
  269. le long de AB.';
  270. MESS '--------------------------------------------------------';
  271.  
  272. MESS ' UAmax = 0.029435 mm :';
  273. MESS ' ------------------- ';
  274. MESS ' Moment theorique :' MOM2.1 'kN.m';
  275. MESS ' Moment calcule :' MOM1.1 'kN.m';
  276. MESS ' Soit un ecart de :' ERG.1 '%';
  277.  
  278. MESS ' UAmax = 0.1 mm :';
  279. MESS ' -------------- ';
  280. MESS ' Moment theorique :' MOM2.2 'kN.m';
  281. MESS ' Moment calcule :' MOM1.2 'kN.m';
  282. MESS ' Soit un ecart de :' ERG.2 '%';
  283.  
  284. MESS ' UAmax = 0.2 mm :';
  285. MESS ' --------------';
  286. MESS ' Moment theorique :' MOM2.3 'kN.m';
  287. MESS ' Moment calcule :' MOM1.3 'kN.m';
  288. MESS ' Soit un ecart de :' ERG.3 '%';
  289.  
  290. MESS ' UAmax = 0.3 mm :';
  291. MESS ' --------------';
  292. MESS ' Moment theorique :' MOM2.4 'kN.m';
  293. MESS ' Moment calcule :' MOM1.4 'kN.m';
  294. MESS ' Soit un ecart de :' ERG.4 '%';
  295.  
  296. MESS ' UAmax = 0.4 mm :';
  297. MESS ' --------------';
  298. MESS ' Moment theorique :' MOM2.5 'kN.m';
  299. MESS ' Moment calcule :' MOM1.5 'kN.m';
  300. MESS ' Soit un ecart de :' ERG.5 '%';
  301.  
  302. MESS ' UAmax = 0.5 mm :';
  303. MESS ' --------------';
  304. MESS ' Moment theorique :' MOM2.6 'kN.m';
  305. MESS ' Moment calcule :' MOM1.6 'kN.m';
  306. MESS ' Soit un ecart de :' ERG.6 '%';
  307.  
  308. MESS ' UAmax = 1.0 mm :';
  309. MESS ' ---------------';
  310. MESS ' Moment theorique :' MOM2.7 'kN.m';
  311. MESS ' Moment calcule :' MOM1.7 'kN.m';
  312. MESS ' Soit un ecart de :' ERG.7 '%';
  313.  
  314. MESS 'Contrainte maximale smxx :';
  315. MESS '------------------------ :';
  316. MESS ' UAmax = 0.029435 mm';
  317. MESS ' -------------------';
  318. MESS ' Valeur theorique :' MOM2.8 'MPa';
  319. MESS ' Valeur calculee :' MOM1.8 'MPa';
  320. MESS ' Soit un ecart de :' ERG.8 '%';
  321.  
  322. MESS ' UAmax = 1.0 mm';
  323. MESS ' --------------';
  324. MESS ' Valeur theorique :' MOM2.9 'MPa';
  325. MESS ' Valeur calculee :' MOM1.9 'MPa';
  326. MESS ' Soit un ecart de :' ERG.9 '%';
  327.  
  328. MESS 'Donnees sur le maillage';
  329. MESS '-----------------------';
  330. MESS ' Nombre d elements :' NBEL1 'QUA4';
  331. MESS ' Nombre de noeuds :' NBNO1 ;
  332.  
  333. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  334. * code fonctionnement *
  335. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  336. ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 ERG.4 ERG.5 ERG.6
  337. ERG.7 ERG.8 ERG.9);
  338.  
  339. SI (ERGMAX <EG 5.0);
  340. ERRE 0;
  341. SINON;
  342. ERRE 5;
  343. FINSI;
  344.  
  345. TEMPS;
  346.  
  347. FIN;
  348.  
  349.  
  350.  
  351.  
  352.  
  353.  
  354.  
  355.  
  356.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales