Télécharger plas10.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas10.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas10.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. OPTION ECHO 0;
  8. * ajout de option epsilon lineaire pour la precision des test!
  9. OPTION epsilon lineaire;
  10. GRAPH='N';
  11. SAUT PAGE ;
  12. *
  13. *******************************************************
  14. * TEST PLAS10
  15. *
  16. * Sortie du domaine élastique et phase plastique
  17. * (comportement élasto-plastique modèle CAM-CLAY).
  18. *
  19. * Un parallelépipède est soumis à des déplacements
  20. * imposés sur trois de ses faces et fixé de manière
  21. * isosattique. On compare la courbe de réponse en
  22. * compression hydrostatique à la solution exacte.
  23. *
  24. *******************************************************
  25.  
  26. TITRE 'PARALLELEPIPEDE EN COMPRESSION HYDROSTATIQUE ' ;
  27. OPTION ECHO 0 ;
  28. OPTION DIME 3 ELEM CUB8 MODE TRID ;
  29. *------------------------------------------------------
  30. * DEFINITION DE LA GEOMETRIE
  31. *------------------------------------------------------
  32. A1= 0. 0. 0.;
  33. B1= 1. 0. 0.;
  34. C1= 1. 1. 0.;
  35. D1= 0. 1. 0.;
  36. A2= 0. 0. 1.;
  37. B2= 1. 0. 1.;
  38. C2= 1. 1. 1.;
  39. D2= 0. 1. 1.;
  40. *
  41. L1 = A1 DROIT 1 B1 ;
  42. L2 = B1 DROIT 1 C1 ;
  43. L3 = C1 DROIT 1 D1 ;
  44. L4 = D1 DROIT 1 A1 ;
  45. LL = L1 ET L2 ET L3 ET L4 ;
  46. SU1= SURF LL PLAN ;
  47. M1 = A2 DROIT 1 B2 ;
  48. M2 = B2 DROIT 1 C2 ;
  49. M3 = C2 DROIT 1 D2 ;
  50. M4 = D2 DROIT 1 A2 ;
  51. MM = M1 ET M2 ET M3 ET M4 ;
  52. SU2= SURF MM PLAN ;
  53. SU = SU1 VOLU 1 SU2 ;
  54. SI(NEG GRAPH 'N');
  55. TRAC (888 1000 2000 ) SU ;
  56. FINSI ;
  57. *------------------------------------------------------
  58. * DEFINITION DES CONDITIONS AUX LIMITES
  59. * ET DES DEPLACEMENTS IMPOSES
  60. *------------------------------------------------------
  61. BLX = BLOQ UX ( A1 ET A2 ET D1 ET D2 );
  62. BLY = BLOQ UY ( A1 ET B1 ET B2 ET A2 ) ;
  63. BLZ = BLOQ UZ SU1 ;
  64. BL = BLX ET BLY ET BLZ ;
  65. *
  66. CLX = BLOQ UX ( B1 ET B2 ET C1 ET C2 );
  67. CLY = BLOQ UY ( D1 ET C1 ET C2 ET D2 ) ;
  68. CLZ = BLOQ UZ SU2 ;
  69. CL = CLX ET CLY ET CLZ ;
  70. *
  71. VAL = -2.664328E-5 ;
  72. DEPX= DEPI CLX VAL ;
  73. DEPY= DEPI CLY VAL ;
  74. DEPZ= DEPI CLZ VAL ;
  75. *
  76. *------------------------------------------------------
  77. * DEFINITION DES PROPRIETES MATERIELLES
  78. *------------------------------------------------------
  79. MO = MODE SU MECANIQUE ELASTIQUE PLASTIQUE CAM_CLAY ;
  80. *
  81. XL = 0.1 ;
  82. CC = 0.5 ;
  83. XK = 0.01 ;
  84. EE = 2. ;
  85. PI0 = 5.;
  86. *
  87. MAT = MATE MO 'YOUN' 1000. 'NU' 0.2
  88. 'E0' EE 'COHE' CC 'M' 1.2 'P0' PI0 'LAMD' XL
  89. 'KAPA' XK 'G1' 416.666667 ;
  90. *
  91. LITX = PROG 0. PAS 1. 300. ;
  92. LIX = PROG 0. PAS 1. 300. ;
  93. EVX= EVOL MANU 'TEMP' LITX 'FX' LIX ;
  94. CHA1 = CHAR 'DIMP' (DEPX ET DEPY ET DEPZ) EVX;
  95. *
  96. *------------------------------------------
  97. * APPEL A PASAPAS
  98. * AU TEMPS T , LE DEPLACEMENT VAUDRA F(T)*D
  99. *------------------------------------------
  100. TAB1 = TABLE ;
  101. LIS1 = PROG 0. PAS 10. 200. ;
  102. TAB1.'MODELE' = MO;
  103. TAB1.'CARACTERISTIQUES' = MAT;
  104. TAB1.'CHARGEMENT' = CHA1;
  105. TAB1.'TEMPS_CALCULES' = LIS1;
  106. TAB1.'BLOCAGES_MECANIQUES' = CL 'ET' BL;
  107. PASAPAS TAB1 ;
  108. *
  109. *------------------------------------------
  110. * DEPOUILLEMENT ET
  111. * CALCUL DE LA SOLUTION ANALYTIQUE
  112. *------------------------------------------
  113. *
  114. SI(NEG GRAPH 'N');
  115. NT = (DIME (TAB1.DEPLACEMENTS)) - 1 ;
  116. IT = 0 ;
  117. PRD = PROG 0. ;
  118. PRF = PROG 0. ;
  119. REPETER BOPI NT;
  120. IT = IT + 1 ;
  121. DD= TAB1.DEPLACEMENTS.IT;
  122. RR = REAC CLY DD;
  123. RRR = RESU RR;
  124. LEP = ( EXTR RRR 'MAIL' 'NOMU' ) POIN 1 ;
  125. PRD = PRD ET (PROG ( EXTR DD UY D1));
  126. PRF = PRF ET (PROG ( EXTR RRR FY LEP) ) ;
  127. FIN BOPI ;
  128. FV = EVOL ROSE MANU 'D' PRD 'F ' PRF;
  129. DESS FV ;
  130. FINSI;
  131. *
  132. VV = PECHE TAB1 VARIABLES_INTERNES 200. ;
  133. SS = PECHE TAB1 CONTRAINTES 200. ;
  134. PCAL = EXTR SS SMXX 1 1 1 ;
  135. PTHE = -1. * ( PI0 + CC) *
  136. (EXP ( ( -300. * VAL ) * ( 1.+EE ) / XL) );
  137. PTHE = PTHE + CC ;
  138. EVPCAL = EXTR VV TRAP 1 1 1 ;
  139. EVPTHE = (300. * VAL ) * ( XL - XK ) / XL ;
  140. SAUTER 3 LIGNE ;
  141. MESS ' PRESSION MOYENNE THEORIQUE ' PTHE
  142. ' CALCULEE' PCAL;
  143. MESS ' TRACE PLASTIQUE THEORIQUE ' EVPTHE
  144. ' CALCULEE ' EVPCAL;
  145. *
  146. RESI1 = ABS ( (PCAL-PTHE)/PTHE );
  147. RESI2 = ABS ( (EVPCAL-EVPTHE)/EVPTHE);
  148. SAUTER 3 LIGNE ;
  149. MESS ' ERREURS RELATIVES ' RESI1 RESI2 ;
  150. *
  151. * CODE FONCTIONNEMENT
  152. *
  153. SI (RESI1 <EG 1.E-6) ;
  154. SI (RESI2 <EG 1.E-6) ;
  155. ERRE 0;
  156. SINO;
  157. ERRE 5;
  158. FINSI;
  159. SINON;
  160. ERRE 5;
  161. FINSI;
  162. FIN;
  163.  
  164.  
  165.  
  166.  
  167.  
  168.  
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales