Télécharger plas1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas1.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. * CAS TEST DU 91/10/24 PROVENANCE : MILL
  9. * CAS TEST DU 91/10/15 PROVENANCE : STRU
  10.  
  11. *******************************************************
  12. * Test plas1.dgibi: Jeux de données *
  13. * --------------------------------- *
  14. *******************************************************
  15.  
  16. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  17. * SINON SI GRAPH DIFFERENT DE N TOUS
  18. * LES GRAPHIQUES SONT AFFICHES
  19.  
  20. GRAPH = 'N' ;
  21. * GRAPH = 'O' ;
  22.  
  23. SAUT PAGE;
  24. *******************************************************
  25. * TEST PLAS1
  26. *
  27. * Sortie du domaine élastique et phase plastique
  28. * (comportement élasto-plastique parfait)
  29. *
  30. * Une plaque rectangulaire est soumise à une flexion
  31. * pure. La flexion est imposée par le déplacement des
  32. * extrémités de la plaque (voir schéma ci-dessous) en
  33. * fonction du temps.
  34. *
  35. * Au premier pas de temps (0.02875) on se trouve dans
  36. * le domaine élastique et au deuxième pas de temps
  37. * (0.05) on se trouve dans le domaine plastique. Au
  38. * deux pas de temps, les moments fléchissants calculés
  39. * à partir des forces de réaction sont comparés avec
  40. * les résultats théoriques.
  41. *
  42. *******************************************************
  43. *
  44. * D .____. A ----> D1
  45. * | |
  46. * | |
  47. * .____. A1
  48. * | |
  49. * | |
  50. * .____. A2
  51. * | |
  52. * | |
  53. * .____. A3
  54. * | |
  55. * | |
  56. * O .____. A4
  57. * | |
  58. * | |
  59. * .____. A5
  60. * | |
  61. * | |
  62. * .____. A6
  63. * | |
  64. * | |
  65. * .____. A7
  66. * | |
  67. * | |
  68. * C .____. B <---- D2
  69. *
  70. *------------------------------------------------------
  71. * LES POINTS A1 A A7 SERVIRONT A FAIRE VARIER LE
  72. * DEPLACEMENT IMPOSE LINEAIREMANT DE A (D1) A B (D2)
  73. *------------------------------------------------------
  74. *
  75. *******************************************************
  76. TITRE 'PLAQUE RECTANGULAIRE EN FLEXION PURE' ;
  77. OPTION ECHO 1 ;
  78. OPTION DIME 2 ELEM QUA4 MODE PLAN CONT ;
  79. TEMPS ;
  80. *
  81. *-------------- Definition de la geometrie ------------
  82. *
  83. O = 0 0 ;
  84. A = 12.5E-3 50E-3 ;
  85. B = 12.5E-3 -50E-3 ;
  86. C = 0 -50E-3 ;
  87. D = 0 50E-3 ;
  88. *
  89. A1 = 12.5E-3 37.5E-3 ;
  90. A2 = 12.5E-3 25E-3 ;
  91. A3 = 12.5E-3 12.5E-3 ;
  92. A4 = 12.5E-3 0 ;
  93. A5 = 12.5E-3 -12.5E-3 ;
  94. A6 = 12.5E-3 -25E-3 ;
  95. A7 = 12.5E-3 -37.5E-3 ;
  96. *
  97. L1 = A DROIT 1 A1 ;
  98. L2 = A1 DROIT 1 A2 ;
  99. L3 = A2 DROIT 1 A3 ;
  100. L4 = A3 DROIT 1 A4 ;
  101. L5 = A4 DROIT 1 A5 ;
  102. L6 = A5 DROIT 1 A6 ;
  103. L7 = A6 DROIT 1 A7 ;
  104. L8 = A7 DROIT 1 B ;
  105.  
  106. L14 = L1 ET L2 ET L3 ET L4 ET L5 ET L6 ET L7 ET L8 ;
  107.  
  108. L9 = B DROIT 1 C ;
  109. L10 = C DROIT 4 O ;
  110. L11 = O DROIT 4 D ;
  111. L12 = L10 ET L11 ;
  112. L13 = D DROIT 1 A ;
  113. *
  114. SU = L14 L9 L12 L13 DALL PLAN ;
  115. ELIM 0.01 SU ;
  116. SI(NEG GRAPH 'N');
  117. TRACE 'QUAL' SU ;
  118. FINSI;
  119.  
  120. *------- Définition des conditions aux limites --------
  121. *----------- et des déplacements imposés --------------
  122. *
  123. CL1 = BLOQ L12 UX ;
  124. CL1B = BLOQ O UY ;
  125. CL2 = BLOQ A UX ;
  126. CL3 = BLOQ B UX ;
  127. CL = CL1 ET CL1B ET CL2 ET CL3 ;
  128. *
  129. D1 = DEPI CL2 1E-3 ;
  130. D2 = DEPI CL3 -1E-3 ;
  131. DEP = D1 ET D2 ;
  132.  
  133. *--------------------------------------
  134. * Exemple : EN A1 , D = 7/8 D1 + 1/8 D2
  135. *--------------------------------------
  136. *
  137. *--------- Les déplacements en chaque noeud -----------
  138. *----------- est une relation linéaire des ------------
  139. *------------ deplacements des extrémités -------------
  140. *------- Création de la rigidité correspondante -------
  141. *
  142. R1 = RELA 8 UX A1 - 7 UX A - 1 UX B ;
  143. R2 = RELA 8 UX A2 - 6 UX A - 2 UX B ;
  144. R3 = RELA 8 UX A3 - 5 UX A - 3 UX B ;
  145. R4 = RELA 8 UX A4 - 4 UX A - 4 UX B ;
  146. R5 = RELA 8 UX A5 - 3 UX A - 5 UX B ;
  147. R6 = RELA 8 UX A6 - 2 UX A - 6 UX B ;
  148. R7 = RELA 8 UX A7 - 1 UX A - 7 UX B ;
  149. R = R1 ET R2 ET R3 ET R4 ET R5 ET R6 ET R7 ;
  150. *
  151. *-------- Utilisation de la procédure PASAPAS ---------
  152. *-- Les objets utilisés par la procédure PASAPAS sont -
  153. *------- définis dans les lignes qui suivent ----------
  154. *
  155. MO= MODE SU MECANIQUE ELASTIQUE PLASTIQUE PARFAIT QUA4;
  156.  
  157. *
  158. *----- Définition du matériau et de la rigidité -------
  159. *----------- SIGY est la limite élastique -------------
  160. *
  161. MAT1 = MATE MO YOUN 2.1E11 SIGY 483E6 NU 0.3 ;
  162. RI1 = RIGI MO MAT1 ;
  163. RIG1 = RI1 ET CL ET R ;
  164. *
  165. *------- Création d'une relation linéaire entre -------
  166. *------------- le déplacement et le temps -------------
  167. *
  168. LI1 = PROG 0. 1. ;
  169. LI2 = PROG 0. 1. ;
  170. EV = EVOL MANU T LI1 F(T) LI2 ;
  171. *
  172. * Remarque : au temps T, le deplacement vaut F(T)*D .
  173. *----------------------------------------------------
  174. *
  175. CHA1 = CHAR 'DIMP' DEP EV ;
  176. *
  177. *------- Création de la liste des pas de calcul -------
  178. *----- 0.02875 est le dernier incrément élastique -----
  179. *- 0.05 est un incrément plastique (calcul analytique)
  180. *
  181. LIS1 = PROG 0.02875 0.05 ;
  182. *
  183. *----------- Calcul par la procédure PASAPAS ----------
  184. *
  185. TAB1 = TABLE 'PASAPAS' ;
  186. TAB1.'BLOCAGES_MECANIQUES' = CL 'ET' R;
  187. TAB1.'MODELE' = MO;
  188. TAB1.'CHARGEMENT' = CHA1;
  189. TAB1.'CARACTERISTIQUES' = MAT1;
  190. TAB1.'TEMPS_CALCULES' = LIS1;
  191.  
  192. PASAPAS TAB1 ;
  193.  
  194.  
  195. *... Test de la procedure EXPLORER ...
  196.  
  197. * ...en interactif
  198. SI (NEG GRAPH 'N');
  199. EXPLORER TAB1;
  200. FINSI;
  201.  
  202. * ...en ps
  203. opti trac PSC;
  204. * par defaut -> contrainte sur maillage deformee d'amplification auto
  205. EXPLORER TAB1;
  206. * reaction puis contrainte sur maillage deformee d'amplification x200
  207. toto = tabl;
  208. toto . 'AMPL' = 200.;
  209. EXPLORER TAB1 (mots 'DEPL' 'REAC' 'VAR') toto;
  210. EXPLORER TAB1 (mots 'DEPL' 'CONT' 'VAR') toto;
  211. * evolution avec le temps de UX en A
  212. toto . 'EVOL' = tabl;
  213. toto . 'EVOL' . 'TYPE' = mot 'TEMP';
  214. toto . 'EVOL' . 'COMP' = mot 'UX';
  215. toto . 'EVOL' . 'POIN' = A;
  216. EXPLORER TAB1 (mots 'DEPL' 'EVOL') toto;
  217. * evolution avec le temps de FY en 0
  218. toto . 'EVOL' . 'COMP' = mot 'FY';
  219. toto . 'EVOL' . 'POIN' = O;
  220. EXPLORER TAB1 (mots 'REAC' 'EVOL') toto;
  221. * evolution avec le temps de SMXX (zone 1, elem 1, ptg 1)
  222. toto . 'EVOL' . 'COMP' = mot 'SMXX';
  223. EXPLORER TAB1 (mots 'CONT' 'EVOL') toto;
  224. * evolution spatiale de FX le long de L14 (ligne A vers B)
  225. toto . 'EVOL' . 'TYPE' = mot 'ESPA';
  226. toto . 'EVOL' . 'COMP' = mot 'FX';
  227. toto . 'EVOL' . 'LIGN' = L14;
  228. EXPLORER TAB1 (mots 'REAC' 'EVOL') toto;
  229.  
  230. *
  231. *--------- calcul et impression des résultats ---------
  232. *
  233. REA1 = REAC RIG1 (TAB1.DEPLACEMENTS.1) ;
  234. REA2 = REAC RIG1 (TAB1.DEPLACEMENTS.2) ;
  235.  
  236. R11 = EXTR REA1 FX A ;
  237. R21 = EXTR REA2 FX A ;
  238. R12 = EXTR REA1 FX A1 ;
  239. R22 = EXTR REA2 FX A1 ;
  240. R13 = EXTR REA1 FX A2 ;
  241. R23 = EXTR REA2 FX A2 ;
  242. R14 = EXTR REA1 FX A3 ;
  243. R24 = EXTR REA2 FX A3 ;
  244. *
  245. * Pour obtenir les moments fléchissants, les réactions
  246. * - obtenues sont multipliées par leur bras de levier -
  247. *
  248. M1 = (2.E-3)*((0.050*R11)+(0.0375*R12)+(0.025*R13)
  249. +(0.0125*R14)) ;
  250. M2 = (2.E-3)*((0.050*R21)+(0.0375*R22)+(0.025*R23)
  251. +(0.0125*R24)) ;
  252.  
  253.  
  254. MR1=805. ;
  255. MR2=1074. ;
  256.  
  257. RESI1=100. * (ABS((M1-MR1)/MR1));
  258. RESI2=100. * (ABS((M2-MR2)/MR2));
  259.  
  260. SAUT PAGE ; SAUT 2 LIGN ;
  261.  
  262. MESS 'INCREMENT ELASTIQUE Theorique : M1= 805 KN ' ;
  263. MESS 'INCREMENT ELASTIQUE Calcule : M1= 'M1 'KN' ;
  264. MESS ' SOIT UN ECART DE : ' RESI1 '%' ;
  265. MESS 'INCREMENT PLASTIQUE Theorique : M2= 1074 KN ' ;
  266. MESS 'INCREMENT PLASTIQUE Calcule : M2= 'M2 'KN' ;
  267. MESS ' SOIT UN ECART DE : ' RESI2 '%' ;
  268. *
  269. TEMPS ;
  270. * CODE FONCTIONNEMENT
  271. SI((RESI1 &lt;EG 1.5) ET (RESI2 &lt;EG 1.5));
  272. ERRE 0;
  273. SINO;
  274. ERRE 5;
  275. FINSI;
  276.  
  277. FIN ;
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales