Télécharger plas11.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas11.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas11.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. OPTION ECHO 1;
  8. GRAPH = 'N';
  9. SAUT PAGE;
  10. *
  11. *******************************************************
  12. * *
  13. * TEST : PLAS11 *
  14. * DEFORMATIONS PLANES GENERALISEES *
  15. * *
  16. * une poutre de section rectangulaire est *
  17. * soumise à une rotation imposée RX : *
  18. * *
  19. * Hauteur:4 Largeur:2 *
  20. * *
  21. * ''''''''' *
  22. * ' * ' *
  23. * ' | ' cette poutre est modélisée *
  24. * --------- avec une partie massive (1x1) *
  25. * | | une autre avec des éléments *
  26. * | -------->@RX COQ2 (long :.5 epais 2.) et *
  27. * | | la dernière avec des éléments *
  28. * --------- point POI1 : 4 point, 2 en *
  29. * ' | ' haut, 2 en bas (sect .5 ) *
  30. * ' * ' *
  31. * ''''''''' *
  32. * *
  33. * On étudie le comportement du moment résultant *
  34. * de cette rotation imposée jusqu'au domaine *
  35. * plastique *
  36. * *
  37. *******************************************************
  38. TITRE 'PLAS11 - SECTION DE POUTRE SOUMISE A UNE ROTATION IMPOSEE';
  39. OPTION ECHO 1;
  40. TEMPS;
  41. *
  42. *
  43. OPTI ELEM QUA8;
  44. *
  45. * on définit le point support des déformations
  46. * planes généralisées
  47. *
  48. PG = 0. 0.;PG1=PG PLUS (0. 0.);PG2 = PG PLUS (0. 0.);
  49. *
  50. OPTI MODE PLAN GENE ;
  51. *
  52. * quelques initialisations :
  53. *
  54. I = 1;
  55. EVL1 = PROG 0. ;
  56. EVL2 = PROG 0. ;
  57. EVL3 = PROG 0. ;
  58. *
  59. * et quelques constantes pour le calcul théorique :
  60. *
  61. * demi hauteur de la section
  62. H = 2.;
  63. * demi largeur de la section
  64. B = 1. ;
  65. * le module de young
  66. E1 = 2E11;
  67. * la limite élastique du matériau
  68. SILIM = 4.83E8;
  69. * le moment d'inertie par rapport a l'axe des X
  70. IX = (2.*B)*((2.*H)**3)/12.;
  71. * la valeur limite de la déformation élastique
  72. EPSEL = SILIM/E1;
  73. * la valeur limite du moment élastique
  74. MOMEL = E1*IX*EPSEL/H;
  75. * le moment plastique ultime
  76. MOLIM = 3*MOMEL/2.;
  77. *
  78. *======================================================
  79. * géometrie : maillage
  80. *======================================================
  81. *
  82. * dimension en mètres
  83. *
  84. *----------maillage partie massive-----------*
  85. *
  86. * points
  87. *
  88. P1 = 1. -1.;
  89. P2 = 1. 1.;
  90. P3 = -1. 1.;
  91. P4 = -1. -1.;
  92. *
  93. * droite et lignes
  94. *
  95. * coefficients de finesse du maillage
  96. *
  97. N = 4;
  98. M = 1;
  99. *
  100. D1 = P1 D N P2 ;
  101. D2 = P2 D M P3 ;
  102. D3 = P3 D N P4 ;
  103. D4 = P4 D M P1 ;
  104. *
  105. SURF1 = DALL D1 D2 D3 D4;
  106. *
  107. *----------maillage éléments coq2------------*
  108. *
  109. OPTI ELEM SEG2 ;
  110. *
  111. P5 = 0. 1. ;
  112. P6 = 0. 1.5 ;
  113. P7 = 0. -1. ;
  114. P8 = 0. -1.5 ;
  115. *
  116. D5 = P5 D 2 P6;
  117. D6 = P7 D 2 P8;
  118. COQU1 = D5 ET D6 ;
  119. *
  120. P9 = 0. 1.625;
  121. P10 = 0. 1.875;
  122. P11 = 0. -1.625;
  123. P12 = 0. -1.875;
  124. *
  125. *----------maillage éléments poi1------------*
  126. *
  127. PO11 = MANU POI1 P9;
  128. PO12 = MANU POI1 P10;
  129. PO13 = MANU POI1 P11;
  130. PO14 = MANU POI1 P12;
  131. PO1 = PO11 ET PO12 ET PO13 ET PO14;
  132. *
  133. SURTOT = SURF1 ET COQU1 ET PO1 ;
  134. *
  135. SI (NEG GRAPH 'N');
  136. TITR 'PLAS12 : MAILLAGE';
  137. TRAC QUAL SURTOT;
  138. FINSI;
  139. *
  140. ELTOT = NBEL SURTOT;
  141. NOTOT = NBNO SURTOT;
  142. *
  143. *
  144. *======================================================
  145. * modèle - matériau
  146. * rigidité
  147. *======================================================
  148. *
  149. *----------------partie massive-----------------*
  150. *
  151. MO1 = MODE SURF1 MECANIQUE ELASTIQUE PLASTIQUE PARFAIT QUA8 DPGE PG;
  152. MA1 = MATE MO1 YOUN E1 NU 0. SIGY SILIM;
  153. ma2= MATE MO1 YOUN 'TOTO' NU 0. SIGY SILIM;
  154. list ma2;
  155. *
  156. *----------------éléments coq2------------------*
  157. *
  158. MO2 = MODE COQU1 MECANIQUE ELASTIQUE PLASTIQUE PARFAIT COQ2 DPGE PG1;
  159. MAT2 = MATE MO2 YOUN E1 NU 0. SIGY SILIM;
  160. CAR2 = CARA MO2 EPAI 2. ;
  161. MA2 = MAT2 ET CAR2 ;
  162. *
  163. *-----------------éléments poi1-----------------*
  164. *
  165. MO3 = MODE PO1 MECANIQUE ELASTIQUE PLASTIQUE PARFAIT POI1 DPGE PG1;
  166. MAT3 = MATE MO3 YOUN E1 NU 0. SIGY SILIM;
  167. CAR3 = CARA MO3 SECT .5 ;
  168. MA3 = MAT3 ET CAR3;
  169. *
  170. MODE1 = MO1 ET MO2 ET MO3;
  171. MATE1 = MA1 ET MA2 ET MA3;
  172. *
  173. RI1 = RIGI MODE1 MATE1;
  174.  
  175. *
  176. *======================================================
  177. * conditions aux limites
  178. *======================================================
  179. *
  180. P15 = SURF1 POINT PROCHE (0. 0.);
  181. P16 = SURF1 POINT PROCHE (0. 1.);
  182. B1 = BLOQ DEPL P15;
  183. B2 = BLOQ UX P16;
  184. B3 = BLOQ DEPL PO1 ;
  185. B4 = BLOQ UX COQU1 ;
  186. B5 = BLOQ UY (P5 ET P7) ;
  187. B6 = BLOQ UZ RY (PG et pg1 );
  188. B7 = BLOQ RX ( PG et pg1 );
  189. BTOT = B1 ET B2 ET B3 ET B4 ET B5 ET B6 ET B7;
  190. RI = RI1 ET BTOT;
  191. *
  192. *======================================================
  193. * chargement
  194. *======================================================
  195. *
  196. TEMP1 = (PROG 4. PAS 2. 30.) ET (PROG 50.);
  197. LAM1 = (PROG 4. PAS 2. 30.) ET (PROG 50.);
  198. FAT1 = .0002;
  199. TITRE 'PLAS11 : CHARGEMENT';
  200. EV1 = EVOL MANU 'TEMPS' TEMP1 'RX(T)' LAM1 ;
  201. DE1 = DEPI B7 FAT1 ;
  202. CHRIX = CHAR 'DIMP' DE1 EV1 ;
  203. *
  204. SI (NEG GRAPH 'N');
  205. DESS EV1 ;
  206. FINSI;
  207. *
  208. *======================================================
  209. * calcul non linéaire
  210. *======================================================
  211. *
  212. opti sauv 'plas11.sauv';
  213. TAB1 = TABLE;
  214. TAB1.'BLOCAGES_MECANIQUES' = BTOT;
  215. TAB1.'MODELE' = MODE1;
  216. TAB1.'CARACTERISTIQUES' = MATE1;
  217. TAB1.'CHARGEMENT' = CHRIX;
  218. TAB1.'TEMPS_CALCULES' = TEMP1;
  219. tab1.'TEMPS_SAUVEGARDES' = TEMP1;
  220. tab1.'PRECISION' = 1.e-6;
  221. tab1.'HYPOTHESE_DEFORMATIONS'='LINEAIRE';
  222.  
  223. PASAPAS TAB1 ;
  224.  
  225.  
  226.  
  227.  
  228. *
  229. * recalcul des trois dernier pas (pour tester l'option reprise de
  230. * pasapas
  231. *
  232. tab1.REPRISE=26.;
  233. tab1.'TEMPS_CALCULES'=prog 28. 30. 50.;
  234. tab1.'TEMPS_SAUVEGARDES'=prog 28. 30. 50.;
  235. pasapas tab1;
  236.  
  237.  
  238. *
  239. *======================================================
  240. * post-traitement : tracé d'une courbe et comparaison
  241. * avec la solution analytique
  242. *======================================================
  243. *
  244. DIM1 = DIMENSION TEMP1;
  245. *
  246. REPETER BLOC1 DIM1;
  247. *
  248. TPS = EXTR TEMP1 I;
  249. CH1 = PECHE TAB1 DEPLACEMENTS TPS;
  250. MOIMP = REAC RI CH1;
  251. *
  252. *EXTRACTION DU MOMENT MX CORRESPONDANT À LA ROTATION RX
  253. *
  254. MMX = EXTR MOIMP MX PG;MMX1= EXTR MOIMP MX PG1;MMX=MMX+MMX1;
  255. RRX = EXTR CH1 RX PG;RRX1= EXTR CH1 RX PG1;RRX=RRX+RRX1;
  256. EVL1 = EVL1 ET (PROG MMX );
  257. EVL2 = EVL2 ET (PROG RRX );
  258. *
  259. *---------------SOLUTION THEORIQUE--------------------*
  260. *
  261. EPSN = 2.*RRX ;
  262. *
  263. * quand on est dans le domaine plastique :
  264. *
  265. SI (EPSN > EPSEL) ;
  266. MOMN = (1 - ((( EPSEL / EPSN) ** 2) / 3)) * MOLIM ;
  267. EVL3 = EVL3 ET (PROG MOMN);
  268. *
  269. * quand on est dans le domaine élastique :
  270. *
  271. SINON;
  272. MOMN = E1 * IX * RRX ;
  273. EVL3 = EVL3 ET (PROG MOMN) ;
  274. FINSI;
  275. *
  276. I = I+1;
  277. *
  278. FIN BLOC1;
  279. *
  280. SI (NEG GRAPH 'N');
  281. *
  282. COURB = TABLE;
  283. COURB.1 = 'MARQ ETOI NOLI' ;
  284. *
  285. titre 'PLAS11 : COURBE MX EN FONCTION DE RX ';
  286. EV1 = EVOL MANU 'RX' EVL2 'MX' EVL1 ;
  287. EV2 = EVOL MANU 'RX' EVL2 'MX' EVL3 ;
  288. * courbe théorique : traits continus
  289. * point calculés : marques étoiles
  290. DESS (EV1 ET EV2) COURB LOGO;
  291. FINSI;
  292. *
  293. * calcul de l'écart avec la solution de référence
  294. *
  295. ERG1 = 100*(ABS((MOMN-MMX)/MOMN));
  296. *
  297. *======================================================
  298. * affichage des résultats
  299. *======================================================
  300. *
  301. MESS ' RESULTATS : TEST PLAS11 ';
  302. MESS '---------------------------';
  303. *
  304. MESS 'on cherche la valeur du moment calculé dans le ';
  305. MESS 'domaine plastique';
  306. MESS 'elle est comparée a une valeur obtenue analytiquement';
  307. MESS ' moment théorique :' MOMN 'MPa';
  308. MESS ' moment calculé :' MMX 'MPa';
  309. MESS ' Soit un écart de :' ERG1 '%';
  310. *
  311. MESS ' Nombre d elements :' ELTOT;
  312. MESS ' Nombre de noeuds :' NOTOT;
  313. MESS ' soit ' (NOTOT * 3) 'd.d.l.';
  314. *
  315. *
  316. *======================================================
  317. * code de fonctionnement
  318. *======================================================
  319. *
  320. * L'écart maximum entre valeur théorique et
  321. * calculée doit être inférieur a 0.5%.
  322. *
  323. SI (ERG1 <EG 0.5);
  324. ERRE 0;
  325. SINON;
  326. ERRE 5;
  327. FINSI;
  328. *
  329. *======================================================
  330. * Temps de calcul et fin
  331. *======================================================
  332. *
  333. TEMPS;
  334. *
  335. FIN;
  336. *
  337.  
  338.  
  339.  
  340.  
  341.  
  342.  
  343.  
  344.  
  345.  
  346.  
  347.  
  348.  
  349.  
  350.  
  351.  
  352.  
  353.  
  354.  
  355.  
  356.  
  357.  
  358.  
  359.  
  360.  
  361.  
  362.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales