Télécharger plas5.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas5.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas5.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. *******************************************************
  9. * Test plas5.dgibi: Jeux de données *
  10. * --------------------------------- *
  11. *******************************************************
  12.  
  13. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  14. * SINON SI GRAPH DIFFERENT DE N TOUS
  15. * LES GRAPHIQUES SONT AFFICHES
  16.  
  17. GRAPH = 'N' ;
  18.  
  19. SAUT PAGE;
  20. SI (NEG GRAPH 'N') ;
  21. OPTI ECHO 1 ;
  22. OPTI TRAC PSC ;
  23. SINO ;
  24. OPTI ECHO 0 ;
  25. FINSI ;
  26.  
  27. SAUT PAGE;
  28. *******************************************************
  29. * TEST PLAS5
  30. *
  31. * Sortie du domaine élastique et phase plastique
  32. * (comportement élasto-plastique modèle DRUCKER-PRAGER)
  33. *
  34. * Une plaque carrée est soumise à un déplacement imposé
  35. * sur deux de ses bords et fixée sur les deux autres.
  36. * On compare les contraintes à la solution exacte.
  37. *
  38. *******************************************************
  39. *
  40. * ^ ^
  41. * | | d(t)
  42. * | |
  43. *
  44. * D .____. C ----> d(t)
  45. * | |
  46. * | |
  47. * A .____. B ----> d(t)
  48. *
  49. *
  50. *******************************************************
  51.  
  52. TITRE 'PLAQUE CARRE EN BI-TRACTION PURE ';
  53. OPTION ECHO 0 ;
  54. OPTION DIME 2 ELEM QUA4 MODE PLAN CONT ;
  55. TEMPS ;
  56. *------------------------------------------------------
  57. * DEFINITION DE LA GEOMETRIE
  58. *------------------------------------------------------
  59. A = 0. 0. ;
  60. B = 1.5 0. ;
  61. C = 1.5 1.5 ;
  62. D = 0. 1.5 ;
  63. *
  64. L1 = A DROIT 1 B ;
  65. L2 = B DROIT 1 C ;
  66. L3 = C DROIT 1 D ;
  67. L4 = D DROIT 1 A ;
  68. LL = L1 ET L2 ET L3 ET L4 ;
  69. SU = SURF LL PLAN ;
  70. SI(NEG GRAPH 'N');
  71. TRACE QUAL SU ;
  72. FINSI;
  73. *------------------------------------------------------
  74. * DEFINITION DES CONDITIONS AUX LIMITES
  75. * ET DES DEPLACEMENTS IMPOSES
  76. *------------------------------------------------------
  77. CL4 = BLOQ L4 UX ;
  78. CL2 = BLOQ L2 UX ;
  79. CL3 = BLOQ L3 UY ;
  80. CL1 = BLOQ L1 UY ;
  81. CL = CL1 ET CL2 ET CL3 ET CL4 ;
  82. *
  83. D3 = DEPI CL3 1.5E-4 ;
  84. D2 = DEPI CL2 1.5E-4 ;
  85. DEP = D2 ET D3 ;
  86. *
  87. *-------- Utilisation de la procedure PASAPAS ---------
  88. *-- Les objets utilisés par la procédure PASAPAS sont -
  89. *-------- définis dans les lignes qui suivent ---------
  90. *
  91. MO = MODE SU MECANIQUE ELASTIQUE PLASTIQUE
  92. DRUCKER_PRAGER QUA4 ;
  93.  
  94. KLL= 3.56 ;
  95. ETT= 0.441;
  96. MUU= 1.02 ;
  97. MAT1 = MATE MO YOUN 40000 NU 0.21
  98. ALFA 0.441 BETA 1.02 K 4.1 GAMM 0.441 DELT 1.02 ETA
  99. ETT MU MUU KL KLL H 0. ;
  100. *
  101. *------- Création d'une relation linéaire entre -------
  102. *----------- le déplacement et le temps ---------------
  103. * Remarque : au temps T, le déplacement vaut F(T)*D .
  104. *
  105. LI1 = PROG 0. 1. 2. 3. 4. 5. ;
  106. LI2 = PROG 0. 1. 2. 3. 4. 5. ;
  107. EV = EVOL MANU T LI1 F(T) LI2 ;
  108. CHA1 = CHAR DIMP DEP EV ;
  109. *
  110. *------- Création de la liste des pas de calcul -------
  111. *
  112. LIS1 = PROG 0. 1. 2.;
  113. TAB1 = TABLE ;
  114. TAB1.'CARACTERISTIQUES' = MAT1;
  115. TAB1.'CHARGEMENT' = CHA1;
  116. TAB1.'MODELE' = MO;
  117. TAB1.'TEMPS_CALCULES' = LIS1;
  118. TAB1.'BLOCAGES_MECANIQUES' = CL;
  119. *
  120. *---------- Calcul par la procedure PASAPAS -----------
  121. *
  122. PASAPAS TAB1;
  123. *
  124. * recherche des contraintes resultats
  125. * par la procedure PECHE
  126. *
  127. SIG1 = PECHE TAB1 CONTRAINTES 1.;
  128. SIG2 = PECHE TAB1 CONTRAINTES 2.;
  129.  
  130.  
  131. SI(NEG GRAPH 'N');
  132. TITR 'Contrainte SMYY increment 2 en MPa';
  133. TRAC (EXCO SMYY SIG2) MO;
  134. FINSI;
  135.  
  136. *
  137. * extraction d'une valeur d'une composante
  138. * en un point de gauss
  139. *
  140. SXX = EXTR SIG2 'SMXX' 1 1 1 ;
  141. SYY = EXTR SIG2 'SMYY' 1 1 1 ;
  142. *
  143. * calcul de la valeur th{orique
  144. *
  145. VALTH = KLL / ( ( 2. * ETT ) + MUU );
  146. RESI1=100 * (ABS((SXX-VALTH)/VALTH));
  147. RESI2=100 * (ABS((SYY-VALTH)/VALTH));
  148. SAUT PAGE ; SAUT 2 LIGN ;
  149. *
  150. MESS ' CONTRAINTE THEORIQUE
  151. CONTRAINTES CALCULEES ';
  152. MESS ' SIG = ' VALTH '
  153. SMXX=' SXX ' SMYY=' SYY ;
  154. MESS ' SOIT UN ECART DE ' RESI1 '% SUR SMXX' ;
  155. MESS ' SOIT UN ECART DE ' RESI2 '% SUR SMYY' ;
  156. *
  157. TEMPS ;
  158. * CODE FONCTIONNEMENT
  159.  
  160. SI((RESI1 <EG 1e-10) ET (RESI2 <EG 1e-10));
  161. ERRE 0;
  162. SINO;
  163. ERRE 5;
  164. FINSI;
  165.  
  166. FIN;
  167.  
  168.  
  169.  
  170.  
  171.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales