Exemples de jeux de données Cast3M

* fichier :  phase2d_02.dgibi
************************************************************************
************************************************************************
graph= FAUX;
*
************************************************************************
*  Cas test :  phase2d_02.dgibi
*  Type     :  Verification & Validation analytique
*
*  Barreau ayant un materiau constant et un changement de phase a 100°C
*  Il est chauffe uniformement sur la surface S1
*  Le test consiste a s'assurer que la chaleur injectee est bien egale
*  a la chaleur specifique accumulee plus la chaleur de changement de 
*  phase
*
************************************************************************
 
OPTI DIME 2 ELEM QUA4 TRAC 'PSC';
 
DT = 20. ;
 
P1 = (0. 0.) ;
P2 = P1 'PLUS' (0. 0.01) ;
 
L1 = 'DROI' 1 P1 P2 ;
L2 = L1 'PLUS' (0.1 0.) ;
L3 = L2 'PLUS' (0.1 0.) ;
 
P3 = POIN 1 L3 ;
 
NBEX = 10 ;
S1   = L1 'REGL' NBEX L2 ;
S2   = L2 'REGL' NBEX L3 ;
STOT = S1 'ET' S2 ;
 
rho1 = 1000. ;
C1   = 4180. ;
K1   = 100.  ;
QL1  = rho1*2257000. ;
 
MOD1  = MODE STOT 'THERMIQUE';
MOD2  = MODE STOT 'CHANGEMENT_PHASE' 'PARFAIT' 'INCO' 'T' 'Q';
MAT1  = MATE MOD1 'RHO' rho1 'C' C1 'K' K1 ;
MAT2  = MATE MOD2 'DUAL' QL1 'PRIM' 100. ;
 
Tps_fin = 5000.D0 ;
 
Qsour = 1D6 ;
CHA1  = CHAR 'Q' ('SOUR' MOD1 Qsour S1) (EVOL 'MANU' 'TEMP' (PROG 0. Tps_fin) 'AMPL' (PROG 1. 1.));
 
TAB1 = 'TABL';
TAB1.'TEMPS_CALCULES'     ='PROG' 0. 'PAS' 10. (Tps_fin / 2.D0) 'PAS' 150. Tps_fin ;
TAB1.'MODELE'             = MOD1 ET MOD2 ;
TAB1.'CARACTERISTIQUES'   = MAT1 ET MAT2 ;
TAB1.'CHARGEMENT'         = CHA1 ;
TAB1.'PRECISION'          = 1.D-8 ;
 
PASAPAS TAB1;
 
EVTP0 = EVOL 'ROUG' 'TEMP' TAB1 'TEMPERATURES' 'T' P1 ;
SI GRAPH ;
  DESS EVTP0 'XBOR' 0. Tps_fin 'YBOR' 0. 200. ;
FINS;
 
LIG_PROI = DROI 1000 P1 P3;
 
DIM1 = DIME TAB1.'TEMPS' ;
REPE SURI DIM1 ;
  ii = &SURI;
  PROPi = TAB1.'PROPORTIONS_PHASE'. (ii - 1) ;
  PROIi = PROI LIG_PROI PROPi;
  EVOLi = EVOL 'CHPO' PROIi 'PPHA'  LIG_PROI;
FIN SURI;
 
SI GRAPH ;
 'TRAC' PROPi MOD2 ;
 'DESS' EVOLi;
'FINS';
 
* Bilan de chaleur
  T_0 ='CHAN' 'CHAM' ('EXCO' TAB1.'TEMPERATURES'. 0         'T' ) MOD2 'STRESSES' 'CARACTERISTIQUES' ;
  T_0 ='NOMC' T_0 'SCAL';
  T_1 ='CHAN' 'CHAM' ('EXCO' TAB1.'TEMPERATURES'.(DIM1 - 1) 'T' ) MOD2 'STRESSES' 'CARACTERISTIQUES' ;
  T_1 ='NOMC' T_1 'SCAL';
 
  ENE1='INTG' (rho1* C1 * (T_1 - T_0)) MOD2 ;
 
* Chaleur Latente consommee
  Prop0='CHAN' 'STRESSES' TAB1.'PROPORTIONS_PHASE'. 0         MOD2 'CARACTERISTIQUES' ;
  Prop0='NOMC'  Prop0 'SCAL' ;
  Prop1='CHAN' 'STRESSES' TAB1.'PROPORTIONS_PHASE'.(DIM1 - 1) MOD2 'CARACTERISTIQUES' ;
  Prop1='NOMC'  Prop1 'SCAL' ;
  ENE2 ='INTG' (QL1 * (Prop1 - Prop0)) MOD2 ;
  Pfin = ENE2/('INTG' (QL1 * (Prop1 ** 0)) MOD2) * 100. ;
 
* Integration temporelle
  ENE3 =('MAXI' ('RESU' ('TIRE' CHA1 0.D0))) * (Tps_fin - 0.D0) ;
 
 'OPTI' ECHO 0;
 'MESS' 'Energie calorifique reguliere :' ENE1              ;
 'MESS' 'Energie de chaleur latente    :' ENE2 '|' Pfin '%' ;
 'MESS' 'Energie totale                :'(ENE1+ENE2)        ;
 'MESS' 'Energie injectee              :' ENE3              ;
 
  ERR_ABS ='ABS' (ENE3 - ENE1 - ENE2) ;
  ERR_REL = ERR_ABS / ENE3 * 100.     ;
 'MESS' 'Erreur de bilan               :' ERR_ABS '|' ERR_REL '%' ;
 
 'OPTI' ECHO 1 ;
FIN;